configure.in.pre

   1 #
   2 #  configure.in.pre
   3 #
   4 #  Author: Pekka Riikonen <priikone@silcnet.org>
   5 #
   6 #  Copyright (C) 2000 - 2002 Pekka Riikonen
   7 #
   8 #  This program is free software; you can redistribute it and/or modify
   9 #  it under the terms of the GNU General Public License as published by
  10 #  the Free Software Foundation; either version 2 of the License, or
  11 #  (at your option) any later version.
  12 #
  13 #  This program is distributed in the hope that it will be useful,
  14 #  but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 #  GNU General Public License for more details.
  17 #
  18
  19 AC_INIT(includes/silcversion.h)
  20
  21 # Put here any platform specific stuff
  22 #
  23 AC_CANONICAL_SYSTEM
  24 case "$target" in
  25   *-*-freebsd*)
  26     check_threads=true
  27     ;;
  28   *-*-*bsd*)
  29     check_threads=false
  30     ;;
  31   *)
  32     check_threads=true
  33     ;;
  34 esac
  35
  36 # ./prepare script will automatically put the correct version. Do not edit!
  37 #
  38 AM_INIT_AUTOMAKE(SILC_PACKAGE, SILC_VERSION)
  39 AC_PREREQ(2.52)
  40 AC_CONFIG_HEADERS(includes/silcdefs.h)
  41
  42 AC_PROG_CC
  43 AC_C_INLINE
  44 AC_C_CONST
  45
  46 AC_PROG_LN_S
  47 AC_SUBST(LN_S)
  48
  49 # Distribution definition. ./prepare will automatically add here a correct
  50 # value. Do not edit!
  51 #
  52 silc_dist=SILC_PACKAGE
  53 SILC_DIST_SUBDIRS="SILC_DISTRIBUTION_SUBDIRS"
  54 AC_DEFINE(SILC_DIST_DEFINE)
  55
  56 # XXX
  57 # Compiler flags
  58 #
  59 if test "$GCC"; then
  60   CFLAGS="-Wall -finline-functions $CFLAGS"
  61 fi
  62
  63 # Program checking
  64 #
  65 AC_PROG_INSTALL
  66 AC_PROG_RANLIB
  67 AC_PROG_MAKE_SET
  68 AC_PROG_LIBTOOL
  69 AC_PATH_PROG(sedpath, sed)
  70
  71 # Header checking
  72 #
  73 AC_HEADER_STDC
  74 AC_HEADER_TIME
  75 AC_HEADER_STAT
  76
  77 # More header checking
  78 #
  79 AC_CHECK_HEADERS(unistd.h string.h getopt.h errno.h fcntl.h assert.h)
  80 AC_CHECK_HEADERS(sys/types.h sys/stat.h sys/time.h stddef.h)
  81 AC_CHECK_HEADERS(netinet/in.h netinet/tcp.h xti.h netdb.h)
  82 AC_CHECK_HEADERS(pwd.h grp.h termcap.h paths.h)
  83 AC_CHECK_HEADERS(ncurses.h signal.h ctype.h utime.h)
  84 AC_CHECK_HEADERS(arpa/inet.h sys/mman.h limits.h termios.h locale.h langinfo.h)
  85
  86 # Data type checking
  87 #
  88 AC_TYPE_SIGNAL
  89 AC_TYPE_SIZE_T
  90 AC_TYPE_MODE_T
  91 AC_TYPE_UID_T
  92 AC_TYPE_PID_T
  93
  94 AC_CHECK_SIZEOF(long long, 0)
  95 AC_SUBST(SILC_SIZEOF_LONG_LONG, $ac_cv_sizeof_long_long)
  96 AC_CHECK_SIZEOF(long, 0)
  97 AC_SUBST(SILC_SIZEOF_LONG, $ac_cv_sizeof_long)
  98 AC_CHECK_SIZEOF(int, 0)
  99 AC_SUBST(SILC_SIZEOF_INT, $ac_cv_sizeof_int)
 100 AC_CHECK_SIZEOF(short, 0)
 101 AC_SUBST(SILC_SIZEOF_SHORT, $ac_cv_sizeof_short)
 102 AC_CHECK_SIZEOF(char, 0)
 103 AC_SUBST(SILC_SIZEOF_CHAR, $ac_cv_sizeof_char)
 104 AC_CHECK_SIZEOF(void *, 0)
 105 AC_SUBST(SILC_SIZEOF_VOID_P, $ac_cv_sizeof_void_p)
 106
 107 # Function and library checking
 108 #
 109 AC_CHECK_FUNC(gethostbyname, [],
 110   [
 111     AC_CHECK_LIB(nsl, gethostbyname, LIBS="$LIBS -lnsl")
 112     AC_CHECK_FUNC(res_gethostbyname, [],
 113        AC_CHECK_LIB(resolv, res_gethostbyname, LIBS="$LIBS -lresolv")
 114     )
 115   ])
 116 AC_CHECK_FUNC(socket, [],
 117   AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
 118 )
 119 AC_CHECK_FUNCS(gethostname gethostbyaddr getservbyname getservbyport)
 120 AC_CHECK_FUNCS(select listen bind shutdown close connect setsockopt)
 121 AC_CHECK_FUNCS(time ctime utime gettimeofday)
 122 AC_CHECK_FUNCS(chmod fcntl stat fstat getenv putenv strerror)
 123 AC_CHECK_FUNCS(getpid getgid getsid getpgid getpgrp getuid)
 124 AC_CHECK_FUNCS(setgroups initgroups nl_langinfo)
 125 AC_CHECK_FUNCS(strchr strstr strcpy strncpy memcpy memset memmove)
 126
 127 # SIM support checking
 128 # XXX These needs to be changed as more supported platforms appear.
 129 # XXX This probably needs to be made platform dependant check.
 130 #
 131 sim_support=false
 132 AC_MSG_CHECKING(for SIM support)
 133 AC_MSG_RESULT()
 134 AC_CHECK_HEADERS(dlfcn.h,
 135   AC_CHECK_LIB(dl, dlopen,
 136     [
 137       AC_DEFINE(SILC_SIM)
 138       sim_support=true
 139       LIBS="$LIBS -ldl"
 140     ],
 141     [
 142       AC_CHECK_LIB(c, dlopen,
 143         [
 144           AC_DEFINE(SILC_SIM)
 145           sim_support=true
 146         ])
 147     ])
 148   )
 149
 150 AM_CONDITIONAL(SILC_SIM, test x$sim_support = xtrue)
 151 if test x$sim_support = xtrue; then
 152   AC_MSG_RESULT(Enabled SIM support.)
 153 else
 154   AC_MSG_RESULT(No SIM support found.)
 155 fi
 156
 157 # lib/contrib conditionals
 158 #
 159 AC_CHECK_HEADER(regex.h, have_regex=1, have_regex=0)
 160 AM_CONDITIONAL(HAVE_REGEX, test x$have_regex = x1)
 161 AC_CHECK_FUNC(getopt_long, have_getopt_long=1, have_getopt_long=0)
 162 AM_CONDITIONAL(HAVE_GETOPT_LONG, test x$have_getopt_long = x1)
 163
 164
 165 ##
 166 ##  Enable/disable checking
 167 ##
 168
 169 # IPv6 support
 170 #
 171 AC_MSG_CHECKING(whether to enable IPv6 support)
 172 AC_ARG_ENABLE(ipv6,
 173   [  --enable-ipv6           enable IPv6 support],
 174   [
 175     case "${enableval}" in
 176       yes)
 177         want_ipv6=true
 178         check_ipv6=false
 179         summary_ipv6="yes"
 180         AC_DEFINE(HAVE_IPV6)
 181         AC_MSG_RESULT(yes)
 182         ;;
 183       *)
 184         want_ipv6=false
 185         check_ipv6=false
 186         summary_ipv6="no"
 187         AC_MSG_RESULT(no)
 188         ;;
 189     esac
 190   ],
 191     check_ipv6=true
 192   )
 193
 194 if test x$check_ipv6 = xtrue; then
 195   summary_ipv6="no"
 196   AC_TRY_COMPILE(
 197     [
 198       #ifdef HAVE_SYS_TYPES_H
 199       #include <sys/types.h>
 200       #endif
 201       #ifdef HAVE_NETINET_TCP_H
 202       #include <netinet/tcp.h>
 203       #endif
 204       #ifdef HAVE_NETDB_H
 205       #include <netdb.h>
 206       #endif
 207       #include <sys/socket.h>
 208       #ifdef HAVE_NETINET_IN_H
 209       #include <netinet/in.h>
 210       #endif
 211     ],
 212     [
 213       struct sockaddr_in6 sin6;
 214       int family = AF_INET6;
 215     ],
 216     [
 217       AC_DEFINE(HAVE_IPV6)
 218       AC_MSG_RESULT(yes)
 219       summary_ipv6="yes"
 220     ],
 221       AC_MSG_RESULT(no)
 222     )
 223 fi
 224
 225 # Debug checking
 226 #
 227 AC_MSG_CHECKING(whether to enable debugging)
 228 summary_debug="no"
 229 AC_ARG_ENABLE(debug,
 230   [  --enable-debug          enable debugging],
 231   [
 232     case "${enableval}" in
 233       yes)
 234         AC_MSG_RESULT(yes)
 235         AC_DEFINE(SILC_DEBUG)
 236         CFLAGS="-O -g $CFLAGS"
 237         summary_debug="yes"
 238         ;;
 239       *)
 240         AC_MSG_RESULT(no)
 241         CFLAGS="-O2 -g $CFLAGS"
 242         ;;
 243     esac
 244   ],
 245   [
 246     CFLAGS="-O2 -g $CFLAGS"
 247     AC_MSG_RESULT(no)
 248   ])
 249
 250 # Stack trace checking
 251 #
 252 AC_MSG_CHECKING(whether to enable stack tracing)
 253 summary_stacktrace="no"
 254 AC_ARG_ENABLE(stack-trace,
 255   [  --enable-stack-trace    enable memory stack trace],
 256   [
 257     case "${enableval}" in
 258     yes)
 259       AC_MSG_RESULT(yes)
 260       AC_DEFINE(SILC_STACKTRACE)
 261       summary_stacktrace="yes"
 262       ;;
 263     *)
 264       AC_MSG_RESULT(no)
 265       ;;
 266     esac
 267   ],
 268     AC_MSG_RESULT(no)
 269   )
 270
 271 # Disable all assembler optimizations
 272 #
 273 AC_MSG_CHECKING(whether to enable assembler optimizations)
 274 summary_asm="no"
 275 AC_ARG_ENABLE(asm,
 276   [  --disable-asm           do not use assembler optimizations],
 277   [
 278     AC_MSG_RESULT(no)
 279   ],
 280   [
 281     AC_MSG_RESULT(yes)
 282     summary_asm="yes"
 283   ])
 284
 285
 286 ##
 287 ##  Installation
 288 ##
 289
 290 # Default installation destination
 291 #
 292 AC_PREFIX_DEFAULT(/usr/local/silc)
 293 if test "x$prefix" != xNONE; then
 294   silc_prefix="$prefix"
 295 else
 296   silc_prefix="$ac_default_prefix"
 297 fi
 298
 299 # etc directory
 300 #
 301 if test "x$sysconfdir" != 'x${prefix}/etc'; then
 302   ETCDIR="$sysconfdir"
 303 else
 304   ETCDIR="$silc_prefix/etc"
 305 fi
 306
 307 AC_ARG_WITH(etcdir,
 308   [[  --with-etcdir=DIR       directory for system files [/etc/silc]]],
 309   [
 310     case "$withval" in
 311       no|yes)
 312         ;;
 313       *)
 314         ETCDIR="$withval"
 315         ;;
 316     esac
 317   ])
 318 AC_SUBST(ETCDIR)
 319 AC_DEFINE_UNQUOTED(SILC_ETCDIR, "$ETCDIR")
 320
 321 # help directory
 322 #
 323 HELPDIR="$silc_prefix/help"
 324 AC_ARG_WITH(helpdir,
 325   [[  --with-helpdir=DIR      directory for SILC help files [PREFIX/help]]],
 326   [
 327     case "$withval" in
 328       no|yes)
 329         ;;
 330       *)
 331        HELPDIR="$withval"
 332        ;;
 333     esac
 334   ])
 335 AC_SUBST(HELPDIR)
 336 AC_DEFINE_UNQUOTED(SILC_HELPDIR, "$HELPDIR")
 337
 338 # doc directory
 339 #
 340 DOCDIR="$silc_prefix/doc"
 341 AC_ARG_WITH(docdir,
 342   [[  --with-docdir=DIR       directory for SILC documentation [PREFIX/doc]]],
 343   [
 344     case "$withval" in
 345       no|yes)
 346         ;;
 347       *)
 348         DOCDIR="$withval"
 349         ;;
 350     esac
 351   ])
 352 AC_SUBST(DOCDIR)
 353 AC_DEFINE_UNQUOTED(SILC_DOCDIR, "$DOCDIR")
 354
 355 # SIM modules directory
 356 #
 357 MODULESDIR="$silc_prefix/modules"
 358 AC_ARG_WITH(simdir,
 359   [[  --with-simdir=DIR       directory for SIM modules [PREFIX/modules]]],
 360   [
 361     case "$withval" in
 362       no|yes)
 363         ;;
 364       *)
 365         MODULESDIR="$withval"
 366         ;;
 367     esac
 368   ])
 369 AC_SUBST(MODULESDIR)
 370 AC_DEFINE_UNQUOTED(SILC_MODULESDIR, "$MODULESDIR")
 371
 372 # Logs directory
 373 #
 374 LOGSDIR="$silc_prefix/logs"
 375 AC_ARG_WITH(logsdir,
 376   [[  --with-logsdir=DIR      directory for SILC Server logs [PREFIX/logs]]],
 377   [
 378     case "$withval" in
 379       no|yes)
 380         ;;
 381       *)
 382         LOGSDIR="$withval"
 383         ;;
 384     esac
 385   ])
 386 AC_SUBST(LOGSDIR)
 387 AC_DEFINE_UNQUOTED(SILC_LOGSDIR, "$LOGSDIR")
 388
 389 # Manual directory
 390 #
 391 MANDIR="$silc_prefix/man"
 392 AC_ARG_WITH(mandir,
 393   [[  --with-mandir=DIR       directory for SILC manual pages [PREFIX/man]]],
 394   [
 395     case "$withval" in
 396       no|yes)
 397         ;;
 398       *)
 399         MANDIR="$withval"
 400         ;;
 401     esac
 402   ])
 403 AC_SUBST(MANDIR)
 404 AC_DEFINE_UNQUOTED(SILC_MANDIR, "$MANDIR")
 405
 406 # silcd config file checking
 407 #
 408 summary_silcd_configfile="/etc/silc/silcd.conf"
 409 AC_ARG_WITH(silcd-config-file,
 410   [[  --with-silcd-config-file=FILE  use FILE as default configuration file
 411                                  for SILC Server [/etc/silc/silcd.conf]]],
 412     AC_DEFINE_UNQUOTED(SILC_SERVER_CONFIG_FILE, "$withval")
 413     summary_silcd_configfile="$withval"
 414   )
 415
 416 # silcd pid file checking
 417 #
 418 if test "x$localstatedir" != 'x${prefix}/var'; then
 419   PIDFILE="$localstatedir/silcd.pid"
 420 else
 421   PIDFILE="$silc_prefix/var/silcd.pid"
 422 fi
 423
 424 AC_ARG_WITH(silcd-pid-file,
 425   [[  --with-silcd-pid-file=FILE     use FILE as default pid file for SILC
 426                                  Server [/var/run/silcd.pid]]],
 427   [
 428     case "$withval" in
 429       no|yes)
 430         ;;
 431       *)
 432         PIDFILE="$withval"
 433         ;;
 434     esac
 435   ])
 436 AC_SUBST(PIDFILE)
 437
 438
 439 ##
 440 ##  With/without checkings
 441 ##
 442
 443 # SOCKS4 support checking
 444 #
 445 AC_MSG_CHECKING(whether to support SOCKS4)
 446 AC_ARG_WITH(socks4,
 447   [[  --with-socks4[=DIR]     with SOCKS4 support [search in DIR/lib and DIR/include]]],
 448   [
 449     case "$withval" in
 450       no)
 451         AC_MSG_RESULT(no)
 452         ;;
 453       *)
 454         AC_MSG_RESULT(yes)
 455         socks=4
 456
 457         if test -d "$withval/include"; then
 458           CFLAGS="$CFLAGS -I$withval/include"
 459         else
 460           CFLAGS="$CFLAGS -I$withval"
 461         fi
 462         if test -d "$withval/lib"; then
 463           withval="-L$withval/lib -lsocks"
 464         else
 465           withval="-L$withval -lsocks"
 466         fi
 467
 468         LIBS="$withval $LIBS"
 469         AC_TRY_LINK([],
 470           [
 471             Rconnect();
 472           ], [],
 473           [
 474             AC_MSG_ERROR(Could not find SOCKS4 library.)
 475           ])
 476         ;;
 477     esac
 478   ],
 479     AC_MSG_RESULT(no)
 480   )
 481
 482 # SOCKS5 support checking
 483 #
 484 AC_MSG_CHECKING(whether to support SOCKS5)
 485 AC_ARG_WITH(socks5,
 486   [[  --with-socks5[=DIR]     with SOCKS5 support [search in DIR/lib and DIR/include]]],
 487   [
 488     case "$withval" in
 489       no)
 490         AC_MSG_RESULT(no)
 491         ;;
 492       *)
 493         AC_MSG_RESULT(yes)
 494         socks=5
 495
 496         if test -d "$withval/include"; then
 497           CFLAGS="$CFLAGS -I$withval/include"
 498         else
 499           CFLAGS="$CFLAGS -I$withval"
 500         fi
 501         if test -d "$withval/lib"; then
 502           withval="-L$withval/lib -lsocks5"
 503         else
 504           withval="-L$withval -lsocks5"
 505         fi
 506
 507         LIBS="$withval $LIBS"
 508         AC_TRY_LINK([],
 509           [
 510             SOCKSconnect();
 511           ], [],
 512           [
 513             AC_MSG_ERROR(Could not find SOCKS5 library.)
 514           ])
 515         ;;
 516     esac
 517   ],
 518     AC_MSG_RESULT(no)
 519   )
 520
 521 if test "x$socks" = "x4"; then
 522   AC_DEFINE(SOCKS)
 523   CFLAGS="$CFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 524 fi
 525
 526 if test "x$socks" = "x5"; then
 527   AC_DEFINE(SOCKS)
 528   AC_DEFINE(SOCKS5)
 529   AC_DEFINE(Rconnect, SOCKSconnect)
 530   AC_DEFINE(Rgetsockname, SOCKSgetsockname)
 531   AC_DEFINE(Rgetpeername, SOCKSgetpeername)
 532   AC_DEFINE(Rbind, SOCKSbind)
 533   AC_DEFINE(Raccept, SOCKSaccept)
 534   AC_DEFINE(Rlisten, SOCKSlisten)
 535   AC_DEFINE(Rselect, SOCKSselect)
 536   AC_DEFINE(Rrecvfrom, SOCKSrecvfrom)
 537   AC_DEFINE(Rsendto, SOCKSsendto)
 538   AC_DEFINE(Rrecv, SOCKSrecv)
 539   AC_DEFINE(Rsend, SOCKSsend)
 540   AC_DEFINE(Rread, SOCKSread)
 541   AC_DEFINE(Rwrite, SOCKSwrite)
 542   AC_DEFINE(Rrresvport, SOCKSrresvport)
 543   AC_DEFINE(Rshutdown, SOCKSshutdown)
 544   AC_DEFINE(Rlisten, SOCKSlisten)
 545   AC_DEFINE(Rclose, SOCKSclose)
 546   AC_DEFINE(Rdup, SOCKSdup)
 547   AC_DEFINE(Rdup2, SOCKSdup2)
 548   AC_DEFINE(Rfclose, SOCKSfclose)
 549   AC_DEFINE(Rgethostbyname, SOCKSgethostbyname)
 550 fi
 551
 552 # MP library checking. First check whether user wants to use GMP and use
 553 # it if found. If not or not defined then compile the MPI library in the
 554 # source tree.
 555 #
 556 mp_gmp=false
 557 SAVELIBS="$LIBS"
 558 SAVECFLAGS="$CFLAGS"
 559 AC_MSG_CHECKING(whether to search for GMP)
 560 AC_ARG_WITH(gmp,
 561   [[  --with-gmp[=DIR]        use GMP instead of MPI [search in DIR/lib and DIR/include]]],
 562   [
 563     case "$withval" in
 564       no)
 565         AC_MSG_RESULT(no)
 566         ;;
 567       yes)
 568         AC_MSG_RESULT(yes)
 569         LIBS="-lgmp $LIBS"
 570         ;;
 571       *)
 572         AC_MSG_RESULT(yes)
 573
 574         if test -d "$withval/include"; then
 575           CFLAGS="$CFLAGS -I$withval/include"
 576         else
 577           CFLAGS="$CFLAGS -I$withval"
 578         fi
 579         if test -d "$withval/lib"; then
 580           withval="-L$withval/lib -lgmp"
 581         else
 582           withval="-L$withval -lgmp"
 583         fi
 584
 585         LIBS="$withval $LIBS"
 586         ;;
 587     esac
 588
 589     AC_CHECK_LIB(gmp, __gmpz_init,
 590       [
 591         mp_gmp=true
 592         AC_DEFINE(SILC_MP_GMP)
 593         AC_MSG_RESULT(Using GMP as a MP library.)
 594       ],
 595       [
 596         LIBS="$SAVELIBS"
 597         CFLAGS="$SAVECFLAGS"
 598       ])
 599   ],
 600     AC_MSG_RESULT(no)
 601   )
 602
 603 AM_CONDITIONAL(SILC_MP_GMP, test x$mp_gmp = xtrue)
 604 AM_CONDITIONAL(SILC_MP_NSS_MPI, test x$mp_gmp = xfalse)
 605 if test x$mp_gmp = xfalse; then
 606   AC_DEFINE(SILC_MP_NSS_MPI)
 607   AC_MSG_RESULT(Using NSS MPI as a MP library.)
 608 fi
 609
 610 # iconv support
 611 #
 612 check_iconv=true
 613 has_iconv=false
 614 AC_MSG_CHECKING(whether to implicit search for libiconv)
 615 AC_ARG_WITH(iconv,
 616   [[  --with-iconv[=DIR]      use libiconv [search in DIR/include and DIR/lib]]],
 617   [
 618     case "${withval}" in
 619       no)
 620         AC_MSG_RESULT(no)
 621
 622         AC_CHECK_HEADERS(iconv.h, AC_CHECK_FUNC(iconv, has_iconv=true))
 623         check_iconv=false
 624         ;;
 625       *)
 626         AC_MSG_RESULT(yes)
 627
 628         if test -d $withval/include; then
 629           CPPFLAGS="$CPPFLAGS -I$withval/include"
 630           CFLAGS="$CFLAGS -I$withval/include"
 631         fi
 632         if test -d $withval/lib; then
 633           LDFLAGS="$LDFLAGS -L$withval/lib"
 634         fi
 635     esac
 636   ],
 637   [
 638     AC_MSG_RESULT(no)
 639
 640     AC_CHECK_HEADERS(iconv.h, AC_CHECK_FUNCS(iconv,
 641                                 [
 642                                   has_iconv=true
 643                                   check_iconv=false
 644                                  ]))
 645   ])
 646
 647 if test x$check_iconv = xtrue; then
 648   AC_MSG_RESULT(starting search...)
 649
 650   # XXX
 651   unset ac_cv_header__iconv_h_ ac_cv_header_iconv_h || true
 652
 653   AC_CHECK_HEADERS(iconv.h,
 654     [
 655       LIBS="$LIBS -liconv"
 656       AC_MSG_CHECKING(for iconv in -liconv)
 657       AC_TRY_LINK(
 658         [
 659           #include <stdlib.h>
 660           #include <iconv.h>
 661         ],
 662         [
 663           iconv_t cd = iconv_open("", "");
 664           iconv(cd, NULL, NULL, NULL, NULL);
 665           iconv_close(cd);
 666         ],
 667         [
 668           echo "yes"
 669           AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 670           has_iconv=true
 671           check_iconv=false
 672         ],
 673         [
 674           echo "no"
 675         ])
 676      ])
 677 fi
 678
 679 if test x$check_iconv = xtrue; then
 680   # search for iconv library..
 681   SAVE_CPPFLAGS="$CPPFLAGS"
 682   SAVE_CFLAGS="$CFLAGS"
 683   SAVE_LDFLAGS="$LDFLAGS"
 684
 685   for dir in `echo "/usr/local /usr/pkg /usr/contrib"`; do
 686     if test x$has_iconv = xfalse; then
 687       AC_MSG_RESULT(searching in $dir...)
 688
 689       CPPFLAGS="$SAVE_CPPFLAGS"
 690       CFLAGS="$SAVE_CFLAGS"
 691       LDFLAGS="$SAVE_LDFLAGS"
 692
 693       if test -d $dir/include; then
 694         CPPFLAGS="$CPPFLAGS -I$dir/include"
 695         CFLAGS="$CFLAGS -I$dir/include"
 696       fi
 697       if test -d $dir/lib; then
 698         LDFLAGS="$LDFLAGS -L$dir/lib"
 699       fi
 700
 701       # XXX
 702       unset ac_cv_header__iconv_h_ ac_cv_header_iconv_h || true
 703
 704       AC_CHECK_HEADERS(iconv.h,
 705         [
 706           LIBS="$LIBS -liconv"
 707           AC_MSG_CHECKING(for iconv in -liconv)
 708           AC_TRY_LINK(
 709             [
 710               #include <stdlib.h>
 711               #include <iconv.h>
 712             ],
 713             [
 714               iconv_t cd = iconv_open("", "");
 715               iconv(cd, NULL, NULL, NULL, NULL);
 716               iconv_close(cd);
 717             ],
 718             [
 719               echo "yes"
 720               has_iconv=true
 721               AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 722             ],
 723             [
 724               echo "no"
 725               has_iconv=false
 726             ])
 727          ])
 728       fi
 729     done
 730 fi
 731
 732 if test x$has_iconv = xtrue; then
 733   # (1) Some implementations of iconv won't convert from UTF-8 to UTF-8.
 734   # (2) In glibc-2.1.2 and earlier there is a bug that messes up ob and
 735   #     obl when args 2 and 3 are 0 (fixed in glibc-2.1.3).
 736   #
 737   AC_CACHE_CHECK([whether this iconv is good enough], ac_iconv_good,
 738     AC_TRY_RUN(
 739       [
 740         #include <iconv.h>
 741         int main() {
 742           iconv_t cd;
 743         changequote(, )dnl
 744           char buf[4];
 745         changequote([, ])dnl
 746           char *ob;
 747           size_t obl;
 748           ob = buf, obl = sizeof(buf);
 749           return ((cd = iconv_open("UTF-8", "UTF-8")) != (iconv_t)(-1) &&
 750                  (iconv(cd, 0, 0, &ob, &obl) ||
 751                  !(ob == buf && obl == sizeof(buf)) ||
 752                  iconv_close(cd)));
 753         }
 754       ],
 755       [
 756         ac_iconv_good=yes
 757       ],
 758       [
 759         ac_iconv_good=no
 760       ],
 761       [
 762         ac_iconv_good=yes
 763       ])
 764     )
 765
 766   if test x$ac_iconv_good = xno; then
 767     AC_MSG_RESULT(Try using libiconv instead.)
 768   fi
 769 fi
 770
 771 # POSIX threads support
 772 #
 773 has_threads=false
 774 AC_MSG_CHECKING(whether to search for POSIX threads)
 775 AC_ARG_WITH(pthreads,
 776   [[  --with-pthreads[=DIR]   use POSIX threads [search in DIR/include and DIR/lib]]],
 777   [
 778     case "${withval}" in
 779       no)
 780         check_threads=false
 781         ;;
 782       *)
 783         if test -d $withval/include; then
 784           CPPFLAGS="$CPPFLAGS -I$withval/include"
 785           CFLAGS="$CFLAGS -I$withval/include"
 786         fi
 787         if test -d $withval/lib; then
 788           LDFLAGS="$LDFLAGS -L$withval/lib"
 789         fi
 790
 791         check_threads=true
 792         ;;
 793     esac
 794   ])
 795
 796 if test x$check_threads = xtrue; then
 797   AC_MSG_RESULT(yes)
 798   AC_CHECK_HEADERS(pthread.h,
 799     [
 800       SAVE_LIBS="$LIBS"
 801       LIBS="$LIBS -lpthread"
 802       AC_CHECK_LIB(pthread, pthread_attr_init, has_threads=true,
 803         [
 804           # FreeBSD
 805           case "${target}" in
 806             *-*-freebsd*)
 807               LIBS="$SAVE_LIBS -pthread"
 808               AC_CHECK_LIB(c_r, pthread_attr_init, has_threads=true)
 809               ;;
 810           esac
 811         ])
 812     ],
 813     [
 814       # search for pthread library..
 815       SAVE_CPPFLAGS="$CPPFLAGS"
 816       SAVE_CFLAGS="$CFLAGS"
 817       SAVE_LDFLAGS="$LDFLAGS"
 818
 819       for dir in `echo "/usr/local /usr/pkg /usr/contrib /usr/pkg/pthreads /usr/local/pthreads"`; do
 820         if test x$has_threads = xfalse; then
 821           AC_MSG_RESULT(searching in $dir...)
 822
 823           CPPFLAGS="$SAVE_CPPFLAGS"
 824           CFLAGS="$SAVE_CFLAGS"
 825           LDFLAGS="$SAVE_LDFLAGS"
 826
 827           if test -d $dir/include; then
 828             CPPFLAGS="$CPPFLAGS -I$dir/include"
 829             CFLAGS="$CFLAGS -I$dir/include"
 830           fi
 831           if test -d $dir/lib; then
 832             LDFLAGS="$LDFLAGS -L$dir/lib"
 833           fi
 834
 835           # XXX
 836           unset ac_cv_header__pthread_h_ ac_cv_header_pthread_h || true
 837
 838           AC_CHECK_HEADERS(pthread.h,
 839             [
 840               LIBS="$LIBS -lpthread"
 841               AC_CHECK_LIB(pthread, pthread_attr_init, has_threads=true,
 842                                                        has_threads=false)
 843             ])
 844         fi
 845       done
 846     ])
 847 else
 848   AC_MSG_RESULT(no)
 849   has_threads=false
 850 fi
 851
 852 AM_CONDITIONAL(SILC_THREADS, test x$has_threads = xtrue)
 853 if test x$has_threads = xtrue; then
 854   CFLAGS="$CFLAGS -D_REENTRANT"
 855
 856   # XXX possibly incomplete
 857   case "${target}" in
 858     *-*-aix*)
 859       CFLAGS="$CFLAGS -D_THREAD_SAFE"
 860       if test x"$GCC" = xyes; then
 861         CFLAGS="$CFLAGS -mthreads"
 862       fi
 863       ;;
 864     *-*-freebsd*)
 865       CFLAGS="$CFLAGS -D_THREAD_SAFE"
 866       ;;
 867     *-*-sysv5uw7*)  # UnixWare 7
 868       if test "$GCC" != "yes"; then
 869         CFLAGS="$CFLAGS -Kthread"
 870       else
 871         CFLAGS="$CFLAGS -pthread"
 872       fi
 873       ;;
 874     *-dg-dgux*)  # DG/UX
 875       CFLAGS="$CFLAGS -D_POSIX4A_DRAFT10_SOURCE"
 876       ;;
 877    esac
 878
 879   AC_CHECK_FUNC(pthread_create)
 880   AC_DEFINE(SILC_HAVE_PTHREAD)
 881   AC_DEFINE(SILC_THREADS)
 882 fi
 883
 884 # Native WIN32 compilation under cygwin
 885 #
 886 AC_MSG_CHECKING(whether to compile native WIN32 code)
 887 AC_ARG_WITH(win32,
 888   [  --with-win32            compile native WIN32 code (-mno-cygwin)],
 889   [
 890     AC_MSG_RESULT(yes)
 891     AC_DEFINE(SILC_WIN32)
 892     win32_support=true
 893     CFLAGS="-mno-cygwin $CFLAGS"
 894     LIBS="$LIBS -lwsock32"
 895   ],
 896   [
 897     AC_MSG_RESULT(no)
 898   ])
 899 AM_CONDITIONAL(SILC_WIN32, test x$win32_support = xtrue)
 900
 901 # Native EPOC support (disabled by default)
 902 #
 903 AM_CONDITIONAL(SILC_EPOC, test xfalse = xtrue)
 904
 905 # Native BeOS support (disabled by default)
 906 #
 907 AM_CONDITIONAL(SILC_BEOS, test xfalse = xtrue)
 908
 909 # Native OS2 support (disabled by default)
 910 #
 911 AM_CONDITIONAL(SILC_OS2, test xfalse = xtrue)
 912
 913 # --without-irssi
 914 #
 915 without_irssi=false
 916 AC_MSG_CHECKING(whether to compile Irssi SILC Client)
 917 AC_ARG_WITH(irssi,
 918   [  --without-irssi         compile without Irssi SILC Client],
 919   [
 920     AC_MSG_RESULT(no)
 921     without_irssi=true
 922     SILC_DIST_SUBDIRS=`echo $SILC_DIST_SUBDIRS | $sedpath -e 's/irssi//'`
 923   ],
 924   [
 925     AC_MSG_RESULT(yes)
 926   ])
 927
 928 # --without-silcd
 929 #
 930 without_silcd=false
 931 AC_MSG_CHECKING(whether to compile SILC Server)
 932 AC_ARG_WITH(silcd,
 933   [  --without-silcd         compile without SILC Server],
 934   [
 935     AC_MSG_RESULT(no)
 936     without_silcd=true
 937     SILC_DIST_SUBDIRS=`echo $SILC_DIST_SUBDIRS | $sedpath -e 's/silcd//'`
 938   ],
 939   [
 940     AC_MSG_RESULT(yes)
 941   ])
 942
 943
 944 ##
 945 ##  Misc
 946 ##
 947
 948 # Other configure scripts
 949 #
 950 if test x$without_irssi = xfalse; then
 951   if test "x$silc_dist" = "xsilc-client" ||
 952      test "x$silc_dist" = "xsilc-toolkit"; then
 953     AC_CONFIG_SUBDIRS(irssi)
 954   fi
 955 fi
 956
 957 if test x$mp_gmp = xfalse; then
 958   AC_CONFIG_SUBDIRS(lib/silcmath/mpi)
 959 fi
 960
 961 #AC_CONFIG_SUBDIRS(lib/zlib)
 962
 963 SILC_TOP_SRCDIR=`pwd`
 964 AC_SUBST(SILC_TOP_SRCDIR)
 965 #SILC_INSTALL_PREFIX=$ac_default_prefix
 966 #AC_SUBST(SILC_INSTALL_PREFIX)
 967 AC_SUBST(LIBS)
 968 INCLUDE_DEFINES_INT="include \$(top_srcdir)/Makefile.defines_int"
 969 AC_SUBST(INCLUDE_DEFINES_INT)
 970 AC_SUBST(SILC_DIST_SUBDIRS)
 971
 972 # Makefile outputs
 973 #
 974 AC_CONFIG_FILES(
 975 Makefile
 976 Makefile.defines
 977 Makefile.defines_int
 978 doc/Makefile
 979 includes/Makefile
 980 lib/Makefile
 981 lib/contrib/Makefile
 982 lib/silccore/Makefile
 983 lib/silccrypt/Makefile
 984 lib/silcmath/Makefile
 985 lib/silcmath/mpi/Makefile.defines
 986 lib/silcmath/mpi/Makefile.defines_int
 987 lib/silcsim/Makefile
 988 lib/silcske/Makefile
 989 lib/silcutil/Makefile
 990 lib/silcutil/unix/Makefile
 991 lib/silcutil/win32/Makefile
 992 lib/silcutil/beos/Makefile
 993 lib/silcutil/os2/Makefile
 994 lib/silcutil/epoc/Makefile
 995 lib/silcsftp/Makefile
 996 lib/silcsftp/tests/Makefile
 997 doc/example_silcd.conf
 998 includes/silcincludes.h
 999 )
