configure.in.pre

   1 #
   2 #  configure.in.pre
   3 #
   4 #  Author: Pekka Riikonen <priikone@silcnet.org>
   5 #
   6 #  Copyright (C) 2000 - 2002 Pekka Riikonen
   7 #
   8 #  This program is free software; you can redistribute it and/or modify
   9 #  it under the terms of the GNU General Public License as published by
  10 #  the Free Software Foundation; either version 2 of the License, or
  11 #  (at your option) any later version.
  12 #
  13 #  This program is distributed in the hope that it will be useful,
  14 #  but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 #  GNU General Public License for more details.
  17 #
  18
  19 AC_INIT(includes/silcversion.h)
  20
  21 # Put here any platform specific stuff
  22 #
  23 AC_CANONICAL_SYSTEM
  24 case "$target" in
  25   *-*-freebsd*)
  26     check_threads=true
  27     ;;
  28   *-*-*bsd*)
  29     check_threads=false
  30     ;;
  31   *)
  32     check_threads=true
  33     ;;
  34 esac
  35
  36 # ./prepare script will automatically put the correct version. Do not edit!
  37 #
  38 AM_INIT_AUTOMAKE(SILC_PACKAGE, SILC_VERSION)
  39 AC_PREREQ(2.52)
  40 AC_CONFIG_HEADERS(includes/silcdefs.h)
  41
  42 AC_PROG_CC
  43 AC_C_INLINE
  44 AC_C_CONST
  45
  46 AC_PROG_LN_S
  47 AC_SUBST(LN_S)
  48
  49 # Distribution definition. ./prepare will automatically add here a correct
  50 # value. Do not edit!
  51 #
  52 silc_dist=SILC_PACKAGE
  53 SILC_DIST_SUBDIRS="SILC_DISTRIBUTION_SUBDIRS"
  54 AC_DEFINE(SILC_DIST_DEFINE)
  55
  56 # XXX
  57 # Compiler flags
  58 #
  59 if test "$GCC"; then
  60   CFLAGS="-Wall -finline-functions $CFLAGS"
  61 fi
  62
  63 # Program checking
  64 #
  65 AC_PROG_INSTALL
  66 AC_PROG_RANLIB
  67 AC_PROG_MAKE_SET
  68 AC_PROG_LIBTOOL
  69 AC_PATH_PROG(sedpath, sed)
  70
  71 # Header checking
  72 #
  73 AC_HEADER_STDC
  74 AC_HEADER_TIME
  75 AC_HEADER_STAT
  76
  77 # More header checking
  78 #
  79 AC_CHECK_HEADERS(unistd.h string.h getopt.h errno.h fcntl.h assert.h)
  80 AC_CHECK_HEADERS(sys/types.h sys/stat.h sys/time.h stddef.h)
  81 AC_CHECK_HEADERS(netinet/in.h netinet/tcp.h xti.h netdb.h)
  82 AC_CHECK_HEADERS(pwd.h grp.h termcap.h paths.h)
  83 AC_CHECK_HEADERS(ncurses.h signal.h ctype.h utime.h)
  84 AC_CHECK_HEADERS(arpa/inet.h sys/mman.h limits.h termios.h locale.h langinfo.h)
  85
  86 # Data type checking
  87 #
  88 AC_TYPE_SIGNAL
  89 AC_TYPE_SIZE_T
  90 AC_TYPE_MODE_T
  91 AC_TYPE_UID_T
  92 AC_TYPE_PID_T
  93
  94 AC_CHECK_SIZEOF(long long, 0)
  95 AC_SUBST(SILC_SIZEOF_LONG_LONG, $ac_cv_sizeof_long_long)
  96 AC_CHECK_SIZEOF(long, 0)
  97 AC_SUBST(SILC_SIZEOF_LONG, $ac_cv_sizeof_long)
  98 AC_CHECK_SIZEOF(int, 0)
  99 AC_SUBST(SILC_SIZEOF_INT, $ac_cv_sizeof_int)
 100 AC_CHECK_SIZEOF(short, 0)
 101 AC_SUBST(SILC_SIZEOF_SHORT, $ac_cv_sizeof_short)
 102 AC_CHECK_SIZEOF(char, 0)
 103 AC_SUBST(SILC_SIZEOF_CHAR, $ac_cv_sizeof_char)
 104 AC_CHECK_SIZEOF(void *, 0)
 105 AC_SUBST(SILC_SIZEOF_VOID_P, $ac_cv_sizeof_void_p)
 106
 107 # Function and library checking
 108 #
 109 AC_CHECK_FUNC(gethostbyname, [],
 110   [
 111     AC_CHECK_LIB(nsl, gethostbyname, LIBS="$LIBS -lnsl")
 112     AC_CHECK_FUNC(res_gethostbyname, [],
 113        AC_CHECK_LIB(resolv, res_gethostbyname, LIBS="$LIBS -lresolv")
 114     )
 115   ])
 116 AC_CHECK_FUNC(socket, [],
 117   AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
 118 )
 119 AC_CHECK_FUNCS(gethostname gethostbyaddr getservbyname getservbyport)
 120 AC_CHECK_FUNCS(select listen bind shutdown close connect setsockopt)
 121 AC_CHECK_FUNCS(time ctime utime gettimeofday)
 122 AC_CHECK_FUNCS(chmod fcntl stat fstat getenv putenv strerror)
 123 AC_CHECK_FUNCS(getpid getgid getsid getpgid getpgrp getuid)
 124 AC_CHECK_FUNCS(setgroups initgroups nl_langinfo)
 125 AC_CHECK_FUNCS(strchr strstr strcpy strncpy memcpy memset memmove)
 126
 127 # SIM support checking
 128 # XXX These needs to be changed as more supported platforms appear.
 129 # XXX This probably needs to be made platform dependant check.
 130 #
 131 sim_support=false
 132 AC_MSG_CHECKING(for SIM support)
 133 AC_MSG_RESULT()
 134 AC_CHECK_HEADERS(dlfcn.h,
 135   AC_CHECK_LIB(dl, dlopen,
 136     [
 137       AC_DEFINE(SILC_SIM)
 138       sim_support=true
 139       LIBS="$LIBS -ldl"
 140     ],
 141     [
 142       AC_CHECK_LIB(c, dlopen,
 143         [
 144           AC_DEFINE(SILC_SIM)
 145           sim_support=true
 146         ])
 147     ])
 148   )
 149
 150 AM_CONDITIONAL(SILC_SIM, test x$sim_support = xtrue)
 151 if test x$sim_support = xtrue; then
 152   AC_MSG_RESULT(Enabled SIM support.)
 153 else
 154   AC_MSG_RESULT(No SIM support found.)
 155 fi
 156
 157 # lib/contrib conditionals
 158 #
 159 AC_CHECK_HEADER(regex.h, have_regex=1, have_regex=0)
 160 AM_CONDITIONAL(HAVE_REGEX, test x$have_regex = x1)
 161 AC_CHECK_FUNC(getopt_long, have_getopt_long=1, have_getopt_long=0)
 162 AM_CONDITIONAL(HAVE_GETOPT_LONG, test x$have_getopt_long = x1)
 163
 164
 165 ##
 166 ##  Enable/disable checking
 167 ##
 168
 169 # IPv6 support
 170 #
 171 AC_MSG_CHECKING(whether to enable IPv6 support)
 172 AC_ARG_ENABLE(ipv6,
 173   [  --enable-ipv6           enable IPv6 support],
 174   [
 175     case "${enableval}" in
 176       yes)
 177         want_ipv6=true
 178         check_ipv6=false
 179         summary_ipv6="yes"
 180         AC_DEFINE(HAVE_IPV6)
 181         AC_MSG_RESULT(yes)
 182         ;;
 183       *)
 184         want_ipv6=false
 185         check_ipv6=false
 186         summary_ipv6="no"
 187         AC_MSG_RESULT(no)
 188         ;;
 189     esac
 190   ],
 191     check_ipv6=true
 192   )
 193
 194 if test x$check_ipv6 = xtrue; then
 195   summary_ipv6="no"
 196   AC_TRY_COMPILE(
 197     [
 198       #ifdef HAVE_SYS_TYPES_H
 199       #include <sys/types.h>
 200       #endif
 201       #ifdef HAVE_NETINET_TCP_H
 202       #include <netinet/tcp.h>
 203       #endif
 204       #ifdef HAVE_NETDB_H
 205       #include <netdb.h>
 206       #endif
 207       #include <sys/socket.h>
 208       #ifdef HAVE_NETINET_IN_H
 209       #include <netinet/in.h>
 210       #endif
 211     ],
 212     [
 213       struct sockaddr_in6 sin6;
 214       int family = AF_INET6;
 215     ],
 216     [
 217       AC_DEFINE(HAVE_IPV6)
 218       AC_MSG_RESULT(yes)
 219       summary_ipv6="yes"
 220     ],
 221       AC_MSG_RESULT(no)
 222     )
 223 fi
 224
 225 # Debug checking
 226 #
 227 AC_MSG_CHECKING(whether to enable debugging)
 228 summary_debug="no"
 229 AC_ARG_ENABLE(debug,
 230   [  --enable-debug          enable debugging],
 231   [
 232     case "${enableval}" in
 233       yes)
 234         AC_MSG_RESULT(yes)
 235         AC_DEFINE(SILC_DEBUG)
 236         CFLAGS="-O -g $CFLAGS"
 237         summary_debug="yes"
 238         ;;
 239       *)
 240         AC_MSG_RESULT(no)
 241         CFLAGS="-O2 -g $CFLAGS"
 242         ;;
 243     esac
 244   ],
 245   [
 246     CFLAGS="-O2 -g $CFLAGS"
 247     AC_MSG_RESULT(no)
 248   ])
 249
 250 # Stack trace checking
 251 #
 252 AC_MSG_CHECKING(whether to enable stack tracing)
 253 summary_stacktrace="no"
 254 AC_ARG_ENABLE(stack-trace,
 255   [  --enable-stack-trace    enable memory stack trace],
 256   [
 257     case "${enableval}" in
 258     yes)
 259       AC_MSG_RESULT(yes)
 260       AC_DEFINE(SILC_STACKTRACE)
 261       summary_stacktrace="yes"
 262       ;;
 263     *)
 264       AC_MSG_RESULT(no)
 265       ;;
 266     esac
 267   ],
 268     AC_MSG_RESULT(no)
 269   )
 270
 271 # Disable all assembler optimizations
 272 #
 273 AC_MSG_CHECKING(whether to enable assembler optimizations)
 274 summary_asm="no"
 275 AC_ARG_ENABLE(asm,
 276   [  --disable-asm           do not use assembler optimizations],
 277   [
 278     AC_MSG_RESULT(no)
 279   ],
 280   [
 281     AC_MSG_RESULT(yes)
 282     summary_asm="yes"
 283   ])
 284
 285
 286 ##
 287 ##  Installation
 288 ##
 289
 290 # Default installation destination
 291 #
 292 AC_PREFIX_DEFAULT(/usr/local/silc)
 293 if test "x$prefix" != xNONE; then
 294   silc_prefix="$prefix"
 295 else
 296   silc_prefix="$ac_default_prefix"
 297 fi
 298
 299 # etc directory
 300 #
 301 if test "x$sysconfdir" != 'x${prefix}/etc'; then
 302   ETCDIR="$sysconfdir"
 303 else
 304   ETCDIR="$silc_prefix/etc"
 305 fi
 306
 307 AC_ARG_WITH(etcdir,
 308   [[  --with-etcdir=DIR       directory for system files [/etc/silc]]],
 309   [
 310     case "$withval" in
 311       no)
 312         ;;
 313       *)
 314         ETCDIR="$withval"
 315         ;;
 316     esac
 317   ])
 318 AC_SUBST(ETCDIR)
 319 AC_DEFINE_UNQUOTED(SILC_ETCDIR, "$ETCDIR")
 320
 321 # help directory
 322 #
 323 HELPDIR="$silc_prefix/help"
 324 AC_ARG_WITH(helpdir,
 325   [[  --with-helpdir=DIR      directory for SILC help files [PREFIX/help]]],
 326   [
 327     case "$withval" in
 328       no)
 329         ;;
 330       *)
 331        HELPDIR="$withval"
 332        ;;
 333     esac
 334   ])
 335 AC_SUBST(HELPDIR)
 336 AC_DEFINE_UNQUOTED(SILC_HELPDIR, "$HELPDIR")
 337
 338 # doc directory
 339 #
 340 DOCDIR="$silc_prefix/doc"
 341 AC_ARG_WITH(docdir,
 342   [[  --with-docdir=DIR       directory for SILC documentation [PREFIX/doc]]],
 343   [
 344     case "$withval" in
 345       no)
 346         ;;
 347       *)
 348         DOCDIR="$withval"
 349         ;;
 350     esac
 351   ])
 352 AC_SUBST(DOCDIR)
 353 AC_DEFINE_UNQUOTED(SILC_DOCDIR, "$DOCDIR")
 354
 355 # SIM modules directory
 356 #
 357 MODULESDIR="$silc_prefix/modules"
 358 AC_ARG_WITH(simdir,
 359   [[  --with-simdir=DIR       directory for SIM modules [PREFIX/modules]]],
 360   [
 361     case "$withval" in
 362       no)
 363         ;;
 364       *)
 365         MODULESDIR="$withval"
 366         ;;
 367     esac
 368   ])
 369 AC_SUBST(MODULESDIR)
 370 AC_DEFINE_UNQUOTED(SILC_MODULESDIR, "$MODULESDIR")
 371
 372 # Logs directory
 373 #
 374 LOGSDIR="$silc_prefix/logs"
 375 AC_ARG_WITH(logsdir,
 376   [[  --with-logsdir=DIR      directory for SILC Server logs [PREFIX/logs]]],
 377   [
 378     case "$withval" in
 379       no)
 380         ;;
 381       *)
 382         LOGSDIR="$withval"
 383         ;;
 384     esac
 385   ])
 386 AC_SUBST(LOGSDIR)
 387 AC_DEFINE_UNQUOTED(SILC_LOGSDIR, "$LOGSDIR")
 388
 389 # Manual directory
 390 #
 391 MANDIR="$silc_prefix/man"
 392 AC_ARG_WITH(mandir,
 393   [[  --with-mandir=DIR       directory for SILC manual pages [PREFIX/man]]],
 394   [
 395     case "$withval" in
 396       no)
 397         ;;
 398       *)
 399         MANDIR="$withval"
 400         ;;
 401     esac
 402   ])
 403 AC_SUBST(MANDIR)
 404 AC_DEFINE_UNQUOTED(SILC_MANDIR, "$MANDIR")
 405
 406 # silcd config file checking
 407 #
 408 summary_silcd_configfile="/etc/silc/silcd.conf"
 409 AC_ARG_WITH(silcd-config-file,
 410   [[  --with-silcd-config-file=FILE  use FILE as default configuration file
 411                                  for SILC Server [/etc/silc/silcd.conf]]],
 412     AC_DEFINE_UNQUOTED(SILC_SERVER_CONFIG_FILE, "$withval")
 413     summary_silcd_configfile="$withval"
 414   )
 415
 416 # silcd pid file checking
 417 #
 418 if test "x$localstatedir" != 'x${prefix}/var'; then
 419   PIDFILE="$localstatedir/silcd.pid"
 420 else
 421   PIDFILE="$silc_prefix/var/silcd.pid"
 422 fi
 423
 424 AC_ARG_WITH(silcd-pid-file,
 425   [[  --with-silcd-pid-file=FILE     use FILE as default pid file for SILC
 426                                  Server [/var/run/silcd.pid]]],
 427   [
 428     case "$withval" in
 429       no)
 430         ;;
 431       *)
 432         PIDFILE="$withval"
 433         ;;
 434     esac
 435   ])
 436 AC_SUBST(PIDFILE)
 437
 438
 439 ##
 440 ##  With/without checkings
 441 ##
 442
 443 # SOCKS4 support checking
 444 #
 445 AC_MSG_CHECKING(whether to support SOCKS4)
 446 AC_ARG_WITH(socks4,
 447   [[  --with-socks4[=DIR]     with SOCKS4 support [search in DIR/lib and DIR/include]]],
 448   [
 449     case "$withval" in
 450       no)
 451         AC_MSG_RESULT(no)
 452         ;;
 453       *)
 454         AC_MSG_RESULT(yes)
 455         socks=4
 456
 457         if test -d "$withval/include"; then
 458           CFLAGS="$CFLAGS -I$withval/include"
 459         else
 460           CFLAGS="$CFLAGS -I$withval"
 461         fi
 462         if test -d "$withval/lib"; then
 463           withval="-L$withval/lib -lsocks"
 464         else
 465           withval="-L$withval -lsocks"
 466         fi
 467
 468         LIBS="$withval $LIBS"
 469         AC_TRY_LINK([],
 470           [
 471             Rconnect();
 472           ], [],
 473           [
 474             AC_MSG_ERROR(Could not find SOCKS4 library.)
 475           ])
 476         ;;
 477     esac
 478   ],
 479     AC_MSG_RESULT(no)
 480   )
 481
 482 # SOCKS5 support checking
 483 #
 484 AC_MSG_CHECKING(whether to support SOCKS5)
 485 AC_ARG_WITH(socks5,
 486   [[  --with-socks5[=DIR]     with SOCKS5 support [search in DIR/lib and DIR/include]]],
 487   [
 488     case "$withval" in
 489       no)
 490         AC_MSG_RESULT(no)
 491         ;;
 492       *)
 493         AC_MSG_RESULT(yes)
 494         socks=5
 495
 496         if test -d "$withval/include"; then
 497           CFLAGS="$CFLAGS -I$withval/include"
 498         else
 499           CFLAGS="$CFLAGS -I$withval"
 500         fi
 501         if test -d "$withval/lib"; then
 502           withval="-L$withval/lib -lsocks5"
 503         else
 504           withval="-L$withval -lsocks5"
 505         fi
 506
 507         LIBS="$withval $LIBS"
 508         AC_TRY_LINK([],
 509           [
 510             SOCKSconnect();
 511           ], [],
 512           [
 513             AC_MSG_ERROR(Could not find SOCKS5 library.)
 514           ])
 515         ;;
 516     esac
 517   ],
 518     AC_MSG_RESULT(no)
 519   )
 520
 521 if test "x$socks" = "x4"; then
 522   AC_DEFINE(SOCKS)
 523   CFLAGS="$CFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 524 fi
 525
 526 if test "x$socks" = "x5"; then
 527   AC_DEFINE(SOCKS)
 528   AC_DEFINE(SOCKS5)
 529   AC_DEFINE(Rconnect, SOCKSconnect)
 530   AC_DEFINE(Rgetsockname, SOCKSgetsockname)
 531   AC_DEFINE(Rgetpeername, SOCKSgetpeername)
 532   AC_DEFINE(Rbind, SOCKSbind)
 533   AC_DEFINE(Raccept, SOCKSaccept)
 534   AC_DEFINE(Rlisten, SOCKSlisten)
 535   AC_DEFINE(Rselect, SOCKSselect)
 536   AC_DEFINE(Rrecvfrom, SOCKSrecvfrom)
 537   AC_DEFINE(Rsendto, SOCKSsendto)
 538   AC_DEFINE(Rrecv, SOCKSrecv)
 539   AC_DEFINE(Rsend, SOCKSsend)
 540   AC_DEFINE(Rread, SOCKSread)
 541   AC_DEFINE(Rwrite, SOCKSwrite)
 542   AC_DEFINE(Rrresvport, SOCKSrresvport)
 543   AC_DEFINE(Rshutdown, SOCKSshutdown)
 544   AC_DEFINE(Rlisten, SOCKSlisten)
 545   AC_DEFINE(Rclose, SOCKSclose)
 546   AC_DEFINE(Rdup, SOCKSdup)
 547   AC_DEFINE(Rdup2, SOCKSdup2)
 548   AC_DEFINE(Rfclose, SOCKSfclose)
 549   AC_DEFINE(Rgethostbyname, SOCKSgethostbyname)
 550 fi
 551
 552 # MP library checking. First check whether user wants to use GMP and use
 553 # it if found. If not or not defined then compile the MPI library in the
 554 # source tree.
 555 #
 556 mp_gmp=false
 557 AC_MSG_CHECKING(whether to search for GMP)
 558 AC_ARG_WITH(gmp,
 559   [[  --with-gmp[=DIR]        use GMP instead of MPI [search in DIR/lib and DIR/include]]],
 560   [
 561     case "$withval" in
 562       no)
 563         AC_MSG_RESULT(no)
 564         ;;
 565       *)
 566         AC_MSG_RESULT(yes)
 567
 568         if test -d "$withval/include"; then
 569           CFLAGS="$CFLAGS -I$withval/include"
 570         else
 571           CFLAGS="$CFLAGS -I$withval"
 572         fi
 573         if test -d "$withval/lib"; then
 574           withval="-L$withval/lib -lgmp"
 575         else
 576           withval="-L$withval -lgmp"
 577         fi
 578
 579         LIBS="$withval $LIBS"
 580         AC_CHECK_LIB(gmp, __gmpz_init,
 581           [
 582             mp_gmp=true
 583             AC_DEFINE(SILC_MP_GMP)
 584             AC_MSG_RESULT(Using GMP as a MP library.)
 585           ])
 586         ;;
 587     esac
 588   ],
 589     AC_MSG_RESULT(no)
 590   )
 591
 592 AM_CONDITIONAL(SILC_MP_GMP, test x$mp_gmp = xtrue)
 593 AM_CONDITIONAL(SILC_MP_NSS_MPI, test x$mp_gmp = xfalse)
 594 if test x$mp_gmp = xfalse; then
 595   AC_DEFINE(SILC_MP_NSS_MPI)
 596   AC_MSG_RESULT(Using NSS MPI as a MP library.)
 597 fi
 598
 599 # iconv support
 600 #
 601 check_iconv=true
 602 has_iconv=false
 603 AC_MSG_CHECKING(whether to implicit search for libiconv)
 604 AC_ARG_WITH(iconv,
 605   [[  --with-iconv[=DIR]      use libiconv [search in DIR/include and DIR/lib]]],
 606   [
 607     case "${withval}" in
 608       no)
 609         AC_MSG_RESULT(no)
 610
 611         AC_CHECK_HEADERS(iconv.h, AC_CHECK_FUNC(iconv, has_iconv=true))
 612         check_iconv=false
 613         ;;
 614       *)
 615         AC_MSG_RESULT(yes)
 616
 617         if test -d $withval/include; then
 618           CPPFLAGS="$CPPFLAGS -I$withval/include"
 619           CFLAGS="$CFLAGS -I$withval/include"
 620         fi
 621         if test -d $withval/lib; then
 622           LDFLAGS="$LDFLAGS -L$withval/lib"
 623         fi
 624     esac
 625   ],
 626   [
 627     AC_MSG_RESULT(no)
 628
 629     AC_CHECK_HEADERS(iconv.h, AC_CHECK_FUNCS(iconv,
 630                                 [
 631                                   has_iconv=true
 632                                   check_iconv=false
 633                                  ]))
 634   ])
 635
 636 if test x$check_iconv = xtrue; then
 637   AC_MSG_RESULT(starting search...)
 638
 639   # XXX
 640   unset ac_cv_header__iconv_h_ ac_cv_header_iconv_h || true
 641
 642   AC_CHECK_HEADERS(iconv.h,
 643     [
 644       LIBS="$LIBS -liconv"
 645       AC_MSG_CHECKING(for iconv in -liconv)
 646       AC_TRY_LINK(
 647         [
 648           #include <stdlib.h>
 649           #include <iconv.h>
 650         ],
 651         [
 652           iconv_t cd = iconv_open("", "");
 653           iconv(cd, NULL, NULL, NULL, NULL);
 654           iconv_close(cd);
 655         ],
 656         [
 657           echo "yes"
 658           AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 659           has_iconv=true
 660           check_iconv=false
 661         ],
 662         [
 663           echo "no"
 664         ])
 665      ])
 666 fi
 667
 668 if test x$check_iconv = xtrue; then
 669   # search for iconv library..
 670   SAVE_CPPFLAGS="$CPPFLAGS"
 671   SAVE_CFLAGS="$CFLAGS"
 672   SAVE_LDFLAGS="$LDFLAGS"
 673
 674   for dir in `echo "/usr/local /usr/pkg /usr/contrib"`; do
 675     if test x$has_iconv = xfalse; then
 676       AC_MSG_RESULT(searching in $dir...)
 677
 678       CPPFLAGS="$SAVE_CPPFLAGS"
 679       CFLAGS="$SAVE_CFLAGS"
 680       LDFLAGS="$SAVE_LDFLAGS"
 681
 682       if test -d $dir/include; then
 683         CPPFLAGS="$CPPFLAGS -I$dir/include"
 684         CFLAGS="$CFLAGS -I$dir/include"
 685       fi
 686       if test -d $dir/lib; then
 687         LDFLAGS="$LDFLAGS -L$dir/lib"
 688       fi
 689
 690       # XXX
 691       unset ac_cv_header__iconv_h_ ac_cv_header_iconv_h || true
 692
 693       AC_CHECK_HEADERS(iconv.h,
 694         [
 695           LIBS="$LIBS -liconv"
 696           AC_MSG_CHECKING(for iconv in -liconv)
 697           AC_TRY_LINK(
 698             [
 699               #include <stdlib.h>
 700               #include <iconv.h>
 701             ],
 702             [
 703               iconv_t cd = iconv_open("", "");
 704               iconv(cd, NULL, NULL, NULL, NULL);
 705               iconv_close(cd);
 706             ],
 707             [
 708               echo "yes"
 709               has_iconv=true
 710               AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 711             ],
 712             [
 713               echo "no"
 714               has_iconv=false
 715             ])
 716          ])
 717       fi
 718     done
 719 fi
 720
 721 if test x$has_iconv = xtrue; then
 722   # (1) Some implementations of iconv won't convert from UTF-8 to UTF-8.
 723   # (2) In glibc-2.1.2 and earlier there is a bug that messes up ob and
 724   #     obl when args 2 and 3 are 0 (fixed in glibc-2.1.3).
 725   #
 726   AC_CACHE_CHECK([whether this iconv is good enough], ac_iconv_good,
 727     AC_TRY_RUN(
 728       [
 729         #include <iconv.h>
 730         int main() {
 731           iconv_t cd;
 732         changequote(, )dnl
 733           char buf[4];
 734         changequote([, ])dnl
 735           char *ob;
 736           size_t obl;
 737           ob = buf, obl = sizeof(buf);
 738           return ((cd = iconv_open("UTF-8", "UTF-8")) != (iconv_t)(-1) &&
 739                  (iconv(cd, 0, 0, &ob, &obl) ||
 740                  !(ob == buf && obl == sizeof(buf)) ||
 741                  iconv_close(cd)));
 742         }
 743       ],
 744       [
 745         ac_iconv_good=yes
 746       ],
 747       [
 748         ac_iconv_good=no
 749       ],
 750       [
 751         ac_iconv_good=yes
 752       ])
 753     )
 754
 755   if test x$ac_iconv_good = xno; then
 756     AC_MSG_RESULT(Try using libiconv instead.)
 757   fi
 758 fi
 759
 760 # POSIX threads support
 761 #
 762 has_threads=false
 763 AC_MSG_CHECKING(whether to search for POSIX threads)
 764 AC_ARG_WITH(pthreads,
 765   [[  --with-pthreads[=DIR]   use POSIX threads [search in DIR/include and DIR/lib]]],
 766   [
 767     case "${withval}" in
 768       no)
 769         check_threads=false
 770         ;;
 771       *)
 772         if test -d $withval/include; then
 773           CPPFLAGS="$CPPFLAGS -I$withval/include"
 774           CFLAGS="$CFLAGS -I$withval/include"
 775         fi
 776         if test -d $withval/lib; then
 777           LDFLAGS="$LDFLAGS -L$withval/lib"
 778         fi
 779
 780         check_threads=true
 781         ;;
 782     esac
 783   ])
 784
 785 if test x$check_threads = xtrue; then
 786   AC_MSG_RESULT(yes)
 787   AC_CHECK_HEADERS(pthread.h,
 788     [
 789       SAVE_LIBS="$LIBS"
 790       LIBS="$LIBS -lpthread"
 791       AC_CHECK_LIB(pthread, pthread_attr_init, has_threads=true,
 792         [
 793           # FreeBSD
 794           case "${target}" in
 795             *-*-freebsd*)
 796               LIBS="$SAVE_LIBS -pthread"
 797               AC_CHECK_LIB(c_r, pthread_attr_init, has_threads=true)
 798               ;;
 799           esac
 800         ])
 801     ],
 802     [
 803       # search for pthread library..
 804       SAVE_CPPFLAGS="$CPPFLAGS"
 805       SAVE_CFLAGS="$CFLAGS"
 806       SAVE_LDFLAGS="$LDFLAGS"
 807
 808       for dir in `echo "/usr/local /usr/pkg /usr/contrib /usr/pkg/pthreads /usr/local/pthreads"`; do
 809         if test x$has_threads = xfalse; then
 810           AC_MSG_RESULT(searching in $dir...)
 811
 812           CPPFLAGS="$SAVE_CPPFLAGS"
 813           CFLAGS="$SAVE_CFLAGS"
 814           LDFLAGS="$SAVE_LDFLAGS"
 815
 816           if test -d $dir/include; then
 817             CPPFLAGS="$CPPFLAGS -I$dir/include"
 818             CFLAGS="$CFLAGS -I$dir/include"
 819           fi
 820           if test -d $dir/lib; then
 821             LDFLAGS="$LDFLAGS -L$dir/lib"
 822           fi
 823
 824           # XXX
 825           unset ac_cv_header__pthread_h_ ac_cv_header_pthread_h || true
 826
 827           AC_CHECK_HEADERS(pthread.h,
 828             [
 829               LIBS="$LIBS -lpthread"
 830               AC_CHECK_LIB(pthread, pthread_attr_init, has_threads=true,
 831                                                        has_threads=false)
 832             ])
 833         fi
 834       done
 835     ])
 836 else
 837   AC_MSG_RESULT(no)
 838   has_threads=false
 839 fi
 840
 841 AM_CONDITIONAL(SILC_THREADS, test x$has_threads = xtrue)
 842 if test x$has_threads = xtrue; then
 843   CFLAGS="$CFLAGS -D_REENTRANT"
 844
 845   # XXX possibly incomplete
 846   case "${target}" in
 847     *-*-aix*)
 848       CFLAGS="$CFLAGS -D_THREAD_SAFE"
 849       if test x"$GCC" = xyes; then
 850         CFLAGS="$CFLAGS -mthreads"
 851       fi
 852       ;;
 853     *-*-freebsd*)
 854       CFLAGS="$CFLAGS -D_THREAD_SAFE"
 855       ;;
 856     *-*-sysv5uw7*)  # UnixWare 7
 857       if test "$GCC" != "yes"; then
 858         CFLAGS="$CFLAGS -Kthread"
 859       else
 860         CFLAGS="$CFLAGS -pthread"
 861       fi
 862       ;;
 863     *-dg-dgux*)  # DG/UX
 864       CFLAGS="$CFLAGS -D_POSIX4A_DRAFT10_SOURCE"
 865       ;;
 866    esac
 867
 868   AC_CHECK_FUNC(pthread_create)
 869   AC_DEFINE(SILC_HAVE_PTHREAD)
 870   AC_DEFINE(SILC_THREADS)
 871 fi
 872
 873 # Native WIN32 compilation under cygwin
 874 #
 875 AC_MSG_CHECKING(whether to compile native WIN32 code)
 876 AC_ARG_WITH(win32,
 877   [  --with-win32            compile native WIN32 code (-mno-cygwin)],
 878   [
 879     AC_MSG_RESULT(yes)
 880     AC_DEFINE(SILC_WIN32)
 881     win32_support=true
 882     CFLAGS="-mno-cygwin $CFLAGS"
 883     LIBS="$LIBS -lwsock32"
 884   ],
 885   [
 886     AC_MSG_RESULT(no)
 887   ])
 888 AM_CONDITIONAL(SILC_WIN32, test x$win32_support = xtrue)
 889
 890 # Native EPOC support (disabled by default)
 891 #
 892 AM_CONDITIONAL(SILC_EPOC, test xfalse = xtrue)
 893
 894 # Native BeOS support (disabled by default)
 895 #
 896 AM_CONDITIONAL(SILC_BEOS, test xfalse = xtrue)
 897
 898 # Native OS2 support (disabled by default)
 899 #
 900 AM_CONDITIONAL(SILC_OS2, test xfalse = xtrue)
 901
 902 # --without-irssi
 903 #
 904 without_irssi=false
 905 AC_MSG_CHECKING(whether to compile Irssi SILC Client)
 906 AC_ARG_WITH(irssi,
 907   [  --without-irssi         compile without Irssi SILC Client],
 908   [
 909     AC_MSG_RESULT(no)
 910     without_irssi=true
 911     SILC_DIST_SUBDIRS=`echo $SILC_DIST_SUBDIRS | $sedpath -e 's/irssi//'`
 912   ],
 913   [
 914     AC_MSG_RESULT(yes)
 915   ])
 916
 917 # --without-silcd
 918 #
 919 without_silcd=false
 920 AC_MSG_CHECKING(whether to compile SILC Server)
 921 AC_ARG_WITH(silcd,
 922   [  --without-silcd         compile without SILC Server],
 923   [
 924     AC_MSG_RESULT(no)
 925     without_silcd=true
 926     SILC_DIST_SUBDIRS=`echo $SILC_DIST_SUBDIRS | $sedpath -e 's/silcd//'`
 927   ],
 928   [
 929     AC_MSG_RESULT(yes)
 930   ])
 931
 932
 933 ##
 934 ##  Misc
 935 ##
 936
 937 # Other configure scripts
 938 #
 939 if test x$without_irssi = xfalse; then
 940   if test "x$silc_dist" = "xsilc-client" ||
 941      test "x$silc_dist" = "xsilc-toolkit"; then
 942     AC_CONFIG_SUBDIRS(irssi)
 943   fi
 944 fi
 945
 946 if test x$mp_gmp = xfalse; then
 947   AC_CONFIG_SUBDIRS(lib/silcmath/mpi)
 948 fi
 949
 950 #AC_CONFIG_SUBDIRS(lib/zlib)
 951
 952 SILC_TOP_SRCDIR=`pwd`
 953 AC_SUBST(SILC_TOP_SRCDIR)
 954 #SILC_INSTALL_PREFIX=$ac_default_prefix
 955 #AC_SUBST(SILC_INSTALL_PREFIX)
 956 AC_SUBST(LIBS)
 957 INCLUDE_DEFINES_INT="include \$(top_srcdir)/Makefile.defines_int"
 958 AC_SUBST(INCLUDE_DEFINES_INT)
 959 AC_SUBST(SILC_DIST_SUBDIRS)
 960
 961 # Makefile outputs
 962 #
 963 AC_CONFIG_FILES(
 964 Makefile
 965 Makefile.defines
 966 Makefile.defines_int
 967 doc/Makefile
 968 includes/Makefile
 969 lib/Makefile
 970 lib/contrib/Makefile
 971 lib/silccore/Makefile
 972 lib/silccrypt/Makefile
 973 lib/silcmath/Makefile
 974 lib/silcmath/mpi/Makefile.defines
 975 lib/silcmath/mpi/Makefile.defines_int
 976 lib/silcsim/Makefile
 977 lib/silcske/Makefile
 978 lib/silcutil/Makefile
 979 lib/silcutil/unix/Makefile
 980 lib/silcutil/win32/Makefile
 981 lib/silcutil/beos/Makefile
 982 lib/silcutil/os2/Makefile
 983 lib/silcutil/epoc/Makefile
 984 lib/silcsftp/Makefile
 985 lib/silcsftp/tests/Makefile
 986 doc/example_silcd.conf
 987 includes/silcincludes.h
 988 )
 989
 990 if test "x$silc_dist" = "xsilc-client" ||
 991    test "x$silc_dist" = "xsilc-toolkit"; then
 992   AC_CONFIG_FILES(lib/silcclient/Makefile)
 993 fi
 994
 995 if test x$without_irssi = xfalse ; then
 996   if test "x$silc_dist" = "xsilc-client" ||
 997      test "x$silc_dist" = "xsilc-toolkit"; then
 998     AC_CONFIG_FILES(
 999 irssi/Makefile.defines
1000 irssi/Makefile.defines_int
1001 )
1002   fi
1003 fi
1004
1005 if test x$without_silcd = xfalse ; then
1006   if test "x$silc_dist" = "xsilc-server" ||
1007      test "x$silc_dist" = "xsilc-toolkit"; then
1008     AC_CONFIG_FILES(
1009 silcd/Makefile
1010 )
1011   fi
1012 fi
1013
1014 if test "x$silc_dist" = "xsilc-toolkit"; then
1015   AC_CONFIG_FILES(
1016 silc/Makefile
1017 win32/Makefile
1018 win32/libsilc/Makefile
1019 win32/libsilcclient/Makefile
1020 tutorial/Makefile
1021 tutorial/Makefile.defines
1022 tutorial/Makefile.defines_int
1023 )
1024 fi
1025
1026 AC_OUTPUT
1027
1028 s_bindir=`eval echo $bindir`;s_bindir=`eval echo $s_bindir`
1029 s_sbindir=`eval echo $sbindir`;s_sbindir=`eval echo $s_sbindir`
1030 s_includedir=`eval echo $includedir`;s_includedir=`eval echo $s_includedir`
1031
1032 echo ""
1033 echo "SILC Configuration Summary:"
1034 echo "---------------------------"
1035 echo " Target host ...................: $target"
1036 echo " Compiler ......................: $CC"
1037 echo " CFLAGS ........................: $CFLAGS"
1038 echo " CPPFLAGS ......................: $CPPFLAGS"
1039 echo " LDFLAGS .......................: $LDFLAGS"
1040 echo " LIBS ..........................: $LIBS"
1041 echo ""
1042 echo " Installation prefix ...........: $prefix"
1043 echo " bin directory .................: $s_bindir"
1044 echo " sbin directory ................: $s_sbindir"
1045 echo " man directory .................: $MANDIR"
1046 echo " help directory ................: $HELPDIR"
1047 echo " doc directory .................: $DOCDIR"
1048 echo " logs directory ................: $LOGSDIR"
1049 echo " SIM directory .................: $MODULESDIR"
1050 echo " include directory .............: $s_includedir"
1051 echo ""
1052
1053 if test "x$silc_dist" = "xsilc-client" ||
1054    test "x$silc_dist" = "xsilc-toolkit"; then
1055   irssi="yes"
1056   if test x$without_irssi = xtrue; then
1057     irssi="no"
1058   fi
1059 echo " Compile SILC Client ...........: $irssi"
1060 fi
1061
1062 if test "x$silc_dist" = "xsilc-server" ||
1063    test "x$silc_dist" = "xsilc-toolkit"; then
1064   silcd="yes"
1065   if test x$without_silcd = xtrue; then
1066     without_silcd="no"
1067   fi
1068 echo " Compile SILC Server ...........: $silcd"
1069 echo " Server configuration file .....: $summary_silcd_configfile"
1070 echo " Server PID file ...............: $PIDFILE"
1071 fi
1072
1073 if test x$sim_support = xfalse; then
1074   sim_support="no"
1075 else
1076   sim_support="yes"
1077 fi
1078 echo " SIM support ...................: $sim_support"
1079 echo " IPv6 support ..................: $summary_ipv6"
1080 echo " Assmebler optimizations .......: $summary_asm"
1081
1082 mp="MPI"
1083 if test x$mp_gmp = xtrue; then
1084   mp="GMP"
1085 fi
1086 echo " Arithmetic library ............: $mp"
1087
1088 threads="no"
1089 if test x$has_threads = xtrue; then
1090   threads="yes"
1091 fi
1092 echo " Multi-threads support .........: $threads"
1093 echo " Debugging enabled .............: $summary_debug"
1094 echo " Stack-trace enabled ...........: $summary_stacktrace"
1095 echo ""
1096 if test "x$silc_dist" = "xsilc-client"; then
1097   echo "Compile the sources with 'make' or 'gmake' command (GNU make is required)."
1098 else
1099   echo "Compile the sources with 'make' or 'gmake' command."
1100 fi