configure.in.pre

   1 #
   2 #  configure.in.pre
   3 #
   4 #  Author: Pekka Riikonen <priikone@silcnet.org>
   5 #
   6 #  Copyright (C) 2000 - 2004 Pekka Riikonen
   7 #
   8 #  This program is free software; you can redistribute it and/or modify
   9 #  it under the terms of the GNU General Public License as published by
  10 #  the Free Software Foundation; either version 2 of the License, or
  11 #  (at your option) any later version.
  12 #
  13 #  This program is distributed in the hope that it will be useful,
  14 #  but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 #  GNU General Public License for more details.
  17 #
  18
  19 AC_INIT(includes/silcversion.h)
  20
  21 # Put here any platform specific stuff
  22 #
  23 AC_CANONICAL_SYSTEM
  24 case "$target" in
  25   *-*-freebsd*)
  26     check_threads=true
  27     ;;
  28   *-*-*bsd*)
  29     check_threads=false
  30     ;;
  31   *)
  32     check_threads=true
  33     ;;
  34 esac
  35
  36 # ./prepare script will automatically put the correct version. Do not edit!
  37 #
  38 AM_INIT_AUTOMAKE(SILC_PACKAGE, SILC_VERSION)
  39 AC_PREREQ(2.52)
  40 AC_CONFIG_HEADERS(includes/silcdefs.h)
  41
  42 CFLAGS=
  43 AC_PROG_CC
  44 AC_C_INLINE
  45 AC_C_CONST
  46
  47 AC_PROG_LN_S
  48 AC_SUBST(LN_S)
  49
  50 ##
  51 ## Distribution definition. ./prepare will automatically add here a correct
  52 ## value. Do not edit!
  53 ##
  54 silc_dist=SILC_PACKAGE
  55 SILC_DIST_SUBDIRS="SILC_DISTRIBUTION_SUBDIRS"
  56 AC_DEFINE(SILC_DIST_DEFINE)
  57
  58
  59 ##
  60 ## Library versioning.
  61 ##
  62 # Do the releases and library versioning according to following rules:
  63 #
  64 #  - If any code has changed in library, increment [LIB]_REVISION
  65 #  - If functions were added, set [LIB]_REVISION to 0
  66 #  - If functions were added, removed or changed, increment [LIB]_CURRENT
  67 #  - If functions were added, increment [LIB]_AGE
  68 #  - If functions were removed, set [LIB]_AGE to 0
  69 #
  70 # where [LIB] is LIBSILC and LIBSILCCLIENT, and where "functions" means
  71 # functions public interfaces.
  72 #
  73 # The LIB_BASE_VERSION defines the SILC software major.minor version and
  74 # it is increment only when these version numbers actually change.
  75 #
  76
  77 # Base version for libraries.  Do not change this unless SILC version
  78 # changes too.
  79 LIB_BASE_VERSION=1.0
  80
  81 # libsilc versions
  82 LIBSILC_CURRENT=3
  83 LIBSILC_REVISION=0
  84 LIBSILC_AGE=1
  85
  86 # libsilcclient versions
  87 LIBSILCCLIENT_CURRENT=3
  88 LIBSILCCLIENT_REVISION=0
  89 LIBSILCCLIENT_AGE=1
  90
  91 # Substitute the version numbers
  92 AC_SUBST(LIB_BASE_VERSION)
  93 AC_SUBST(LIBSILC_CURRENT)
  94 AC_SUBST(LIBSILC_REVISION)
  95 AC_SUBST(LIBSILC_AGE)
  96 AC_SUBST(LIBSILCCLIENT_CURRENT)
  97 AC_SUBST(LIBSILCCLIENT_REVISION)
  98 AC_SUBST(LIBSILCCLIENT_AGE)
  99
 100 #
 101 # Program checking
 102 #
 103 AC_PROG_INSTALL
 104 AC_PROG_RANLIB
 105 AC_PROG_MAKE_SET
 106 AC_DISABLE_SHARED
 107 AC_PROG_LIBTOOL
 108 AC_PATH_PROG(sedpath, sed)
 109
 110 # Header checking
 111 #
 112 AC_HEADER_STDC
 113 AC_HEADER_TIME
 114 AC_HEADER_STAT
 115
 116 # More header checking
 117 #
 118 AC_CHECK_HEADERS(unistd.h string.h getopt.h errno.h fcntl.h assert.h)
 119 AC_CHECK_HEADERS(sys/types.h sys/stat.h sys/time.h stddef.h)
 120 AC_CHECK_HEADERS(netinet/in.h netinet/tcp.h xti.h netdb.h)
 121 AC_CHECK_HEADERS(pwd.h grp.h termcap.h paths.h)
 122 AC_CHECK_HEADERS(ncurses.h signal.h ctype.h utime.h)
 123 AC_CHECK_HEADERS(arpa/inet.h sys/mman.h limits.h termios.h locale.h langinfo.h)
 124
 125 # Data type checking
 126 #
 127 AC_TYPE_SIGNAL
 128 AC_TYPE_SIZE_T
 129 AC_TYPE_MODE_T
 130 AC_TYPE_UID_T
 131 AC_TYPE_PID_T
 132
 133 AC_CHECK_SIZEOF(long long, 0)
 134 AC_SUBST(SILC_SIZEOF_LONG_LONG, $ac_cv_sizeof_long_long)
 135 AC_CHECK_SIZEOF(long, 0)
 136 AC_SUBST(SILC_SIZEOF_LONG, $ac_cv_sizeof_long)
 137 AC_CHECK_SIZEOF(int, 0)
 138 AC_SUBST(SILC_SIZEOF_INT, $ac_cv_sizeof_int)
 139 AC_CHECK_SIZEOF(short, 0)
 140 AC_SUBST(SILC_SIZEOF_SHORT, $ac_cv_sizeof_short)
 141 AC_CHECK_SIZEOF(char, 0)
 142 AC_SUBST(SILC_SIZEOF_CHAR, $ac_cv_sizeof_char)
 143 AC_CHECK_SIZEOF(void *, 0)
 144 AC_SUBST(SILC_SIZEOF_VOID_P, $ac_cv_sizeof_void_p)
 145
 146 # Function and library checking
 147 #
 148 AC_CHECK_FUNC(gethostbyname, [],
 149   [
 150     AC_CHECK_LIB(nsl, gethostbyname, LIBS="$LIBS -lnsl")
 151     AC_CHECK_FUNC(res_gethostbyname, [],
 152        AC_CHECK_LIB(resolv, res_gethostbyname, LIBS="$LIBS -lresolv")
 153     )
 154   ])
 155 AC_CHECK_FUNC(socket, [],
 156   AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
 157 )
 158 AC_CHECK_FUNCS(gethostname gethostbyaddr getservbyname getservbyport)
 159 AC_CHECK_FUNCS(select listen bind shutdown close connect setsockopt)
 160 AC_CHECK_FUNCS(time ctime utime gettimeofday)
 161 AC_CHECK_FUNCS(chmod fcntl stat fstat getenv putenv strerror)
 162 AC_CHECK_FUNCS(getpid getgid getsid getpgid getpgrp getuid)
 163 AC_CHECK_FUNCS(setgroups initgroups nl_langinfo)
 164 AC_CHECK_FUNCS(strchr strstr strcpy strncpy memcpy memset memmove)
 165
 166 # SIM support checking
 167 # XXX These needs to be changed as more supported platforms appear.
 168 # XXX This probably needs to be made platform dependant check.
 169 #
 170 sim_support=false
 171 AC_MSG_CHECKING(for SIM support)
 172 AC_MSG_RESULT()
 173 AC_CHECK_HEADERS(dlfcn.h,
 174   [
 175     AC_CHECK_LIB(dl, dlopen,
 176       [
 177         AC_DEFINE(SILC_SIM)
 178         sim_support=true
 179         LIBS="$LIBS -ldl"
 180       ],
 181       [
 182         AC_CHECK_LIB(c, dlopen,
 183           [
 184             AC_DEFINE(SILC_SIM)
 185             sim_support=true
 186           ])
 187       ])
 188    ])
 189
 190 AM_CONDITIONAL(SILC_SIM, test x$sim_support = xtrue)
 191 if test x$sim_support = xtrue; then
 192   AC_MSG_RESULT(Enabled SIM support.)
 193 else
 194   AC_MSG_RESULT(No SIM support found.)
 195 fi
 196
 197 # lib/contrib conditionals
 198 #
 199 AC_CHECK_HEADER(regex.h,
 200   [
 201     AC_DEFINE(HAVE_REGEX)
 202     have_regex=1
 203   ], have_regex=0
 204 )
 205 AM_CONDITIONAL(HAVE_REGEX, test x$have_regex = x1)
 206
 207 AC_CHECK_FUNC(getopt_long,
 208   [
 209     AC_DEFINE(HAVE_GETOPT_LONG)
 210     have_getopt_long=1
 211   ], have_getopt_long=0
 212 )
 213 AM_CONDITIONAL(HAVE_GETOPT_LONG, test x$have_getopt_long = x1)
 214
 215 ##
 216 ##  Enable/disable checking
 217 ##
 218
 219 # IPv6 support
 220 #
 221 AC_MSG_CHECKING(whether to enable IPv6 support)
 222 AC_ARG_ENABLE(ipv6,
 223   [  --enable-ipv6           enable IPv6 support],
 224   [
 225     case "${enableval}" in
 226       yes)
 227         want_ipv6=true
 228         check_ipv6=false
 229         summary_ipv6="yes"
 230         AC_DEFINE(HAVE_IPV6)
 231         AC_MSG_RESULT(yes)
 232         ;;
 233       *)
 234         want_ipv6=false
 235         check_ipv6=false
 236         summary_ipv6="no"
 237         AC_MSG_RESULT(no)
 238         ;;
 239     esac
 240   ],
 241     check_ipv6=true
 242   )
 243
 244 if test x$check_ipv6 = xtrue; then
 245   summary_ipv6="no"
 246   AC_TRY_COMPILE(
 247     [
 248       #ifdef HAVE_SYS_TYPES_H
 249       #include <sys/types.h>
 250       #endif
 251       #ifdef HAVE_NETINET_TCP_H
 252       #include <netinet/tcp.h>
 253       #endif
 254       #ifdef HAVE_NETDB_H
 255       #include <netdb.h>
 256       #endif
 257       #include <sys/socket.h>
 258       #ifdef HAVE_NETINET_IN_H
 259       #include <netinet/in.h>
 260       #endif
 261     ],
 262     [
 263       struct sockaddr_in6 sin6;
 264       int family = AF_INET6;
 265     ],
 266     [
 267       AC_DEFINE(HAVE_IPV6)
 268       AC_MSG_RESULT(yes)
 269       summary_ipv6="yes"
 270     ],
 271       AC_MSG_RESULT(no)
 272     )
 273 fi
 274
 275 # Debug checking
 276 #
 277 AC_MSG_CHECKING(whether to enable debugging)
 278 summary_debug="no"
 279 AC_ARG_ENABLE(debug,
 280   [  --enable-debug          enable debugging],
 281   [
 282     case "${enableval}" in
 283       yes)
 284         AC_MSG_RESULT(yes)
 285         AC_DEFINE(SILC_DEBUG)
 286         summary_debug="yes"
 287         ;;
 288       *)
 289         AC_MSG_RESULT(no)
 290         ;;
 291     esac
 292   ],
 293   [
 294     AC_MSG_RESULT(no)
 295   ])
 296
 297 # Stack trace checking
 298 #
 299 AC_MSG_CHECKING(whether to enable stack tracing)
 300 summary_stacktrace="no"
 301 AC_ARG_ENABLE(stack-trace,
 302   [  --enable-stack-trace    enable memory stack trace],
 303   [
 304     case "${enableval}" in
 305     yes)
 306       AC_MSG_RESULT(yes)
 307       AC_DEFINE(SILC_STACKTRACE)
 308       summary_stacktrace="yes"
 309       ;;
 310     *)
 311       AC_MSG_RESULT(no)
 312       ;;
 313     esac
 314   ],
 315     AC_MSG_RESULT(no)
 316   )
 317
 318 # Disable all assembler optimizations
 319 #
 320 AC_MSG_CHECKING(whether to enable assembler optimizations)
 321 want_asm=true
 322 AC_ARG_ENABLE(asm,
 323   [  --disable-asm           do not use assembler optimizations],
 324   [
 325     AC_MSG_RESULT(no)
 326     want_asm=false
 327   ],
 328   [
 329     AC_MSG_RESULT(yes)
 330     want_asm=true
 331   ])
 332
 333
 334 ##
 335 ## Compiler and compiler flag checks
 336 ##
 337
 338 # Function to check if compiler flag works
 339 # Usage: SILC_ADD_CFLAGS(FLAGS, [ACTION-IF-FAILED])
 340 AC_DEFUN([SILC_ADD_CFLAGS],
 341 [ tmp_CFLAGS="$CFLAGS"
 342   CFLAGS="$CFLAGS $1"
 343   AC_MSG_CHECKING(whether $CC accepts $1 flag)
 344   AC_TRY_LINK([], [], [AC_MSG_RESULT(yes)], [AC_MSG_RESULT(no)
 345                                        CFLAGS="$tmp_CFLAGS"
 346                                        $2])
 347   unset tmp_CFLAGS
 348 ])
 349
 350 if test "$GCC"; then
 351   # GCC specific options
 352   if test "x$summary_debug" = "xyes"; then
 353     SILC_ADD_CFLAGS(-g -O)
 354   else
 355     SILC_ADD_CFLAGS(-g -O2)
 356   fi
 357   SILC_ADD_CFLAGS(-Wall -finline-functions)
 358 else
 359   # Other compilers
 360   case "$target" in
 361     alpha*-dec-osf*)
 362       SILC_ADD_CFLAGS(-g3 -O2, SILC_ADD_CFLAGS(-g3 -O, SILC_ADD_CFLAGS(-O)))
 363       ;;
 364     *)
 365       SILC_ADD_CFLAGS(-g)
 366       SILC_ADD_CFLAGS(-O2, SILC_ADD_CFLAGS(-O))
 367       ;;
 368   esac
 369
 370   # Intel C++ Compiler needs -restrict
 371   if test "x$CC" = "xicc"; then
 372     SILC_ADD_CFLAGS(-restrict)
 373   fi
 374 fi
 375
 376 #
 377 # Workaround a bug in GCC 2.x which causes memory exhaustion
 378 # when compiling sha1 with optimizations on UltraSPARC.
 379 #
 380 FIX_SHA1='#'
 381 if test "$GCC" -a "$host_cpu" = "sparc64"; then
 382   AC_MSG_CHECKING(whether to enable GCC 2.x workaround for SHA1)
 383   AC_TRY_COMPILE(
 384     [
 385       #if defined(__sparc64__) && (__GNUC__ == 2)
 386       #else
 387       choke me
 388       #endif
 389     ],
 390     [],
 391     [
 392       FIX_SHA1=''
 393       AC_MSG_RESULT(yes)
 394     ],
 395       AC_MSG_RESULT(no)
 396     )
 397 fi
 398 AC_SUBST(FIX_SHA1)
 399
 400 ##
 401 ##  Installation
 402 ##
 403
 404 # Default installation destination
 405 #
 406 AC_PREFIX_DEFAULT(/usr/local/silc)
 407 if test "x$prefix" != xNONE; then
 408   silc_prefix="$prefix"
 409 else
 410   silc_prefix="$ac_default_prefix"
 411 fi
 412
 413 # etc directory
 414 #
 415 if test "x$sysconfdir" != 'x${prefix}/etc'; then
 416   ETCDIR="$sysconfdir"
 417 else
 418   ETCDIR="$silc_prefix/etc"
 419 fi
 420
 421 AC_ARG_WITH(etcdir,
 422   [[  --with-etcdir=DIR       directory for system files [/etc/silc]]],
 423   [
 424     case "$withval" in
 425       no|yes)
 426         ;;
 427       *)
 428         ETCDIR="$withval"
 429         ;;
 430     esac
 431   ])
 432 AC_SUBST(ETCDIR)
 433 AC_DEFINE_UNQUOTED(SILC_ETCDIR, "$ETCDIR")
 434
 435 # help directory
 436 #
 437 HELPDIR="$silc_prefix/help"
 438 AC_ARG_WITH(helpdir,
 439   [[  --with-helpdir=DIR      directory for SILC help files [PREFIX/help]]],
 440   [
 441     case "$withval" in
 442       no|yes)
 443         ;;
 444       *)
 445        HELPDIR="$withval"
 446        ;;
 447     esac
 448   ])
 449 AC_SUBST(HELPDIR)
 450 AC_DEFINE_UNQUOTED(SILC_HELPDIR, "$HELPDIR")
 451
 452 # doc directory
 453 #
 454 DOCDIR="$silc_prefix/doc"
 455 AC_ARG_WITH(docdir,
 456   [[  --with-docdir=DIR       directory for SILC documentation [PREFIX/doc]]],
 457   [
 458     case "$withval" in
 459       no|yes)
 460         ;;
 461       *)
 462         DOCDIR="$withval"
 463         ;;
 464     esac
 465   ])
 466 AC_SUBST(DOCDIR)
 467 AC_DEFINE_UNQUOTED(SILC_DOCDIR, "$DOCDIR")
 468
 469 # SIM modules directory
 470 #
 471 MODULESDIR="$silc_prefix/modules"
 472 AC_ARG_WITH(simdir,
 473   [[  --with-simdir=DIR       directory for SIM modules [PREFIX/modules]]],
 474   [
 475     case "$withval" in
 476       no|yes)
 477         ;;
 478       *)
 479         MODULESDIR="$withval"
 480         ;;
 481     esac
 482   ])
 483 AC_SUBST(MODULESDIR)
 484 AC_DEFINE_UNQUOTED(SILC_MODULESDIR, "$MODULESDIR")
 485
 486 # Logs directory
 487 #
 488 LOGSDIR="$silc_prefix/logs"
 489 AC_ARG_WITH(logsdir,
 490   [[  --with-logsdir=DIR      directory for SILC Server logs [PREFIX/logs]]],
 491   [
 492     case "$withval" in
 493       no|yes)
 494         ;;
 495       *)
 496         LOGSDIR="$withval"
 497         ;;
 498     esac
 499   ])
 500 AC_SUBST(LOGSDIR)
 501 AC_DEFINE_UNQUOTED(SILC_LOGSDIR, "$LOGSDIR")
 502
 503 # silcd config file checking
 504 #
 505 summary_silcd_configfile="/etc/silc/silcd.conf"
 506 AC_ARG_WITH(silcd-config-file,
 507   [[  --with-silcd-config-file=FILE  use FILE as default configuration file
 508                                  for SILC Server [/etc/silc/silcd.conf]]],
 509     AC_DEFINE_UNQUOTED(SILC_SERVER_CONFIG_FILE, "$withval")
 510     summary_silcd_configfile="$withval"
 511   )
 512
 513 # silcd pid file checking
 514 #
 515 if test "x$localstatedir" != 'x${prefix}/var'; then
 516   PIDFILE="$localstatedir/silcd.pid"
 517 else
 518   PIDFILE="$silc_prefix/var/silcd.pid"
 519 fi
 520
 521 AC_ARG_WITH(silcd-pid-file,
 522   [[  --with-silcd-pid-file=FILE     use FILE as default pid file for SILC
 523                                  Server [/var/run/silcd.pid]]],
 524   [
 525     case "$withval" in
 526       no|yes)
 527         ;;
 528       *)
 529         PIDFILE="$withval"
 530         ;;
 531     esac
 532   ])
 533 AC_SUBST(PIDFILE)
 534
 535
 536 ##
 537 ##  With/without checkings
 538 ##
 539
 540 # SOCKS4 support checking
 541 #
 542 SAVE_LIBS="$LIBS"
 543 SAVE_CFLAGS="$CFLAGS"
 544 SAVE_LDFLAGS="$LDFLAGS"
 545 AC_MSG_CHECKING(whether to support SOCKS4)
 546 AC_ARG_WITH(socks4,
 547   [[  --with-socks4[=DIR]     with SOCKS4 support [search in DIR/lib and DIR/include]]],
 548   [
 549     case "$withval" in
 550       no)
 551         AC_MSG_RESULT(no)
 552         ;;
 553       *)
 554         AC_MSG_RESULT(yes)
 555         socks=4
 556
 557         if test -d "$withval/include"; then
 558           CFLAGS="$CFLAGS -I$withval/include"
 559         fi
 560         if test -d "$withval/lib"; then
 561           LDFLAGS="$LDFLAGS -L$withval/lib"
 562         fi
 563
 564         LIBS="-lsocks $LIBS"
 565         ;;
 566     esac
 567
 568     AC_TRY_LINK([],
 569       [
 570         Rconnect();
 571       ], [],
 572       [
 573         AC_MSG_ERROR(Could not find SOCKS4 library.)
 574         LIBS="$SAVE_LIBS"
 575         CFLAGS="$SAVE_CFLAGS"
 576         LDFLAGS="$SAVE_LDFLAGS"
 577       ])
 578   ],
 579     AC_MSG_RESULT(no)
 580   )
 581
 582 # SOCKS5 support checking
 583 #
 584 SAVE_LIBS="$LIBS"
 585 SAVE_CFLAGS="$CFLAGS"
 586 SAVE_LDFLAGS="$LDFLAGS"
 587 AC_MSG_CHECKING(whether to support SOCKS5)
 588 AC_ARG_WITH(socks5,
 589   [[  --with-socks5[=DIR]     with SOCKS5 support [search in DIR/lib and DIR/include]]],
 590   [
 591     case "$withval" in
 592       no)
 593         AC_MSG_RESULT(no)
 594         ;;
 595       *)
 596         AC_MSG_RESULT(yes)
 597         socks=5
 598
 599         if test -d "$withval/include"; then
 600           CFLAGS="$CFLAGS -I$withval/include"
 601         fi
 602         if test -d "$withval/lib"; then
 603           LDFLAGS="$LDFLAGS -L$withval/lib"
 604         fi
 605
 606         LIBS="-lsocks5 $LIBS"
 607         ;;
 608     esac
 609
 610     AC_TRY_LINK([],
 611       [
 612         SOCKSconnect();
 613       ], [],
 614       [
 615         AC_MSG_ERROR(Could not find SOCKS5 library.)
 616         LIBS="$SAVE_LIBS"
 617         CFLAGS="$SAVE_CFLAGS"
 618         LDFLAGS="$SAVE_LDFLAGS"
 619       ])
 620   ],
 621     AC_MSG_RESULT(no)
 622   )
 623
 624 if test "x$socks" = "x4"; then
 625   AC_DEFINE(SOCKS)
 626   CFLAGS="$CFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 627 fi
 628
 629 if test "x$socks" = "x5"; then
 630   AC_DEFINE(SOCKS)
 631   AC_DEFINE(SOCKS5)
 632   AC_DEFINE(Rconnect, SOCKSconnect)
 633   AC_DEFINE(Rgetsockname, SOCKSgetsockname)
 634   AC_DEFINE(Rgetpeername, SOCKSgetpeername)
 635   AC_DEFINE(Rbind, SOCKSbind)
 636   AC_DEFINE(Raccept, SOCKSaccept)
 637   AC_DEFINE(Rlisten, SOCKSlisten)
 638   AC_DEFINE(Rselect, SOCKSselect)
 639   AC_DEFINE(Rrecvfrom, SOCKSrecvfrom)
 640   AC_DEFINE(Rsendto, SOCKSsendto)
 641   AC_DEFINE(Rrecv, SOCKSrecv)
 642   AC_DEFINE(Rsend, SOCKSsend)
 643   AC_DEFINE(Rread, SOCKSread)
 644   AC_DEFINE(Rwrite, SOCKSwrite)
 645   AC_DEFINE(Rrresvport, SOCKSrresvport)
 646   AC_DEFINE(Rshutdown, SOCKSshutdown)
 647   AC_DEFINE(Rlisten, SOCKSlisten)
 648   AC_DEFINE(Rclose, SOCKSclose)
 649   AC_DEFINE(Rdup, SOCKSdup)
 650   AC_DEFINE(Rdup2, SOCKSdup2)
 651   AC_DEFINE(Rfclose, SOCKSfclose)
 652   AC_DEFINE(Rgethostbyname, SOCKSgethostbyname)
 653 fi
 654
 655 # MP library checking. First check whether user wants to use GMP and use
 656 # it if found. If not or not defined then compile the MPI library in the
 657 # source tree.
 658 #
 659 mp_gmp=false
 660 SAVE_LIBS="$LIBS"
 661 SAVE_CFLAGS="$CFLAGS"
 662 SAVE_LDFLAGS="$LDFLAGS"
 663 AC_MSG_CHECKING(whether to search for GMP)
 664 AC_ARG_WITH(gmp,
 665   [[  --with-gmp[=DIR]        use GMP instead of MPI [search in DIR/lib and DIR/include]]],
 666   [
 667     case "$withval" in
 668       no)
 669         AC_MSG_RESULT(no)
 670         ;;
 671       *)
 672         AC_MSG_RESULT(yes)
 673
 674         if test -d "$withval/include"; then
 675           CFLAGS="$CFLAGS -I$withval/include"
 676         fi
 677         if test -d "$withval/lib"; then
 678           LDFLAGS="$LDFLAGS -L$withval/lib"
 679         fi
 680
 681         LIBS="-lgmp $LIBS"
 682         ;;
 683     esac
 684
 685     AC_CHECK_LIB(gmp, __gmpz_init,
 686       [
 687         mp_gmp=true
 688         AC_DEFINE(SILC_MP_GMP)
 689         AC_MSG_RESULT(Using GMP as a MP library.)
 690       ],
 691       [
 692         LIBS="$SAVE_LIBS"
 693         CFLAGS="$SAVE_CFLAGS"
 694         LDFLAGS="$SAVE_LDFLAGS"
 695       ])
 696   ],
 697     AC_MSG_RESULT(no)
 698   )
 699
 700 AM_CONDITIONAL(SILC_MP_GMP, test x$mp_gmp = xtrue)
 701 AM_CONDITIONAL(SILC_MP_NSS_MPI, test x$mp_gmp = xfalse)
 702 if test x$mp_gmp = xfalse; then
 703   AC_DEFINE(SILC_MP_NSS_MPI)
 704   AC_MSG_RESULT(Using NSS MPI as a MP library.)
 705 fi
 706
 707 # iconv support
 708 #
 709 check_iconv=true
 710 has_iconv=false
 711 SAVE_LIBS="$LIBS"
 712 SAVE_CFLAGS="$CFLAGS"
 713 SAVE_LDFLAGS="$LDFLAGS"
 714 SAVE_CPPFLAGS="$CPPFLAGS"
 715 AC_MSG_CHECKING(whether to implicit search for libiconv)
 716 AC_ARG_WITH(iconv,
 717   [[  --with-iconv[=DIR]      use libiconv [search in DIR/include and DIR/lib]]],
 718   [
 719     case "${withval}" in
 720       no)
 721         AC_MSG_RESULT(no)
 722         AC_CHECK_HEADERS(iconv.h,
 723           [
 724             AC_CHECK_FUNC(iconv, has_iconv=true)
 725           ])
 726         check_iconv=false
 727         ;;
 728       *)
 729         AC_MSG_RESULT(yes)
 730         if test -d $withval/include; then
 731           CPPFLAGS="$CPPFLAGS -I$withval/include"
 732           CFLAGS="$CFLAGS -I$withval/include"
 733         fi
 734         if test -d $withval/lib; then
 735           LDFLAGS="$LDFLAGS -L$withval/lib"
 736         fi
 737         ;;
 738     esac
 739   ],
 740   [
 741     AC_MSG_RESULT(no)
 742     AC_CHECK_HEADERS(iconv.h,
 743       [
 744         AC_CHECK_FUNCS(iconv,
 745           [
 746             has_iconv=true
 747             check_iconv=false
 748           ])
 749       ])
 750   ])
 751
 752 if test x$check_iconv = xtrue; then
 753   AC_MSG_RESULT(starting search...)
 754
 755   # XXX
 756   unset ac_cv_header__iconv_h_ ac_cv_header_iconv_h || true
 757
 758   AC_CHECK_HEADERS(iconv.h,
 759     [
 760       LIBS="$LIBS -liconv"
 761       AC_MSG_CHECKING(for iconv in -liconv)
 762       AC_TRY_LINK(
 763         [
 764           #include <stdlib.h>
 765           #include <iconv.h>
 766         ],
 767         [
 768           iconv_t cd = iconv_open("", "");
 769           iconv(cd, NULL, NULL, NULL, NULL);
 770           iconv_close(cd);
 771         ],
 772         [
 773           echo "yes"
 774           AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 775           has_iconv=true
 776           check_iconv=false
 777         ],
 778         [
 779           echo "no"
 780           LIBS="$SAVE_LIBS"
 781           CFLAGS="$SAVE_CFLAGS"
 782           LDFLAGS="$SAVE_LDFLAGS"
 783           CPPFLAGS="$SAVE_CPPFLAGS"
 784         ])
 785      ])
 786 fi
 787
 788 if test x$check_iconv = xtrue; then
 789   # search for iconv library..
 790   SAVE_LIBS="$LIBS"
 791   SAVE_CFLAGS="$CFLAGS"
 792   SAVE_LDFLAGS="$LDFLAGS"
 793   SAVE_CPPFLAGS="$CPPFLAGS"
 794
 795   for dir in `echo "/usr/local /usr/pkg /usr/contrib"`; do
 796     if test x$has_iconv = xfalse; then
 797       AC_MSG_RESULT(searching in $dir...)
 798
 799       if test -d $dir/include; then
 800         CPPFLAGS="$CPPFLAGS -I$dir/include"
 801         CFLAGS="$CFLAGS -I$dir/include"
 802       fi
 803       if test -d $dir/lib; then
 804         LDFLAGS="$LDFLAGS -L$dir/lib"
 805       fi
 806
 807       # XXX
 808       unset ac_cv_header__iconv_h_ ac_cv_header_iconv_h || true
 809
 810       AC_CHECK_HEADERS(iconv.h,
 811         [
 812           LIBS="$LIBS -liconv"
 813           AC_MSG_CHECKING(for iconv in -liconv)
 814           AC_TRY_LINK(
 815             [
 816               #include <stdlib.h>
 817               #include <iconv.h>
 818             ],
 819             [
 820               iconv_t cd = iconv_open("", "");
 821               iconv(cd, NULL, NULL, NULL, NULL);
 822               iconv_close(cd);
 823             ],
 824             [
 825               echo "yes"
 826               has_iconv=true
 827               AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 828             ],
 829             [
 830               echo "no"
 831               has_iconv=false
 832
 833               LIBS="$SAVE_LIBS"
 834               CFLAGS="$SAVE_CFLAGS"
 835               LDFLAGS="$SAVE_LDFLAGS"
 836               CPPFLAGS="$SAVE_CPPFLAGS"
 837             ])
 838          ],
 839          [
 840            CFLAGS="$SAVE_CFLAGS"
 841            LDFLAGS="$SAVE_LDFLAGS"
 842            CPPFLAGS="$SAVE_CPPFLAGS"
 843          ])
 844       fi
 845     done
 846 fi
 847
 848 if test x$has_iconv = xtrue; then
 849   # (1) Some implementations of iconv won't convert from UTF-8 to UTF-8.
 850   # (2) In glibc-2.1.2 and earlier there is a bug that messes up ob and
 851   #     obl when args 2 and 3 are 0 (fixed in glibc-2.1.3).
 852   #
 853   AC_CACHE_CHECK([whether this iconv is good enough], ac_iconv_good,
 854     AC_TRY_RUN(
 855       [
 856         #include <iconv.h>
 857         int main() {
 858           iconv_t cd;
 859         changequote(, )dnl
 860           char buf[4];
 861         changequote([, ])dnl
 862           char *ob;
 863           size_t obl;
 864           ob = buf, obl = sizeof(buf);
 865           return ((cd = iconv_open("UTF-8", "UTF-8")) != (iconv_t)(-1) &&
 866                  (iconv(cd, 0, 0, &ob, &obl) ||
 867                  !(ob == buf && obl == sizeof(buf)) ||
 868                  iconv_close(cd)));
 869         }
 870       ],
 871       [
 872         ac_iconv_good=yes
 873       ],
 874       [
 875         ac_iconv_good=no
 876       ],
 877       [
 878         ac_iconv_good=yes
 879       ])
 880     )
 881
 882   if test x$ac_iconv_good = xno; then
 883     AC_MSG_RESULT(Try using libiconv instead.)
 884   fi
 885 fi
 886
 887 # POSIX threads support
 888 #
 889 has_threads=false
 890 AC_MSG_CHECKING(whether to search for POSIX threads)
 891 AC_ARG_WITH(pthreads,
 892   [[  --with-pthreads[=DIR]   use POSIX threads [search in DIR/include and DIR/lib]]],
 893   [
 894     case "${withval}" in
 895       no)
 896         check_threads=false
 897         ;;
 898       *)
 899         if test -d $withval/include; then
 900           CPPFLAGS="$CPPFLAGS -I$withval/include"
 901           CFLAGS="$CFLAGS -I$withval/include"
 902         fi
 903         if test -d $withval/lib; then
 904           LDFLAGS="$LDFLAGS -L$withval/lib"
 905         fi
 906
 907         check_threads=true
 908         ;;
 909     esac
 910   ])
 911
 912 if test x$check_threads = xtrue; then
 913   SAVE_LIBS="$LIBS"
 914   SAVE_CFLAGS="$CFLAGS"
 915   SAVE_LDFLAGS="$LDFLAGS"
 916   SAVE_CPPFLAGS="$CPPFLAGS"
 917
 918   AC_MSG_RESULT(yes)
 919   AC_CHECK_HEADERS(pthread.h,
 920     [
 921       LIBS="$LIBS -lpthread"
 922       AC_CHECK_LIB(pthread, pthread_attr_init, has_threads=true,
 923         [
 924           # FreeBSD
 925           case "${target}" in
 926             *-*-freebsd*)
 927               LIBS="$SAVE_LIBS -pthread"
 928               AC_CHECK_LIB(c_r, pthread_attr_init, has_threads=true, LIBS="$SAVE_LIBS")
 929               ;;
 930             *)
 931               LIBS="$SAVE_LIBS"
 932               ;;
 933           esac
 934         ])
 935     ],
 936     [
 937       # search for pthread library..
 938       for dir in `echo "/usr/local /usr/pkg /usr/contrib /usr/pkg/pthreads /usr/local/pthreads"`; do
 939         if test x$has_threads = xfalse; then
 940           AC_MSG_RESULT(searching in $dir...)
 941
 942           if test -d $dir/include; then
 943             CPPFLAGS="$CPPFLAGS -I$dir/include"
 944             CFLAGS="$CFLAGS -I$dir/include"
 945           fi
 946           if test -d $dir/lib; then
 947             LDFLAGS="$LDFLAGS -L$dir/lib"
 948           fi
 949
 950           # XXX
 951           unset ac_cv_header__pthread_h_ ac_cv_header_pthread_h || true
 952
 953           AC_CHECK_HEADERS(pthread.h,
 954             [
 955               LIBS="$LIBS -lpthread"
 956               AC_CHECK_LIB(pthread, pthread_attr_init, has_threads=true,
 957                 [
 958                   has_threads=false
 959
 960                   LIBS="$SAVE_LIBS"
 961                   CFLAGS="$SAVE_CFLAGS"
 962                   LDFLAGS="$SAVE_LDFLAGS"
 963                   CPPFLAGS="$SAVE_CPPFLAGS"
 964                 ])
 965             ],
 966             [
 967               CFLAGS="$SAVE_CFLAGS"
 968               LDFLAGS="$SAVE_LDFLAGS"
 969               CPPFLAGS="$SAVE_CPPFLAGS"
 970             ])
 971         fi
 972       done
 973     ])
 974 else
 975   AC_MSG_RESULT(no)
 976   has_threads=false
 977 fi
 978
 979 AM_CONDITIONAL(SILC_THREADS, test x$has_threads = xtrue)
 980 if test x$has_threads = xtrue; then
 981   CFLAGS="$CFLAGS -D_REENTRANT"
 982
 983   # XXX possibly incomplete
 984   case "${target}" in
 985     *-*-aix*)
 986       CFLAGS="$CFLAGS -D_THREAD_SAFE"
 987       if test x"$GCC" = xyes; then
 988         CFLAGS="$CFLAGS -mthreads"
 989       fi
 990       ;;
 991     *-*-freebsd*)
 992       CFLAGS="$CFLAGS -D_THREAD_SAFE"
 993       ;;
 994     *-*-sysv5uw7*)  # UnixWare 7
 995       if test "$GCC" != "yes"; then
 996         CFLAGS="$CFLAGS -Kthread"
 997       else
 998         CFLAGS="$CFLAGS -pthread"
 999       fi
