configure.in.pre

   1 #
   2 #  configure.in.pre
   3 #
   4 #  Author: Pekka Riikonen <priikone@silcnet.org>
   5 #
   6 #  Copyright (C) 2000 - 2002 Pekka Riikonen
   7 #
   8 #  This program is free software; you can redistribute it and/or modify
   9 #  it under the terms of the GNU General Public License as published by
  10 #  the Free Software Foundation; either version 2 of the License, or
  11 #  (at your option) any later version.
  12 #
  13 #  This program is distributed in the hope that it will be useful,
  14 #  but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 #  GNU General Public License for more details.
  17 #
  18
  19 AC_INIT(includes/silcversion.h)
  20
  21 # Put here any platform specific stuff
  22 #
  23 AC_CANONICAL_SYSTEM
  24 case "$target" in
  25   *-*-freebsd*)
  26     check_threads=true
  27     ;;
  28   *-*-*bsd*)
  29     check_threads=false
  30     ;;
  31   *)
  32     check_threads=true
  33     ;;
  34 esac
  35
  36 # ./prepare script will automatically put the correct version. Do not edit!
  37 #
  38 AM_INIT_AUTOMAKE(SILC_PACKAGE, SILC_VERSION)
  39 AC_PREREQ(2.52)
  40 AC_CONFIG_HEADERS(includes/silcdefs.h)
  41
  42 AC_PROG_CC
  43 AC_C_INLINE
  44 AC_C_CONST
  45
  46 AC_PROG_LN_S
  47 AC_SUBST(LN_S)
  48
  49 # Distribution definition. ./prepare will automatically add here a correct
  50 # value. Do not edit!
  51 #
  52 silc_dist=SILC_PACKAGE
  53 SILC_DIST_SUBDIRS="SILC_DISTRIBUTION_SUBDIRS"
  54 AC_DEFINE(SILC_DIST_DEFINE)
  55
  56 # XXX
  57 # Compiler flags
  58 #
  59 if test "$GCC"; then
  60   CFLAGS="-Wall -finline-functions $CFLAGS"
  61 fi
  62
  63 # Program checking
  64 #
  65 AC_PROG_INSTALL
  66 AC_PROG_RANLIB
  67 AC_PROG_MAKE_SET
  68 AC_PROG_LIBTOOL
  69 AC_PATH_PROG(sedpath, sed)
  70
  71 # Header checking
  72 #
  73 AC_HEADER_STDC
  74 AC_HEADER_TIME
  75 AC_HEADER_STAT
  76
  77 # More header checking
  78 #
  79 AC_CHECK_HEADERS(unistd.h string.h getopt.h errno.h fcntl.h assert.h)
  80 AC_CHECK_HEADERS(sys/types.h sys/stat.h sys/time.h stddef.h)
  81 AC_CHECK_HEADERS(netinet/in.h netinet/tcp.h xti.h netdb.h)
  82 AC_CHECK_HEADERS(pwd.h grp.h termcap.h paths.h)
  83 AC_CHECK_HEADERS(ncurses.h signal.h ctype.h utime.h)
  84 AC_CHECK_HEADERS(arpa/inet.h sys/mman.h limits.h termios.h locale.h langinfo.h)
  85
  86 # Data type checking
  87 #
  88 AC_TYPE_SIGNAL
  89 AC_TYPE_SIZE_T
  90 AC_TYPE_MODE_T
  91 AC_TYPE_UID_T
  92 AC_TYPE_PID_T
  93
  94 AC_CHECK_SIZEOF(long long, 0)
  95 AC_SUBST(SILC_SIZEOF_LONG_LONG, $ac_cv_sizeof_long_long)
  96 AC_CHECK_SIZEOF(long, 0)
  97 AC_SUBST(SILC_SIZEOF_LONG, $ac_cv_sizeof_long)
  98 AC_CHECK_SIZEOF(int, 0)
  99 AC_SUBST(SILC_SIZEOF_INT, $ac_cv_sizeof_int)
 100 AC_CHECK_SIZEOF(short, 0)
 101 AC_SUBST(SILC_SIZEOF_SHORT, $ac_cv_sizeof_short)
 102 AC_CHECK_SIZEOF(char, 0)
 103 AC_SUBST(SILC_SIZEOF_CHAR, $ac_cv_sizeof_char)
 104 AC_CHECK_SIZEOF(void *, 0)
 105 AC_SUBST(SILC_SIZEOF_VOID_P, $ac_cv_sizeof_void_p)
 106
 107 # Function and library checking
 108 #
 109 AC_CHECK_FUNC(gethostbyname, [],
 110   [
 111     AC_CHECK_LIB(nsl, gethostbyname, LIBS="$LIBS -lnsl")
 112     AC_CHECK_FUNC(res_gethostbyname, [],
 113        AC_CHECK_LIB(resolv, res_gethostbyname, LIBS="$LIBS -lresolv")
 114     )
 115   ])
 116 AC_CHECK_FUNC(socket, [],
 117   AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
 118 )
 119 AC_CHECK_FUNCS(gethostname gethostbyaddr getservbyname getservbyport)
 120 AC_CHECK_FUNCS(select listen bind shutdown close connect setsockopt)
 121 AC_CHECK_FUNCS(time ctime utime gettimeofday)
 122 AC_CHECK_FUNCS(chmod fcntl stat fstat getenv putenv strerror)
 123 AC_CHECK_FUNCS(getpid getgid getsid getpgid getpgrp getuid)
 124 AC_CHECK_FUNCS(setgroups initgroups nl_langinfo)
 125 AC_CHECK_FUNCS(strchr strstr strcpy strncpy memcpy memset memmove)
 126
 127 # SIM support checking
 128 # XXX These needs to be changed as more supported platforms appear.
 129 # XXX This probably needs to be made platform dependant check.
 130 #
 131 sim_support=false
 132 AC_MSG_CHECKING(for SIM support)
 133 AC_MSG_RESULT()
 134 AC_CHECK_HEADERS(dlfcn.h,
 135   AC_CHECK_LIB(dl, dlopen,
 136     [
 137       AC_DEFINE(SILC_SIM)
 138       sim_support=true
 139       LIBS="$LIBS -ldl"
 140     ],
 141     [
 142       AC_CHECK_LIB(c, dlopen,
 143         [
 144           AC_DEFINE(SILC_SIM)
 145           sim_support=true
 146         ])
 147     ])
 148   )
 149
 150 AM_CONDITIONAL(SILC_SIM, test x$sim_support = xtrue)
 151 if test x$sim_support = xtrue; then
 152   AC_MSG_RESULT(Enabled SIM support.)
 153 else
 154   AC_MSG_RESULT(No SIM support found.)
 155 fi
 156
 157 # lib/contrib conditionals
 158 #
 159 AC_CHECK_HEADER(regex.h, have_regex=1, have_regex=0)
 160 AM_CONDITIONAL(HAVE_REGEX, test x$have_regex = x1)
 161 AC_CHECK_FUNC(getopt_long, have_getopt_long=1, have_getopt_long=0)
 162 AM_CONDITIONAL(HAVE_GETOPT_LONG, test x$have_getopt_long = x1)
 163
 164
 165 ##
 166 ##  Enable/disable checking
 167 ##
 168
 169 # IPv6 support
 170 #
 171 AC_MSG_CHECKING(whether to enable IPv6 support)
 172 AC_ARG_ENABLE(ipv6,
 173   [  --enable-ipv6           enable IPv6 support],
 174   [
 175     case "${enableval}" in
 176       yes)
 177         want_ipv6=true
 178         check_ipv6=false
 179         summary_ipv6="yes"
 180         AC_DEFINE(HAVE_IPV6)
 181         AC_MSG_RESULT(yes)
 182         ;;
 183       *)
 184         want_ipv6=false
 185         check_ipv6=false
 186         summary_ipv6="no"
 187         AC_MSG_RESULT(no)
 188         ;;
 189     esac
 190   ],
 191     check_ipv6=true
 192   )
 193
 194 if test x$check_ipv6 = xtrue; then
 195   summary_ipv6="no"
 196   AC_TRY_COMPILE(
 197     [
 198       #ifdef HAVE_SYS_TYPES_H
 199       #include <sys/types.h>
 200       #endif
 201       #ifdef HAVE_NETINET_TCP_H
 202       #include <netinet/tcp.h>
 203       #endif
 204       #ifdef HAVE_NETDB_H
 205       #include <netdb.h>
 206       #endif
 207       #include <sys/socket.h>
 208       #ifdef HAVE_NETINET_IN_H
 209       #include <netinet/in.h>
 210       #endif
 211     ],
 212     [
 213       struct sockaddr_in6 sin6;
 214       int family = AF_INET6;
 215     ],
 216     [
 217       AC_DEFINE(HAVE_IPV6)
 218       AC_MSG_RESULT(yes)
 219       summary_ipv6="yes"
 220     ],
 221       AC_MSG_RESULT(no)
 222     )
 223 fi
 224
 225 # Debug checking
 226 #
 227 AC_MSG_CHECKING(whether to enable debugging)
 228 summary_debug="no"
 229 AC_ARG_ENABLE(debug,
 230   [  --enable-debug          enable debugging],
 231   [
 232     case "${enableval}" in
 233       yes)
 234         AC_MSG_RESULT(yes)
 235         AC_DEFINE(SILC_DEBUG)
 236         CFLAGS="-O -g $CFLAGS"
 237         summary_debug="yes"
 238         ;;
 239       *)
 240         AC_MSG_RESULT(no)
 241         CFLAGS="-O2 -g $CFLAGS"
 242         ;;
 243     esac
 244   ],
 245   [
 246     CFLAGS="-O2 -g $CFLAGS"
 247     AC_MSG_RESULT(no)
 248   ])
 249
 250 # Stack trace checking
 251 #
 252 AC_MSG_CHECKING(whether to enable stack tracing)
 253 summary_stacktrace="no"
 254 AC_ARG_ENABLE(stack-trace,
 255   [  --enable-stack-trace    enable memory stack trace],
 256   [
 257     case "${enableval}" in
 258     yes)
 259       AC_MSG_RESULT(yes)
 260       AC_DEFINE(SILC_STACKTRACE)
 261       summary_stacktrace="yes"
 262       ;;
 263     *)
 264       AC_MSG_RESULT(no)
 265       ;;
 266     esac
 267   ],
 268     AC_MSG_RESULT(no)
 269   )
 270
 271 # Disable all assembler optimizations
 272 #
 273 AC_MSG_CHECKING(whether to enable assembler optimizations)
 274 summary_asm="no"
 275 AC_ARG_ENABLE(asm,
 276   [  --disable-asm           do not use assembler optimizations],
 277   [
 278     AC_MSG_RESULT(no)
 279   ],
 280   [
 281     AC_MSG_RESULT(yes)
 282     summary_asm="yes"
 283   ])
 284
 285
 286 ##
 287 ##  Installation
 288 ##
 289
 290 # Default installation destination
 291 #
 292 AC_PREFIX_DEFAULT(/usr/local/silc)
 293 if test "x$prefix" != xNONE; then
 294   silc_prefix="$prefix"
 295 else
 296   silc_prefix="$ac_default_prefix"
 297 fi
 298
 299 # etc directory
 300 #
 301 if test "x$sysconfdir" != 'x${prefix}/etc'; then
 302   ETCDIR="$sysconfdir"
 303 else
 304   ETCDIR="$silc_prefix/etc"
 305 fi
 306
 307 AC_ARG_WITH(etcdir,
 308   [[  --with-etcdir=DIR       directory for system files [/etc/silc]]],
 309   [
 310     case "$withval" in
 311       no|yes)
 312         ;;
 313       *)
 314         ETCDIR="$withval"
 315         ;;
 316     esac
 317   ])
 318 AC_SUBST(ETCDIR)
 319 AC_DEFINE_UNQUOTED(SILC_ETCDIR, "$ETCDIR")
 320
 321 # help directory
 322 #
 323 HELPDIR="$silc_prefix/help"
 324 AC_ARG_WITH(helpdir,
 325   [[  --with-helpdir=DIR      directory for SILC help files [PREFIX/help]]],
 326   [
 327     case "$withval" in
 328       no|yes)
 329         ;;
 330       *)
 331        HELPDIR="$withval"
 332        ;;
 333     esac
 334   ])
 335 AC_SUBST(HELPDIR)
 336 AC_DEFINE_UNQUOTED(SILC_HELPDIR, "$HELPDIR")
 337
 338 # doc directory
 339 #
 340 DOCDIR="$silc_prefix/doc"
 341 AC_ARG_WITH(docdir,
 342   [[  --with-docdir=DIR       directory for SILC documentation [PREFIX/doc]]],
 343   [
 344     case "$withval" in
 345       no|yes)
 346         ;;
 347       *)
 348         DOCDIR="$withval"
 349         ;;
 350     esac
 351   ])
 352 AC_SUBST(DOCDIR)
 353 AC_DEFINE_UNQUOTED(SILC_DOCDIR, "$DOCDIR")
 354
 355 # SIM modules directory
 356 #
 357 MODULESDIR="$silc_prefix/modules"
 358 AC_ARG_WITH(simdir,
 359   [[  --with-simdir=DIR       directory for SIM modules [PREFIX/modules]]],
 360   [
 361     case "$withval" in
 362       no|yes)
 363         ;;
 364       *)
 365         MODULESDIR="$withval"
 366         ;;
 367     esac
 368   ])
 369 AC_SUBST(MODULESDIR)
 370 AC_DEFINE_UNQUOTED(SILC_MODULESDIR, "$MODULESDIR")
 371
 372 # Logs directory
 373 #
 374 LOGSDIR="$silc_prefix/logs"
 375 AC_ARG_WITH(logsdir,
 376   [[  --with-logsdir=DIR      directory for SILC Server logs [PREFIX/logs]]],
 377   [
 378     case "$withval" in
 379       no|yes)
 380         ;;
 381       *)
 382         LOGSDIR="$withval"
 383         ;;
 384     esac
 385   ])
 386 AC_SUBST(LOGSDIR)
 387 AC_DEFINE_UNQUOTED(SILC_LOGSDIR, "$LOGSDIR")
 388
 389 # Manual directory
 390 #
 391 MANDIR="$silc_prefix/man"
 392 AC_ARG_WITH(mandir,
 393   [[  --with-mandir=DIR       directory for SILC manual pages [PREFIX/man]]],
 394   [
 395     case "$withval" in
 396       no|yes)
 397         ;;
 398       *)
 399         MANDIR="$withval"
 400         ;;
 401     esac
 402   ])
 403 AC_SUBST(MANDIR)
 404 AC_DEFINE_UNQUOTED(SILC_MANDIR, "$MANDIR")
 405
 406 # silcd config file checking
 407 #
 408 summary_silcd_configfile="/etc/silc/silcd.conf"
 409 AC_ARG_WITH(silcd-config-file,
 410   [[  --with-silcd-config-file=FILE  use FILE as default configuration file
 411                                  for SILC Server [/etc/silc/silcd.conf]]],
 412     AC_DEFINE_UNQUOTED(SILC_SERVER_CONFIG_FILE, "$withval")
 413     summary_silcd_configfile="$withval"
 414   )
 415
 416 # silcd pid file checking
 417 #
 418 if test "x$localstatedir" != 'x${prefix}/var'; then
 419   PIDFILE="$localstatedir/silcd.pid"
 420 else
 421   PIDFILE="$silc_prefix/var/silcd.pid"
 422 fi
 423
 424 AC_ARG_WITH(silcd-pid-file,
 425   [[  --with-silcd-pid-file=FILE     use FILE as default pid file for SILC
 426                                  Server [/var/run/silcd.pid]]],
 427   [
 428     case "$withval" in
 429       no|yes)
 430         ;;
 431       *)
 432         PIDFILE="$withval"
 433         ;;
 434     esac
 435   ])
 436 AC_SUBST(PIDFILE)
 437
 438
 439 ##
 440 ##  With/without checkings
 441 ##
 442
 443 # SOCKS4 support checking
 444 #
 445 SAVELIBS="$LIBS"
 446 SAVECFLAGS="$CFLAGS"
 447 SAVELDFLAGS="$LDFLAGS"
 448 AC_MSG_CHECKING(whether to support SOCKS4)
 449 AC_ARG_WITH(socks4,
 450   [[  --with-socks4[=DIR]     with SOCKS4 support [search in DIR/lib and DIR/include]]],
 451   [
 452     case "$withval" in
 453       no)
 454         AC_MSG_RESULT(no)
 455         ;;
 456       *)
 457         AC_MSG_RESULT(yes)
 458         socks=4
 459
 460         if test -d "$withval/include"; then
 461           CFLAGS="$CFLAGS -I$withval/include"
 462         fi
 463         if test -d "$withval/lib"; then
 464           LDFLAGS="$LDFLAGS -L$withval/lib"
 465         fi
 466
 467         LIBS="-lsocks $LIBS"
 468         ;;
 469     esac
 470
 471     AC_TRY_LINK([],
 472       [
 473         Rconnect();
 474       ], [],
 475       [
 476         AC_MSG_ERROR(Could not find SOCKS4 library.)
 477         LIBS="$SAVELIBS"
 478         CFLAGS="$SAVECFLAGS"
 479         LDFLAGS="$SAVELDFLAGS"
 480       ])
 481   ],
 482     AC_MSG_RESULT(no)
 483   )
 484
 485 # SOCKS5 support checking
 486 #
 487 SAVELIBS="$LIBS"
 488 SAVECFLAGS="$CFLAGS"
 489 SAVELDFLAGS="$LDFLAGS"
 490 AC_MSG_CHECKING(whether to support SOCKS5)
 491 AC_ARG_WITH(socks5,
 492   [[  --with-socks5[=DIR]     with SOCKS5 support [search in DIR/lib and DIR/include]]],
 493   [
 494     case "$withval" in
 495       no)
 496         AC_MSG_RESULT(no)
 497         ;;
 498       *)
 499         AC_MSG_RESULT(yes)
 500         socks=5
 501
 502         if test -d "$withval/include"; then
 503           CFLAGS="$CFLAGS -I$withval/include"
 504         fi
 505         if test -d "$withval/lib"; then
 506           LDFLAGS="$LDFLAGS -L$withval/lib"
 507         fi
 508
 509         LIBS="-lsocks5 $LIBS"
 510         ;;
 511     esac
 512
 513     AC_TRY_LINK([],
 514       [
 515         SOCKSconnect();
 516       ], [],
 517       [
 518         AC_MSG_ERROR(Could not find SOCKS5 library.)
 519         LIBS="$SAVELIBS"
 520         CFLAGS="$SAVECFLAGS"
 521         LDFLAGS="$SAVELDFLAGS"
 522       ])
 523   ],
 524     AC_MSG_RESULT(no)
 525   )
 526
 527 if test "x$socks" = "x4"; then
 528   AC_DEFINE(SOCKS)
 529   CFLAGS="$CFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 530 fi
 531
 532 if test "x$socks" = "x5"; then
 533   AC_DEFINE(SOCKS)
 534   AC_DEFINE(SOCKS5)
 535   AC_DEFINE(Rconnect, SOCKSconnect)
 536   AC_DEFINE(Rgetsockname, SOCKSgetsockname)
 537   AC_DEFINE(Rgetpeername, SOCKSgetpeername)
 538   AC_DEFINE(Rbind, SOCKSbind)
 539   AC_DEFINE(Raccept, SOCKSaccept)
 540   AC_DEFINE(Rlisten, SOCKSlisten)
 541   AC_DEFINE(Rselect, SOCKSselect)
 542   AC_DEFINE(Rrecvfrom, SOCKSrecvfrom)
 543   AC_DEFINE(Rsendto, SOCKSsendto)
 544   AC_DEFINE(Rrecv, SOCKSrecv)
 545   AC_DEFINE(Rsend, SOCKSsend)
 546   AC_DEFINE(Rread, SOCKSread)
 547   AC_DEFINE(Rwrite, SOCKSwrite)
 548   AC_DEFINE(Rrresvport, SOCKSrresvport)
 549   AC_DEFINE(Rshutdown, SOCKSshutdown)
 550   AC_DEFINE(Rlisten, SOCKSlisten)
 551   AC_DEFINE(Rclose, SOCKSclose)
 552   AC_DEFINE(Rdup, SOCKSdup)
 553   AC_DEFINE(Rdup2, SOCKSdup2)
 554   AC_DEFINE(Rfclose, SOCKSfclose)
 555   AC_DEFINE(Rgethostbyname, SOCKSgethostbyname)
 556 fi
 557
 558 # MP library checking. First check whether user wants to use GMP and use
 559 # it if found. If not or not defined then compile the MPI library in the
 560 # source tree.
 561 #
 562 mp_gmp=false
 563 SAVELIBS="$LIBS"
 564 SAVECFLAGS="$CFLAGS"
 565 SAVELDFLAGS="$LDFLAGS"
 566 AC_MSG_CHECKING(whether to search for GMP)
 567 AC_ARG_WITH(gmp,
 568   [[  --with-gmp[=DIR]        use GMP instead of MPI [search in DIR/lib and DIR/include]]],
 569   [
 570     case "$withval" in
 571       no)
 572         AC_MSG_RESULT(no)
 573         ;;
 574       *)
 575         AC_MSG_RESULT(yes)
 576
 577         if test -d "$withval/include"; then
 578           CFLAGS="$CFLAGS -I$withval/include"
 579         fi
 580         if test -d "$withval/lib"; then
 581           LDFLAGS="$LDFLAGS -L$withval/lib"
 582         fi
 583
 584         LIBS="-lgmp $LIBS"
 585         ;;
 586     esac
 587
 588     AC_CHECK_LIB(gmp, __gmpz_init,
 589       [
 590         mp_gmp=true
 591         AC_DEFINE(SILC_MP_GMP)
 592         AC_MSG_RESULT(Using GMP as a MP library.)
 593       ],
 594       [
 595         LIBS="$SAVELIBS"
 596         CFLAGS="$SAVECFLAGS"
 597         LDFLAGS="$SAVELDFLAGS"
 598       ])
 599   ],
 600     AC_MSG_RESULT(no)
 601   )
 602
 603 AM_CONDITIONAL(SILC_MP_GMP, test x$mp_gmp = xtrue)
 604 AM_CONDITIONAL(SILC_MP_NSS_MPI, test x$mp_gmp = xfalse)
 605 if test x$mp_gmp = xfalse; then
 606   AC_DEFINE(SILC_MP_NSS_MPI)
 607   AC_MSG_RESULT(Using NSS MPI as a MP library.)
 608 fi
 609
 610 # iconv support
 611 #
 612 check_iconv=true
 613 has_iconv=false
 614 SAVELIBS="$LIBS"
 615 SAVECFLAGS="$CFLAGS"
 616 SAVELDFLAGS="$LDFLAGS"
 617 SAVECPPFLAGS="$CPPFLAGS"
 618 AC_MSG_CHECKING(whether to implicit search for libiconv)
 619 AC_ARG_WITH(iconv,
 620   [[  --with-iconv[=DIR]      use libiconv [search in DIR/include and DIR/lib]]],
 621   [
 622     case "${withval}" in
 623       no)
 624         AC_MSG_RESULT(no)
 625
 626         AC_CHECK_HEADERS(iconv.h, AC_CHECK_FUNC(iconv, has_iconv=true))
 627         check_iconv=false
 628         ;;
 629       *)
 630         AC_MSG_RESULT(yes)
 631
 632         if test -d $withval/include; then
 633           CPPFLAGS="$CPPFLAGS -I$withval/include"
 634           CFLAGS="$CFLAGS -I$withval/include"
 635         fi
 636         if test -d $withval/lib; then
 637           LDFLAGS="$LDFLAGS -L$withval/lib"
 638         fi
 639     esac
 640   ],
 641   [
 642     AC_MSG_RESULT(no)
 643
 644     AC_CHECK_HEADERS(iconv.h, AC_CHECK_FUNCS(iconv,
 645                                 [
 646                                   has_iconv=true
 647                                   check_iconv=false
 648                                  ]))
 649   ])
 650
 651 if test x$check_iconv = xtrue; then
 652   AC_MSG_RESULT(starting search...)
 653
 654   # XXX
 655   unset ac_cv_header__iconv_h_ ac_cv_header_iconv_h || true
 656
 657   AC_CHECK_HEADERS(iconv.h,
 658     [
 659       LIBS="$LIBS -liconv"
 660       AC_MSG_CHECKING(for iconv in -liconv)
 661       AC_TRY_LINK(
 662         [
 663           #include <stdlib.h>
 664           #include <iconv.h>
 665         ],
 666         [
 667           iconv_t cd = iconv_open("", "");
 668           iconv(cd, NULL, NULL, NULL, NULL);
 669           iconv_close(cd);
 670         ],
 671         [
 672           echo "yes"
 673           AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 674           has_iconv=true
 675           check_iconv=false
 676         ],
 677         [
 678           echo "no"
 679           LIBS="$SAVELIBS"
 680           CFLAGS="$SAVECFLAGS"
 681           LDFLAGS="$SAVELDFLAGS"
 682           CPPFLAGS="$SAVECPPFLAGS"
 683         ])
 684      ])
 685 fi
 686
 687 if test x$check_iconv = xtrue; then
 688   # search for iconv library..
 689   SAVELIBS="$LIBS"
 690   SAVECFLAGS="$CFLAGS"
 691   SAVELDFLAGS="$LDFLAGS"
 692   SAVECPPFLAGS="$CPPFLAGS"
 693
 694   for dir in `echo "/usr/local /usr/pkg /usr/contrib"`; do
 695     if test x$has_iconv = xfalse; then
 696       AC_MSG_RESULT(searching in $dir...)
 697
 698       if test -d $dir/include; then
 699         CPPFLAGS="$CPPFLAGS -I$dir/include"
 700         CFLAGS="$CFLAGS -I$dir/include"
 701       fi
 702       if test -d $dir/lib; then
 703         LDFLAGS="$LDFLAGS -L$dir/lib"
 704       fi
 705
 706       # XXX
 707       unset ac_cv_header__iconv_h_ ac_cv_header_iconv_h || true
 708
 709       AC_CHECK_HEADERS(iconv.h,
 710         [
 711           LIBS="$LIBS -liconv"
 712           AC_MSG_CHECKING(for iconv in -liconv)
 713           AC_TRY_LINK(
 714             [
 715               #include <stdlib.h>
 716               #include <iconv.h>
 717             ],
 718             [
 719               iconv_t cd = iconv_open("", "");
 720               iconv(cd, NULL, NULL, NULL, NULL);
 721               iconv_close(cd);
 722             ],
 723             [
 724               echo "yes"
 725               has_iconv=true
 726               AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 727             ],
 728             [
 729               echo "no"
 730               has_iconv=false
 731
 732               LIBS="$SAVELIBS"
 733               CFLAGS="$SAVECFLAGS"
 734               LDFLAGS="$SAVELDFLAGS"
 735               CPPFLAGS="$SAVECPPFLAGS"
 736             ])
 737          ],
 738          [
 739            CFLAGS="$SAVECFLAGS"
 740            LDFLAGS="$SAVELDFLAGS"
 741            CPPFLAGS="$SAVECPPFLAGS"
 742          ])
 743       fi
 744     done
 745 fi
 746
 747 if test x$has_iconv = xtrue; then
 748   # (1) Some implementations of iconv won't convert from UTF-8 to UTF-8.
 749   # (2) In glibc-2.1.2 and earlier there is a bug that messes up ob and
 750   #     obl when args 2 and 3 are 0 (fixed in glibc-2.1.3).
 751   #
 752   AC_CACHE_CHECK([whether this iconv is good enough], ac_iconv_good,
 753     AC_TRY_RUN(
 754       [
 755         #include <iconv.h>
 756         int main() {
 757           iconv_t cd;
 758         changequote(, )dnl
 759           char buf[4];
 760         changequote([, ])dnl
 761           char *ob;
 762           size_t obl;
 763           ob = buf, obl = sizeof(buf);
 764           return ((cd = iconv_open("UTF-8", "UTF-8")) != (iconv_t)(-1) &&
 765                  (iconv(cd, 0, 0, &ob, &obl) ||
 766                  !(ob == buf && obl == sizeof(buf)) ||
 767                  iconv_close(cd)));
 768         }
 769       ],
 770       [
 771         ac_iconv_good=yes
 772       ],
 773       [
 774         ac_iconv_good=no
 775       ],
 776       [
 777         ac_iconv_good=yes
 778       ])
 779     )
 780
 781   if test x$ac_iconv_good = xno; then
 782     AC_MSG_RESULT(Try using libiconv instead.)
 783   fi
 784 fi
 785
 786 # POSIX threads support
 787 #
 788 has_threads=false
 789 AC_MSG_CHECKING(whether to search for POSIX threads)
 790 AC_ARG_WITH(pthreads,
 791   [[  --with-pthreads[=DIR]   use POSIX threads [search in DIR/include and DIR/lib]]],
 792   [
 793     case "${withval}" in
 794       no)
 795         check_threads=false
 796         ;;
 797       *)
 798         if test -d $withval/include; then
 799           CPPFLAGS="$CPPFLAGS -I$withval/include"
 800           CFLAGS="$CFLAGS -I$withval/include"
 801         fi
 802         if test -d $withval/lib; then
 803           LDFLAGS="$LDFLAGS -L$withval/lib"
 804         fi
 805
 806         check_threads=true
 807         ;;
 808     esac
 809   ])
 810
 811 if test x$check_threads = xtrue; then
 812   AC_MSG_RESULT(yes)
 813   AC_CHECK_HEADERS(pthread.h,
 814     [
 815       SAVE_LIBS="$LIBS"
 816       LIBS="$LIBS -lpthread"
 817       AC_CHECK_LIB(pthread, pthread_attr_init, has_threads=true,
 818         [
 819           # FreeBSD
 820           case "${target}" in
 821             *-*-freebsd*)
 822               LIBS="$SAVE_LIBS -pthread"
 823               AC_CHECK_LIB(c_r, pthread_attr_init, has_threads=true)
 824               ;;
 825           esac
 826         ])
 827     ],
 828     [
 829       # search for pthread library..
 830       SAVE_CPPFLAGS="$CPPFLAGS"
 831       SAVE_CFLAGS="$CFLAGS"
 832       SAVE_LDFLAGS="$LDFLAGS"
 833
 834       for dir in `echo "/usr/local /usr/pkg /usr/contrib /usr/pkg/pthreads /usr/local/pthreads"`; do
 835         if test x$has_threads = xfalse; then
 836           AC_MSG_RESULT(searching in $dir...)
 837
 838           CPPFLAGS="$SAVE_CPPFLAGS"
 839           CFLAGS="$SAVE_CFLAGS"
 840           LDFLAGS="$SAVE_LDFLAGS"
 841
 842           if test -d $dir/include; then
 843             CPPFLAGS="$CPPFLAGS -I$dir/include"
 844             CFLAGS="$CFLAGS -I$dir/include"
 845           fi
 846           if test -d $dir/lib; then
 847             LDFLAGS="$LDFLAGS -L$dir/lib"
 848           fi
 849
 850           # XXX
 851           unset ac_cv_header__pthread_h_ ac_cv_header_pthread_h || true
 852
 853           AC_CHECK_HEADERS(pthread.h,
 854             [
 855               LIBS="$LIBS -lpthread"
 856               AC_CHECK_LIB(pthread, pthread_attr_init, has_threads=true,
 857                                                        has_threads=false)
 858             ])
 859         fi
 860       done
 861     ])
 862 else
 863   AC_MSG_RESULT(no)
 864   has_threads=false
 865 fi
 866
 867 AM_CONDITIONAL(SILC_THREADS, test x$has_threads = xtrue)
 868 if test x$has_threads = xtrue; then
 869   CFLAGS="$CFLAGS -D_REENTRANT"
 870
 871   # XXX possibly incomplete
 872   case "${target}" in
 873     *-*-aix*)
 874       CFLAGS="$CFLAGS -D_THREAD_SAFE"
 875       if test x"$GCC" = xyes; then
 876         CFLAGS="$CFLAGS -mthreads"
 877       fi
 878       ;;
 879     *-*-freebsd*)
 880       CFLAGS="$CFLAGS -D_THREAD_SAFE"
 881       ;;
 882     *-*-sysv5uw7*)  # UnixWare 7
 883       if test "$GCC" != "yes"; then
 884         CFLAGS="$CFLAGS -Kthread"
 885       else
 886         CFLAGS="$CFLAGS -pthread"
 887       fi
 888       ;;
 889     *-dg-dgux*)  # DG/UX
 890       CFLAGS="$CFLAGS -D_POSIX4A_DRAFT10_SOURCE"
 891       ;;
 892    esac
 893
 894   AC_CHECK_FUNC(pthread_create)
 895   AC_DEFINE(SILC_HAVE_PTHREAD)
 896   AC_DEFINE(SILC_THREADS)
 897 fi
 898
 899 # Native WIN32 compilation under cygwin
 900 #
 901 AC_MSG_CHECKING(whether to compile native WIN32 code)
 902 AC_ARG_WITH(win32,
 903   [  --with-win32            compile native WIN32 code (-mno-cygwin)],
 904   [
 905     AC_MSG_RESULT(yes)
 906     AC_DEFINE(SILC_WIN32)
 907     win32_support=true
 908     CFLAGS="-mno-cygwin $CFLAGS"
 909     LIBS="$LIBS -lwsock32"
 910   ],
 911   [
 912     AC_MSG_RESULT(no)
 913   ])
 914 AM_CONDITIONAL(SILC_WIN32, test x$win32_support = xtrue)
 915
 916 # Native EPOC support (disabled by default)
 917 #
 918 AM_CONDITIONAL(SILC_EPOC, test xfalse = xtrue)
 919
 920 # Native BeOS support (disabled by default)
 921 #
 922 AM_CONDITIONAL(SILC_BEOS, test xfalse = xtrue)
 923
 924 # Native OS2 support (disabled by default)
 925 #
 926 AM_CONDITIONAL(SILC_OS2, test xfalse = xtrue)
 927
 928 # --without-irssi
 929 #
 930 without_irssi=false
 931 AC_MSG_CHECKING(whether to compile Irssi SILC Client)
 932 AC_ARG_WITH(irssi,
 933   [  --without-irssi         compile without Irssi SILC Client],
 934   [
 935     AC_MSG_RESULT(no)
 936     without_irssi=true
 937     SILC_DIST_SUBDIRS=`echo $SILC_DIST_SUBDIRS | $sedpath -e 's/irssi//'`
 938   ],
 939   [
 940     AC_MSG_RESULT(yes)
 941   ])
 942
 943 # --without-silcd
 944 #
 945 without_silcd=false
 946 AC_MSG_CHECKING(whether to compile SILC Server)
 947 AC_ARG_WITH(silcd,
 948   [  --without-silcd         compile without SILC Server],
 949   [
 950     AC_MSG_RESULT(no)
 951     without_silcd=true
 952     SILC_DIST_SUBDIRS=`echo $SILC_DIST_SUBDIRS | $sedpath -e 's/silcd//'`
 953   ],
 954   [
 955     AC_MSG_RESULT(yes)
 956   ])
 957
 958
 959 ##
 960 ##  Misc
 961 ##
 962
 963 # Other configure scripts
 964 #
 965 if test x$without_irssi = xfalse; then
 966   if test "x$silc_dist" = "xsilc-client" ||
 967      test "x$silc_dist" = "xsilc-toolkit"; then
 968     AC_CONFIG_SUBDIRS(irssi)
 969   fi
 970 fi
 971
 972 if test x$mp_gmp = xfalse; then
 973   AC_CONFIG_SUBDIRS(lib/silcmath/mpi)
 974 fi
 975
 976 #AC_CONFIG_SUBDIRS(lib/zlib)
 977
 978 SILC_TOP_SRCDIR=`pwd`
 979 AC_SUBST(SILC_TOP_SRCDIR)
 980 #SILC_INSTALL_PREFIX=$ac_default_prefix
 981 #AC_SUBST(SILC_INSTALL_PREFIX)
 982 AC_SUBST(LIBS)
 983 INCLUDE_DEFINES_INT="include \$(top_srcdir)/Makefile.defines_int"
 984 AC_SUBST(INCLUDE_DEFINES_INT)
 985 AC_SUBST(SILC_DIST_SUBDIRS)
 986
 987 # Makefile outputs
 988 #
 989 AC_CONFIG_FILES(
 990 Makefile
 991 Makefile.defines
 992 Makefile.defines_int
 993 doc/Makefile
 994 includes/Makefile
 995 lib/Makefile
 996 lib/contrib/Makefile
 997 lib/silccore/Makefile
 998 lib/silccrypt/Makefile
 999 lib/silcmath/Makefile
1000 lib/silcmath/mpi/Makefile.defines
1001 lib/silcmath/mpi/Makefile.defines_int
1002 lib/silcsim/Makefile
1003 lib/silcske/Makefile
1004 lib/silcutil/Makefile
1005 lib/silcutil/unix/Makefile
1006 lib/silcutil/win32/Makefile
1007 lib/silcutil/beos/Makefile
1008 lib/silcutil/os2/Makefile
1009 lib/silcutil/epoc/Makefile
1010 lib/silcsftp/Makefile
1011 lib/silcsftp/tests/Makefile
1012 doc/example_silcd.conf
1013 includes/silcincludes.h
1014 )
1015
1016 if test "x$silc_dist" = "xsilc-client" ||
1017    test "x$silc_dist" = "xsilc-toolkit"; then
1018   AC_CONFIG_FILES(lib/silcclient/Makefile)
1019 fi
1020
1021 if test x$without_irssi = xfalse ; then
1022   if test "x$silc_dist" = "xsilc-client" ||
1023      test "x$silc_dist" = "xsilc-toolkit"; then
1024     AC_CONFIG_FILES(
1025 irssi/Makefile.defines
1026 irssi/Makefile.defines_int
1027 )
1028   fi
1029 fi
1030
1031 if test x$without_silcd = xfalse ; then
1032   if test "x$silc_dist" = "xsilc-server" ||
1033      test "x$silc_dist" = "xsilc-toolkit"; then
1034     AC_CONFIG_FILES(
1035 silcd/Makefile
1036 )
1037   fi
1038 fi
1039
1040 if test "x$silc_dist" = "xsilc-toolkit"; then
1041   AC_CONFIG_FILES(
1042 silc/Makefile
1043 win32/Makefile
1044 win32/libsilc/Makefile
1045 win32/libsilcclient/Makefile
1046 tutorial/Makefile
1047 tutorial/Makefile.defines
1048 tutorial/Makefile.defines_int
1049 )
1050 fi
1051
1052 AC_OUTPUT
1053
1054 s_bindir=`eval echo $bindir`;s_bindir=`eval echo $s_bindir`
1055 s_sbindir=`eval echo $sbindir`;s_sbindir=`eval echo $s_sbindir`
1056 s_includedir=`eval echo $includedir`;s_includedir=`eval echo $s_includedir`
1057
1058 echo ""
1059 echo "SILC Configuration Summary:"
1060 echo "---------------------------"
1061 echo " Target host ...................: $target"
1062 echo " Compiler ......................: $CC"
1063 echo " CFLAGS ........................: $CFLAGS"
1064 echo " CPPFLAGS ......................: $CPPFLAGS"
1065 echo " LDFLAGS .......................: $LDFLAGS"
1066 echo " LIBS ..........................: $LIBS"
1067 echo ""
1068 echo " Installation prefix ...........: $prefix"
1069 echo " bin directory .................: $s_bindir"
1070 echo " sbin directory ................: $s_sbindir"
1071 echo " man directory .................: $MANDIR"
1072 echo " help directory ................: $HELPDIR"
1073 echo " doc directory .................: $DOCDIR"
1074 echo " logs directory ................: $LOGSDIR"
1075 echo " SIM directory .................: $MODULESDIR"
1076 echo " include directory .............: $s_includedir"
1077 echo ""
1078
1079 if test "x$silc_dist" = "xsilc-client" ||
1080    test "x$silc_dist" = "xsilc-toolkit"; then
1081   irssi="yes"
1082   if test x$without_irssi = xtrue; then
1083     irssi="no"
1084   fi
1085 echo " Compile SILC Client ...........: $irssi"
1086 fi
1087
1088 if test "x$silc_dist" = "xsilc-server" ||
1089    test "x$silc_dist" = "xsilc-toolkit"; then
1090   silcd="yes"
1091   if test x$without_silcd = xtrue; then
1092     without_silcd="no"
1093   fi
1094 echo " Compile SILC Server ...........: $silcd"
1095 echo " Server configuration file .....: $summary_silcd_configfile"
1096 echo " Server PID file ...............: $PIDFILE"
1097 fi
1098
1099 if test x$sim_support = xfalse; then
1100   sim_support="no"
1101 else
1102   sim_support="yes"
1103 fi
1104 echo " SIM support ...................: $sim_support"
1105 echo " IPv6 support ..................: $summary_ipv6"
1106 echo " Assmebler optimizations .......: $summary_asm"
1107
1108 mp="MPI"
1109 if test x$mp_gmp = xtrue; then
1110   mp="GMP"
1111 fi
1112 echo " Arithmetic library ............: $mp"
1113
1114 threads="no"
1115 if test x$has_threads = xtrue; then
1116   threads="yes"
1117 fi
1118 echo " Multi-threads support .........: $threads"
1119 echo " Debugging enabled .............: $summary_debug"
1120 echo " Stack-trace enabled ...........: $summary_stacktrace"
1121 echo ""
1122 if test "x$silc_dist" = "xsilc-client"; then
1123   echo "Compile the sources with 'make' or 'gmake' command (GNU make is required)."
1124 else
1125   echo "Compile the sources with 'make' or 'gmake' command."
1126 fi