configure.in.pre

   1 #
   2 #  configure.in
   3 #
   4 #  Author: Pekka Riikonen <priikone@poseidon.pspt.fi>
   5 #
   6 #  Copyright (C) 2000 - 2001 Pekka Riikonen
   7 #
   8 #  This program is free software; you can redistribute it and/or modify
   9 #  it under the terms of the GNU General Public License as published by
  10 #  the Free Software Foundation; either version 2 of the License, or
  11 #  (at your option) any later version.
  12 #
  13 #  This program is distributed in the hope that it will be useful,
  14 #  but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 #  GNU General Public License for more details.
  17 #
  18
  19 AC_INIT(includes/version.h)
  20
  21 #
  22 # Put here any platform specific stuff
  23 #
  24 AC_CANONICAL_SYSTEM
  25 case "$target" in
  26   *)
  27     ;;
  28 esac
  29
  30 # ./prepare script will automatically put the correct version. Do not edit!
  31 AM_INIT_AUTOMAKE(SILC_PACKAGE, SILC_VERSION)
  32 AC_PREREQ(2.3)
  33 AM_CONFIG_HEADER(includes/silcdefs.h)
  34
  35 AC_PROG_CC
  36 AC_C_INLINE
  37 AC_C_CONST
  38 AC_ARG_PROGRAM
  39
  40 AC_PROG_LN_S
  41 AC_SUBST(LN_S)
  42
  43 # Distribution definition. ./prepare will automatically add here a correct
  44 # value. Do not edit!
  45 AC_DEFINE(SILC_DIST_DEFINE)
  46
  47 # XXX
  48 # Compiler flags
  49 if test "$GCC"; then
  50   CFLAGS="-Wall -finline-functions $CFLAGS"
  51 fi
  52
  53 # Program checking
  54 AC_PROG_INSTALL
  55 AC_PROG_RANLIB
  56 AC_PROG_MAKE_SET
  57
  58 # Header checking
  59 AC_HEADER_STDC
  60 AC_HEADER_TIME
  61 AC_HEADER_STAT
  62
  63 # More header checking
  64 AC_CHECK_HEADERS(unistd.h string.h getopt.h errno.h fcntl.h assert.h)
  65 AC_CHECK_HEADERS(sys/types.h sys/stat.h sys/time.h)
  66 AC_CHECK_HEADERS(netinet/in.h netinet/tcp.h netdb.h)
  67 AC_CHECK_HEADERS(pwd.h grp.h termcap.h paths.h)
  68 AC_CHECK_HEADERS(ncurses.h signal.h ctype.h regex.h)
  69 AC_CHECK_HEADERS(arpa/inet.h sys/mman.h limits.h)
  70 AC_CHECK_HEADERS(pthread.h)
  71
  72 # Data type checking
  73 AC_TYPE_SIGNAL
  74 AC_TYPE_SIZE_T
  75 AC_TYPE_MODE_T
  76 AC_TYPE_UID_T
  77 AC_TYPE_PID_T
  78
  79 AC_CHECK_SIZEOF(long long, 0)
  80 AC_DEFINE_UNQUOTED(SILC_SIZEOF_LONG_LONG, $ac_cv_sizeof_long_long)
  81 AC_CHECK_SIZEOF(long, 0)
  82 AC_DEFINE_UNQUOTED(SILC_SIZEOF_LONG, $ac_cv_sizeof_long)
  83 AC_CHECK_SIZEOF(int, 0)
  84 AC_DEFINE_UNQUOTED(SILC_SIZEOF_INT, $ac_cv_sizeof_int)
  85 AC_CHECK_SIZEOF(short, 0)
  86 AC_DEFINE_UNQUOTED(SILC_SIZEOF_SHORT, $ac_cv_sizeof_short)
  87 AC_CHECK_SIZEOF(char, 0)
  88 AC_DEFINE_UNQUOTED(SILC_SIZEOF_CHAR, $ac_cv_sizeof_char)
  89 AC_CHECK_SIZEOF(void *, 0)
  90 AC_DEFINE_UNQUOTED(SILC_SIZEOF_VOID_P, $ac_cv_sizeof_void_p)
  91
  92 dnl Curses detection: Munged from Midnight Commander's configure.in
  93 AC_DEFUN(AC_CHECK_CURSES,[
  94         search_ncurses=true
  95         screen_manager=""
  96         has_curses=false
  97
  98         CFLAGS=${CFLAGS--O}
  99
 100         AC_SUBST(CURSES_LIBS)
 101         AC_SUBST(CURSES_INCLUDEDIR)
 102
 103         AC_ARG_WITH(sunos-curses,
 104           [  --with-sunos-curses     Used to force SunOS 4.x curses],[
 105           if test x$withval = xyes; then
 106                 AC_USE_SUNOS_CURSES
 107           fi
 108         ])
 109
 110         AC_ARG_WITH(osf1-curses,
 111           [  --with-osf1-curses      Used to force OSF/1 curses],[
 112           if test x$withval = xyes; then
 113                 AC_USE_OSF1_CURSES
 114           fi
 115         ])
 116
 117         AC_ARG_WITH(vcurses,
 118           [  --with-vcurses[=incdir] Used to force SysV curses],
 119           if test x$withval != xyes; then
 120                 CURSES_INCLUDEDIR="-I$withval"
 121           fi
 122           AC_USE_SYSV_CURSES
 123         )
 124
 125         AC_ARG_WITH(ncurses,
 126           [  --with-ncurses[=dir]    Compile with ncurses/locate base dir],
 127           if test x$withval = xno ; then
 128                 search_ncurses=false
 129           elif test x$withval != xyes ; then
 130                 AC_NCURSES($withval/include, ncurses.h, -L$withval/lib -lncurses, -I$withval/include, "ncurses on $withval/include")
 131           fi
 132         )
 133
 134         if $search_ncurses
 135         then
 136                 AC_SEARCH_NCURSES()
 137         fi
 138 ])
 139
 140
 141 AC_DEFUN(AC_USE_SUNOS_CURSES, [
 142         search_ncurses=false
 143         screen_manager="SunOS 4.x /usr/5include curses"
 144         AC_MSG_RESULT(Using SunOS 4.x /usr/5include curses)
 145         AC_DEFINE(USE_SUNOS_CURSES)
 146         AC_DEFINE(HAS_CURSES)
 147         has_curses=true
 148         AC_DEFINE(NO_COLOR_CURSES)
 149         AC_DEFINE(USE_SYSV_CURSES)
 150         CURSES_INCLUDEDIR="-I/usr/5include"
 151         CURSES_LIBS="/usr/5lib/libcurses.a /usr/5lib/libtermcap.a"
 152         AC_MSG_RESULT(Please note that some screen refreshs may fail)
 153 ])
 154
 155 AC_DEFUN(AC_USE_OSF1_CURSES, [
 156        AC_MSG_RESULT(Using OSF1 curses)
 157        search_ncurses=false
 158        screen_manager="OSF1 curses"
 159        AC_DEFINE(HAS_CURSES)
 160        has_curses=true
 161        AC_DEFINE(NO_COLOR_CURSES)
 162        AC_DEFINE(USE_SYSV_CURSES)
 163        CURSES_LIBS="-lcurses"
 164 ])
 165
 166 AC_DEFUN(AC_USE_SYSV_CURSES, [
 167         AC_MSG_RESULT(Using SysV curses)
 168         AC_DEFINE(HAS_CURSES)
 169         has_curses=true
 170         AC_DEFINE(USE_SYSV_CURSES)
 171         search_ncurses=false
 172         screen_manager="SysV/curses"
 173         CURSES_LIBS="-lcurses"
 174 ])
 175
 176 dnl
 177 dnl Parameters: directory filename cureses_LIBS curses_INCLUDEDIR nicename
 178 dnl
 179 AC_DEFUN(AC_NCURSES, [
 180     if $search_ncurses
 181     then
 182         if test -f $1/$2
 183         then
 184             AC_MSG_RESULT(Found ncurses on $1/$2)
 185
 186             CURSES_LIBS="$3"
 187             AC_CHECK_LIB(ncurses, initscr, [
 188             ], [
 189                 CHECKLIBS=`echo "$3"|sed 's/-lncurses/-lcurses/g'`
 190                 AC_CHECK_LIB(curses, initscr, [
 191                         CURSES_LIBS="$CHECKLIBS"
 192                 ],, $CHECKLIBS)
 193             ], $CURSES_LIBS)
 194             CURSES_INCLUDEDIR="$4"
 195             search_ncurses=false
 196             screen_manager=$5
 197             AC_DEFINE(HAS_CURSES)
 198             has_curses=true
 199             has_ncurses=true
 200             AC_DEFINE(USE_NCURSES)
 201         fi
 202     fi
 203 ])
 204
 205 AC_DEFUN(AC_SEARCH_NCURSES, [
 206     AC_CHECKING("location of ncurses.h file")
 207
 208     AC_NCURSES(/usr/include, ncurses.h, -lncurses,, "ncurses on /usr/include")
 209     AC_NCURSES(/usr/include/ncurses, ncurses.h, -lncurses, -I/usr/include/ncurses, "ncurses on /usr/include/ncurses")
 210     AC_NCURSES(/usr/local/include, ncurses.h, -L/usr/local/lib -lncurses, -I/usr/local/include, "ncurses on /usr/local")
 211     AC_NCURSES(/usr/pkg/include, ncurses.h, -L/usr/pkg/lib -lncurses, -I/usr/pkg/include, "ncurses on /usr/pkg")
 212     AC_NCURSES(/usr/contrib/include, ncurses.h, -L/usr/contrib/lib -lncurses, -I/usr/contrib/include, "ncurses on /usr/contrib")
 213     AC_NCURSES(/usr/local/include/ncurses, ncurses.h, -L/usr/local/lib -L/usr/local/lib/ncurses -lncurses, -I/usr/local/include/ncurses, "ncurses on /usr/local/include/ncurses")
 214
 215     AC_NCURSES(/usr/local/include/ncurses, curses.h, -L/usr/local/lib -lncurses, -I/usr/local/include/ncurses -DRENAMED_NCURSES, "renamed ncurses on /usr/local/.../ncurses")
 216
 217     AC_NCURSES(/usr/include/ncurses, curses.h, -lncurses, -I/usr/include/ncurses -DRENAMED_NCURSES, "renamed ncurses on /usr/include/ncurses")
 218
 219     dnl
 220     dnl We couldn't find ncurses, try SysV curses
 221     dnl
 222     if $search_ncurses
 223     then
 224         AC_EGREP_HEADER(init_color, /usr/include/curses.h,
 225             AC_USE_SYSV_CURSES)
 226         AC_EGREP_CPP(USE_NCURSES,[
 227 #include <curses.h>
 228 #ifdef __NCURSES_H
 229 #undef USE_NCURSES
 230 USE_NCURSES
 231 #endif
 232 ],[
 233         CURSES_INCLUDEDIR="$CURSES_INCLUDEDIR -DRENAMED_NCURSES"
 234         AC_DEFINE(HAS_CURSES)
 235         has_curses=true
 236         has_ncurses=true
 237         AC_DEFINE(USE_NCURSES)
 238         search_ncurses=false
 239         screen_manager="ncurses installed as curses"
 240 ])
 241     fi
 242
 243     dnl
 244     dnl Try SunOS 4.x /usr/5{lib,include} ncurses
 245     dnl The flags USE_SUNOS_CURSES, USE_BSD_CURSES and BUGGY_CURSES
 246     dnl should be replaced by a more fine grained selection routine
 247     dnl
 248     if $search_ncurses
 249     then
 250         if test -f /usr/5include/curses.h
 251         then
 252             AC_USE_SUNOS_CURSES
 253         fi
 254     fi
 255
 256     dnl use whatever curses there happens to be
 257     if $search_ncurses
 258     then
 259         if test -f /usr/include/curses.h
 260         then
 261           CURSES_LIBS="-lcurses"
 262           AC_DEFINE(HAS_CURSES)
 263           has_curses=true
 264           search_ncurses=false
 265           screen_manager="curses"
 266         fi
 267     fi
 268 ])
 269
 270 AC_CHECK_CURSES
 271 LIBS="$LIBS $CURSES_LIBS"
 272
 273 # Function and library checking
 274 AC_CHECK_FUNC(gethostbyname, ac_gethostbyname_found=1,
 275 ac_gethostbyname_found=0)
 276 if test x$ac_gethostbyname_found = x0; then
 277     AC_CHECK_LIB(nsl, gethostbyname, LIBS="$LIBS -lnsl")
 278     AC_CHECK_FUNC(res_gethostbyname, ac_res_ghbn_found=1, ac_res_ghbn_found=0)
 279     if test x$ac_res_ghbn_found = x0; then
 280         AC_CHECK_LIB(resolv, res_gethostbyname,  LIBS="$LIBS -lresolv")
 281     fi
 282 fi
 283 AC_CHECK_FUNC(socket, ac_socket_found=1, ac_socket_found=0)
 284 if test x$ac_socket_found = x0; then
 285     AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
 286 fi
 287 AC_CHECK_FUNCS(gethostname gethostbyaddr getservbyname getservbyport)
 288 AC_CHECK_FUNCS(select listen bind shutdown close connect)
 289 AC_CHECK_FUNCS(fcntl setsockopt)
 290 AC_CHECK_FUNCS(getopt_long time)
 291 AC_CHECK_FUNCS(mlock munlock)
 292 AC_CHECK_FUNCS(chmod stat fstat getenv putenv strerror ctime gettimeofday)
 293 AC_CHECK_FUNCS(getpid getgid getsid getpgid getpgrp getuid)
 294 AC_CHECK_FUNCS(strchr strstr strcpy strncpy memcpy memset memmove)
 295 AC_CHECK_FUNCS(pthread_create)
 296
 297 # SIM support checking
 298 # XXX These needs to be changed as more supported platforms appear.
 299 # XXX This probably needs to be made platform dependant check.
 300 sim_support=false
 301 AM_CONDITIONAL(SILC_SIM, test x$sim_support = xtrue)
 302 AC_CHECKING(for SIM support)
 303 AC_CHECK_HEADERS(dlfcn.h,
 304   AC_CHECK_LIB(dl, dlopen,
 305     AC_DEFINE(SILC_SIM)
 306     sim_support=true
 307     AM_CONDITIONAL(SILC_SIM, test x$sim_support = xtrue)
 308     AC_MSG_RESULT(enabled SIM support)
 309     LIBS="$LIBS -ldl",
 310     AC_MSG_RESULT(no SIM support found)),
 311   AC_MSG_RESULT(no SIM support found))
 312
 313 #
 314 # Installation
 315 #
 316
 317 # Default installation destination
 318 AC_PREFIX_DEFAULT(/usr/local/silc)
 319
 320 # etc directory
 321 ETCDIR="/etc/silc"
 322 AC_ARG_WITH(etcdir,
 323 [  --with-etcdir[=PATH]    Directory for system files [/etc/silc]],
 324 [ case "$withval" in
 325   no)
 326     ;;
 327   yes)
 328     ETCDIR="$withval"
 329     ;;
 330   *)
 331     ETCDIR="$withval"
 332     ;;
 333   esac ],
 334 )
 335 AC_SUBST(ETCDIR)
 336 AC_DEFINE_UNQUOTED(SILC_ETCDIR, "$ETCDIR")
 337
 338 # help directory
 339 HELPDIR="help"
 340 AC_ARG_WITH(helpdir,
 341 [  --with-helpdir[=PATH]   Directory for SILC help files [PREFIX/help]],
 342 [ case "$withval" in
 343   no)
 344     ;;
 345   yes)
 346     HELPDIR="$withval"
 347     ;;
 348   *)
 349     HELPDIR="$withval"
 350     ;;
 351   esac ],
 352 )
 353 AC_SUBST(HELPDIR)
 354 AC_DEFINE_UNQUOTED(SILC_HELPDIR, "$HELPDIR")
 355
 356 # doc directory
 357 DOCDIR="doc"
 358 AC_ARG_WITH(docdir,
 359 [  --with-docdir[=PATH]    Directory for SILC documentation [PREFIX/doc]],
 360 [ case "$withval" in
 361   no)
 362     ;;
 363   yes)
 364     DOCDIR="$withval"
 365     ;;
 366   *)
 367     DOCDIR="$withval"
 368     ;;
 369   esac ],
 370 )
 371 AC_SUBST(DOCDIR)
 372 AC_DEFINE_UNQUOTED(SILC_DOCDIR, "$DOCDIR")
 373
 374 # SIM modules directory
 375 MODULESDIR="modules"
 376 AC_ARG_WITH(simdir,
 377 [  --with-simdir[=PATH]    Directory for SIM modules [PREFIX/modules]],
 378 [ case "$withval" in
 379   no)
 380     ;;
 381   yes)
 382     MODULESDIR="$withval"
 383     ;;
 384   *)
 385     MODULESDIR="$withval"
 386     ;;
 387   esac ],
 388 )
 389 AC_SUBST(MODULESDIR)
 390 AC_DEFINE_UNQUOTED(SILC_MODULESDIR, "$MODULESDIR")
 391
 392 # Logs directory
 393 LOGSDIR="logs"
 394 AC_ARG_WITH(logsdir,
 395 [  --with-logsdir[=PATH]   Directory for Server logs [PREFIX/logs]],
 396 [ case "$withval" in
 397   no)
 398     ;;
 399   yes)
 400     LOGSDIR="$withval"
 401     ;;
 402   *)
 403     LOGSDIR="$withval"
 404     ;;
 405   esac ],
 406 )
 407 AC_SUBST(LOGSDIR)
 408 AC_DEFINE_UNQUOTED(SILC_LOGSDIR, "$LOGSDIR")
 409
 410 # SOCKS4 support checking
 411 AC_MSG_CHECKING(whether to support SOCKS4)
 412 AC_ARG_WITH(socks4,
 413 [  --with-socks4[=PATH]    Compile with SOCKS4 support],
 414 [ case "$withval" in
 415   no)
 416     AC_MSG_RESULT(no)
 417     ;;
 418   *)
 419     AC_MSG_RESULT(yes)
 420     socks=4
 421
 422     if test -d "$withval/include"; then
 423       CFLAGS="$CFLAGS -I$withval/include"
 424     else
 425       CFLAGS="$CFLAGS -I$withval"
 426     fi
 427     if test -d "$withval/lib"; then
 428       withval="-L$withval/lib -lsocks"
 429     else
 430       withval="-L$withval -lsocks"
 431     fi
 432
 433     LIBS="$withval $LIBS"
 434
 435     AC_TRY_LINK([],
 436                 [ Rconnect(); ],
 437                 [],
 438                 [ AC_MSG_ERROR(Could not find SOCKS4 library.)])
 439       ;;
 440   esac ],
 441   AC_MSG_RESULT(no)
 442 )
 443
 444 # SOCKS5 support checking
 445 AC_MSG_CHECKING(whether to support SOCKS5)
 446 AC_ARG_WITH(socks5,
 447 [  --with-socks5[=PATH]    Compile with SOCKS5 support],
 448 [ case "$withval" in
 449   no)
 450     AC_MSG_RESULT(no)
 451     ;;
 452   *)
 453     AC_MSG_RESULT(yes)
 454     socks=5
 455
 456     if test -d "$withval/include"; then
 457       CFLAGS="$CFLAGS -I$withval/include"
 458     else
 459       CFLAGS="$CFLAGS -I$withval"
 460     fi
 461     if test -d "$withval/lib"; then
 462       withval="-L$withval/lib -lsocks5"
 463     else
 464       withval="-L$withval -lsocks5"
 465     fi
 466
 467     LIBS="$withval $LIBS"
 468
 469     AC_TRY_LINK([],
 470                 [ SOCKSconnect(); ],
 471                 [],
 472                 [ AC_MSG_ERROR(Could not find SOCKS5 library.)])
 473       ;;
 474   esac ],
 475   AC_MSG_RESULT(no)
 476 )
 477
 478 if test "x$socks" = "x4"; then
 479   AC_DEFINE(SOCKS)
 480   CFLAGS="$CFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 481 fi
 482
 483 if test "x$socks" = "x5"; then
 484   AC_DEFINE(SOCKS)
 485   AC_DEFINE(SOCKS5)
 486   AC_DEFINE(Rconnect, SOCKSconnect)
 487   AC_DEFINE(Rgetsockname, SOCKSgetsockname)
 488   AC_DEFINE(Rgetpeername, SOCKSgetpeername)
 489   AC_DEFINE(Rbind, SOCKSbind)
 490   AC_DEFINE(Raccept, SOCKSaccept)
 491   AC_DEFINE(Rlisten, SOCKSlisten)
 492   AC_DEFINE(Rselect, SOCKSselect)
 493   AC_DEFINE(Rrecvfrom, SOCKSrecvfrom)
 494   AC_DEFINE(Rsendto, SOCKSsendto)
 495   AC_DEFINE(Rrecv, SOCKSrecv)
 496   AC_DEFINE(Rsend, SOCKSsend)
 497   AC_DEFINE(Rread, SOCKSread)
 498   AC_DEFINE(Rwrite, SOCKSwrite)
 499   AC_DEFINE(Rrresvport, SOCKSrresvport)
 500   AC_DEFINE(Rshutdown, SOCKSshutdown)
 501   AC_DEFINE(Rlisten, SOCKSlisten)
 502   AC_DEFINE(Rclose, SOCKSclose)
 503   AC_DEFINE(Rdup, SOCKSdup)
 504   AC_DEFINE(Rdup2, SOCKSdup2)
 505   AC_DEFINE(Rfclose, SOCKSfclose)
 506   AC_DEFINE(Rgethostbyname, SOCKSgethostbyname)
 507 fi
 508
 509 #
 510 # MP library checking. First check whether system has GMP. If it has that
 511 # then use it. If not then compile the MPI library in the source tree.
 512 #
 513 mp_gmp=false
 514 AC_CHECK_HEADER(gmp.h,
 515   AC_CHECK_LIB(gmp, __gmpz_init,
 516     mp_gmp=true
 517     AC_DEFINE(SILC_MP_GMP)
 518     LIBS="$LIBS -L/usr/lib -L/usr/local/lib -lgmp"
 519     AC_MSG_RESULT(Using GMP as MP library)
 520   )
 521 )
 522 AM_CONDITIONAL(SILC_MP_GMP, test x$mp_gmp = xtrue)
 523 if test x$mp_gmp = xfalse; then
 524   AM_CONDITIONAL(SILC_MP_NSS_MPI, test x$mp_gmp = xfalse)
 525   AC_DEFINE(SILC_MP_NSS_MPI)
 526   AC_MSG_RESULT(Using NSS MPI as MP library)
 527 fi
 528
 529 AC_ARG_WITH(silcd-config-file,
 530 [  --with-silcd-config-file[=PATH]
 531                           Use PATH as default configuration file in SILC
 532                           server [/etc/silc/silcd.conf]],
 533 [ AC_DEFINE_UNQUOTED(SILC_SERVER_CONFIG_FILE, "$withval") ])
 534
 535 # Native WIN32 compilation under cygwin
 536 AC_ARG_WITH(win32,
 537 [  --with-win32            Compile native WIN32 code (-mno-cygwin)],
 538 [ AC_DEFINE(SILC_WIN32)
 539   AM_CONDITIONAL(SILC_WIN32, test xtrue = xtrue)
 540   CFLAGS="-mno-cygwin $CFLAGS"
 541   LIBS="$LIBS -lwsock32" ])
 542
 543 # Debug checking
 544 AC_MSG_CHECKING(for enabled debugging)
 545 AC_ARG_ENABLE(debug,
 546 [  --enable-debug          Enable debugging (warning: it is heavy!)],
 547 [ case "${enableval}" in
 548   yes)
 549     AC_MSG_RESULT(yes)
 550     AC_DEFINE(SILC_DEBUG)
 551     CFLAGS="-O -g $CFLAGS"
 552     ;;
 553   *)
 554     AC_MSG_RESULT(no)
 555     CFLAGS="-O2 -g $CFLAGS"
 556     ;;
 557 esac ], CFLAGS="-O2 -g $CFLAGS"
 558         AC_MSG_RESULT(no))
 559
 560 # Pthread checking
 561 AC_ARG_ENABLE(threads,
 562 [  --disable-threads       Do not compile with multi-thread support],
 563 [ case "${enableval}" in
 564   yes)
 565     AC_DEFINE(SILC_THREADS)
 566     AM_CONDITIONAL(SILC_THREADS)
 567     want_threads=true
 568     ;;
 569   *)
 570     want_threads=false
 571     ;;
 572 esac ], AC_DEFINE(SILC_THREADS)
 573         AM_CONDITIONAL(SILC_THREADS)
 574         want_threads=true)
 575
 576 if test x$want_threads = xtrue; then
 577   AC_TRY_COMPILE([#include <pthread.h>],
 578                  [pthread_attr_t attr; pthread_attr_init(&attr);],
 579                  LIBS="$LIBS -lpthread")
 580 fi
 581
 582 #
 583 # Other configure scripts
 584 #
 585 AC_CONFIG_SUBDIRS(lib/dotconf)
 586 AC_CONFIG_SUBDIRS(lib/trq)
 587 AC_CONFIG_SUBDIRS(lib/silcmath/mpi)
 588 AC_CONFIG_SUBDIRS(irssi)
 589 #AC_CONFIG_SUBDIRS(lib/zlib)
 590
 591 SILC_TOP_SRCDIR=`pwd`
 592 AC_SUBST(SILC_TOP_SRCDIR)
 593 #SILC_INSTALL_PREFIX=$ac_default_prefix
 594 #AC_SUBST(SILC_INSTALL_PREFIX)
 595 AC_SUBST(LIBS)
 596 INCLUDE_DEFINES_INT="include \$(top_srcdir)/Makefile.defines_int"
 597 AC_SUBST(INCLUDE_DEFINES_INT)
 598
 599 #
 600 # Makefile outputs
 601 #
 602 AC_OUTPUT( \
 603 Makefile
 604 Makefile.defines
 605 Makefile.defines_int
 606 irssi/Makefile.defines
 607 irssi/Makefile.defines_int
 608 doc/Makefile
 609 includes/Makefile
 610 lib/Makefile
 611 lib/contrib/Makefile
 612 lib/silcclient/Makefile
 613 lib/silccore/Makefile
 614 lib/silccrypt/Makefile
 615 lib/silcmath/Makefile
 616 lib/silcmath/mpi/Makefile.defines
 617 lib/silcmath/mpi/Makefile.defines_int
 618 lib/silcsim/Makefile
 619 lib/silcsim/modules/Makefile
 620 lib/silcske/Makefile
 621 lib/silcutil/Makefile
 622 lib/silcutil/unix/Makefile
 623 lib/silcutil/win32/Makefile
 624 silc/Makefile
 625 silcd/Makefile)