configure.in.pre

   1 #
   2 #  configure.in
   3 #
   4 #  Author: Pekka Riikonen <priikone@poseidon.pspt.fi>
   5 #
   6 #  Copyright (C) 2000 - 2001 Pekka Riikonen
   7 #
   8 #  This program is free software; you can redistribute it and/or modify
   9 #  it under the terms of the GNU General Public License as published by
  10 #  the Free Software Foundation; either version 2 of the License, or
  11 #  (at your option) any later version.
  12 #
  13 #  This program is distributed in the hope that it will be useful,
  14 #  but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 #  GNU General Public License for more details.
  17 #
  18
  19 AC_INIT(includes/version.h)
  20
  21 # Compiler settings
  22 CFLAGS="-Wall $CFLAGS"
  23
  24 #
  25 # Put here any platform specific stuff
  26 #
  27 AC_CANONICAL_SYSTEM
  28 case "$target" in
  29   *-*-linux*|*-*-mklinux*)
  30     CFLAGS="-D_GNU_SOURCE $CFLAGS"
  31     ;;
  32   *)
  33     ;;
  34 esac
  35
  36 # ./prepare script will automatically put the correct version. Do not edit!
  37 AM_INIT_AUTOMAKE(SILC_PACKAGE, SILC_VERSION)
  38 AC_PREREQ(2.3)
  39 AM_CONFIG_HEADER(includes/silcdefs.h)
  40
  41 AC_PROG_CC
  42 AC_C_INLINE
  43 AC_C_CONST
  44 AC_ARG_PROGRAM
  45
  46 AC_PROG_LN_S
  47 AC_SUBST(LN_S)
  48
  49 # Distribution definition. ./prepare will automatically add here a correct
  50 # value. Do not edit!
  51 AC_DEFINE(SILC_DIST_DEFINE)
  52 AM_CONDITIONAL(SILC_DIST_DEFINE, test xtrue = xtrue)
  53
  54 # XXX
  55 # Compiler flags
  56 if test "$GCC"; then
  57   CFLAGS="-finline-functions $CFLAGS"
  58 else
  59   # Currently GCC is only supported compiler
  60   AC_MSG_ERROR(GCC is only supported compiler currently)
  61 fi
  62
  63 # Program checking
  64 AC_PROG_INSTALL
  65 AC_PROG_RANLIB
  66 AC_PROG_MAKE_SET
  67
  68 # Header checking
  69 AC_HEADER_STDC
  70 AC_HEADER_TIME
  71 AC_HEADER_STAT
  72
  73 # More header checking
  74 AC_CHECK_HEADERS(unistd.h string.h getopt.h errno.h fcntl.h assert.h)
  75 AC_CHECK_HEADERS(sys/types.h sys/stat.h sys/time.h)
  76 AC_CHECK_HEADERS(netinet/in.h netinet/tcp.h netdb.h)
  77 AC_CHECK_HEADERS(pwd.h grp.h termcap.h paths.h)
  78 AC_CHECK_HEADERS(ncurses.h signal.h ctype.h regex.h)
  79 AC_CHECK_HEADERS(arpa/inet.h sys/mman.h)
  80
  81 # Data type checking
  82 AC_TYPE_SIGNAL
  83 AC_TYPE_SIZE_T
  84 AC_TYPE_MODE_T
  85 AC_TYPE_UID_T
  86 AC_TYPE_PID_T
  87
  88 AC_CHECK_SIZEOF(long long, 0)
  89 AC_DEFINE_UNQUOTED(SILC_SIZEOF_LONG_LONG, $ac_cv_sizeof_long_long)
  90 AC_CHECK_SIZEOF(long, 0)
  91 AC_DEFINE_UNQUOTED(SILC_SIZEOF_LONG, $ac_cv_sizeof_long)
  92 AC_CHECK_SIZEOF(int, 0)
  93 AC_DEFINE_UNQUOTED(SILC_SIZEOF_INT, $ac_cv_sizeof_int)
  94 AC_CHECK_SIZEOF(short, 0)
  95 AC_DEFINE_UNQUOTED(SILC_SIZEOF_SHORT, $ac_cv_sizeof_short)
  96 AC_CHECK_SIZEOF(char, 0)
  97 AC_DEFINE_UNQUOTED(SILC_SIZEOF_CHAR, $ac_cv_sizeof_char)
  98 AC_CHECK_SIZEOF(void *, 0)
  99 AC_DEFINE_UNQUOTED(SILC_SIZEOF_VOID_P, $ac_cv_sizeof_void_p)
 100
 101 dnl Curses detection: Munged from Midnight Commander's configure.in
 102 AC_DEFUN(AC_CHECK_CURSES,[
 103         search_ncurses=true
 104         screen_manager=""
 105         has_curses=false
 106
 107         CFLAGS=${CFLAGS--O}
 108
 109         AC_SUBST(CURSES_LIBS)
 110         AC_SUBST(CURSES_INCLUDEDIR)
 111
 112         AC_ARG_WITH(sco,
 113           [  --with-sco              Use this to turn on SCO-specific code],[
 114           if test x$withval = xyes; then
 115                 AC_DEFINE(SCO_FLAVOR)
 116                 CFLAGS="$CFLAGS -D_SVID3"
 117           fi
 118         ])
 119
 120         AC_ARG_WITH(sunos-curses,
 121           [  --with-sunos-curses     Used to force SunOS 4.x curses],[
 122           if test x$withval = xyes; then
 123                 AC_USE_SUNOS_CURSES
 124           fi
 125         ])
 126
 127         AC_ARG_WITH(osf1-curses,
 128           [  --with-osf1-curses      Used to force OSF/1 curses],[
 129           if test x$withval = xyes; then
 130                 AC_USE_OSF1_CURSES
 131           fi
 132         ])
 133
 134         AC_ARG_WITH(vcurses,
 135           [  --with-vcurses[=incdir] Used to force SysV curses],
 136           if test x$withval != xyes; then
 137                 CURSES_INCLUDEDIR="-I$withval"
 138           fi
 139           AC_USE_SYSV_CURSES
 140         )
 141
 142         AC_ARG_WITH(ncurses,
 143           [  --with-ncurses[=dir]    Compile with ncurses/locate base dir],
 144           if test x$withval = xno ; then
 145                 search_ncurses=false
 146           elif test x$withval != xyes ; then
 147                 AC_NCURSES($withval/include, ncurses.h, -L$withval/lib -lncurses, -I$withval/include, "ncurses on $withval/include")
 148           fi
 149         )
 150
 151         if $search_ncurses
 152         then
 153                 AC_SEARCH_NCURSES()
 154         fi
 155 ])
 156
 157
 158 AC_DEFUN(AC_USE_SUNOS_CURSES, [
 159         search_ncurses=false
 160         screen_manager="SunOS 4.x /usr/5include curses"
 161         AC_MSG_RESULT(Using SunOS 4.x /usr/5include curses)
 162         AC_DEFINE(USE_SUNOS_CURSES)
 163         AC_DEFINE(HAS_CURSES)
 164         has_curses=true
 165         AC_DEFINE(NO_COLOR_CURSES)
 166         AC_DEFINE(USE_SYSV_CURSES)
 167         CURSES_INCLUDEDIR="-I/usr/5include"
 168         CURSES_LIBS="/usr/5lib/libcurses.a /usr/5lib/libtermcap.a"
 169         AC_MSG_RESULT(Please note that some screen refreshs may fail)
 170 ])
 171
 172 AC_DEFUN(AC_USE_OSF1_CURSES, [
 173        AC_MSG_RESULT(Using OSF1 curses)
 174        search_ncurses=false
 175        screen_manager="OSF1 curses"
 176        AC_DEFINE(HAS_CURSES)
 177        has_curses=true
 178        AC_DEFINE(NO_COLOR_CURSES)
 179        AC_DEFINE(USE_SYSV_CURSES)
 180        CURSES_LIBS="-lcurses"
 181 ])
 182
 183 AC_DEFUN(AC_USE_SYSV_CURSES, [
 184         AC_MSG_RESULT(Using SysV curses)
 185         AC_DEFINE(HAS_CURSES)
 186         has_curses=true
 187         AC_DEFINE(USE_SYSV_CURSES)
 188         search_ncurses=false
 189         screen_manager="SysV/curses"
 190         CURSES_LIBS="-lcurses"
 191 ])
 192
 193 dnl
 194 dnl Parameters: directory filename cureses_LIBS curses_INCLUDEDIR nicename
 195 dnl
 196 AC_DEFUN(AC_NCURSES, [
 197     if $search_ncurses
 198     then
 199         if test -f $1/$2
 200         then
 201             AC_MSG_RESULT(Found ncurses on $1/$2)
 202
 203             CURSES_LIBS="$3"
 204             AC_CHECK_LIB(ncurses, initscr, [
 205             ], [
 206                 CHECKLIBS=`echo "$3"|sed 's/-lncurses/-lcurses/g'`
 207                 AC_CHECK_LIB(curses, initscr, [
 208                         CURSES_LIBS="$CHECKLIBS"
 209                 ],, $CHECKLIBS)
 210             ], $CURSES_LIBS)
 211             CURSES_INCLUDEDIR="$4"
 212             search_ncurses=false
 213             screen_manager=$5
 214             AC_DEFINE(HAS_CURSES)
 215             has_curses=true
 216             has_ncurses=true
 217             AC_DEFINE(USE_NCURSES)
 218         fi
 219     fi
 220 ])
 221
 222 AC_DEFUN(AC_SEARCH_NCURSES, [
 223     AC_CHECKING("location of ncurses.h file")
 224
 225     AC_NCURSES(/usr/include, ncurses.h, -lncurses,, "ncurses on /usr/include")
 226     AC_NCURSES(/usr/include/ncurses, ncurses.h, -lncurses, -I/usr/include/ncurses, "ncurses on /usr/include/ncurses")
 227     AC_NCURSES(/usr/local/include, ncurses.h, -L/usr/local/lib -lncurses, -I/usr/local/include, "ncurses on /usr/local")
 228     AC_NCURSES(/usr/pkg/include, ncurses.h, -L/usr/pkg/lib -lncurses, -I/usr/pkg/include, "ncurses on /usr/pkg")
 229     AC_NCURSES(/usr/contrib/include, ncurses.h, -L/usr/contrib/lib -lncurses, -I/usr/contrib/include, "ncurses on /usr/contrib")
 230     AC_NCURSES(/usr/local/include/ncurses, ncurses.h, -L/usr/local/lib -L/usr/local/lib/ncurses -lncurses, -I/usr/local/include/ncurses, "ncurses on /usr/local/include/ncurses")
 231
 232     AC_NCURSES(/usr/local/include/ncurses, curses.h, -L/usr/local/lib -lncurses, -I/usr/local/include/ncurses -DRENAMED_NCURSES, "renamed ncurses on /usr/local/.../ncurses")
 233
 234     AC_NCURSES(/usr/include/ncurses, curses.h, -lncurses, -I/usr/include/ncurses -DRENAMED_NCURSES, "renamed ncurses on /usr/include/ncurses")
 235
 236     dnl
 237     dnl We couldn't find ncurses, try SysV curses
 238     dnl
 239     if $search_ncurses
 240     then
 241         AC_EGREP_HEADER(init_color, /usr/include/curses.h,
 242             AC_USE_SYSV_CURSES)
 243         AC_EGREP_CPP(USE_NCURSES,[
 244 #include <curses.h>
 245 #ifdef __NCURSES_H
 246 #undef USE_NCURSES
 247 USE_NCURSES
 248 #endif
 249 ],[
 250         CURSES_INCLUDEDIR="$CURSES_INCLUDEDIR -DRENAMED_NCURSES"
 251         AC_DEFINE(HAS_CURSES)
 252         has_curses=true
 253         has_ncurses=true
 254         AC_DEFINE(USE_NCURSES)
 255         search_ncurses=false
 256         screen_manager="ncurses installed as curses"
 257 ])
 258     fi
 259
 260     dnl
 261     dnl Try SunOS 4.x /usr/5{lib,include} ncurses
 262     dnl The flags USE_SUNOS_CURSES, USE_BSD_CURSES and BUGGY_CURSES
 263     dnl should be replaced by a more fine grained selection routine
 264     dnl
 265     if $search_ncurses
 266     then
 267         if test -f /usr/5include/curses.h
 268         then
 269             AC_USE_SUNOS_CURSES
 270         fi
 271     fi
 272
 273     dnl use whatever curses there happens to be
 274     if $search_ncurses
 275     then
 276         if test -f /usr/include/curses.h
 277         then
 278           CURSES_LIBS="-lcurses"
 279           AC_DEFINE(HAS_CURSES)
 280           has_curses=true
 281           search_ncurses=false
 282           screen_manager="curses"
 283         fi
 284     fi
 285 ])
 286
 287 AC_CHECK_CURSES
 288 LIBS="$LIBS $CURSES_LIBS"
 289
 290 # Function and library checking
 291 AC_CHECK_FUNC(gethostbyname, ac_gethostbyname_found=1,
 292 ac_gethostbyname_found=0)
 293 if test x$ac_gethostbyname_found = x0; then
 294     AC_CHECK_LIB(nsl, gethostbyname, LIBS="$LIBS -lnsl")
 295     AC_CHECK_FUNC(res_gethostbyname, ac_res_ghbn_found=1, ac_res_ghbn_found=0)
 296     if test x$ac_res_ghbn_found = x0; then
 297         AC_CHECK_LIB(resolv, res_gethostbyname,  LIBS="$LIBS -lresolv")
 298     fi
 299 fi
 300 AC_CHECK_FUNC(socket, ac_socket_found=1, ac_socket_found=0)
 301 if test x$ac_socket_found = x0; then
 302     AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
 303 fi
 304 AC_CHECK_FUNCS(gethostname gethostbyaddr getservbyname getservbyport)
 305 AC_CHECK_FUNCS(select listen bind shutdown close connect)
 306 AC_CHECK_FUNCS(fcntl setsockopt)
 307 AC_CHECK_FUNCS(getopt_long time)
 308 AC_CHECK_FUNCS(mlock munlock)
 309 AC_CHECK_FUNCS(chmod stat fstat getenv putenv strerror ctime gettimeofday)
 310 AC_CHECK_FUNCS(getpid getgid getsid getpgid getpgrp getuid)
 311 AC_CHECK_FUNCS(strchr strstr strcpy strncpy memcpy memset memmove)
 312
 313 # SIM support checking
 314 # XXX These needs to be changed as more supported platforms appear.
 315 # XXX This probably needs to be made platform dependant check.
 316 sim_support=false
 317 AM_CONDITIONAL(SILC_SIM, test x$sim_support = xtrue)
 318 AC_CHECKING(for SIM support)
 319 AC_CHECK_HEADERS(dlfcn.h,
 320   AC_CHECK_LIB(dl, dlopen,
 321     AC_DEFINE(SILC_SIM)
 322     sim_support=true
 323     AM_CONDITIONAL(SILC_SIM, test x$sim_support = xtrue)
 324     AC_MSG_RESULT(enabled SIM support)
 325     LIBS="$LIBS -ldl",
 326     AC_MSG_RESULT(no SIM support found)),
 327   AC_MSG_RESULT(no SIM support found))
 328
 329 #
 330 # Installation
 331 #
 332
 333 # Default installation destination
 334 AC_PREFIX_DEFAULT(/usr/local/silc)
 335
 336 # etc directory
 337 ETCDIR="/etc/silc"
 338 AC_ARG_WITH(etcdir,
 339 [  --with-etcdir[=PATH]    Directory for system files [/etc/silc]],
 340 [ case "$withval" in
 341   no)
 342     ;;
 343   yes)
 344     ETCDIR="$withval"
 345     ;;
 346   *)
 347     ETCDIR="$withval"
 348     ;;
 349   esac ],
 350 )
 351 AC_SUBST(ETCDIR)
 352
 353 # help directory
 354 HELPDIR="help"
 355 AC_ARG_WITH(helpdir,
 356 [  --with-helpdir[=PATH]   Directory for SILC help files [PREFIX/help]],
 357 [ case "$withval" in
 358   no)
 359     ;;
 360   yes)
 361     HELPDIR="$withval"
 362     ;;
 363   *)
 364     HELPDIR="$withval"
 365     ;;
 366   esac ],
 367 )
 368 AC_SUBST(HELPDIR)
 369
 370 # doc directory
 371 DOCDIR="doc"
 372 AC_ARG_WITH(docdir,
 373 [  --with-docdir[=PATH]    Directory for SILC documentation [PREFIX/doc]],
 374 [ case "$withval" in
 375   no)
 376     ;;
 377   yes)
 378     DOCDIR="$withval"
 379     ;;
 380   *)
 381     DOCDIR="$withval"
 382     ;;
 383   esac ],
 384 )
 385 AC_SUBST(DOCDIR)
 386
 387 # SIM modules directory
 388 MODULESDIR="modules"
 389 AC_ARG_WITH(simdir,
 390 [  --with-simdir[=PATH]    Directory for SIM modules [PREFIX/modules]],
 391 [ case "$withval" in
 392   no)
 393     ;;
 394   yes)
 395     MODULESDIR="$withval"
 396     ;;
 397   *)
 398     MODULESDIR="$withval"
 399     ;;
 400   esac ],
 401 )
 402 AC_SUBST(MODULESDIR)
 403
 404 # Logs directory
 405 LOGSDIR="logs"
 406 AC_ARG_WITH(logsdir,
 407 [  --with-logsdir[=PATH]   Directory for Server logs [PREFIX/logs]],
 408 [ case "$withval" in
 409   no)
 410     ;;
 411   yes)
 412     LOGSDIR="$withval"
 413     ;;
 414   *)
 415     LOGSDIR="$withval"
 416     ;;
 417   esac ],
 418 )
 419 AC_SUBST(LOGSDIR)
 420
 421 # Debug checking
 422 AC_MSG_CHECKING(for enabled debugging)
 423 AC_ARG_ENABLE(debug,
 424 [  --enable-debug          Enable debugging (warning: it is heavy!)],
 425 [ case "${enableval}" in
 426   yes)
 427     AC_MSG_RESULT(yes)
 428     AC_DEFINE(SILC_DEBUG)
 429     CFLAGS="-O -g $CFLAGS"
 430     ;;
 431   *)
 432     AC_MSG_RESULT(no)
 433     CFLAGS="-O2 -g $CFLAGS"
 434     ;;
 435 esac ], CFLAGS="-O2 -g $CFLAGS"
 436         AC_MSG_RESULT(no))
 437
 438 # SOCKS4 support checking
 439 AC_MSG_CHECKING(whether to support SOCKS4)
 440 AC_ARG_WITH(socks4,
 441 [  --with-socks4[=PATH]    Compile with SOCKS4 support],
 442 [ case "$withval" in
 443   no)
 444     AC_MSG_RESULT(no)
 445     ;;
 446   *)
 447     AC_MSG_RESULT(yes)
 448     socks=4
 449
 450     if test -d "$withval/include"; then
 451       CFLAGS="$CFLAGS -I$withval/include"
 452     else
 453       CFLAGS="$CFLAGS -I$withval"
 454     fi
 455     if test -d "$withval/lib"; then
 456       withval="-L$withval/lib -lsocks"
 457     else
 458       withval="-L$withval -lsocks"
 459     fi
 460
 461     LIBS="$withval $LIBS"
 462
 463     AC_TRY_LINK([],
 464                 [ Rconnect(); ],
 465                 [],
 466                 [ AC_MSG_ERROR(Could not find SOCKS4 library.)])
 467       ;;
 468   esac ],
 469   AC_MSG_RESULT(no)
 470 )
 471
 472 # SOCKS5 support checking
 473 AC_MSG_CHECKING(whether to support SOCKS5)
 474 AC_ARG_WITH(socks5,
 475 [  --with-socks5[=PATH]    Compile with SOCKS5 support],
 476 [ case "$withval" in
 477   no)
 478     AC_MSG_RESULT(no)
 479     ;;
 480   *)
 481     AC_MSG_RESULT(yes)
 482     socks=5
 483
 484     if test -d "$withval/include"; then
 485       CFLAGS="$CFLAGS -I$withval/include"
 486     else
 487       CFLAGS="$CFLAGS -I$withval"
 488     fi
 489     if test -d "$withval/lib"; then
 490       withval="-L$withval/lib -lsocks5"
 491     else
 492       withval="-L$withval -lsocks5"
 493     fi
 494
 495     LIBS="$withval $LIBS"
 496
 497     AC_TRY_LINK([],
 498                 [ SOCKSconnect(); ],
 499                 [],
 500                 [ AC_MSG_ERROR(Could not find SOCKS5 library.)])
 501       ;;
 502   esac ],
 503   AC_MSG_RESULT(no)
 504 )
 505
 506 if test "x$socks" = "x4"; then
 507   AC_DEFINE(SOCKS)
 508   CFLAGS="$CFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 509 fi
 510
 511 if test "x$socks" = "x5"; then
 512   AC_DEFINE(SOCKS)
 513   AC_DEFINE(SOCKS5)
 514   AC_DEFINE(Rconnect, SOCKSconnect)
 515   AC_DEFINE(Rgetsockname, SOCKSgetsockname)
 516   AC_DEFINE(Rgetpeername, SOCKSgetpeername)
 517   AC_DEFINE(Rbind, SOCKSbind)
 518   AC_DEFINE(Raccept, SOCKSaccept)
 519   AC_DEFINE(Rlisten, SOCKSlisten)
 520   AC_DEFINE(Rselect, SOCKSselect)
 521   AC_DEFINE(Rrecvfrom, SOCKSrecvfrom)
 522   AC_DEFINE(Rsendto, SOCKSsendto)
 523   AC_DEFINE(Rrecv, SOCKSrecv)
 524   AC_DEFINE(Rsend, SOCKSsend)
 525   AC_DEFINE(Rread, SOCKSread)
 526   AC_DEFINE(Rwrite, SOCKSwrite)
 527   AC_DEFINE(Rrresvport, SOCKSrresvport)
 528   AC_DEFINE(Rshutdown, SOCKSshutdown)
 529   AC_DEFINE(Rlisten, SOCKSlisten)
 530   AC_DEFINE(Rclose, SOCKSclose)
 531   AC_DEFINE(Rdup, SOCKSdup)
 532   AC_DEFINE(Rdup2, SOCKSdup2)
 533   AC_DEFINE(Rfclose, SOCKSfclose)
 534   AC_DEFINE(Rgethostbyname, SOCKSgethostbyname)
 535 fi
 536
 537 # GMP Library checking
 538 AC_MSG_CHECKING(whether to compile GMP)
 539 AC_ARG_WITH(gmp,
 540 [  --with-gmp              Build the GMP in the SILC source tree],
 541 [ case "${withval}" in
 542   yes)
 543     AM_CONDITIONAL(SILC_BUILD_GMP, test x$withval = xyes)
 544     AC_MSG_RESULT(yes)
 545     ;;
 546   *)
 547     AC_CHECK_HEADER(gmp.h,
 548       AC_CHECK_LIB(gmp, __gmpz_init,
 549         AM_CONDITIONAL(SILC_BUILD_GMP, test x$withval = yes)
 550         LIBS="$LIBS -L/usr/lib -L/usr/local/lib -lgmp"
 551         AC_MSG_RESULT(GMP will not be compiled),
 552         AM_CONDITIONAL(SILC_BUILD_GMP, test x$withval != yes)
 553         AC_MSG_RESULT(GMP will be compiled)
 554       ),
 555       AM_CONDITIONAL(SILC_BUILD_GMP, test x$withval != yes)
 556       AC_MSG_RESULT(GMP will be compiled)
 557     )
 558     ;;
 559 esac ], [
 560   AC_CHECK_HEADER(gmp.h,
 561     AC_CHECK_LIB(gmp, __gmpz_init,
 562       build_gmp=false
 563       AM_CONDITIONAL(SILC_BUILD_GMP, test x$build_gmp = xtrue)
 564       LIBS="$LIBS -L/usr/lib -L/usr/local/lib -lgmp"
 565       AC_MSG_RESULT(GMP will not be compiled),
 566       build_gmp=true
 567       AM_CONDITIONAL(SILC_BUILD_GMP, test x$build_gmp = xtrue)
 568       AC_MSG_RESULT(GMP will be compiled)
 569     ),
 570     build_gmp=true
 571     AM_CONDITIONAL(SILC_BUILD_GMP, test x$build_gmp = xtrue)
 572     AC_MSG_RESULT(GMP will be compiled)
 573   )
 574 ])
 575
 576 AC_ARG_WITH(silcd-config-file,
 577 [  --with-silcd-config-file[=PATH]
 578                           Use PATH as default configuration file in SILC
 579                           server [/etc/silc/silcd.conf]],
 580 [ AC_DEFINE_UNQUOTED(SILC_SERVER_CONFIG_FILE, "$withval") ])
 581
 582 #
 583 # Other configure scripts
 584 #
 585 AC_CONFIG_SUBDIRS(irssi)
 586 AC_CONFIG_SUBDIRS(lib/dotconf)
 587 AC_CONFIG_SUBDIRS(lib/silcmath/gmp)
 588 AC_CONFIG_SUBDIRS(lib/trq)
 589 #AC_CONFIG_SUBDIRS(lib/zlib)
 590
 591 SILC_TOP_SRCDIR=`pwd`
 592 AC_SUBST(SILC_TOP_SRCDIR)
 593 #SILC_INSTALL_PREFIX=$ac_default_prefix
 594 #AC_SUBST(SILC_INSTALL_PREFIX)
 595 AC_SUBST(LIBS)
 596 INCLUDE_DEFINES_INT="include \$(top_srcdir)/Makefile.defines_int"
 597 AC_SUBST(INCLUDE_DEFINES_INT)
 598
 599 #
 600 # Makefile outputs
 601 #
 602 AC_OUTPUT( \
 603 Makefile
 604 Makefile.defines
 605 Makefile.defines_int
 606 irssi/Makefile.defines
 607 irssi/Makefile.defines_int
 608 doc/Makefile
 609 includes/Makefile
 610 lib/Makefile
 611 lib/contrib/Makefile
 612 lib/silcclient/Makefile
 613 lib/silccore/Makefile
 614 lib/silccrypt/Makefile
 615 lib/silcmath/Makefile
 616 lib/silcsim/Makefile
 617 lib/silcsim/modules/Makefile
 618 lib/silcske/Makefile
 619 lib/silcutil/Makefile
 620 silc/Makefile
 621 silcd/Makefile)