1000
1001 if test "x$silc_dist" = "xsilc-client" ||
1002    test "x$silc_dist" = "xsilc-toolkit"; then
1003   AC_CONFIG_FILES(lib/silcclient/Makefile)
1004 fi
1005
1006 if test x$without_irssi = xfalse ; then
1007   if test "x$silc_dist" = "xsilc-client" ||
1008      test "x$silc_dist" = "xsilc-toolkit"; then
1009     AC_CONFIG_FILES(
1010 irssi/Makefile.defines
1011 irssi/Makefile.defines_int
1012 )
1013   fi
1014 fi
1015
1016 if test x$without_silcd = xfalse ; then
1017   if test "x$silc_dist" = "xsilc-server" ||
1018      test "x$silc_dist" = "xsilc-toolkit"; then
1019     AC_CONFIG_FILES(
1020 silcd/Makefile
1021 )
1022   fi
1023 fi
1024
1025 if test "x$silc_dist" = "xsilc-toolkit"; then
1026   AC_CONFIG_FILES(
1027 silc/Makefile
1028 win32/Makefile
1029 win32/libsilc/Makefile
1030 win32/libsilcclient/Makefile
1031 tutorial/Makefile
1032 tutorial/Makefile.defines
1033 tutorial/Makefile.defines_int
1034 )
1035 fi
1036
1037 AC_OUTPUT
1038
1039 s_bindir=`eval echo $bindir`;s_bindir=`eval echo $s_bindir`
1040 s_sbindir=`eval echo $sbindir`;s_sbindir=`eval echo $s_sbindir`
1041 s_includedir=`eval echo $includedir`;s_includedir=`eval echo $s_includedir`
1042
1043 echo ""
1044 echo "SILC Configuration Summary:"
1045 echo "---------------------------"
1046 echo " Target host ...................: $target"
1047 echo " Compiler ......................: $CC"
1048 echo " CFLAGS ........................: $CFLAGS"
1049 echo " CPPFLAGS ......................: $CPPFLAGS"
1050 echo " LDFLAGS .......................: $LDFLAGS"
1051 echo " LIBS ..........................: $LIBS"
1052 echo ""
1053 echo " Installation prefix ...........: $prefix"
1054 echo " bin directory .................: $s_bindir"
1055 echo " sbin directory ................: $s_sbindir"
1056 echo " man directory .................: $MANDIR"
1057 echo " help directory ................: $HELPDIR"
1058 echo " doc directory .................: $DOCDIR"
1059 echo " logs directory ................: $LOGSDIR"
1060 echo " SIM directory .................: $MODULESDIR"
1061 echo " include directory .............: $s_includedir"
1062 echo ""
1063
1064 if test "x$silc_dist" = "xsilc-client" ||
1065    test "x$silc_dist" = "xsilc-toolkit"; then
1066   irssi="yes"
1067   if test x$without_irssi = xtrue; then
1068     irssi="no"
1069   fi
1070 echo " Compile SILC Client ...........: $irssi"
1071 fi
1072
1073 if test "x$silc_dist" = "xsilc-server" ||
1074    test "x$silc_dist" = "xsilc-toolkit"; then
1075   silcd="yes"
1076   if test x$without_silcd = xtrue; then
1077     without_silcd="no"
1078   fi
1079 echo " Compile SILC Server ...........: $silcd"
1080 echo " Server configuration file .....: $summary_silcd_configfile"
1081 echo " Server PID file ...............: $PIDFILE"
1082 fi
1083
1084 if test x$sim_support = xfalse; then
1085   sim_support="no"
1086 else
1087   sim_support="yes"
1088 fi
1089 echo " SIM support ...................: $sim_support"
1090 echo " IPv6 support ..................: $summary_ipv6"
1091 echo " Assmebler optimizations .......: $summary_asm"
1092
1093 mp="MPI"
1094 if test x$mp_gmp = xtrue; then
1095   mp="GMP"
1096 fi
1097 echo " Arithmetic library ............: $mp"
1098
1099 threads="no"
1100 if test x$has_threads = xtrue; then
1101   threads="yes"
1102 fi
1103 echo " Multi-threads support .........: $threads"
1104 echo " Debugging enabled .............: $summary_debug"
1105 echo " Stack-trace enabled ...........: $summary_stacktrace"
1106 echo ""
1107 if test "x$silc_dist" = "xsilc-client"; then
1108   echo "Compile the sources with 'make' or 'gmake' command (GNU make is required)."
1109 else
1110   echo "Compile the sources with 'make' or 'gmake' command."
1111 fi