configure.in.pre

   1 #
   2 #  configure.in
   3 #
   4 #  Author: Pekka Riikonen <priikone@poseidon.pspt.fi>
   5 #
   6 #  Copyright (C) 2000 - 2001 Pekka Riikonen
   7 #
   8 #  This program is free software; you can redistribute it and/or modify
   9 #  it under the terms of the GNU General Public License as published by
  10 #  the Free Software Foundation; either version 2 of the License, or
  11 #  (at your option) any later version.
  12 #
  13 #  This program is distributed in the hope that it will be useful,
  14 #  but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 #  GNU General Public License for more details.
  17 #
  18
  19 AC_INIT(includes/version.h)
  20
  21 #
  22 # Put here any platform specific stuff
  23 #
  24 AC_CANONICAL_SYSTEM
  25 case "$target" in
  26   *-*-*bsd*)
  27     check_threads=false
  28     ;;
  29   *)
  30     check_threads=true
  31     ;;
  32 esac
  33
  34 # ./prepare script will automatically put the correct version. Do not edit!
  35 AM_INIT_AUTOMAKE(SILC_PACKAGE, SILC_VERSION)
  36 AC_PREREQ(2.3)
  37 AM_CONFIG_HEADER(includes/silcdefs.h)
  38
  39 AC_PROG_CC
  40 AC_C_INLINE
  41 AC_C_CONST
  42 AC_ARG_PROGRAM
  43
  44 AC_PROG_LN_S
  45 AC_SUBST(LN_S)
  46
  47 # Distribution definition. ./prepare will automatically add here a correct
  48 # value. Do not edit!
  49 AC_DEFINE(SILC_DIST_DEFINE)
  50
  51 # XXX
  52 # Compiler flags
  53 if test "$GCC"; then
  54   CFLAGS="-Wall -finline-functions $CFLAGS"
  55 fi
  56
  57 # Program checking
  58 AC_PROG_INSTALL
  59 AC_PROG_RANLIB
  60 AC_PROG_MAKE_SET
  61
  62 # Header checking
  63 AC_HEADER_STDC
  64 AC_HEADER_TIME
  65 AC_HEADER_STAT
  66
  67 # More header checking
  68 AC_CHECK_HEADERS(unistd.h string.h getopt.h errno.h fcntl.h assert.h)
  69 AC_CHECK_HEADERS(sys/types.h sys/stat.h sys/time.h)
  70 AC_CHECK_HEADERS(netinet/in.h netinet/tcp.h xti.h netdb.h)
  71 AC_CHECK_HEADERS(pwd.h grp.h termcap.h paths.h)
  72 AC_CHECK_HEADERS(ncurses.h signal.h ctype.h regex.h)
  73 AC_CHECK_HEADERS(arpa/inet.h sys/mman.h limits.h)
  74
  75 # Data type checking
  76 AC_TYPE_SIGNAL
  77 AC_TYPE_SIZE_T
  78 AC_TYPE_MODE_T
  79 AC_TYPE_UID_T
  80 AC_TYPE_PID_T
  81
  82 AC_CHECK_SIZEOF(long long, 0)
  83 AC_DEFINE_UNQUOTED(SILC_SIZEOF_LONG_LONG, $ac_cv_sizeof_long_long)
  84 AC_CHECK_SIZEOF(long, 0)
  85 AC_DEFINE_UNQUOTED(SILC_SIZEOF_LONG, $ac_cv_sizeof_long)
  86 AC_CHECK_SIZEOF(int, 0)
  87 AC_DEFINE_UNQUOTED(SILC_SIZEOF_INT, $ac_cv_sizeof_int)
  88 AC_CHECK_SIZEOF(short, 0)
  89 AC_DEFINE_UNQUOTED(SILC_SIZEOF_SHORT, $ac_cv_sizeof_short)
  90 AC_CHECK_SIZEOF(char, 0)
  91 AC_DEFINE_UNQUOTED(SILC_SIZEOF_CHAR, $ac_cv_sizeof_char)
  92 AC_CHECK_SIZEOF(void *, 0)
  93 AC_DEFINE_UNQUOTED(SILC_SIZEOF_VOID_P, $ac_cv_sizeof_void_p)
  94
  95 dnl Curses detection: Munged from Midnight Commander's configure.in
  96 AC_DEFUN(AC_CHECK_CURSES,[
  97         search_ncurses=true
  98         screen_manager=""
  99         has_curses=false
 100
 101         CFLAGS=${CFLAGS--O}
 102
 103         AC_SUBST(CURSES_LIBS)
 104         AC_SUBST(CURSES_INCLUDEDIR)
 105
 106         AC_ARG_WITH(sunos-curses,
 107           [  --with-sunos-curses     Used to force SunOS 4.x curses],[
 108           if test x$withval = xyes; then
 109                 AC_USE_SUNOS_CURSES
 110           fi
 111         ])
 112
 113         AC_ARG_WITH(osf1-curses,
 114           [  --with-osf1-curses      Used to force OSF/1 curses],[
 115           if test x$withval = xyes; then
 116                 AC_USE_OSF1_CURSES
 117           fi
 118         ])
 119
 120         AC_ARG_WITH(vcurses,
 121           [  --with-vcurses[=incdir] Used to force SysV curses],
 122           if test x$withval != xyes; then
 123                 CURSES_INCLUDEDIR="-I$withval"
 124           fi
 125           AC_USE_SYSV_CURSES
 126         )
 127
 128         AC_ARG_WITH(ncurses,
 129           [  --with-ncurses[=dir]    Compile with ncurses/locate base dir],
 130           if test x$withval = xno ; then
 131                 search_ncurses=false
 132           elif test x$withval != xyes ; then
 133                 AC_NCURSES($withval/include, ncurses.h, -L$withval/lib -lncurses, -I$withval/include, "ncurses on $withval/include")
 134           fi
 135         )
 136
 137         if $search_ncurses
 138         then
 139                 AC_SEARCH_NCURSES()
 140         fi
 141 ])
 142
 143
 144 AC_DEFUN(AC_USE_SUNOS_CURSES, [
 145         search_ncurses=false
 146         screen_manager="SunOS 4.x /usr/5include curses"
 147         AC_MSG_RESULT(Using SunOS 4.x /usr/5include curses)
 148         AC_DEFINE(USE_SUNOS_CURSES)
 149         AC_DEFINE(HAS_CURSES)
 150         has_curses=true
 151         AC_DEFINE(NO_COLOR_CURSES)
 152         AC_DEFINE(USE_SYSV_CURSES)
 153         CURSES_INCLUDEDIR="-I/usr/5include"
 154         CURSES_LIBS="/usr/5lib/libcurses.a /usr/5lib/libtermcap.a"
 155         AC_MSG_RESULT(Please note that some screen refreshs may fail)
 156 ])
 157
 158 AC_DEFUN(AC_USE_OSF1_CURSES, [
 159        AC_MSG_RESULT(Using OSF1 curses)
 160        search_ncurses=false
 161        screen_manager="OSF1 curses"
 162        AC_DEFINE(HAS_CURSES)
 163        has_curses=true
 164        AC_DEFINE(NO_COLOR_CURSES)
 165        AC_DEFINE(USE_SYSV_CURSES)
 166        CURSES_LIBS="-lcurses"
 167 ])
 168
 169 AC_DEFUN(AC_USE_SYSV_CURSES, [
 170         AC_MSG_RESULT(Using SysV curses)
 171         AC_DEFINE(HAS_CURSES)
 172         has_curses=true
 173         AC_DEFINE(USE_SYSV_CURSES)
 174         search_ncurses=false
 175         screen_manager="SysV/curses"
 176         CURSES_LIBS="-lcurses"
 177 ])
 178
 179 dnl
 180 dnl Parameters: directory filename cureses_LIBS curses_INCLUDEDIR nicename
 181 dnl
 182 AC_DEFUN(AC_NCURSES, [
 183     if $search_ncurses
 184     then
 185         if test -f $1/$2
 186         then
 187             AC_MSG_RESULT(Found ncurses on $1/$2)
 188
 189             CURSES_LIBS="$3"
 190             AC_CHECK_LIB(ncurses, initscr, [
 191             ], [
 192                 CHECKLIBS=`echo "$3"|sed 's/-lncurses/-lcurses/g'`
 193                 AC_CHECK_LIB(curses, initscr, [
 194                         CURSES_LIBS="$CHECKLIBS"
 195                 ],, $CHECKLIBS)
 196             ], $CURSES_LIBS)
 197             CURSES_INCLUDEDIR="$4"
 198             search_ncurses=false
 199             screen_manager=$5
 200             AC_DEFINE(HAS_CURSES)
 201             has_curses=true
 202             has_ncurses=true
 203             AC_DEFINE(USE_NCURSES)
 204         fi
 205     fi
 206 ])
 207
 208 AC_DEFUN(AC_SEARCH_NCURSES, [
 209     AC_CHECKING("location of ncurses.h file")
 210
 211     AC_NCURSES(/usr/include, ncurses.h, -lncurses,, "ncurses on /usr/include")
 212     AC_NCURSES(/usr/include/ncurses, ncurses.h, -lncurses, -I/usr/include/ncurses, "ncurses on /usr/include/ncurses")
 213     AC_NCURSES(/usr/local/include, ncurses.h, -L/usr/local/lib -lncurses, -I/usr/local/include, "ncurses on /usr/local")
 214     AC_NCURSES(/usr/pkg/include, ncurses.h, -L/usr/pkg/lib -lncurses, -I/usr/pkg/include, "ncurses on /usr/pkg")
 215     AC_NCURSES(/usr/contrib/include, ncurses.h, -L/usr/contrib/lib -lncurses, -I/usr/contrib/include, "ncurses on /usr/contrib")
 216     AC_NCURSES(/usr/local/include/ncurses, ncurses.h, -L/usr/local/lib -L/usr/local/lib/ncurses -lncurses, -I/usr/local/include/ncurses, "ncurses on /usr/local/include/ncurses")
 217
 218     AC_NCURSES(/usr/local/include/ncurses, curses.h, -L/usr/local/lib -lncurses, -I/usr/local/include/ncurses -DRENAMED_NCURSES, "renamed ncurses on /usr/local/.../ncurses")
 219
 220     AC_NCURSES(/usr/include/ncurses, curses.h, -lncurses, -I/usr/include/ncurses -DRENAMED_NCURSES, "renamed ncurses on /usr/include/ncurses")
 221
 222     dnl
 223     dnl We couldn't find ncurses, try SysV curses
 224     dnl
 225     if $search_ncurses
 226     then
 227         AC_EGREP_HEADER(init_color, /usr/include/curses.h,
 228             AC_USE_SYSV_CURSES)
 229         AC_EGREP_CPP(USE_NCURSES,[
 230 #include <curses.h>
 231 #ifdef __NCURSES_H
 232 #undef USE_NCURSES
 233 USE_NCURSES
 234 #endif
 235 ],[
 236         CURSES_INCLUDEDIR="$CURSES_INCLUDEDIR -DRENAMED_NCURSES"
 237         AC_DEFINE(HAS_CURSES)
 238         has_curses=true
 239         has_ncurses=true
 240         AC_DEFINE(USE_NCURSES)
 241         search_ncurses=false
 242         screen_manager="ncurses installed as curses"
 243 ])
 244     fi
 245
 246     dnl
 247     dnl Try SunOS 4.x /usr/5{lib,include} ncurses
 248     dnl The flags USE_SUNOS_CURSES, USE_BSD_CURSES and BUGGY_CURSES
 249     dnl should be replaced by a more fine grained selection routine
 250     dnl
 251     if $search_ncurses
 252     then
 253         if test -f /usr/5include/curses.h
 254         then
 255             AC_USE_SUNOS_CURSES
 256         fi
 257     fi
 258
 259     dnl use whatever curses there happens to be
 260     if $search_ncurses
 261     then
 262         if test -f /usr/include/curses.h
 263         then
 264           CURSES_LIBS="-lcurses"
 265           AC_DEFINE(HAS_CURSES)
 266           has_curses=true
 267           search_ncurses=false
 268           screen_manager="curses"
 269         fi
 270     fi
 271 ])
 272
 273 AC_CHECK_CURSES
 274 LIBS="$LIBS $CURSES_LIBS"
 275
 276 # Function and library checking
 277 AC_CHECK_FUNC(gethostbyname, ac_gethostbyname_found=1,
 278 ac_gethostbyname_found=0)
 279 if test x$ac_gethostbyname_found = x0; then
 280     AC_CHECK_LIB(nsl, gethostbyname, LIBS="$LIBS -lnsl")
 281     AC_CHECK_FUNC(res_gethostbyname, ac_res_ghbn_found=1, ac_res_ghbn_found=0)
 282     if test x$ac_res_ghbn_found = x0; then
 283         AC_CHECK_LIB(resolv, res_gethostbyname,  LIBS="$LIBS -lresolv")
 284     fi
 285 fi
 286 AC_CHECK_FUNC(socket, ac_socket_found=1, ac_socket_found=0)
 287 if test x$ac_socket_found = x0; then
 288     AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
 289 fi
 290 AC_CHECK_FUNCS(gethostname gethostbyaddr getservbyname getservbyport)
 291 AC_CHECK_FUNCS(select listen bind shutdown close connect)
 292 AC_CHECK_FUNCS(fcntl setsockopt)
 293 AC_CHECK_FUNCS(getopt_long time)
 294 AC_CHECK_FUNCS(chmod stat fstat getenv putenv strerror ctime gettimeofday)
 295 AC_CHECK_FUNCS(getpid getgid getsid getpgid getpgrp getuid)
 296 AC_CHECK_FUNCS(strchr strstr strcpy strncpy memcpy memset memmove)
 297 AC_CHECK_FUNCS(pthread_create)
 298
 299 # SIM support checking
 300 # XXX These needs to be changed as more supported platforms appear.
 301 # XXX This probably needs to be made platform dependant check.
 302 sim_support=false
 303 AM_CONDITIONAL(SILC_SIM, test x$sim_support = xtrue)
 304 AC_CHECKING(for SIM support)
 305 AC_CHECK_HEADERS(dlfcn.h,
 306   AC_CHECK_LIB(dl, dlopen,
 307     AC_DEFINE(SILC_SIM)
 308     sim_support=true
 309     AM_CONDITIONAL(SILC_SIM, test x$sim_support = xtrue)
 310     AC_MSG_RESULT(enabled SIM support)
 311     LIBS="$LIBS -ldl",
 312     AC_MSG_RESULT(no SIM support found)),
 313   AC_MSG_RESULT(no SIM support found))
 314
 315 #
 316 # Installation
 317 #
 318
 319 # Default installation destination
 320 AC_PREFIX_DEFAULT(/usr/local/silc)
 321
 322 # etc directory
 323 ETCDIR="/etc/silc"
 324 AC_ARG_WITH(etcdir,
 325 [  --with-etcdir[=PATH]    Directory for system files [/etc/silc]],
 326 [ case "$withval" in
 327   no)
 328     ;;
 329   yes)
 330     ETCDIR="$withval"
 331     ;;
 332   *)
 333     ETCDIR="$withval"
 334     ;;
 335   esac ],
 336 )
 337 AC_SUBST(ETCDIR)
 338 AC_DEFINE_UNQUOTED(SILC_ETCDIR, "$ETCDIR")
 339
 340 # help directory
 341 HELPDIR="help"
 342 AC_ARG_WITH(helpdir,
 343 [  --with-helpdir[=PATH]   Directory for SILC help files [PREFIX/help]],
 344 [ case "$withval" in
 345   no)
 346     ;;
 347   yes)
 348     HELPDIR="$withval"
 349     ;;
 350   *)
 351     HELPDIR="$withval"
 352     ;;
 353   esac ],
 354 )
 355 AC_SUBST(HELPDIR)
 356 AC_DEFINE_UNQUOTED(SILC_HELPDIR, "$HELPDIR")
 357
 358 # doc directory
 359 DOCDIR="doc"
 360 AC_ARG_WITH(docdir,
 361 [  --with-docdir[=PATH]    Directory for SILC documentation [PREFIX/doc]],
 362 [ case "$withval" in
 363   no)
 364     ;;
 365   yes)
 366     DOCDIR="$withval"
 367     ;;
 368   *)
 369     DOCDIR="$withval"
 370     ;;
 371   esac ],
 372 )
 373 AC_SUBST(DOCDIR)
 374 AC_DEFINE_UNQUOTED(SILC_DOCDIR, "$DOCDIR")
 375
 376 # SIM modules directory
 377 MODULESDIR="modules"
 378 AC_ARG_WITH(simdir,
 379 [  --with-simdir[=PATH]    Directory for SIM modules [PREFIX/modules]],
 380 [ case "$withval" in
 381   no)
 382     ;;
 383   yes)
 384     MODULESDIR="$withval"
 385     ;;
 386   *)
 387     MODULESDIR="$withval"
 388     ;;
 389   esac ],
 390 )
 391 AC_SUBST(MODULESDIR)
 392 AC_DEFINE_UNQUOTED(SILC_MODULESDIR, "$MODULESDIR")
 393
 394 # Logs directory
 395 LOGSDIR="logs"
 396 AC_ARG_WITH(logsdir,
 397 [  --with-logsdir[=PATH]   Directory for Server logs [PREFIX/logs]],
 398 [ case "$withval" in
 399   no)
 400     ;;
 401   yes)
 402     LOGSDIR="$withval"
 403     ;;
 404   *)
 405     LOGSDIR="$withval"
 406     ;;
 407   esac ],
 408 )
 409 AC_SUBST(LOGSDIR)
 410 AC_DEFINE_UNQUOTED(SILC_LOGSDIR, "$LOGSDIR")
 411
 412 # SOCKS4 support checking
 413 AC_MSG_CHECKING(whether to support SOCKS4)
 414 AC_ARG_WITH(socks4,
 415 [  --with-socks4[=PATH]    Compile with SOCKS4 support],
 416 [ case "$withval" in
 417   no)
 418     AC_MSG_RESULT(no)
 419     ;;
 420   *)
 421     AC_MSG_RESULT(yes)
 422     socks=4
 423
 424     if test -d "$withval/include"; then
 425       CFLAGS="$CFLAGS -I$withval/include"
 426     else
 427       CFLAGS="$CFLAGS -I$withval"
 428     fi
 429     if test -d "$withval/lib"; then
 430       withval="-L$withval/lib -lsocks"
 431     else
 432       withval="-L$withval -lsocks"
 433     fi
 434
 435     LIBS="$withval $LIBS"
 436
 437     AC_TRY_LINK([],
 438                 [ Rconnect(); ],
 439                 [],
 440                 [ AC_MSG_ERROR(Could not find SOCKS4 library.)])
 441       ;;
 442   esac ],
 443   AC_MSG_RESULT(no)
 444 )
 445
 446 # SOCKS5 support checking
 447 AC_MSG_CHECKING(whether to support SOCKS5)
 448 AC_ARG_WITH(socks5,
 449 [  --with-socks5[=PATH]    Compile with SOCKS5 support],
 450 [ case "$withval" in
 451   no)
 452     AC_MSG_RESULT(no)
 453     ;;
 454   *)
 455     AC_MSG_RESULT(yes)
 456     socks=5
 457
 458     if test -d "$withval/include"; then
 459       CFLAGS="$CFLAGS -I$withval/include"
 460     else
 461       CFLAGS="$CFLAGS -I$withval"
 462     fi
 463     if test -d "$withval/lib"; then
 464       withval="-L$withval/lib -lsocks5"
 465     else
 466       withval="-L$withval -lsocks5"
 467     fi
 468
 469     LIBS="$withval $LIBS"
 470
 471     AC_TRY_LINK([],
 472                 [ SOCKSconnect(); ],
 473                 [],
 474                 [ AC_MSG_ERROR(Could not find SOCKS5 library.)])
 475       ;;
 476   esac ],
 477   AC_MSG_RESULT(no)
 478 )
 479
 480 if test "x$socks" = "x4"; then
 481   AC_DEFINE(SOCKS)
 482   CFLAGS="$CFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 483 fi
 484
 485 if test "x$socks" = "x5"; then
 486   AC_DEFINE(SOCKS)
 487   AC_DEFINE(SOCKS5)
 488   AC_DEFINE(Rconnect, SOCKSconnect)
 489   AC_DEFINE(Rgetsockname, SOCKSgetsockname)
 490   AC_DEFINE(Rgetpeername, SOCKSgetpeername)
 491   AC_DEFINE(Rbind, SOCKSbind)
 492   AC_DEFINE(Raccept, SOCKSaccept)
 493   AC_DEFINE(Rlisten, SOCKSlisten)
 494   AC_DEFINE(Rselect, SOCKSselect)
 495   AC_DEFINE(Rrecvfrom, SOCKSrecvfrom)
 496   AC_DEFINE(Rsendto, SOCKSsendto)
 497   AC_DEFINE(Rrecv, SOCKSrecv)
 498   AC_DEFINE(Rsend, SOCKSsend)
 499   AC_DEFINE(Rread, SOCKSread)
 500   AC_DEFINE(Rwrite, SOCKSwrite)
 501   AC_DEFINE(Rrresvport, SOCKSrresvport)
 502   AC_DEFINE(Rshutdown, SOCKSshutdown)
 503   AC_DEFINE(Rlisten, SOCKSlisten)
 504   AC_DEFINE(Rclose, SOCKSclose)
 505   AC_DEFINE(Rdup, SOCKSdup)
 506   AC_DEFINE(Rdup2, SOCKSdup2)
 507   AC_DEFINE(Rfclose, SOCKSfclose)
 508   AC_DEFINE(Rgethostbyname, SOCKSgethostbyname)
 509 fi
 510
 511 #
 512 # MP library checking. First check whether user wants to use GMP and use
 513 # it if found. If not or not defined then compile the MPI library in the
 514 # source tree.
 515 #
 516 AC_MSG_CHECKING(whether to support GMP)
 517 AC_ARG_WITH(gmp,
 518 [  --with-gmp[=PATH]       Compile with GMP support instead of MPI],
 519 [ case "$withval" in
 520   no)
 521     AC_MSG_RESULT(no)
 522     mp_gmp=false
 523     ;;
 524   *)
 525     AC_MSG_RESULT(yes)
 526
 527     if test -d "$withval/include"; then
 528       CFLAGS="$CFLAGS -I$withval/include"
 529     else
 530       CFLAGS="$CFLAGS -I$withval"
 531     fi
 532     if test -d "$withval/lib"; then
 533       withval="-L$withval/lib -lgmp"
 534     else
 535       withval="-L$withval -lgmp"
 536     fi
 537
 538     LIBS="$withval $LIBS"
 539     mp_gmp=false
 540     AC_CHECK_LIB(gmp, __gmpz_init,
 541       mp_gmp=true
 542       AC_DEFINE(SILC_MP_GMP)
 543       AC_MSG_RESULT(Using GMP as MP library)
 544     )
 545       ;;
 546   esac ],
 547   AC_MSG_RESULT(no)
 548   mp_gmp=false
 549 )
 550
 551 AM_CONDITIONAL(SILC_MP_GMP, test x$mp_gmp = xtrue)
 552 AM_CONDITIONAL(SILC_MP_NSS_MPI, test x$mp_gmp = xfalse)
 553 if test x$mp_gmp = xfalse; then
 554   AC_DEFINE(SILC_MP_NSS_MPI)
 555   AC_MSG_RESULT(Using NSS MPI as MP library)
 556 fi
 557
 558 AC_ARG_WITH(silcd-config-file,
 559 [  --with-silcd-config-file[=PATH]
 560                           Use PATH as default configuration file in SILC
 561                           server [/etc/silc/silcd.conf]],
 562 [ AC_DEFINE_UNQUOTED(SILC_SERVER_CONFIG_FILE, "$withval") ])
 563
 564 #
 565 # Native WIN32 compilation under cygwin
 566 #
 567 AC_ARG_WITH(win32,
 568 [  --with-win32            Compile native WIN32 code (-mno-cygwin)],
 569 [ AC_DEFINE(SILC_WIN32)
 570   win32-support = true
 571   CFLAGS="-mno-cygwin $CFLAGS"
 572   LIBS="$LIBS -lwsock32" ])
 573
 574 AM_CONDITIONAL(SILC_WIN32, test x$win32-support = xtrue)
 575
 576 #
 577 # Debug checking
 578 #
 579 AC_MSG_CHECKING(for enabled debugging)
 580 AC_ARG_ENABLE(debug,
 581 [  --enable-debug          Enable debugging (warning: it is heavy!)],
 582 [ case "${enableval}" in
 583   yes)
 584     AC_MSG_RESULT(yes)
 585     AC_DEFINE(SILC_DEBUG)
 586     CFLAGS="-O -g $CFLAGS"
 587     ;;
 588   *)
 589     AC_MSG_RESULT(no)
 590     CFLAGS="-O2 -g $CFLAGS"
 591     ;;
 592 esac ], CFLAGS="-O2 -g $CFLAGS"
 593         AC_MSG_RESULT(no))
 594
 595 #
 596 # Threads support
 597 #
 598 AC_ARG_ENABLE(threads,
 599 [  --disable-threads       Do not compile with multi-thread support],
 600 [ case "${enableval}" in
 601   yes)
 602     want_threads=true
 603     check_threads=true
 604     ;;
 605   *)
 606     want_threads=false
 607     check_threads=false
 608     ;;
 609 esac ])
 610
 611 if test x$check_threads = xtrue; then
 612 want_threads=false
 613 AC_CHECK_HEADERS(pthread.h,
 614         [ AC_DEFINE(SILC_HAVE_PTHREAD)
 615           want_threads=true ],
 616         [ if test -f /usr/pkg/include/pthread.h ; then
 617             AC_DEFINE(SILC_HAVE_PTHREAD)
 618             AC_MSG_RESULT(Found pthread.h in /usr/pkg/include/)
 619             CFLAGS="$CFLAGS -I/usr/pkg/include"
 620             want_threads=true
 621           elif test -f /usr/contrib/include/pthread.h ; then
 622             AC_DEFINE(SILC_HAVE_PTHREAD)
 623             AC_MSG_RESULT(Found pthread.h in /usr/contrib/include/)
 624             CFLAGS="$CFLAGS -I/usr/contrib/include"
 625             want_threads=true
 626           fi
 627         ])
 628
 629 AM_CONDITIONAL(SILC_THREADS, test x$want_threads = xtrue)
 630 if test x$want_threads = xtrue; then
 631   TMP_LIBS="$LIBS"
 632   LIBS="-lpthread"
 633   AC_TRY_LINK([#include <pthread.h>],
 634               [pthread_attr_t attr; pthread_attr_init(&attr);],
 635   AC_DEFINE(SILC_THREADS),
 636   LIBS="-L/usr/pkg/lib -lpthread"
 637   AC_TRY_LINK([#include <pthread.h>],
 638               [pthread_attr_t attr; pthread_attr_init(&attr);],
 639   AC_DEFINE(SILC_THREADS),
 640   LIBS="-L/usr/contrib/lib -lpthread"
 641   AC_TRY_LINK([#include <pthread.h>],
 642               [pthread_attr_t attr; pthread_attr_init(&attr);],
 643   AC_DEFINE(SILC_THREADS),
 644   LIBS=""
 645   )))
 646
 647   CFLAGS="$CFLAGS -D_REENTRANT"
 648   case $host in
 649     *-aix*)
 650       CFLAGS="$CFLAGS -D_THREAD_SAFE"
 651       if test x"$GCC" = xyes; then
 652         CFLAGS="$CFLAGS -mthreads"
 653       fi
 654       ;;
 655     *-freebsd2.2*)
 656       CFLAGS="$CFLAGS -D_THREAD_SAFE"
 657       ;;
 658     *-sysv5uw7*)  # UnixWare 7
 659       if test "$GCC" != "yes"; then
 660         CFLAGS="$CFLAGS -Kthread"
 661       else
 662         CFLAGS="$CFLAGS -pthread"
 663       fi
 664       ;;
 665     *-dg-dgux*)  # DG/UX
 666       CFLAGS="$CFLAGS -D_POSIX4A_DRAFT10_SOURCE"
 667       ;;
 668     esac
 669
 670   LIBS="$TMP_LIBS $LIBS"
 671 fi
 672 fi
 673
 674 #
 675 # Other configure scripts
 676 #
 677 AC_CONFIG_SUBDIRS(lib/dotconf)
 678 AC_CONFIG_SUBDIRS(lib/trq)
 679 AC_CONFIG_SUBDIRS(irssi)
 680 AC_CONFIG_SUBDIRS(lib/silcmath/mpi)
 681 #AC_CONFIG_SUBDIRS(lib/zlib)
 682
 683 SILC_TOP_SRCDIR=`pwd`
 684 AC_SUBST(SILC_TOP_SRCDIR)
 685 #SILC_INSTALL_PREFIX=$ac_default_prefix
 686 #AC_SUBST(SILC_INSTALL_PREFIX)
 687 AC_SUBST(LIBS)
 688 INCLUDE_DEFINES_INT="include \$(top_srcdir)/Makefile.defines_int"
 689 AC_SUBST(INCLUDE_DEFINES_INT)
 690
 691 #
 692 # Makefile outputs
 693 #
 694 AC_OUTPUT( \
 695 Makefile
 696 Makefile.defines
 697 Makefile.defines_int
 698 irssi/Makefile.defines
 699 irssi/Makefile.defines_int
 700 doc/Makefile
 701 doc/whitepaper/Makefile
 702 includes/Makefile
 703 lib/Makefile
 704 lib/contrib/Makefile
 705 lib/silcclient/Makefile
 706 lib/silccore/Makefile
 707 lib/silccrypt/Makefile
 708 lib/silcmath/Makefile
 709 lib/silcmath/mpi/Makefile.defines
 710 lib/silcmath/mpi/Makefile.defines_int
 711 lib/silcsim/Makefile
 712 lib/silcsim/modules/Makefile
 713 lib/silcske/Makefile
 714 lib/silcutil/Makefile
 715 lib/silcutil/unix/Makefile
 716 lib/silcutil/win32/Makefile
 717 silc/Makefile
 718 silcd/Makefile
 719 win32/Makefile
 720 win32/libsilc/Makefile
 721 win32/libsilcclient/Makefile)