configure.in.pre

   1 #
   2 #  configure.in.pre
   3 #
   4 #  Author: Pekka Riikonen <priikone@silcnet.org>
   5 #
   6 #  Copyright (C) 2000 - 2002 Pekka Riikonen
   7 #
   8 #  This program is free software; you can redistribute it and/or modify
   9 #  it under the terms of the GNU General Public License as published by
  10 #  the Free Software Foundation; either version 2 of the License, or
  11 #  (at your option) any later version.
  12 #
  13 #  This program is distributed in the hope that it will be useful,
  14 #  but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 #  GNU General Public License for more details.
  17 #
  18
  19 AC_INIT(includes/silcversion.h)
  20
  21 #
  22 # Put here any platform specific stuff
  23 #
  24 AC_CANONICAL_SYSTEM
  25 case "$target" in
  26   *-*-*bsd*)
  27     check_threads=false
  28     ;;
  29   *)
  30     check_threads=true
  31     ;;
  32 esac
  33
  34 # ./prepare script will automatically put the correct version. Do not edit!
  35 AM_INIT_AUTOMAKE(SILC_PACKAGE, SILC_VERSION)
  36 AC_PREREQ(2.52)
  37 AM_CONFIG_HEADER(includes/silcdefs.h)
  38
  39 AC_PROG_CC
  40 AC_C_INLINE
  41 AC_C_CONST
  42
  43 AC_PROG_LN_S
  44 AC_SUBST(LN_S)
  45
  46 # Distribution definition. ./prepare will automatically add here a correct
  47 # value. Do not edit!
  48 silc_dist=SILC_PACKAGE
  49 SILC_DIST_SUBDIRS="SILC_DISTRIBUTION_SUBDIRS"
  50 AC_DEFINE(SILC_DIST_DEFINE)
  51
  52 # XXX
  53 # Compiler flags
  54 if test "$GCC"; then
  55   CFLAGS="-Wall -finline-functions $CFLAGS"
  56 fi
  57
  58 # Program checking
  59 AC_PROG_INSTALL
  60 AC_PROG_RANLIB
  61 AC_PROG_MAKE_SET
  62 AC_PROG_LIBTOOL
  63 AC_PATH_PROG(sedpath, sed)
  64
  65 # Header checking
  66 AC_HEADER_STDC
  67 AC_HEADER_TIME
  68 AC_HEADER_STAT
  69
  70 # More header checking
  71 AC_CHECK_HEADERS(unistd.h string.h getopt.h errno.h fcntl.h assert.h)
  72 AC_CHECK_HEADERS(sys/types.h sys/stat.h sys/time.h stddef.h)
  73 AC_CHECK_HEADERS(netinet/in.h netinet/tcp.h xti.h netdb.h)
  74 AC_CHECK_HEADERS(pwd.h grp.h termcap.h paths.h)
  75 AC_CHECK_HEADERS(ncurses.h signal.h ctype.h regex.h utime.h iconv.h)
  76 AC_CHECK_HEADERS(arpa/inet.h sys/mman.h limits.h termios.h locale.h langinfo.h)
  77
  78 # Data type checking
  79 AC_TYPE_SIGNAL
  80 AC_TYPE_SIZE_T
  81 AC_TYPE_MODE_T
  82 AC_TYPE_UID_T
  83 AC_TYPE_PID_T
  84
  85 AC_CHECK_SIZEOF(long long, 0)
  86 AC_DEFINE_UNQUOTED(SILC_SIZEOF_LONG_LONG, $ac_cv_sizeof_long_long)
  87 AC_CHECK_SIZEOF(long, 0)
  88 AC_DEFINE_UNQUOTED(SILC_SIZEOF_LONG, $ac_cv_sizeof_long)
  89 AC_CHECK_SIZEOF(int, 0)
  90 AC_DEFINE_UNQUOTED(SILC_SIZEOF_INT, $ac_cv_sizeof_int)
  91 AC_CHECK_SIZEOF(short, 0)
  92 AC_DEFINE_UNQUOTED(SILC_SIZEOF_SHORT, $ac_cv_sizeof_short)
  93 AC_CHECK_SIZEOF(char, 0)
  94 AC_DEFINE_UNQUOTED(SILC_SIZEOF_CHAR, $ac_cv_sizeof_char)
  95 AC_CHECK_SIZEOF(void *, 0)
  96 AC_DEFINE_UNQUOTED(SILC_SIZEOF_VOID_P, $ac_cv_sizeof_void_p)
  97
  98 # Function and library checking
  99 AC_CHECK_FUNC(gethostbyname, ac_gethostbyname_found=1,ac_gethostbyname_found=0)
 100 if test x$ac_gethostbyname_found = x0; then
 101     AC_CHECK_LIB(nsl, gethostbyname, LIBS="$LIBS -lnsl")
 102     AC_CHECK_FUNC(res_gethostbyname, ac_res_ghbn_found=1, ac_res_ghbn_found=0)
 103     if test x$ac_res_ghbn_found = x0; then
 104         AC_CHECK_LIB(resolv, res_gethostbyname,  LIBS="$LIBS -lresolv")
 105     fi
 106 fi
 107 AC_CHECK_FUNC(socket, ac_socket_found=1, ac_socket_found=0)
 108 if test x$ac_socket_found = x0; then
 109     AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
 110 fi
 111 AC_CHECK_FUNCS(gethostname gethostbyaddr getservbyname getservbyport)
 112 AC_CHECK_FUNCS(select listen bind shutdown close connect)
 113 AC_CHECK_FUNCS(fcntl setsockopt)
 114 AC_CHECK_FUNCS(getopt_long time)
 115 AC_CHECK_FUNCS(chmod stat fstat getenv putenv strerror ctime gettimeofday)
 116 AC_CHECK_FUNCS(getpid getgid getsid getpgid getpgrp getuid)
 117 AC_CHECK_FUNCS(setgroups initgroups)
 118 AC_CHECK_FUNCS(strchr strstr strcpy strncpy memcpy memset memmove utime iconv)
 119 AC_CHECK_FUNCS(pthread_create nl_langinfo)
 120
 121 # SIM support checking
 122 # XXX These needs to be changed as more supported platforms appear.
 123 # XXX This probably needs to be made platform dependant check.
 124 sim_support=false
 125 AM_CONDITIONAL(SILC_SIM, test x$sim_support = xtrue)
 126 AC_CHECKING(for SIM support)
 127 AC_CHECK_HEADERS(dlfcn.h,
 128   AC_CHECK_LIB(dl, dlopen,
 129     AC_DEFINE(SILC_SIM)
 130     sim_support=true
 131     AM_CONDITIONAL(SILC_SIM, test x$sim_support = xtrue)
 132     AC_MSG_RESULT(enabled SIM support)
 133     LIBS="$LIBS -ldl",
 134     AC_MSG_RESULT(no SIM support found)),
 135   AC_MSG_RESULT(no SIM support found))
 136
 137 #
 138 # Installation
 139 #
 140
 141 # Default installation destination
 142 AC_PREFIX_DEFAULT(/usr/local/silc)
 143
 144 if test "x$prefix" != xNONE; then
 145         silc_prefix="$prefix"
 146 else
 147         silc_prefix="$ac_default_prefix"
 148 fi
 149
 150 # etc directory
 151 if test "x$sysconfdir" != 'x${prefix}/etc'; then
 152         ETCDIR="$sysconfdir"
 153 else
 154         ETCDIR="$silc_prefix/etc"
 155 fi
 156 AC_ARG_WITH(etcdir,
 157 [  --with-etcdir[=PATH]      Directory for system files [/etc/silc]],
 158 [ case "$withval" in
 159   no)
 160     ;;
 161   yes)
 162     ETCDIR="$withval"
 163     ;;
 164   *)
 165     ETCDIR="$withval"
 166     ;;
 167   esac ],
 168 )
 169 AC_SUBST(ETCDIR)
 170 AC_DEFINE_UNQUOTED(SILC_ETCDIR, "$ETCDIR")
 171
 172 # help directory
 173 HELPDIR="$silc_prefix/help"
 174 AC_ARG_WITH(helpdir,
 175 [  --with-helpdir[=PATH]     Directory for SILC help files [PREFIX/help]],
 176 [ case "$withval" in
 177   no)
 178     ;;
 179   yes)
 180     HELPDIR="$withval"
 181     ;;
 182   *)
 183     HELPDIR="$withval"
 184     ;;
 185   esac ],
 186 )
 187 AC_SUBST(HELPDIR)
 188 AC_DEFINE_UNQUOTED(SILC_HELPDIR, "$HELPDIR")
 189
 190 # doc directory
 191 DOCDIR="$silc_prefix/doc"
 192 AC_ARG_WITH(docdir,
 193 [  --with-docdir[=PATH]      Directory for SILC documentation [PREFIX/doc]],
 194 [ case "$withval" in
 195   no)
 196     ;;
 197   yes)
 198     DOCDIR="$withval"
 199     ;;
 200   *)
 201     DOCDIR="$withval"
 202     ;;
 203   esac ],
 204 )
 205 AC_SUBST(DOCDIR)
 206 AC_DEFINE_UNQUOTED(SILC_DOCDIR, "$DOCDIR")
 207
 208 # SIM modules directory
 209 MODULESDIR="$silc_prefix/modules"
 210 AC_ARG_WITH(simdir,
 211 [  --with-simdir[=PATH]      Directory for SIM modules [PREFIX/modules]],
 212 [ case "$withval" in
 213   no)
 214     ;;
 215   yes)
 216     MODULESDIR="$withval"
 217     ;;
 218   *)
 219     MODULESDIR="$withval"
 220     ;;
 221   esac ],
 222 )
 223 AC_SUBST(MODULESDIR)
 224 AC_DEFINE_UNQUOTED(SILC_MODULESDIR, "$MODULESDIR")
 225
 226 # Logs directory
 227 LOGSDIR="$silc_prefix/logs"
 228 AC_ARG_WITH(logsdir,
 229 [  --with-logsdir[=PATH]     Directory for Server logs [PREFIX/logs]],
 230 [ case "$withval" in
 231   no)
 232     ;;
 233   yes)
 234     LOGSDIR="$withval"
 235     ;;
 236   *)
 237     LOGSDIR="$withval"
 238     ;;
 239   esac ],
 240 )
 241 AC_SUBST(LOGSDIR)
 242 AC_DEFINE_UNQUOTED(SILC_LOGSDIR, "$LOGSDIR")
 243
 244 # SOCKS4 support checking
 245 AC_MSG_CHECKING(whether to support SOCKS4)
 246 AC_ARG_WITH(socks4,
 247 [  --with-socks4[=PATH]      Compile with SOCKS4 support],
 248 [ case "$withval" in
 249   no)
 250     AC_MSG_RESULT(no)
 251     ;;
 252   *)
 253     AC_MSG_RESULT(yes)
 254     socks=4
 255
 256     if test -d "$withval/include"; then
 257       CFLAGS="$CFLAGS -I$withval/include"
 258     else
 259       CFLAGS="$CFLAGS -I$withval"
 260     fi
 261     if test -d "$withval/lib"; then
 262       withval="-L$withval/lib -lsocks"
 263     else
 264       withval="-L$withval -lsocks"
 265     fi
 266
 267     LIBS="$withval $LIBS"
 268
 269     AC_TRY_LINK([],
 270                 [ Rconnect(); ],
 271                 [],
 272                 [ AC_MSG_ERROR(Could not find SOCKS4 library.)])
 273       ;;
 274   esac ],
 275   AC_MSG_RESULT(no)
 276 )
 277
 278 # SOCKS5 support checking
 279 AC_MSG_CHECKING(whether to support SOCKS5)
 280 AC_ARG_WITH(socks5,
 281 [  --with-socks5[=PATH]      Compile with SOCKS5 support],
 282 [ case "$withval" in
 283   no)
 284     AC_MSG_RESULT(no)
 285     ;;
 286   *)
 287     AC_MSG_RESULT(yes)
 288     socks=5
 289
 290     if test -d "$withval/include"; then
 291       CFLAGS="$CFLAGS -I$withval/include"
 292     else
 293       CFLAGS="$CFLAGS -I$withval"
 294     fi
 295     if test -d "$withval/lib"; then
 296       withval="-L$withval/lib -lsocks5"
 297     else
 298       withval="-L$withval -lsocks5"
 299     fi
 300
 301     LIBS="$withval $LIBS"
 302
 303     AC_TRY_LINK([],
 304                 [ SOCKSconnect(); ],
 305                 [],
 306                 [ AC_MSG_ERROR(Could not find SOCKS5 library.)])
 307       ;;
 308   esac ],
 309   AC_MSG_RESULT(no)
 310 )
 311
 312 if test "x$socks" = "x4"; then
 313   AC_DEFINE(SOCKS)
 314   CFLAGS="$CFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 315 fi
 316
 317 if test "x$socks" = "x5"; then
 318   AC_DEFINE(SOCKS)
 319   AC_DEFINE(SOCKS5)
 320   AC_DEFINE(Rconnect, SOCKSconnect)
 321   AC_DEFINE(Rgetsockname, SOCKSgetsockname)
 322   AC_DEFINE(Rgetpeername, SOCKSgetpeername)
 323   AC_DEFINE(Rbind, SOCKSbind)
 324   AC_DEFINE(Raccept, SOCKSaccept)
 325   AC_DEFINE(Rlisten, SOCKSlisten)
 326   AC_DEFINE(Rselect, SOCKSselect)
 327   AC_DEFINE(Rrecvfrom, SOCKSrecvfrom)
 328   AC_DEFINE(Rsendto, SOCKSsendto)
 329   AC_DEFINE(Rrecv, SOCKSrecv)
 330   AC_DEFINE(Rsend, SOCKSsend)
 331   AC_DEFINE(Rread, SOCKSread)
 332   AC_DEFINE(Rwrite, SOCKSwrite)
 333   AC_DEFINE(Rrresvport, SOCKSrresvport)
 334   AC_DEFINE(Rshutdown, SOCKSshutdown)
 335   AC_DEFINE(Rlisten, SOCKSlisten)
 336   AC_DEFINE(Rclose, SOCKSclose)
 337   AC_DEFINE(Rdup, SOCKSdup)
 338   AC_DEFINE(Rdup2, SOCKSdup2)
 339   AC_DEFINE(Rfclose, SOCKSfclose)
 340   AC_DEFINE(Rgethostbyname, SOCKSgethostbyname)
 341 fi
 342
 343 #
 344 # MP library checking. First check whether user wants to use GMP and use
 345 # it if found. If not or not defined then compile the MPI library in the
 346 # source tree.
 347 #
 348 AC_MSG_CHECKING(whether to support GMP)
 349 AC_ARG_WITH(gmp,
 350 [  --with-gmp[=PATH]         Compile with GMP support instead of MPI],
 351 [ case "$withval" in
 352   no)
 353     AC_MSG_RESULT(no)
 354     mp_gmp=false
 355     ;;
 356   *)
 357     AC_MSG_RESULT(yes)
 358
 359     if test -d "$withval/include"; then
 360       CFLAGS="$CFLAGS -I$withval/include"
 361     else
 362       CFLAGS="$CFLAGS -I$withval"
 363     fi
 364     if test -d "$withval/lib"; then
 365       withval="-L$withval/lib -lgmp"
 366     else
 367       withval="-L$withval -lgmp"
 368     fi
 369
 370     LIBS="$withval $LIBS"
 371     mp_gmp=false
 372     AC_CHECK_LIB(gmp, __gmpz_init,
 373       mp_gmp=true
 374       AC_DEFINE(SILC_MP_GMP)
 375       AC_MSG_RESULT(Using GMP as MP library)
 376     )
 377       ;;
 378   esac ],
 379   AC_MSG_RESULT(no)
 380   mp_gmp=false
 381 )
 382
 383 AM_CONDITIONAL(SILC_MP_GMP, test x$mp_gmp = xtrue)
 384 AM_CONDITIONAL(SILC_MP_NSS_MPI, test x$mp_gmp = xfalse)
 385 if test x$mp_gmp = xfalse; then
 386   AC_DEFINE(SILC_MP_NSS_MPI)
 387   AC_MSG_RESULT(Using NSS MPI as MP library)
 388 fi
 389
 390 AC_ARG_WITH(silcd-config-file,
 391 [  --with-silcd-config-file[=PATH]
 392                           Use PATH as default configuration file in SILC
 393                           server [/etc/silc/silcd.conf]],
 394 [ AC_DEFINE_UNQUOTED(SILC_SERVER_CONFIG_FILE, "$withval") ])
 395
 396 if test "x$localstatedir" != 'x${prefix}/var'; then
 397         PIDFILE="$localstatedir/silcd.pid"
 398 else
 399         PIDFILE="$silc_prefix/var/silcd.pid"
 400 fi
 401 AC_ARG_WITH(silcd-pid-file,
 402 [  --with-silcd-pid-file[=PATH]
 403                           Use PATH as default pid file in SILC
 404                           server [/var/run/silcd.pid]],
 405 [ case "$withval" in
 406         no)
 407                 ;;
 408         yes)
 409                 PIDFILE="$withval"
 410                 ;;
 411         *)
 412                 PIDFILE="$withval"
 413                 ;;
 414         esac ],
 415 )
 416 AC_SUBST(PIDFILE)
 417
 418 #
 419 # Native WIN32 compilation under cygwin
 420 #
 421 AC_ARG_WITH(win32,
 422 [  --with-win32            Compile native WIN32 code (-mno-cygwin)],
 423 [ AC_DEFINE(SILC_WIN32)
 424   win32_support=true
 425   CFLAGS="-mno-cygwin $CFLAGS"
 426   LIBS="$LIBS -lwsock32" ])
 427
 428 AM_CONDITIONAL(SILC_WIN32, test x$win32_support = xtrue)
 429
 430 #
 431 # Native EPOC support (disabled by default)
 432 #
 433 AM_CONDITIONAL(SILC_EPOC, test xfalse = xtrue)
 434
 435 #
 436 # Native BeOS support (disabled by default)
 437 #
 438 AM_CONDITIONAL(SILC_BEOS, test xfalse = xtrue)
 439
 440 #
 441 # Native OS2 support (disabled by default)
 442 #
 443 AM_CONDITIONAL(SILC_OS2, test xfalse = xtrue)
 444
 445 #
 446 # --without-irssi
 447 #
 448 without_irssi=false
 449 AC_ARG_WITH(irssi,
 450 [  --without-irssi         Compile without Irssi SILC Client],
 451 [ without_irssi=true
 452   SILC_DIST_SUBDIRS=`echo $SILC_DIST_SUBDIRS | $sedpath -e 's/irssi//'`
 453 ])
 454
 455 #
 456 # --without-silcd
 457 #
 458 without_silcd=false
 459 AC_ARG_WITH(silcd,
 460 [  --without-silcd         Compile without SILC Server],
 461 [ without_silcd=true
 462   SILC_DIST_SUBDIRS=`echo $SILC_DIST_SUBDIRS | $sedpath -e 's/silcd//'`
 463 ])
 464
 465 #
 466 # IPv6 support
 467 #
 468 AC_MSG_CHECKING(for IPv6 support)
 469 AC_ARG_ENABLE(ipv6,
 470 [  --enable-ipv6           Enable IPv6 support],
 471 [ case "${enableval}" in
 472   yes)
 473     want_ipv6=true
 474     check_ipv6=false
 475     AC_DEFINE(HAVE_IPV6)
 476     AC_MSG_RESULT(yes)
 477     ;;
 478   *)
 479     want_ipv6=false
 480     check_ipv6=false
 481     AC_MSG_RESULT(no)
 482     ;;
 483 esac ], check_ipv6=true)
 484
 485 if test x$check_ipv6 = xtrue; then
 486   AC_TRY_COMPILE([#ifdef HAVE_NETINET_TCP_H
 487                   #include <netinet/tcp.h>
 488                   #endif
 489                   #ifdef HAVE_NETDB_H
 490                   #include <netdb.h>
 491                   #endif
 492                   #include <sys/socket.h>
 493                   #ifdef HAVE_NETDB_IN_H
 494                   #include <netinet/in.h>
 495                   #endif],
 496                   [struct sockaddr_in6 sin6;
 497                    int family = AF_INET6;
 498                   ], [AC_DEFINE(HAVE_IPV6)
 499                       AC_MSG_RESULT(yes)], [AC_MSG_RESULT(no)])
 500 fi
 501
 502 #
 503 # Debug checking
 504 #
 505 AC_MSG_CHECKING(for enabled debugging)
 506 AC_ARG_ENABLE(debug,
 507 [  --enable-debug          Enable debugging],
 508 [ case "${enableval}" in
 509   yes)
 510     AC_MSG_RESULT(yes)
 511     AC_DEFINE(SILC_DEBUG)
 512     CFLAGS="-O -g $CFLAGS"
 513     ;;
 514   *)
 515     AC_MSG_RESULT(no)
 516     CFLAGS="-O2 -g $CFLAGS"
 517     ;;
 518 esac ], CFLAGS="-O2 -g $CFLAGS"
 519         AC_MSG_RESULT(no))
 520
 521 AC_MSG_CHECKING(for enabled stack tracing)
 522 AC_ARG_ENABLE(stack-trace,
 523 [  --enable-stack-trace    Enable memory stack trace],
 524 [ case "${enableval}" in
 525   yes)
 526     AC_MSG_RESULT(yes)
 527     AC_DEFINE(SILC_STACKTRACE)
 528     ;;
 529   *)
 530     AC_MSG_RESULT(no)
 531     ;;
 532 esac ], AC_MSG_RESULT(no))
 533
 534 #
 535 # Disable all assembler optimizations
 536 #
 537 AC_ARG_ENABLE(asm,
 538 [  --disable-asm           Do not use assembler optimizations ],
 539 [])
 540
 541 #
 542 # Threads support
 543 #
 544 AC_ARG_ENABLE(threads,
 545 [  --disable-threads       Do not compile with multi-thread support],
 546 [ case "${enableval}" in
 547   yes)
 548     want_threads=true
 549     check_threads=true
 550     ;;
 551   *)
 552     want_threads=false
 553     check_threads=false
 554     ;;
 555 esac ])
 556
 557 if test x$check_threads = xtrue; then
 558 want_threads=false
 559 AC_CHECK_HEADERS(pthread.h,
 560         [ AC_DEFINE(SILC_HAVE_PTHREAD)
 561           want_threads=true ],
 562         [ if test -f /usr/pkg/include/pthread.h ; then
 563             AC_DEFINE(SILC_HAVE_PTHREAD)
 564             AC_MSG_RESULT(Found pthread.h in /usr/pkg/include/)
 565             CFLAGS="$CFLAGS -I/usr/pkg/include"
 566             want_threads=true
 567           elif test -f /usr/contrib/include/pthread.h ; then
 568             AC_DEFINE(SILC_HAVE_PTHREAD)
 569             AC_MSG_RESULT(Found pthread.h in /usr/contrib/include/)
 570             CFLAGS="$CFLAGS -I/usr/contrib/include"
 571             want_threads=true
 572           fi
 573         ])
 574
 575 AM_CONDITIONAL(SILC_THREADS, test x$want_threads = xtrue)
 576 if test x$want_threads = xtrue; then
 577   TMP_LIBS="$LIBS"
 578   LIBS="-lpthread"
 579   AC_TRY_LINK([#include <pthread.h>],
 580               [pthread_attr_t attr; pthread_attr_init(&attr);],
 581   AC_DEFINE(SILC_THREADS),
 582   LIBS="-L/usr/pkg/lib -lpthread"
 583   AC_TRY_LINK([#include <pthread.h>],
 584               [pthread_attr_t attr; pthread_attr_init(&attr);],
 585   AC_DEFINE(SILC_THREADS),
 586   LIBS="-L/usr/contrib/lib -lpthread"
 587   AC_TRY_LINK([#include <pthread.h>],
 588               [pthread_attr_t attr; pthread_attr_init(&attr);],
 589   AC_DEFINE(SILC_THREADS),
 590   LIBS=""
 591   )))
 592
 593   CFLAGS="$CFLAGS -D_REENTRANT"
 594   case $host in
 595     *-aix*)
 596       CFLAGS="$CFLAGS -D_THREAD_SAFE"
 597       if test x"$GCC" = xyes; then
 598         CFLAGS="$CFLAGS -mthreads"
 599       fi
 600       ;;
 601     *-freebsd2.2*)
 602       CFLAGS="$CFLAGS -D_THREAD_SAFE"
 603       ;;
 604     *-sysv5uw7*)  # UnixWare 7
 605       if test "$GCC" != "yes"; then
 606         CFLAGS="$CFLAGS -Kthread"
 607       else
 608         CFLAGS="$CFLAGS -pthread"
 609       fi
 610       ;;
 611     *-dg-dgux*)  # DG/UX
 612       CFLAGS="$CFLAGS -D_POSIX4A_DRAFT10_SOURCE"
 613       ;;
 614     esac
 615
 616   LIBS="$TMP_LIBS $LIBS"
 617 fi
 618 fi
 619
 620 #
 621 # Other configure scripts
 622 #
 623 if test x$without_irssi = xfalse; then
 624   if test "x$silc_dist" = "xsilc-client" ||
 625      test "x$silc_dist" = "xsilc-toolkit"; then
 626   AC_CONFIG_SUBDIRS(irssi)
 627   fi
 628 fi
 629
 630 AC_CONFIG_SUBDIRS(lib/silcmath/mpi)
 631 #AC_CONFIG_SUBDIRS(lib/zlib)
 632
 633 SILC_TOP_SRCDIR=`pwd`
 634 AC_SUBST(SILC_TOP_SRCDIR)
 635 #SILC_INSTALL_PREFIX=$ac_default_prefix
 636 #AC_SUBST(SILC_INSTALL_PREFIX)
 637 AC_SUBST(LIBS)
 638 INCLUDE_DEFINES_INT="include \$(top_srcdir)/Makefile.defines_int"
 639 AC_SUBST(INCLUDE_DEFINES_INT)
 640 AC_SUBST(SILC_DIST_SUBDIRS)
 641
 642 #
 643 # Makefile outputs
 644 #
 645 AC_CONFIG_FILES( \
 646 Makefile
 647 Makefile.defines
 648 Makefile.defines_int
 649 doc/Makefile
 650 includes/Makefile
 651 lib/Makefile
 652 lib/contrib/Makefile
 653 lib/silccore/Makefile
 654 lib/silccrypt/Makefile
 655 lib/silcmath/Makefile
 656 lib/silcmath/mpi/Makefile.defines
 657 lib/silcmath/mpi/Makefile.defines_int
 658 lib/silcsim/Makefile
 659 lib/silcske/Makefile
 660 lib/silcutil/Makefile
 661 lib/silcutil/unix/Makefile
 662 lib/silcutil/win32/Makefile
 663 lib/silcutil/beos/Makefile
 664 lib/silcutil/os2/Makefile
 665 lib/silcutil/epoc/Makefile
 666 lib/silcsftp/Makefile
 667 lib/silcsftp/tests/Makefile
 668 doc/example_silcd.conf
 669 )
 670
 671 if test "x$silc_dist" = "xsilc-client" ||
 672    test "x$silc_dist" = "xsilc-toolkit"; then
 673 AC_CONFIG_FILES(lib/silcclient/Makefile)
 674 fi
 675
 676 if test x$without_irssi = xfalse ; then
 677 if test "x$silc_dist" = "xsilc-client" ||
 678    test "x$silc_dist" = "xsilc-toolkit"; then
 679 AC_CONFIG_FILES( \
 680 irssi/Makefile.defines
 681 irssi/Makefile.defines_int
 682 )
 683 fi
 684 fi
 685
 686 if test x$without_silcd = xfalse ; then
 687 if test "x$silc_dist" = "xsilc-server" ||
 688    test "x$silc_dist" = "xsilc-toolkit"; then
 689 AC_CONFIG_FILES( \
 690 silcd/Makefile
 691 )
 692 fi
 693 fi
 694
 695 if test "x$silc_dist" = "xsilc-toolkit"; then
 696 AC_CONFIG_FILES( \
 697 silc/Makefile
 698 win32/Makefile
 699 win32/libsilc/Makefile
 700 win32/libsilcclient/Makefile
 701 )
 702 fi
 703
 704 AC_OUTPUT