1000       ;;
1001     *-dg-dgux*)  # DG/UX
1002       CFLAGS="$CFLAGS -D_POSIX4A_DRAFT10_SOURCE"
1003       ;;
1004    esac
1005
1006   AC_CHECK_FUNC(pthread_create)
1007   AC_DEFINE(SILC_HAVE_PTHREAD)
1008   AC_DEFINE(SILC_THREADS)
1009 fi
1010
1011 # Native WIN32 compilation under cygwin
1012 #
1013 AC_MSG_CHECKING(whether to compile native WIN32 code)
1014 AC_ARG_WITH(win32,
1015   [  --with-win32            compile native WIN32 (MinGW) code (-mno-cygwin)],
1016   [
1017     AC_MSG_RESULT(yes)
1018     AC_DEFINE(SILC_WIN32)
1019     win32_support=true
1020     CFLAGS="-mno-cygwin $CFLAGS"
1021     LIBS="$LIBS -lwsock32"
1022   ],
1023   [
1024     AC_MSG_RESULT(no)
1025   ])
1026 AM_CONDITIONAL(SILC_WIN32, test x$win32_support = xtrue)
1027
1028 # Native EPOC support (disabled by default)
1029 #
1030 AM_CONDITIONAL(SILC_EPOC, test xfalse = xtrue)
1031
1032 # Native BeOS support (disabled by default)
1033 #
1034 AM_CONDITIONAL(SILC_BEOS, test xfalse = xtrue)
1035
1036 # Native OS2 support (disabled by default)
1037 #
1038 AM_CONDITIONAL(SILC_OS2, test xfalse = xtrue)
1039
1040 # --without-irssi
1041 #
1042 without_irssi=false
1043 AC_MSG_CHECKING(whether to compile Irssi SILC Client)
1044 AC_ARG_WITH(irssi,
1045   [  --without-irssi         compile without Irssi SILC Client],
1046   [
1047     AC_MSG_RESULT(no)
1048     without_irssi=true
1049     SILC_DIST_SUBDIRS=`echo $SILC_DIST_SUBDIRS | $sedpath -e 's/irssi//'`
1050   ],
1051   [
1052     AC_MSG_RESULT(yes)
1053   ])
1054
1055 # --without-silcd
1056 #
1057 without_silcd=false
1058 AC_MSG_CHECKING(whether to compile SILC Server)
1059 AC_ARG_WITH(silcd,
1060   [  --without-silcd         compile without SILC Server],
1061   [
1062     AC_MSG_RESULT(no)
1063     without_silcd=true
1064     SILC_DIST_SUBDIRS=`echo $SILC_DIST_SUBDIRS | $sedpath -e 's/silcd//'`
1065   ],
1066   [
1067     AC_MSG_RESULT(yes)
1068   ])
1069
1070 # Irssi perl support
1071 #
1072 AC_ARG_WITH(perl,
1073   [[  --with-perl[=yes|no|module]  Build with Perl support - also specifies
1074                                if it should be built into main silc binary
1075                                (static, default) or as a module]])
1076
1077 libtoolfix=true
1078 AC_MSG_CHECKING(whether to do libtoolfix)
1079 AC_ARG_WITH(libtoolfix,
1080   [  --without-libtoolfix     Do not fix libtool, for package builders],
1081   [
1082     AC_MSG_RESULT(no)
1083     libtoolfix=false
1084   ],
1085   [
1086     AC_MSG_RESULT(yes)
1087   ])
1088
1089 AC_SUBST(ETCDIR)
1090 AC_DEFINE_UNQUOTED(SILC_ETCDIR, "$ETCDIR")
1091
1092
1093
1094 ##
1095 ##  Misc
1096 ##
1097
1098 # Other configure scripts
1099 #
1100 if test x$without_irssi = xfalse; then
1101   if test "x$silc_dist" = "xsilc-client" ||
1102      test "x$silc_dist" = "xsilc-toolkit"; then
1103     AC_CONFIG_SUBDIRS(irssi)
1104   fi
1105 fi
1106
1107 SILC_TOP_SRCDIR=`pwd`
1108 AC_SUBST(SILC_TOP_SRCDIR)
1109 #SILC_INSTALL_PREFIX=$ac_default_prefix
1110 #AC_SUBST(SILC_INSTALL_PREFIX)
1111 AC_SUBST(LIBS)
1112 INCLUDE_DEFINES_INT="include \$(top_srcdir)/Makefile.defines_int"
1113 AC_SUBST(INCLUDE_DEFINES_INT)
1114 AC_SUBST(SILC_DIST_SUBDIRS)
1115
1116 #
1117 # Fix the libtool to support run-time configuration.  This allows us
1118 # to in run-time specify when to compile shared/static libraries without
1119 # need to reconfigure the entire libtool.
1120 #
1121 if test x$libtoolfix = xtrue; then
1122   ./libtoolfix $SILC_TOP_SRCDIR/ltmain.sh
1123 fi
1124 AM_CONDITIONAL(SILC_LIBTOOLFIX, test x$libtoolfix = xtrue)
1125
1126 # Included configure scripts
1127 AD_INCLUDE_CONFIGURE
1128
1129 #
1130 # Makefile outputs
1131 #
1132 AC_CONFIG_FILES(
1133 Makefile
1134 Makefile.defines
1135 Makefile.defines_int
1136 doc/Makefile
1137 includes/Makefile
1138 lib/Makefile
1139 lib/contrib/Makefile
1140 lib/silccore/Makefile
1141 lib/silccore/tests/Makefile
1142 lib/silccrypt/Makefile
1143 lib/silccrypt/tests/Makefile
1144 lib/silcsim/Makefile
1145 lib/silcske/Makefile
1146 lib/silcutil/Makefile
1147 lib/silcutil/unix/Makefile
1148 lib/silcutil/win32/Makefile
1149 lib/silcutil/beos/Makefile
1150 lib/silcutil/os2/Makefile
1151 lib/silcutil/epoc/Makefile
1152 lib/silcutil/tests/Makefile
1153 lib/silcmath/Makefile
1154 lib/silcsftp/Makefile
1155 lib/silcsftp/tests/Makefile
1156 doc/example_silcd.conf
1157 includes/silcincludes.h
1158 )
1159
1160 if test "x$silc_dist" = "xsilc-client" ||
1161    test "x$silc_dist" = "xsilc-toolkit"; then
1162   AC_CONFIG_FILES(lib/silcclient/Makefile)
1163 fi
1164
1165 if test x$without_irssi = xfalse ; then
1166   if test "x$silc_dist" = "xsilc-client" ||
1167      test "x$silc_dist" = "xsilc-toolkit"; then
1168     AC_CONFIG_FILES(
1169 irssi/Makefile.defines
1170 irssi/Makefile.defines_int
1171 )
1172   fi
1173 fi
1174
1175 if test x$without_silcd = xfalse ; then
1176   if test "x$silc_dist" = "xsilc-server" ||
1177      test "x$silc_dist" = "xsilc-toolkit"; then
1178     AC_CONFIG_FILES(
1179 silcd/Makefile
1180 )
1181   fi
1182 fi
1183
1184 if test "x$silc_dist" = "xsilc-toolkit"; then
1185   AC_CONFIG_FILES(
1186 silc/Makefile
1187 win32/Makefile
1188 win32/libsilc/Makefile
1189 win32/libsilcclient/Makefile
1190 tutorial/Makefile
1191 tutorial/Makefile.defines
1192 tutorial/Makefile.defines_int
1193 )
1194 fi
1195
1196 AC_OUTPUT
1197
1198 s_bindir=`eval echo $bindir`;s_bindir=`eval echo $s_bindir`
1199 s_sbindir=`eval echo $sbindir`;s_sbindir=`eval echo $s_sbindir`
1200 s_mandir=`eval echo $mandir`;s_mandir=`eval echo $s_mandir`
1201 s_includedir=`eval echo $includedir`;s_includedir=`eval echo $s_includedir`
1202
1203 echo ""
1204 echo "SILC Configuration Summary:"
1205 echo "---------------------------"
1206 echo " Target host ...................: $target"
1207 echo " Compiler ......................: $CC"
1208 echo " CFLAGS ........................: $CFLAGS"
1209 echo " CPPFLAGS ......................: $CPPFLAGS"
1210 echo " LDFLAGS .......................: $LDFLAGS"
1211 echo " LIBS ..........................: $LIBS"
1212 echo ""
1213 echo " Installation prefix ...........: $prefix"
1214 echo " bin directory .................: $s_bindir"
1215 echo " sbin directory ................: $s_sbindir"
1216 echo " etc directory .................: $ETCDIR"
1217 echo " man directory .................: $s_mandir"
1218 echo " help directory ................: $HELPDIR"
1219 echo " doc directory .................: $DOCDIR"
1220 echo " logs directory ................: $LOGSDIR"
1221 echo " SIM directory .................: $MODULESDIR"
1222 echo " include directory .............: $s_includedir"
1223 echo ""
1224
1225 if test "x$silc_dist" = "xsilc-client" ||
1226    test "x$silc_dist" = "xsilc-toolkit"; then
1227   irssi="yes"
1228   if test x$without_irssi = xtrue; then
1229     irssi="no"
1230   fi
1231 echo " Compile SILC Client ...........: $irssi"
1232 fi
1233
1234 if test "x$silc_dist" = "xsilc-server" ||
1235    test "x$silc_dist" = "xsilc-toolkit"; then
1236   silcd="yes"
1237   if test x$without_silcd = xtrue; then
1238     silcd="no"
1239   fi
1240 echo " Compile SILC Server ...........: $silcd"
1241 echo " Server configuration file .....: $summary_silcd_configfile"
1242 echo " Server PID file ...............: $PIDFILE"
1243 fi
1244
1245 if test x$sim_support = xfalse; then
1246   sim_support="no"
1247 else
1248   sim_support="yes"
1249 fi
1250 if test x$has_iconv = xfalse; then
1251   iconv_support="no"
1252 else
1253   iconv_support="yes"
1254 fi
1255 echo " SIM support ...................: $sim_support"
1256 echo " IPv6 support ..................: $summary_ipv6"
1257 echo " Iconv support .................: $iconv_support"
1258 if test x$want_asm = xfalse; then
1259   summary_asm="no"
1260 else
1261   summary_asm="yes"
1262 fi
1263 echo " Assembler optimizations .......: $summary_asm"
1264
1265 mp="MPI"
1266 if test x$mp_gmp = xtrue; then
1267   mp="GMP"
1268 fi
1269 echo " Arithmetic library ............: $mp"
1270
1271 threads="no"
1272 if test x$has_threads = xtrue; then
1273   threads="yes"
1274 fi
1275 echo " Multi-threads support .........: $threads"
1276 echo " Debugging enabled .............: $summary_debug"
1277 echo " Stack-trace enabled ...........: $summary_stacktrace"
1278 echo ""
1279 if test "x$silc_dist" = "xsilc-client"; then
1280   echo "Compile the sources with 'make' or 'gmake' command (GNU make is required)."
1281 else
1282   echo "Compile the sources with 'make' or 'gmake' command."
1283 fi