configure.in.pre

   1 #
   2 #  configure.in
   3 #
   4 #  Author: Pekka Riikonen <priikone@poseidon.pspt.fi>
   5 #
   6 #  Copyright (C) 2000 - 2001 Pekka Riikonen
   7 #
   8 #  This program is free software; you can redistribute it and/or modify
   9 #  it under the terms of the GNU General Public License as published by
  10 #  the Free Software Foundation; either version 2 of the License, or
  11 #  (at your option) any later version.
  12 #
  13 #  This program is distributed in the hope that it will be useful,
  14 #  but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 #  GNU General Public License for more details.
  17 #
  18
  19 AC_INIT(includes/version.h)
  20
  21 # Compiler settings
  22 CFLAGS="-Wall $CFLAGS"
  23
  24 #
  25 # Put here any platform specific stuff
  26 #
  27 AC_CANONICAL_SYSTEM
  28 case "$target" in
  29   *-*-linux*|*-*-mklinux*)
  30     CFLAGS="-D_GNU_SOURCE $CFLAGS"
  31     ;;
  32   *)
  33     ;;
  34 esac
  35
  36 # ./prepare script will automatically put the correct version. Do not edit!
  37 AM_INIT_AUTOMAKE(SILC_PACKAGE, SILC_VERSION)
  38 AC_PREREQ(2.3)
  39 AM_CONFIG_HEADER(includes/silcdefs.h)
  40
  41 AC_PROG_CC
  42 AC_C_INLINE
  43 AC_C_CONST
  44 AC_ARG_PROGRAM
  45
  46 AC_PROG_LN_S
  47 AC_SUBST(LN_S)
  48
  49 # XXX
  50 # Compiler flags
  51 if test "$GCC"; then
  52   CFLAGS="-finline-functions $CFLAGS"
  53 else
  54   # Currently GCC is only supported compiler
  55   AC_MSG_ERROR(GCC is only supported compiler currently)
  56 fi
  57
  58 # Program checking
  59 AC_PROG_INSTALL
  60 AC_PROG_RANLIB
  61 AC_PROG_MAKE_SET
  62
  63 # Header checking
  64 AC_HEADER_STDC
  65 AC_HEADER_TIME
  66 AC_HEADER_STAT
  67
  68 # More header checking
  69 AC_CHECK_HEADERS(unistd.h string.h getopt.h errno.h fcntl.h assert.h)
  70 AC_CHECK_HEADERS(sys/types.h sys/stat.h sys/time.h)
  71 AC_CHECK_HEADERS(netinet/in.h netinet/tcp.h netdb.h)
  72 AC_CHECK_HEADERS(pwd.h grp.h termcap.h paths.h)
  73 AC_CHECK_HEADERS(ncurses.h signal.h ctype.h regex.h)
  74 AC_CHECK_HEADERS(arpa/inet.h sys/mman.h)
  75
  76 # Data type checking
  77 AC_TYPE_SIGNAL
  78 AC_TYPE_SIZE_T
  79 AC_TYPE_MODE_T
  80 AC_TYPE_UID_T
  81 AC_TYPE_PID_T
  82
  83 AC_CHECK_SIZEOF(long long, 0)
  84 AC_DEFINE_UNQUOTED(SILC_SIZEOF_LONG_LONG, $ac_cv_sizeof_long_long)
  85 AC_CHECK_SIZEOF(long, 0)
  86 AC_DEFINE_UNQUOTED(SILC_SIZEOF_LONG, $ac_cv_sizeof_long)
  87 AC_CHECK_SIZEOF(int, 0)
  88 AC_DEFINE_UNQUOTED(SILC_SIZEOF_INT, $ac_cv_sizeof_int)
  89 AC_CHECK_SIZEOF(short, 0)
  90 AC_DEFINE_UNQUOTED(SILC_SIZEOF_SHORT, $ac_cv_sizeof_short)
  91 AC_CHECK_SIZEOF(char, 0)
  92 AC_DEFINE_UNQUOTED(SILC_SIZEOF_CHAR, $ac_cv_sizeof_char)
  93 AC_CHECK_SIZEOF(void *, 0)
  94 AC_DEFINE_UNQUOTED(SILC_SIZEOF_VOID_P, $ac_cv_sizeof_void_p)
  95
  96 dnl Curses detection: Munged from Midnight Commander's configure.in
  97 AC_DEFUN(AC_CHECK_CURSES,[
  98         search_ncurses=true
  99         screen_manager=""
 100         has_curses=false
 101
 102         CFLAGS=${CFLAGS--O}
 103
 104         AC_SUBST(CURSES_LIBS)
 105         AC_SUBST(CURSES_INCLUDEDIR)
 106
 107         AC_ARG_WITH(sco,
 108           [  --with-sco              Use this to turn on SCO-specific code],[
 109           if test x$withval = xyes; then
 110                 AC_DEFINE(SCO_FLAVOR)
 111                 CFLAGS="$CFLAGS -D_SVID3"
 112           fi
 113         ])
 114
 115         AC_ARG_WITH(sunos-curses,
 116           [  --with-sunos-curses     Used to force SunOS 4.x curses],[
 117           if test x$withval = xyes; then
 118                 AC_USE_SUNOS_CURSES
 119           fi
 120         ])
 121
 122         AC_ARG_WITH(osf1-curses,
 123           [  --with-osf1-curses      Used to force OSF/1 curses],[
 124           if test x$withval = xyes; then
 125                 AC_USE_OSF1_CURSES
 126           fi
 127         ])
 128
 129         AC_ARG_WITH(vcurses,
 130           [  --with-vcurses[=incdir] Used to force SysV curses],
 131           if test x$withval != xyes; then
 132                 CURSES_INCLUDEDIR="-I$withval"
 133           fi
 134           AC_USE_SYSV_CURSES
 135         )
 136
 137         AC_ARG_WITH(ncurses,
 138           [  --with-ncurses[=dir]    Compile with ncurses/locate base dir],
 139           if test x$withval = xno ; then
 140                 search_ncurses=false
 141           elif test x$withval != xyes ; then
 142                 AC_NCURSES($withval/include, ncurses.h, -L$withval/lib -lncurses, -I$withval/include, "ncurses on $withval/include")
 143           fi
 144         )
 145
 146         if $search_ncurses
 147         then
 148                 AC_SEARCH_NCURSES()
 149         fi
 150 ])
 151
 152
 153 AC_DEFUN(AC_USE_SUNOS_CURSES, [
 154         search_ncurses=false
 155         screen_manager="SunOS 4.x /usr/5include curses"
 156         AC_MSG_RESULT(Using SunOS 4.x /usr/5include curses)
 157         AC_DEFINE(USE_SUNOS_CURSES)
 158         AC_DEFINE(HAS_CURSES)
 159         has_curses=true
 160         AC_DEFINE(NO_COLOR_CURSES)
 161         AC_DEFINE(USE_SYSV_CURSES)
 162         CURSES_INCLUDEDIR="-I/usr/5include"
 163         CURSES_LIBS="/usr/5lib/libcurses.a /usr/5lib/libtermcap.a"
 164         AC_MSG_RESULT(Please note that some screen refreshs may fail)
 165 ])
 166
 167 AC_DEFUN(AC_USE_OSF1_CURSES, [
 168        AC_MSG_RESULT(Using OSF1 curses)
 169        search_ncurses=false
 170        screen_manager="OSF1 curses"
 171        AC_DEFINE(HAS_CURSES)
 172        has_curses=true
 173        AC_DEFINE(NO_COLOR_CURSES)
 174        AC_DEFINE(USE_SYSV_CURSES)
 175        CURSES_LIBS="-lcurses"
 176 ])
 177
 178 AC_DEFUN(AC_USE_SYSV_CURSES, [
 179         AC_MSG_RESULT(Using SysV curses)
 180         AC_DEFINE(HAS_CURSES)
 181         has_curses=true
 182         AC_DEFINE(USE_SYSV_CURSES)
 183         search_ncurses=false
 184         screen_manager="SysV/curses"
 185         CURSES_LIBS="-lcurses"
 186 ])
 187
 188 dnl
 189 dnl Parameters: directory filename cureses_LIBS curses_INCLUDEDIR nicename
 190 dnl
 191 AC_DEFUN(AC_NCURSES, [
 192     if $search_ncurses
 193     then
 194         if test -f $1/$2
 195         then
 196             AC_MSG_RESULT(Found ncurses on $1/$2)
 197
 198             CURSES_LIBS="$3"
 199             AC_CHECK_LIB(ncurses, initscr, [
 200             ], [
 201                 CHECKLIBS=`echo "$3"|sed 's/-lncurses/-lcurses/g'`
 202                 AC_CHECK_LIB(curses, initscr, [
 203                         CURSES_LIBS="$CHECKLIBS"
 204                 ],, $CHECKLIBS)
 205             ], $CURSES_LIBS)
 206             CURSES_INCLUDEDIR="$4"
 207             search_ncurses=false
 208             screen_manager=$5
 209             AC_DEFINE(HAS_CURSES)
 210             has_curses=true
 211             has_ncurses=true
 212             AC_DEFINE(USE_NCURSES)
 213         fi
 214     fi
 215 ])
 216
 217 AC_DEFUN(AC_SEARCH_NCURSES, [
 218     AC_CHECKING("location of ncurses.h file")
 219
 220     AC_NCURSES(/usr/include, ncurses.h, -lncurses,, "ncurses on /usr/include")
 221     AC_NCURSES(/usr/include/ncurses, ncurses.h, -lncurses, -I/usr/include/ncurses, "ncurses on /usr/include/ncurses")
 222     AC_NCURSES(/usr/local/include, ncurses.h, -L/usr/local/lib -lncurses, -I/usr/local/include, "ncurses on /usr/local")
 223     AC_NCURSES(/usr/pkg/include, ncurses.h, -L/usr/pkg/lib -lncurses, -I/usr/pkg/include, "ncurses on /usr/pkg")
 224     AC_NCURSES(/usr/contrib/include, ncurses.h, -L/usr/contrib/lib -lncurses, -I/usr/contrib/include, "ncurses on /usr/contrib")
 225     AC_NCURSES(/usr/local/include/ncurses, ncurses.h, -L/usr/local/lib -L/usr/local/lib/ncurses -lncurses, -I/usr/local/include/ncurses, "ncurses on /usr/local/include/ncurses")
 226
 227     AC_NCURSES(/usr/local/include/ncurses, curses.h, -L/usr/local/lib -lncurses, -I/usr/local/include/ncurses -DRENAMED_NCURSES, "renamed ncurses on /usr/local/.../ncurses")
 228
 229     AC_NCURSES(/usr/include/ncurses, curses.h, -lncurses, -I/usr/include/ncurses -DRENAMED_NCURSES, "renamed ncurses on /usr/include/ncurses")
 230
 231     dnl
 232     dnl We couldn't find ncurses, try SysV curses
 233     dnl
 234     if $search_ncurses
 235     then
 236         AC_EGREP_HEADER(init_color, /usr/include/curses.h,
 237             AC_USE_SYSV_CURSES)
 238         AC_EGREP_CPP(USE_NCURSES,[
 239 #include <curses.h>
 240 #ifdef __NCURSES_H
 241 #undef USE_NCURSES
 242 USE_NCURSES
 243 #endif
 244 ],[
 245         CURSES_INCLUDEDIR="$CURSES_INCLUDEDIR -DRENAMED_NCURSES"
 246         AC_DEFINE(HAS_CURSES)
 247         has_curses=true
 248         has_ncurses=true
 249         AC_DEFINE(USE_NCURSES)
 250         search_ncurses=false
 251         screen_manager="ncurses installed as curses"
 252 ])
 253     fi
 254
 255     dnl
 256     dnl Try SunOS 4.x /usr/5{lib,include} ncurses
 257     dnl The flags USE_SUNOS_CURSES, USE_BSD_CURSES and BUGGY_CURSES
 258     dnl should be replaced by a more fine grained selection routine
 259     dnl
 260     if $search_ncurses
 261     then
 262         if test -f /usr/5include/curses.h
 263         then
 264             AC_USE_SUNOS_CURSES
 265         fi
 266     fi
 267
 268     dnl use whatever curses there happens to be
 269     if $search_ncurses
 270     then
 271         if test -f /usr/include/curses.h
 272         then
 273           CURSES_LIBS="-lcurses"
 274           AC_DEFINE(HAS_CURSES)
 275           has_curses=true
 276           search_ncurses=false
 277           screen_manager="curses"
 278         fi
 279     fi
 280 ])
 281
 282 AC_CHECK_CURSES
 283 LIBS="$LIBS $CURSES_LIBS"
 284
 285 # Function and library checking
 286 AC_CHECK_FUNC(gethostbyname, ac_gethostbyname_found=1,
 287 ac_gethostbyname_found=0)
 288 if test x$ac_gethostbyname_found = x0; then
 289     AC_CHECK_LIB(nsl, gethostbyname, LIBS="$LIBS -lnsl")
 290     AC_CHECK_FUNC(res_gethostbyname, ac_res_ghbn_found=1, ac_res_ghbn_found=0)
 291     if test x$ac_res_ghbn_found = x0; then
 292         AC_CHECK_LIB(resolv, res_gethostbyname,  LIBS="$LIBS -lresolv")
 293     fi
 294 fi
 295 AC_CHECK_FUNC(socket, ac_socket_found=1, ac_socket_found=0)
 296 if test x$ac_socket_found = x0; then
 297     AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
 298 fi
 299 AC_CHECK_FUNCS(gethostname gethostbyaddr getservbyname getservbyport)
 300 AC_CHECK_FUNCS(select listen bind shutdown close connect)
 301 AC_CHECK_FUNCS(fcntl setsockopt)
 302 AC_CHECK_FUNCS(getopt_long time)
 303 AC_CHECK_FUNCS(mlock munlock)
 304 AC_CHECK_FUNCS(chmod stat fstat getenv putenv strerror ctime gettimeofday)
 305 AC_CHECK_FUNCS(getpid getgid getsid getpgid getpgrp getuid)
 306 AC_CHECK_FUNCS(strchr strstr strcpy strncpy memcpy memset memmove)
 307
 308 # SIM support checking
 309 # XXX These needs to be changed as more supported platforms appear.
 310 # XXX This probably needs to be made platform dependant check.
 311 sim_support=false
 312 AM_CONDITIONAL(SILC_SIM, test x$sim_support = xtrue)
 313 AC_CHECKING(for SIM support)
 314 AC_CHECK_HEADERS(dlfcn.h,
 315   AC_CHECK_LIB(dl, dlopen,
 316     AC_DEFINE(SILC_SIM)
 317     sim_support=true
 318     AM_CONDITIONAL(SILC_SIM, test x$sim_support = xtrue)
 319     AC_MSG_RESULT(enabled SIM support)
 320     LIBS="$LIBS -ldl",
 321     AC_MSG_RESULT(no SIM support found)),
 322   AC_MSG_RESULT(no SIM support found))
 323
 324 #
 325 # Installation
 326 #
 327
 328 # Default installation destination
 329 AC_PREFIX_DEFAULT(/usr/local/silc)
 330
 331 # etc directory
 332 ETCDIR="/etc/silc"
 333 AC_ARG_WITH(etcdir,
 334 [  --with-etcdir[=PATH]    Directory for system files [/etc/silc]],
 335 [ case "$withval" in
 336   no)
 337     ;;
 338   yes)
 339     ETCDIR="$withval"
 340     ;;
 341   *)
 342     ETCDIR="$withval"
 343     ;;
 344   esac ],
 345 )
 346 AC_SUBST(ETCDIR)
 347
 348 # help directory
 349 HELPDIR="help"
 350 AC_ARG_WITH(helpdir,
 351 [  --with-helpdir[=PATH]   Directory for SILC help files [PREFIX/help]],
 352 [ case "$withval" in
 353   no)
 354     ;;
 355   yes)
 356     HELPDIR="$withval"
 357     ;;
 358   *)
 359     HELPDIR="$withval"
 360     ;;
 361   esac ],
 362 )
 363 AC_SUBST(HELPDIR)
 364
 365 # doc directory
 366 DOCDIR="doc"
 367 AC_ARG_WITH(docdir,
 368 [  --with-docdir[=PATH]    Directory for SILC documentation [PREFIX/doc]],
 369 [ case "$withval" in
 370   no)
 371     ;;
 372   yes)
 373     DOCDIR="$withval"
 374     ;;
 375   *)
 376     DOCDIR="$withval"
 377     ;;
 378   esac ],
 379 )
 380 AC_SUBST(DOCDIR)
 381
 382 # SIM modules directory
 383 MODULESDIR="modules"
 384 AC_ARG_WITH(simdir,
 385 [  --with-simdir[=PATH]    Directory for SIM modules [PREFIX/modules]],
 386 [ case "$withval" in
 387   no)
 388     ;;
 389   yes)
 390     MODULESDIR="$withval"
 391     ;;
 392   *)
 393     MODULESDIR="$withval"
 394     ;;
 395   esac ],
 396 )
 397 AC_SUBST(MODULESDIR)
 398
 399 # Logs directory
 400 LOGSDIR="logs"
 401 AC_ARG_WITH(logsdir,
 402 [  --with-logsdir[=PATH]   Directory for Server logs [PREFIX/logs]],
 403 [ case "$withval" in
 404   no)
 405     ;;
 406   yes)
 407     LOGSDIR="$withval"
 408     ;;
 409   *)
 410     LOGSDIR="$withval"
 411     ;;
 412   esac ],
 413 )
 414 AC_SUBST(LOGSDIR)
 415
 416 # Debug checking
 417 AC_MSG_CHECKING(for enabled debugging)
 418 AC_ARG_ENABLE(debug,
 419 [  --enable-debug          Enable debugging (warning: it is heavy!)],
 420 [ case "${enableval}" in
 421   yes)
 422     AC_MSG_RESULT(yes)
 423     AC_DEFINE(SILC_DEBUG)
 424     CFLAGS="-O -g $CFLAGS"
 425     ;;
 426   *)
 427     AC_MSG_RESULT(no)
 428     CFLAGS="-O2 -g $CFLAGS"
 429     ;;
 430 esac ], CFLAGS="-O2 -g $CFLAGS"
 431         AC_MSG_RESULT(no))
 432
 433 # SOCKS4 support checking
 434 AC_MSG_CHECKING(whether to support SOCKS4)
 435 AC_ARG_WITH(socks4,
 436 [  --with-socks4[=PATH]    Compile with SOCKS4 support],
 437 [ case "$withval" in
 438   no)
 439     AC_MSG_RESULT(no)
 440     ;;
 441   *)
 442     AC_MSG_RESULT(yes)
 443     socks=4
 444
 445     if test -d "$withval/include"; then
 446       CFLAGS="$CFLAGS -I$withval/include"
 447     else
 448       CFLAGS="$CFLAGS -I$withval"
 449     fi
 450     if test -d "$withval/lib"; then
 451       withval="-L$withval/lib -lsocks"
 452     else
 453       withval="-L$withval -lsocks"
 454     fi
 455
 456     LIBS="$withval $LIBS"
 457
 458     AC_TRY_LINK([],
 459                 [ Rconnect(); ],
 460                 [],
 461                 [ AC_MSG_ERROR(Could not find SOCKS4 library.)])
 462       ;;
 463   esac ],
 464   AC_MSG_RESULT(no)
 465 )
 466
 467 # SOCKS5 support checking
 468 AC_MSG_CHECKING(whether to support SOCKS5)
 469 AC_ARG_WITH(socks5,
 470 [  --with-socks5[=PATH]    Compile with SOCKS5 support],
 471 [ case "$withval" in
 472   no)
 473     AC_MSG_RESULT(no)
 474     ;;
 475   *)
 476     AC_MSG_RESULT(yes)
 477     socks=5
 478
 479     if test -d "$withval/include"; then
 480       CFLAGS="$CFLAGS -I$withval/include"
 481     else
 482       CFLAGS="$CFLAGS -I$withval"
 483     fi
 484     if test -d "$withval/lib"; then
 485       withval="-L$withval/lib -lsocks5"
 486     else
 487       withval="-L$withval -lsocks5"
 488     fi
 489
 490     LIBS="$withval $LIBS"
 491
 492     AC_TRY_LINK([],
 493                 [ SOCKSconnect(); ],
 494                 [],
 495                 [ AC_MSG_ERROR(Could not find SOCKS5 library.)])
 496       ;;
 497   esac ],
 498   AC_MSG_RESULT(no)
 499 )
 500
 501 if test "x$socks" = "x4"; then
 502   AC_DEFINE(SOCKS)
 503   CFLAGS="$CFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 504 fi
 505
 506 if test "x$socks" = "x5"; then
 507   AC_DEFINE(SOCKS)
 508   AC_DEFINE(SOCKS5)
 509   AC_DEFINE(Rconnect, SOCKSconnect)
 510   AC_DEFINE(Rgetsockname, SOCKSgetsockname)
 511   AC_DEFINE(Rgetpeername, SOCKSgetpeername)
 512   AC_DEFINE(Rbind, SOCKSbind)
 513   AC_DEFINE(Raccept, SOCKSaccept)
 514   AC_DEFINE(Rlisten, SOCKSlisten)
 515   AC_DEFINE(Rselect, SOCKSselect)
 516   AC_DEFINE(Rrecvfrom, SOCKSrecvfrom)
 517   AC_DEFINE(Rsendto, SOCKSsendto)
 518   AC_DEFINE(Rrecv, SOCKSrecv)
 519   AC_DEFINE(Rsend, SOCKSsend)
 520   AC_DEFINE(Rread, SOCKSread)
 521   AC_DEFINE(Rwrite, SOCKSwrite)
 522   AC_DEFINE(Rrresvport, SOCKSrresvport)
 523   AC_DEFINE(Rshutdown, SOCKSshutdown)
 524   AC_DEFINE(Rlisten, SOCKSlisten)
 525   AC_DEFINE(Rclose, SOCKSclose)
 526   AC_DEFINE(Rdup, SOCKSdup)
 527   AC_DEFINE(Rdup2, SOCKSdup2)
 528   AC_DEFINE(Rfclose, SOCKSfclose)
 529   AC_DEFINE(Rgethostbyname, SOCKSgethostbyname)
 530 fi
 531
 532 # GMP Library checking
 533 AC_MSG_CHECKING(whether to compile GMP)
 534 AC_ARG_WITH(gmp,
 535 [  --with-gmp              Build the GMP in the SILC source tree],
 536 [ case "${withval}" in
 537   yes)
 538     AM_CONDITIONAL(SILC_BUILD_GMP, test x$withval = xyes)
 539     AC_MSG_RESULT(yes)
 540     ;;
 541   *)
 542     AC_CHECK_HEADER(gmp.h,
 543       AC_CHECK_LIB(gmp, __gmpz_init,
 544         AM_CONDITIONAL(SILC_BUILD_GMP, test x$withval = yes)
 545         LIBS="$LIBS -L/usr/lib -L/usr/local/lib -lgmp"
 546         AC_MSG_RESULT(GMP will not be compiled),
 547         AM_CONDITIONAL(SILC_BUILD_GMP, test x$withval != yes)
 548         AC_MSG_RESULT(GMP will be compiled)
 549       ),
 550       AM_CONDITIONAL(SILC_BUILD_GMP, test x$withval != yes)
 551       AC_MSG_RESULT(GMP will be compiled)
 552     )
 553     ;;
 554 esac ], [
 555   AC_CHECK_HEADER(gmp.h,
 556     AC_CHECK_LIB(gmp, __gmpz_init,
 557       build_gmp=false
 558       AM_CONDITIONAL(SILC_BUILD_GMP, test x$build_gmp = xtrue)
 559       LIBS="$LIBS -L/usr/lib -L/usr/local/lib -lgmp"
 560       AC_MSG_RESULT(GMP will not be compiled),
 561       build_gmp=true
 562       AM_CONDITIONAL(SILC_BUILD_GMP, test x$build_gmp = xtrue)
 563       AC_MSG_RESULT(GMP will be compiled)
 564     ),
 565     build_gmp=true
 566     AM_CONDITIONAL(SILC_BUILD_GMP, test x$build_gmp = xtrue)
 567     AC_MSG_RESULT(GMP will be compiled)
 568   )
 569 ])
 570
 571 AC_ARG_WITH(silcd-config-file,
 572 [  --with-silcd-config-file[=PATH]
 573                           Use PATH as default configuration file in SILC
 574                           server [/etc/silc/silcd.conf]],
 575 [ AC_DEFINE_UNQUOTED(SILC_SERVER_CONFIG_FILE, "$withval") ])
 576
 577 #
 578 # Other configure scripts
 579 #
 580 AC_CONFIG_SUBDIRS(irssi)
 581 AC_CONFIG_SUBDIRS(lib/dotconf)
 582 AC_CONFIG_SUBDIRS(lib/silcmath/gmp)
 583 AC_CONFIG_SUBDIRS(lib/trq)
 584 #AC_CONFIG_SUBDIRS(lib/zlib)
 585
 586 SILC_TOP_SRCDIR=`pwd`
 587 AC_SUBST(SILC_TOP_SRCDIR)
 588 #SILC_INSTALL_PREFIX=$ac_default_prefix
 589 #AC_SUBST(SILC_INSTALL_PREFIX)
 590 AC_SUBST(LIBS)
 591 INCLUDE_DEFINES_INT="include \$(top_srcdir)/Makefile.defines_int"
 592 AC_SUBST(INCLUDE_DEFINES_INT)
 593
 594 #
 595 # Makefile outputs
 596 #
 597 AC_OUTPUT( \
 598 Makefile
 599 Makefile.defines
 600 Makefile.defines_int
 601 irssi/Makefile.defines
 602 irssi/Makefile.defines_int
 603 doc/Makefile
 604 includes/Makefile
 605 lib/Makefile
 606 lib/contrib/Makefile
 607 lib/silcclient/Makefile
 608 lib/silccore/Makefile
 609 lib/silccrypt/Makefile
 610 lib/silcmath/Makefile
 611 lib/silcsim/Makefile
 612 lib/silcsim/modules/Makefile
 613 lib/silcske/Makefile
 614 lib/silcutil/Makefile
 615 silc/Makefile
 616 silcd/Makefile)