configure.ad

   1 #
   2 #  configure.ad
   3 #
   4 #  Author: Pekka Riikonen <priikone@silcnet.org>
   5 #
   6 #  Copyright (C) 2000 - 2005 Pekka Riikonen
   7 #
   8 #  This program is free software; you can redistribute it and/or modify
   9 #  it under the terms of the GNU General Public License as published by
  10 #  the Free Software Foundation; version 2 of the License.
  11 #
  12 #  This program is distributed in the hope that it will be useful,
  13 #  but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #  GNU General Public License for more details.
  16 #
  17
  18 AD_INIT
  19 AC_CANONICAL_SYSTEM
  20 AM_INIT_AUTOMAKE
  21 AC_PREREQ(2.52)
  22 AC_CONFIG_HEADERS(silcdefs.h)
  23
  24 AC_PROG_INSTALL
  25 AC_PROG_MAKE_SET
  26
  27 AC_PROG_LN_S
  28 AC_PROG_EGREP
  29 AC_SUBST(LN_S)
  30 AC_PATH_PROG(sedpath, sed)
  31
  32 #ifdef SILC_DIST_COMPILER
  33 # Put here any platform specific stuff
  34 #
  35 case "$target" in
  36   *-*-freebsd*)
  37     check_threads=true
  38     ;;
  39   *-*-*bsd*)
  40     check_threads=false
  41     ;;
  42   *)
  43     check_threads=true
  44     ;;
  45 esac
  46
  47 CFLAGS=
  48 AC_PROG_CC
  49 AC_C_INLINE
  50 AC_C_CONST
  51
  52 __SILC_HAVE_PTHREAD=""
  53 __SILC_HAVE_SIM=""
  54 __SILC_ENABLE_DEBUG=""
  55
  56 AC_PROG_RANLIB
  57 AC_DISABLE_SHARED
  58 AC_PROG_LIBTOOL
  59
  60 # Header checking
  61 #
  62 AC_HEADER_STDC
  63 AC_HEADER_TIME
  64 AC_HEADER_STAT
  65
  66 # More header checking
  67 #
  68 AC_CHECK_HEADERS(unistd.h string.h getopt.h errno.h fcntl.h assert.h)
  69 AC_CHECK_HEADERS(sys/types.h sys/stat.h sys/time.h stddef.h)
  70 AC_CHECK_HEADERS(netinet/in.h netinet/tcp.h xti.h netdb.h sys/resource.h)
  71 AC_CHECK_HEADERS(pwd.h grp.h termcap.h paths.h)
  72 AC_CHECK_HEADERS(ncurses.h signal.h ctype.h utime.h)
  73 AC_CHECK_HEADERS(arpa/inet.h sys/mman.h limits.h termios.h locale.h langinfo.h)
  74
  75 # Data type checking
  76 #
  77 AC_TYPE_SIGNAL
  78 AC_TYPE_SIZE_T
  79 AC_TYPE_MODE_T
  80 AC_TYPE_UID_T
  81 AC_TYPE_PID_T
  82
  83 AC_CHECK_SIZEOF(long long, 0)
  84 AC_SUBST(SILC_SIZEOF_LONG_LONG, $ac_cv_sizeof_long_long)
  85 AC_CHECK_SIZEOF(long, 0)
  86 AC_SUBST(SILC_SIZEOF_LONG, $ac_cv_sizeof_long)
  87 AC_CHECK_SIZEOF(int, 0)
  88 AC_SUBST(SILC_SIZEOF_INT, $ac_cv_sizeof_int)
  89 AC_CHECK_SIZEOF(short, 0)
  90 AC_SUBST(SILC_SIZEOF_SHORT, $ac_cv_sizeof_short)
  91 AC_CHECK_SIZEOF(char, 0)
  92 AC_SUBST(SILC_SIZEOF_CHAR, $ac_cv_sizeof_char)
  93 AC_CHECK_SIZEOF(void *, 0)
  94 AC_SUBST(SILC_SIZEOF_VOID_P, $ac_cv_sizeof_void_p)
  95
  96 # Function and library checking
  97 #
  98 AC_CHECK_FUNC(gethostbyname, [],
  99   [
 100     AC_CHECK_LIB(nsl, gethostbyname, LIBS="$LIBS -lnsl")
 101     AC_CHECK_FUNC(res_gethostbyname, [],
 102        AC_CHECK_LIB(resolv, res_gethostbyname, LIBS="$LIBS -lresolv")
 103     )
 104   ])
 105 AC_CHECK_FUNC(socket, [],
 106   AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
 107 )
 108 AC_CHECK_FUNCS(gethostname gethostbyaddr getservbyname getservbyport)
 109 AC_CHECK_FUNCS(select listen bind shutdown close connect setsockopt)
 110 AC_CHECK_FUNCS(time ctime utime gettimeofday getrusage)
 111 AC_CHECK_FUNCS(chmod fcntl stat fstat getenv putenv strerror)
 112 AC_CHECK_FUNCS(getpid getgid getsid getpgid getpgrp getuid)
 113 AC_CHECK_FUNCS(setgroups initgroups nl_langinfo)
 114 AC_CHECK_FUNCS(strchr strstr strcpy strncpy memcpy memset memmove)
 115
 116 #ifdef SILC_DIST_SIM
 117 # SIM support checking
 118 # XXX These needs to be changed as more supported platforms appear.
 119 # XXX This probably needs to be made platform dependant check.
 120 #
 121 sim_support=false
 122 AC_MSG_CHECKING(for SIM support)
 123 AC_MSG_RESULT()
 124 AC_CHECK_HEADERS(dlfcn.h,
 125   [
 126     AC_CHECK_LIB(dl, dlopen,
 127       [
 128         AC_DEFINE([SILC_SIM], [], [HAVE_SIM])
 129         sim_support=true
 130         LIBS="$LIBS -ldl"
 131       ],
 132       [
 133         AC_CHECK_LIB(c, dlopen,
 134           [
 135             AC_DEFINE([SILC_SIM], [], [HAVE_SIM])
 136             sim_support=true
 137           ])
 138       ])
 139    ])
 140
 141 AM_CONDITIONAL(SILC_SIM, test x$sim_support = xtrue)
 142 if test x$sim_support = xtrue; then
 143   AC_MSG_RESULT(Enabled SIM support.)
 144   __SILC_HAVE_SIM="#define __SILC_HAVE_SIM 1"
 145 else
 146   AC_MSG_RESULT(No SIM support found.)
 147 fi
 148 #endif SILC_DIST_SIM
 149
 150 # lib/contrib conditionals
 151 #
 152 AC_CHECK_HEADER(regex.h,
 153   [
 154     AC_DEFINE([HAVE_REGEX], [], [HAVE_REGEX])
 155     have_regex=1
 156   ], have_regex=0
 157 )
 158 AM_CONDITIONAL(HAVE_REGEX, test x$have_regex = x1)
 159
 160 AC_CHECK_FUNC(getopt_long,
 161   [
 162     AC_DEFINE([HAVE_GETOPT_LONG], [], [HAVE_GETOPT_LONG])
 163     have_getopt_long=1
 164   ], have_getopt_long=0
 165 )
 166 AM_CONDITIONAL(HAVE_GETOPT_LONG, test x$have_getopt_long = x1)
 167
 168 ##
 169 ##  Enable/disable checking
 170 ##
 171
 172 # IPv6 support
 173 #
 174 AC_MSG_CHECKING(whether to enable IPv6 support)
 175 AC_ARG_ENABLE(ipv6,
 176   [  --enable-ipv6           enable IPv6 support],
 177   [
 178     case "${enableval}" in
 179       yes)
 180         want_ipv6=true
 181         check_ipv6=false
 182         summary_ipv6="yes"
 183         AC_DEFINE([HAVE_IPV6], [], [HAVE_IPV6])
 184         AC_MSG_RESULT(yes)
 185         ;;
 186       *)
 187         want_ipv6=false
 188         check_ipv6=false
 189         summary_ipv6="no"
 190         AC_MSG_RESULT(no)
 191         ;;
 192     esac
 193   ],
 194     check_ipv6=true
 195   )
 196
 197 if test x$check_ipv6 = xtrue; then
 198   summary_ipv6="no"
 199   AC_TRY_COMPILE(
 200     [
 201       #ifdef HAVE_SYS_TYPES_H
 202       #include <sys/types.h>
 203       #endif
 204       #ifdef HAVE_NETINET_TCP_H
 205       #include <netinet/tcp.h>
 206       #endif
 207       #ifdef HAVE_NETDB_H
 208       #include <netdb.h>
 209       #endif
 210       #include <sys/socket.h>
 211       #ifdef HAVE_NETINET_IN_H
 212       #include <netinet/in.h>
 213       #endif
 214     ],
 215     [
 216       struct sockaddr_in6 sin6;
 217       int family = AF_INET6;
 218     ],
 219     [
 220       AC_DEFINE([HAVE_IPV6], [], [HAVE_IPV6])
 221       AC_MSG_RESULT(yes)
 222       summary_ipv6="yes"
 223     ],
 224       AC_MSG_RESULT(no)
 225     )
 226 fi
 227
 228 # Debug checking
 229 #
 230 AC_MSG_CHECKING(whether to enable debugging)
 231 summary_debug="no"
 232 __SILC_ENABLE_DEBUG=""
 233 AC_ARG_ENABLE(debug,
 234   [  --enable-debug          enable debugging],
 235   [
 236     case "${enableval}" in
 237       yes)
 238         AC_MSG_RESULT(yes)
 239         AC_DEFINE([SILC_DEBUG], [], [enable-debug])
 240         summary_debug="yes"
 241         __SILC_ENABLE_DEBUG="#define __SILC_ENABLE_DEBUG 1"
 242         ;;
 243       *)
 244         AC_MSG_RESULT(no)
 245         ;;
 246     esac
 247   ],
 248   [
 249     AC_MSG_RESULT(no)
 250   ])
 251
 252 # Disable all assembler optimizations
 253 #
 254 AC_MSG_CHECKING(whether to enable assembler optimizations)
 255 want_asm=true
 256 AC_ARG_ENABLE(asm,
 257   [  --disable-asm           do not use assembler optimizations],
 258   [
 259     AC_MSG_RESULT(no)
 260     want_asm=false
 261   ],
 262   [
 263     AC_MSG_RESULT(yes)
 264     want_asm=true
 265   ])
 266
 267 ##
 268 ## Compiler and compiler flag checks
 269 ##
 270
 271 # Function to check if compiler flag works
 272 # Usage: SILC_ADD_CFLAGS(FLAGS, [ACTION-IF-FAILED])
 273 AC_DEFUN([SILC_ADD_CFLAGS],
 274 [ tmp_CFLAGS="$CFLAGS"
 275   CFLAGS="$CFLAGS $1"
 276   AC_MSG_CHECKING(whether $CC accepts $1 flag)
 277   AC_TRY_LINK([], [], [AC_MSG_RESULT(yes)], [AC_MSG_RESULT(no)
 278                                        CFLAGS="$tmp_CFLAGS"
 279                                        $2])
 280   unset tmp_CFLAGS
 281 ])
 282
 283 if test "$GCC"; then
 284   # GCC specific options
 285   if test "x$summary_debug" = "xyes"; then
 286     SILC_ADD_CFLAGS(-g -O)
 287   else
 288     SILC_ADD_CFLAGS(-g -O2)
 289   fi
 290   SILC_ADD_CFLAGS(-Wall -finline-functions)
 291 else
 292   # Other compilers
 293   case "$target" in
 294     alpha*-dec-osf*)
 295       SILC_ADD_CFLAGS(-g3 -O2, SILC_ADD_CFLAGS(-g3 -O, SILC_ADD_CFLAGS(-O)))
 296       ;;
 297     *)
 298       SILC_ADD_CFLAGS(-g)
 299       SILC_ADD_CFLAGS(-O2, SILC_ADD_CFLAGS(-O))
 300       ;;
 301   esac
 302
 303   # Intel C++ Compiler needs -restrict
 304   if test "x$CC" = "xicc"; then
 305     SILC_ADD_CFLAGS(-restrict)
 306   fi
 307 fi
 308
 309 #
 310 # Workaround a bug in GCC 2.x which causes memory exhaustion
 311 # when compiling sha1 with optimizations on UltraSPARC.
 312 #
 313 FIX_SHA1='#'
 314 if test "$GCC" -a "$host_cpu" = "sparc64"; then
 315   AC_MSG_CHECKING(whether to enable GCC 2.x workaround for SHA1)
 316   AC_TRY_COMPILE(
 317     [
 318       #if defined(__sparc64__) && (__GNUC__ == 2)
 319       #else
 320       choke me
 321       #endif
 322     ],
 323     [],
 324     [
 325       FIX_SHA1=''
 326       AC_MSG_RESULT(yes)
 327     ],
 328       AC_MSG_RESULT(no)
 329     )
 330 fi
 331 AC_SUBST(FIX_SHA1)
 332 #endif SILC_DIST_COMPILER
 333
 334 ##
 335 ##  Installation
 336 ##
 337
 338 # Default installation destination
 339 #
 340 #ifdef SILC_DIST_AUTODIST
 341 AC_PREFIX_DEFAULT(/usr/local)
 342 #else !SILC_DIST_AUTODIST
 343 AC_PREFIX_DEFAULT(/usr/local/silc)
 344 #endif SILC_DIST_AUTODIST
 345 if test "x$prefix" != xNONE; then
 346   silc_prefix="$prefix"
 347 else
 348   silc_prefix="$ac_default_prefix"
 349 fi
 350
 351 #ifndef SILC_DIST_AUTODIST
 352 # etc directory
 353 #
 354 if test "x$sysconfdir" != 'x${prefix}/etc'; then
 355   ETCDIR="$sysconfdir"
 356 else
 357   ETCDIR="$silc_prefix/etc"
 358 fi
 359
 360 AC_ARG_WITH(etcdir,
 361   [[  --with-etcdir=DIR       directory for system files [/etc/silc]]],
 362   [
 363     case "$withval" in
 364       no|yes)
 365         ;;
 366       *)
 367         ETCDIR="$withval"
 368         ;;
 369     esac
 370   ])
 371 AC_SUBST(ETCDIR)
 372 AC_DEFINE_UNQUOTED([SILC_ETCDIR], "$ETCDIR", [SILC_ETCDIR])
 373
 374 # doc directory
 375 #
 376 DOCDIR="$silc_prefix/doc"
 377 AC_ARG_WITH(docdir,
 378   [[  --with-docdir=DIR       directory for SILC documentation [PREFIX/doc]]],
 379   [
 380     case "$withval" in
 381       no|yes)
 382         ;;
 383       *)
 384         DOCDIR="$withval"
 385         ;;
 386     esac
 387   ])
 388 AC_SUBST(DOCDIR)
 389 AC_DEFINE_UNQUOTED([SILC_DOCDIR], "$DOCDIR", [SILC_DOCDIR])
 390 #endif SILC_DIST_AUTODIST
 391
 392 #ifdef SILC_DIST_CLIENT
 393 # help directory
 394 #
 395 HELPDIR="$silc_prefix/help"
 396 AC_ARG_WITH(helpdir,
 397   [[  --with-helpdir=DIR      directory for SILC help files [PREFIX/help]]],
 398   [
 399     case "$withval" in
 400       no|yes)
 401         ;;
 402       *)
 403        HELPDIR="$withval"
 404        ;;
 405     esac
 406   ])
 407 AC_SUBST(HELPDIR)
 408 AC_DEFINE_UNQUOTED([SILC_HELPDIR], "$HELPDIR", [SILC_HELPDIR])
 409 #endif SILC_DIST_CLIENT
 410
 411 #ifdef SILC_DIST_SIM
 412 # SIM modules directory
 413 #
 414 MODULESDIR="$silc_prefix/modules"
 415 AC_ARG_WITH(simdir,
 416   [[  --with-simdir=DIR       directory for SIM modules [PREFIX/modules]]],
 417   [
 418     case "$withval" in
 419       no|yes)
 420         ;;
 421       *)
 422         MODULESDIR="$withval"
 423         ;;
 424     esac
 425   ])
 426 AC_SUBST(MODULESDIR)
 427 AC_DEFINE_UNQUOTED([SILC_MODULESDIR], "$MODULESDIR", [SILC_MODULESDIR])
 428 #endif SILC_DIST_SIM
 429
 430 #ifdef SILC_DIST_SERVER
 431 # Logs directory
 432 #
 433 LOGSDIR="$silc_prefix/logs"
 434 AC_ARG_WITH(logsdir,
 435   [[  --with-logsdir=DIR      directory for SILC Server logs [PREFIX/logs]]],
 436   [
 437     case "$withval" in
 438       no|yes)
 439         ;;
 440       *)
 441         LOGSDIR="$withval"
 442         ;;
 443     esac
 444   ])
 445 AC_SUBST(LOGSDIR)
 446 AC_DEFINE_UNQUOTED([SILC_LOGSDIR], "$LOGSDIR", [SILC_LOGSDIR])
 447
 448 # silcd config file checking
 449 #
 450 summary_silcd_configfile="/etc/silc/silcd.conf"
 451 AC_ARG_WITH(silcd-config-file,
 452   [[  --with-silcd-config-file=FILE  use FILE as default configuration file
 453                                  for SILC Server [/etc/silc/silcd.conf]]],
 454     AC_DEFINE_UNQUOTED([SILC_SERVER_CONFIG_FILE], "$withval", [SILC_SERVER_CONFIG_FILE])
 455     summary_silcd_configfile="$withval"
 456   )
 457
 458 # silcd pid file checking
 459 #
 460 if test "x$localstatedir" != 'x${prefix}/var'; then
 461   PIDFILE="$localstatedir/silcd.pid"
 462 else
 463   PIDFILE="$silc_prefix/var/silcd.pid"
 464 fi
 465
 466 AC_ARG_WITH(silcd-pid-file,
 467   [[  --with-silcd-pid-file=FILE     use FILE as default pid file for SILC
 468                                  Server [/var/run/silcd.pid]]],
 469   [
 470     case "$withval" in
 471       no|yes)
 472         ;;
 473       *)
 474         PIDFILE="$withval"
 475         ;;
 476     esac
 477   ])
 478 AC_SUBST(PIDFILE)
 479 #endif SILC_DIST_SERVER
 480
 481 #ifdef SILC_DIST_COMPILER
 482 ##
 483 ##  With/without checkings
 484 ##
 485
 486 #
 487 # SILC library checking
 488 compile_libs=true
 489
 490 #ifndef SILC_DIST_TOOLKIT
 491 AC_ARG_WITH(silc-includes,
 492   [  --with-silc-includes=DIR SILC Toolkit includes [search in DIR]],
 493   [ac_silc_includes="$withval"], [ac_silc_includes="no"])
 494 AC_ARG_WITH(silc-libs,
 495   [  --with-silc-libs=DIR     SILC Toolkit libraries [search in DIR]],
 496   [ac_silc_libs="$withval"], [ac_silc_libs="no"])
 497
 498 if test -n "$with_silc_includes" || test -n "$with_silc_libs"; then
 499
 500   # Manually provided libs
 501   if test "$ac_silc_includes" != "no"; then
 502     compile_libs=false
 503     SILC_LIB_INCLUDES="-I$ac_silc_includes"
 504   fi
 505   if test "$ac_silc_libs" != "no"; then
 506     compile_libs=false
 507     LIBS="$LIBS -L$ac_silc_libs"
 508   fi
 509
 510   # Check libs to link against
 511   f=`$EGREP __SILC_HAVE_PTHREAD $ac_silc_includes/silcincludes.h`
 512   if test -n "$f"; then
 513     LIBS="$LIBS -lpthread"
 514     check_threads=false
 515   fi
 516   f=`$EGREP __SILC_HAVE_SIM $ac_silc_includes/silcincludes.h`
 517   if test -n "$f"; then
 518     LIBS="$LIBS -ldl"
 519   fi
 520
 521 else
 522   # pkg-config check
 523   PKG_CHECK_MODULES(SILC, silc, compile_libs=false, compile_libs=true)
 524   PKG_CHECK_MODULES(SILCCLIENT, silcclient, compile_libs=false, compile_libs=true)
 525
 526   if test x$compile_libs = xfalse; then
 527     LIBS="$LIBS $SILC_LIBS"
 528     CFLAGS="$CFLAGS $SILC_CFLAGS"
 529     LIBS="$LIBS $SILCCLIENT_LIBS"
 530     CFLAGS="$CFLAGS $SILCCLIENT_CFLAGS"
 531   fi
 532 fi
 533 #endif SILC_DIST_TOOLKIT
 534
 535 # SOCKS4 support checking
 536 #
 537 SAVE_LIBS="$LIBS"
 538 SAVE_CFLAGS="$CFLAGS"
 539 SAVE_LDFLAGS="$LDFLAGS"
 540 AC_MSG_CHECKING(whether to support SOCKS4)
 541 AC_ARG_WITH(socks4,
 542   [[  --with-socks4[=DIR]     with SOCKS4 support [search in DIR/lib and DIR/include]]],
 543   [
 544     case "$withval" in
 545       no)
 546         AC_MSG_RESULT(no)
 547         ;;
 548       *)
 549         AC_MSG_RESULT(yes)
 550         socks=4
 551
 552         if test -d "$withval/include"; then
 553           CFLAGS="$CFLAGS -I$withval/include"
 554         fi
 555         if test -d "$withval/lib"; then
 556           LDFLAGS="$LDFLAGS -L$withval/lib"
 557         fi
 558
 559         LIBS="-lsocks $LIBS"
 560         ;;
 561     esac
 562
 563     AC_TRY_LINK([],
 564       [
 565         Rconnect();
 566       ], [],
 567       [
 568         AC_MSG_ERROR(Could not find SOCKS4 library.)
 569         LIBS="$SAVE_LIBS"
 570         CFLAGS="$SAVE_CFLAGS"
 571         LDFLAGS="$SAVE_LDFLAGS"
 572       ])
 573   ],
 574     AC_MSG_RESULT(no)
 575   )
 576
 577 # SOCKS5 support checking
 578 #
 579 SAVE_LIBS="$LIBS"
 580 SAVE_CFLAGS="$CFLAGS"
 581 SAVE_LDFLAGS="$LDFLAGS"
 582 AC_MSG_CHECKING(whether to support SOCKS5)
 583 AC_ARG_WITH(socks5,
 584   [[  --with-socks5[=DIR]     with SOCKS5 support [search in DIR/lib and DIR/include]]],
 585   [
 586     case "$withval" in
 587       no)
 588         AC_MSG_RESULT(no)
 589         ;;
 590       *)
 591         AC_MSG_RESULT(yes)
 592         socks=5
 593
 594         if test -d "$withval/include"; then
 595           CFLAGS="$CFLAGS -I$withval/include"
 596         fi
 597         if test -d "$withval/lib"; then
 598           LDFLAGS="$LDFLAGS -L$withval/lib"
 599         fi
 600
 601         LIBS="-lsocks5 $LIBS"
 602         ;;
 603     esac
 604
 605     AC_TRY_LINK([],
 606       [
 607         SOCKSconnect();
 608       ], [],
 609       [
 610         AC_MSG_ERROR(Could not find SOCKS5 library.)
 611         LIBS="$SAVE_LIBS"
 612         CFLAGS="$SAVE_CFLAGS"
 613         LDFLAGS="$SAVE_LDFLAGS"
 614       ])
 615   ],
 616     AC_MSG_RESULT(no)
 617   )
 618
 619 if test "x$socks" = "x4"; then
 620   AC_DEFINE([SOCKS], [], [Socks])
 621   CFLAGS="$CFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 622 fi
 623
 624 if test "x$socks" = "x5"; then
 625   AC_DEFINE([SOCKS], [], [Socks])
 626   AC_DEFINE([SOCKS5], [], [Socks5])
 627   AC_DEFINE([Rconnect], [SOCKSconnect], [Socks])
 628   AC_DEFINE([Rgetsockname], [SOCKSgetsockname], [Socks])
 629   AC_DEFINE([Rgetpeername], [SOCKSgetpeername], [Socks])
 630   AC_DEFINE([Rbind], [SOCKSbind], [Socks])
 631   AC_DEFINE([Raccept], [SOCKSaccept], [Socks])
 632   AC_DEFINE([Rlisten], [SOCKSlisten], [Socks])
 633   AC_DEFINE([Rselect], [SOCKSselect], [Socks])
 634   AC_DEFINE([Rrecvfrom], [SOCKSrecvfrom], [Socks])
 635   AC_DEFINE([Rsendto], [SOCKSsendto], [Socks])
 636   AC_DEFINE([Rrecv], [SOCKSrecv], [Socks])
 637   AC_DEFINE([Rsend], [SOCKSsend], [Socks])
 638   AC_DEFINE([Rread], [SOCKSread], [Socks])
 639   AC_DEFINE([Rwrite], [SOCKSwrite], [Socks])
 640   AC_DEFINE([Rrresvport], [SOCKSrresvport], [Socks])
 641   AC_DEFINE([Rshutdown], [SOCKSshutdown], [Socks])
 642   AC_DEFINE([Rlisten], [SOCKSlisten], [Socks])
 643   AC_DEFINE([Rclose], [SOCKSclose], [Socks])
 644   AC_DEFINE([Rdup], [SOCKSdup], [Socks])
 645   AC_DEFINE([Rdup2], [SOCKSdup2], [Socks])
 646   AC_DEFINE([Rfclose], [SOCKSfclose], [Socks])
 647   AC_DEFINE([Rgethostbyname], [SOCKSgethostbyname], [Socks])
 648 fi
 649
 650 #ifdef SILC_DIST_MATH
 651 # MP library checking. First check whether user wants to use GMP and use
 652 # it if found. If not or not defined then compile the MPI library in the
 653 # source tree.
 654 #
 655 mp_gmp=false
 656 SAVE_LIBS="$LIBS"
 657 SAVE_CFLAGS="$CFLAGS"
 658 SAVE_LDFLAGS="$LDFLAGS"
 659 AC_MSG_CHECKING(whether to search for GMP)
 660 AC_ARG_WITH(gmp,
 661   [[  --with-gmp[=DIR]        use GMP instead of MPI [search in DIR/lib and DIR/include]]],
 662   [
 663     case "$withval" in
 664       no)
 665         AC_MSG_RESULT(no)
 666         ;;
 667       *)
 668         AC_MSG_RESULT(yes)
 669
 670         if test -d "$withval/include"; then
 671           CFLAGS="$CFLAGS -I$withval/include"
 672         fi
 673         if test -d "$withval/lib"; then
 674           LDFLAGS="$LDFLAGS -L$withval/lib"
 675         fi
 676
 677         LIBS="-lgmp $LIBS"
 678         ;;
 679     esac
 680
 681     AC_CHECK_LIB(gmp, __gmpz_init,
 682       [
 683         mp_gmp=true
 684         AC_DEFINE([SILC_MP_GMP], [], [GMP])
 685         AC_MSG_RESULT(Using GMP as a MP library.)
 686       ],
 687       [
 688         LIBS="$SAVE_LIBS"
 689         CFLAGS="$SAVE_CFLAGS"
 690         LDFLAGS="$SAVE_LDFLAGS"
 691       ])
 692   ],
 693     AC_MSG_RESULT(no)
 694   )
 695
 696 AM_CONDITIONAL(SILC_MP_GMP, test x$mp_gmp = xtrue)
 697 AM_CONDITIONAL(SILC_MP_NSS_MPI, test x$mp_gmp = xfalse)
 698 if test x$mp_gmp = xfalse; then
 699   AC_DEFINE([SILC_MP_NSS_MPI], [], [MPI])
 700   AC_MSG_RESULT(Using NSS MPI as a MP library.)
 701 fi
 702 #endif SILC_DIST_MATH
 703
 704 # iconv support
 705 #
 706 check_iconv=true
 707 has_iconv=false
 708 SAVE_LIBS="$LIBS"
 709 SAVE_CFLAGS="$CFLAGS"
 710 SAVE_LDFLAGS="$LDFLAGS"
 711 SAVE_CPPFLAGS="$CPPFLAGS"
 712 AC_MSG_CHECKING(whether to implicit search for libiconv)
 713 AC_ARG_WITH(iconv,
 714   [[  --with-iconv[=DIR]      use libiconv [search in DIR/include and DIR/lib]]],
 715   [
 716     case "${withval}" in
 717       no)
 718         AC_MSG_RESULT(no)
 719         AC_CHECK_HEADERS(iconv.h,
 720           [
 721             AC_CHECK_FUNC(iconv, has_iconv=true)
 722           ])
 723         check_iconv=false
 724         ;;
 725       *)
 726         AC_MSG_RESULT(yes)
 727         if test -d $withval/include; then
 728           CPPFLAGS="$CPPFLAGS -I$withval/include"
 729           CFLAGS="$CFLAGS -I$withval/include"
 730         fi
 731         if test -d $withval/lib; then
 732           LDFLAGS="$LDFLAGS -L$withval/lib"
 733         fi
 734         ;;
 735     esac
 736   ],
 737   [
 738     AC_MSG_RESULT(no)
 739     AC_CHECK_HEADERS(iconv.h,
 740       [
 741         AC_CHECK_FUNCS(iconv,
 742           [
 743             has_iconv=true
 744             check_iconv=false
 745           ])
 746       ])
 747   ])
 748
 749 if test x$check_iconv = xtrue; then
 750   AC_MSG_RESULT(Searching for iconv...)
 751
 752   # XXX
 753   unset ac_cv_header__iconv_h_ ac_cv_header_iconv_h || true
 754
 755   AC_CHECK_HEADERS(iconv.h,
 756     [
 757       LIBS="$LIBS -liconv"
 758       AC_MSG_CHECKING(for iconv in -liconv)
 759       AC_TRY_LINK(
 760         [
 761           #include <stdlib.h>
 762           #include <iconv.h>
 763         ],
 764         [
 765           iconv_t cd = iconv_open("", "");
 766           iconv(cd, NULL, NULL, NULL, NULL);
 767           iconv_close(cd);
 768         ],
 769         [
 770           echo "yes"
 771           AC_DEFINE([HAVE_ICONV], [], [Define if you have the iconv() function.])
 772           has_iconv=true
 773           check_iconv=false
 774         ],
 775         [
 776           echo "no"
 777           LIBS="$SAVE_LIBS"
 778           CFLAGS="$SAVE_CFLAGS"
 779           LDFLAGS="$SAVE_LDFLAGS"
 780           CPPFLAGS="$SAVE_CPPFLAGS"
 781         ])
 782      ])
 783 fi
 784
 785 if test x$check_iconv = xtrue; then
 786   # search for iconv library..
 787   SAVE_LIBS="$LIBS"
 788   SAVE_CFLAGS="$CFLAGS"
 789   SAVE_LDFLAGS="$LDFLAGS"
 790   SAVE_CPPFLAGS="$CPPFLAGS"
 791
 792   for dir in `echo "/usr/local /usr/pkg /usr/contrib"`; do
 793     if test x$has_iconv = xfalse; then
 794       AC_MSG_RESULT(searching in $dir...)
 795
 796       if test -d $dir/include; then
 797         CPPFLAGS="$CPPFLAGS -I$dir/include"
 798         CFLAGS="$CFLAGS -I$dir/include"
 799       fi
 800       if test -d $dir/lib; then
 801         LDFLAGS="$LDFLAGS -L$dir/lib"
 802       fi
 803
 804       # XXX
 805       unset ac_cv_header__iconv_h_ ac_cv_header_iconv_h || true
 806
 807       AC_CHECK_HEADERS(iconv.h,
 808         [
 809           LIBS="$LIBS -liconv"
 810           AC_MSG_CHECKING(for iconv in -liconv)
 811           AC_TRY_LINK(
 812             [
 813               #include <stdlib.h>
 814               #include <iconv.h>
 815             ],
 816             [
 817               iconv_t cd = iconv_open("", "");
 818               iconv(cd, NULL, NULL, NULL, NULL);
 819               iconv_close(cd);
 820             ],
 821             [
 822               echo "yes"
 823               has_iconv=true
 824               AC_DEFINE([HAVE_ICONV], [], [Define if you have the iconv() function.])
 825             ],
 826             [
 827               echo "no"
 828               has_iconv=false
 829
 830               LIBS="$SAVE_LIBS"
 831               CFLAGS="$SAVE_CFLAGS"
 832               LDFLAGS="$SAVE_LDFLAGS"
 833               CPPFLAGS="$SAVE_CPPFLAGS"
 834             ])
 835          ],
 836          [
 837            CFLAGS="$SAVE_CFLAGS"
 838            LDFLAGS="$SAVE_LDFLAGS"
 839            CPPFLAGS="$SAVE_CPPFLAGS"
 840          ])
 841       fi
 842     done
 843 fi
 844
 845 if test x$has_iconv = xtrue; then
 846   # (1) Some implementations of iconv won't convert from UTF-8 to UTF-8.
 847   # (2) In glibc-2.1.2 and earlier there is a bug that messes up ob and
 848   #     obl when args 2 and 3 are 0 (fixed in glibc-2.1.3).
 849   #
 850   AC_CACHE_CHECK([whether this iconv is good enough], ac_iconv_good,
 851     AC_TRY_RUN(
 852       [
 853         #include <iconv.h>
 854         int main() {
 855           iconv_t cd;
 856         changequote(, )dnl
 857           char buf[4];
 858         changequote([, ])dnl
 859           char *ob;
 860           size_t obl;
 861           ob = buf, obl = sizeof(buf);
 862           return ((cd = iconv_open("UTF-8", "UTF-8")) != (iconv_t)(-1) &&
 863                  (iconv(cd, 0, 0, &ob, &obl) ||
 864                  !(ob == buf && obl == sizeof(buf)) ||
 865                  iconv_close(cd)));
 866         }
 867       ],
 868       [
 869         ac_iconv_good=yes
 870       ],
 871       [
 872         ac_iconv_good=no
 873       ],
 874       [
 875         ac_iconv_good=yes
 876       ])
 877     )
 878
 879   if test x$ac_iconv_good = xno; then
 880     AC_MSG_RESULT(Try using libiconv instead.)
 881   fi
 882 fi
 883
 884 # POSIX threads support
 885 #
 886 has_threads=false
 887 AC_MSG_CHECKING(whether to search for POSIX threads)
 888 AC_ARG_WITH(pthreads,
 889   [[  --with-pthreads[=DIR]   use POSIX threads [search in DIR/include and DIR/lib]]],
 890   [
 891     case "${withval}" in
 892       no)
 893         check_threads=false
 894         ;;
 895       *)
 896         if test -d $withval/include; then
 897           CPPFLAGS="$CPPFLAGS -I$withval/include"
 898           CFLAGS="$CFLAGS -I$withval/include"
 899         fi
 900         if test -d $withval/lib; then
 901           LDFLAGS="$LDFLAGS -L$withval/lib"
 902         fi
 903
 904         check_threads=true
 905         ;;
 906     esac
 907   ])
 908
 909 if test x$check_threads = xtrue; then
 910   SAVE_LIBS="$LIBS"
 911   SAVE_CFLAGS="$CFLAGS"
 912   SAVE_LDFLAGS="$LDFLAGS"
 913   SAVE_CPPFLAGS="$CPPFLAGS"
 914
 915   AC_MSG_RESULT(yes)
 916   AC_CHECK_HEADERS(pthread.h,
 917     [
 918       LIBS="$LIBS -lpthread"
 919       AC_CHECK_LIB(pthread, pthread_attr_init, has_threads=true,
 920         [
 921           # FreeBSD
 922           case "${target}" in
 923             *-*-freebsd*)
 924               LIBS="$SAVE_LIBS -pthread"
 925               AC_CHECK_LIB(c_r, pthread_attr_init, has_threads=true, LIBS="$SAVE_LIBS")
 926               ;;
 927             *)
 928               LIBS="$SAVE_LIBS"
 929               ;;
 930           esac
 931         ])
 932     ],
 933     [
 934       # search for pthread library..
 935       for dir in `echo "/usr/local /usr/pkg /usr/contrib /usr/pkg/pthreads /usr/local/pthreads"`; do
 936         if test x$has_threads = xfalse; then
 937           AC_MSG_RESULT(searching in $dir...)
 938
 939           if test -d $dir/include; then
 940             CPPFLAGS="$CPPFLAGS -I$dir/include"
 941             CFLAGS="$CFLAGS -I$dir/include"
 942           fi
 943           if test -d $dir/lib; then
 944             LDFLAGS="$LDFLAGS -L$dir/lib"
 945           fi
 946
 947           # XXX
 948           unset ac_cv_header__pthread_h_ ac_cv_header_pthread_h || true
 949
 950           AC_CHECK_HEADERS(pthread.h,
 951             [
 952               LIBS="$LIBS -lpthread"
 953               AC_CHECK_LIB(pthread, pthread_attr_init, has_threads=true,
 954                 [
 955                   has_threads=false
 956
 957                   LIBS="$SAVE_LIBS"
 958                   CFLAGS="$SAVE_CFLAGS"
 959                   LDFLAGS="$SAVE_LDFLAGS"
 960                   CPPFLAGS="$SAVE_CPPFLAGS"
 961                 ])
 962             ],
 963             [
 964               CFLAGS="$SAVE_CFLAGS"
 965               LDFLAGS="$SAVE_LDFLAGS"
 966               CPPFLAGS="$SAVE_CPPFLAGS"
 967             ])
 968         fi
 969       done
 970     ])
 971 else
 972   AC_MSG_RESULT(no)
 973   has_threads=false
 974 fi
 975
 976 __SILC_HAVE_PTHREAD=""
 977 AM_CONDITIONAL(SILC_THREADS, test x$has_threads = xtrue)
 978 if test x$has_threads = xtrue; then
 979   CFLAGS="$CFLAGS -D_REENTRANT"
 980
 981   # XXX possibly incomplete
 982   case "${target}" in
 983     *-*-aix*)
 984       CFLAGS="$CFLAGS -D_THREAD_SAFE"
 985       if test x"$GCC" = xyes; then
 986         CFLAGS="$CFLAGS -mthreads"
 987       fi
 988       ;;
 989     *-*-freebsd*)
 990       CFLAGS="$CFLAGS -D_THREAD_SAFE"
 991       ;;
 992     *-*-sysv5uw7*)  # UnixWare 7
 993       if test "$GCC" != "yes"; then
 994         CFLAGS="$CFLAGS -Kthread"
 995       else
 996         CFLAGS="$CFLAGS -pthread"
 997       fi
 998       ;;
 999     *-dg-dgux*)  # DG/UX
1000       CFLAGS="$CFLAGS -D_POSIX4A_DRAFT10_SOURCE"
1001       ;;
1002    esac
1003
1004   AC_CHECK_FUNC(pthread_create)
1005   AC_DEFINE([SILC_HAVE_PTHREAD], [], [HAVE_PTHREAD])
1006   AC_DEFINE([SILC_THREADS], [], [HAVE_THREAD])
1007   __SILC_HAVE_PTHREAD="#define __SILC_HAVE_PTHREAD 1"
1008 fi
1009
1010 # Native WIN32 compilation under cygwin
1011 #
1012 AC_MSG_CHECKING(whether to compile native WIN32 code)
1013 AC_ARG_WITH(win32,
1014   [  --with-win32            compile native WIN32 (MinGW) code (-mno-cygwin)],
1015   [
1016     AC_MSG_RESULT(yes)
1017     AC_DEFINE([SILC_WIN32], [], [SILC_WIN32])
1018     win32_support=true
1019     CFLAGS="-mno-cygwin $CFLAGS"
1020     LIBS="$LIBS -lwsock32"
1021   ],
1022   [
1023     AC_MSG_RESULT(no)
1024   ])
1025 AM_CONDITIONAL(SILC_WIN32, test x$win32_support = xtrue)
1026
1027 # Native EPOC support (disabled by default)
1028 #
1029 AM_CONDITIONAL(SILC_EPOC, test xfalse = xtrue)
1030
1031 # Native BeOS support (disabled by default)
1032 #
1033 AM_CONDITIONAL(SILC_BEOS, test xfalse = xtrue)
1034
1035 # Native OS2 support (disabled by default)
1036 #
1037 AM_CONDITIONAL(SILC_OS2, test xfalse = xtrue)
1038
1039 #ifdef SILC_DIST_TOOLKIT
1040
1041 # --without-irssi
1042 #
1043 without_irssi=false
1044 AC_MSG_CHECKING(whether to compile Irssi SILC Client)
1045 AC_ARG_WITH(irssi,
1046   [  --without-irssi         compile without Irssi SILC Client],
1047   [
1048     AC_MSG_RESULT(no)
1049     without_irssi=true
1050   ],
1051   [
1052     AC_MSG_RESULT(yes)
1053   ])
1054
1055 # --without-silcd
1056 #
1057 without_silcd=false
1058 AC_MSG_CHECKING(whether to compile SILC Server)
1059 AC_ARG_WITH(silcd,
1060   [  --without-silcd         compile without SILC Server],
1061   [
1062     AC_MSG_RESULT(no)
1063     without_silcd=true
1064   ],
1065   [
1066     AC_MSG_RESULT(yes)
1067   ])
1068
1069 #endif SILC_DIST_TOOLKIT
1070
1071 #ifdef SILC_DIST_CLIENT
1072 # Irssi perl support
1073 #
1074 AC_ARG_WITH(perl,
1075   [[  --with-perl[=yes|no|module]  Build with Perl support - also specifies
1076                                if it should be built into main silc binary
1077                                (static, default) or as a module]])
1078 #endif SILC_DIST_CLIENT
1079
1080 libtoolfix=true
1081 AC_MSG_CHECKING(whether to do libtoolfix)
1082 AC_ARG_WITH(libtoolfix,
1083   [  --without-libtoolfix    Do not fix libtool, for package builders],
1084   [
1085     AC_MSG_RESULT(no)
1086     libtoolfix=false
1087   ],
1088   [
1089     AC_MSG_RESULT(yes)
1090   ])
1091
1092 AC_SUBST(ETCDIR)
1093 AC_DEFINE_UNQUOTED([SILC_ETCDIR], "$ETCDIR", [SILC_ETCDIR])
1094
1095 #endif SILC_DIST_COMPILER
1096
1097 ##
1098 ##  Misc
1099 ##
1100
1101 # Make enable-shared aware
1102 AM_CONDITIONAL(SILC_ENABLE_SHARED, test "$enable_shared" = yes)
1103
1104 # Other configure scripts
1105 #
1106
1107 #ifdef SILC_DIST_TOOLKIT
1108 if test x$without_irssi = xfalse; then
1109 #endif SILC_DIST_TOOLKIT
1110 #ifdef SILC_DIST_CLIENT
1111   AC_CONFIG_SUBDIRS(irssi)
1112   irssi="yes"
1113 #endif SILC_DIST_CLIENT
1114 #ifdef SILC_DIST_TOOLKIT
1115 fi
1116 #endif SILC_DIST_TOOLKIT
1117
1118 SILC_TOP_SRCDIR=`pwd`
1119
1120 # Included configure scripts
1121 AD_INCLUDE_CONFIGURE
1122
1123 #ifdef SILC_DIST_COMPILER
1124 #
1125 # Substitutions
1126 #
1127 AC_SUBST(SILC_TOP_SRCDIR)
1128 AC_SUBST(LIBS)
1129 AC_SUBST(SILC_LIB_INCLUDES)
1130 AC_SUBST(__SILC_HAVE_PTHREAD)
1131 AC_SUBST(__SILC_HAVE_SIM)
1132 AC_SUBST(__SILC_ENABLE_DEBUG)
1133
1134 #
1135 # Fix the libtool to support run-time configuration.  This allows us
1136 # to in run-time specify when to compile shared/static libraries without
1137 # need to reconfigure the entire libtool.
1138 #
1139 if test x$libtoolfix = xtrue; then
1140   ./libtoolfix $SILC_TOP_SRCDIR/ltmain.sh
1141 fi
1142 AM_CONDITIONAL(SILC_LIBTOOLFIX, test x$libtoolfix = xtrue)
1143
1144 INCLUDE_DEFINES_INT="include \$(top_srcdir)/Makefile.defines_int"
1145 AC_SUBST(INCLUDE_DEFINES_INT)
1146
1147 #endif SILC_DIST_COMPILER
1148
1149 #
1150 # Makefile outputs
1151 #
1152 AC_CONFIG_FILES(
1153 Makefile
1154 #ifdef SILC_DIST_DOC
1155 doc/Makefile
1156 #endif SILC_DIST_DOC
1157 #ifdef SILC_DIST_COMPILER
1158 Makefile.defines
1159 Makefile.defines_int
1160 includes/Makefile
1161 includes/silcversion.h
1162 includes/silcincludes.h
1163 #endif SILC_DIST_COMPILER
1164 #ifdef SILC_DIST_APPS
1165 apps/Makefile
1166 #endif SILC_DIST_APPS
1167 )
1168
1169 #ifdef SILC_DIST_TOOLKIT
1170 if test x$without_irssi = xfalse ; then
1171 #endif SILC_DIST_TOOLKIT
1172 #ifdef SILC_DIST_CLIENT
1173   AC_CONFIG_FILES(
1174 irssi/Makefile.defines
1175 irssi/Makefile.defines_int
1176 )
1177 #endif SILC_DIST_CLIENT
1178 #ifdef SILC_DIST_TOOLKIT
1179 fi
1180 #endif SILC_DIST_TOOLKIT
1181
1182 #ifdef SILC_DIST_TOOLKIT
1183 if test x$without_silcd = xfalse ; then
1184 #endif SILC_DIST_TOOLKIT
1185 #ifdef SILC_DIST_SERVER
1186   AC_CONFIG_FILES(
1187 silcd/Makefile
1188 doc/example_silcd.conf
1189 )
1190 #endif SILC_DIST_SERVER
1191 #ifdef SILC_DIST_TOOLKIT
1192 fi
1193 #endif SILC_DIST_TOOLKIT
1194
1195 #ifdef SILC_DIST_TOOLKIT
1196 AC_CONFIG_FILES(
1197 silc/Makefile
1198 win32/Makefile
1199 win32/libsilc/Makefile
1200 win32/libsilcclient/Makefile
1201 tutorial/Makefile
1202 tutorial/Makefile.defines
1203 tutorial/Makefile.defines_int
1204 )
1205 #endif SILC_DIST_TOOLKIT
1206
1207 AC_OUTPUT
1208
1209 #ifdef SILC_DIST_COMPILER
1210 s_bindir=`eval echo $bindir`;s_bindir=`eval echo $s_bindir`
1211 s_sbindir=`eval echo $sbindir`;s_sbindir=`eval echo $s_sbindir`
1212 s_mandir=`eval echo $mandir`;s_mandir=`eval echo $s_mandir`
1213 s_includedir=`eval echo $includedir`;s_includedir=`eval echo $s_includedir`
1214
1215 echo ""
1216 echo "$PACKAGE Configuration Summary:"
1217 echo "---------------------------"
1218 echo " Target host ...................: $target"
1219 echo " Compiler ......................: $CC"
1220 echo " CFLAGS ........................: $CFLAGS"
1221 echo " LDFLAGS .......................: $LDFLAGS"
1222 echo " LIBS ..........................: $LIBS"
1223 echo ""
1224 echo " Installation prefix ...........: $prefix"
1225 echo " bin directory .................: $s_bindir"
1226 echo " sbin directory ................: $s_sbindir"
1227 echo " etc directory .................: $ETCDIR"
1228 echo " man directory .................: $s_mandir"
1229 echo " doc directory .................: $DOCDIR"
1230 #ifdef SILC_DIST_CLIENT
1231 echo " help directory ................: $HELPDIR"
1232 #endif SILC_DIST_CLIENT
1233 #ifdef SILC_DIST_SERVER
1234 echo " logs directory ................: $LOGSDIR"
1235 #endif SILC_DIST_SERVER
1236 #ifdef SILC_DIST_SIM
1237 echo " SIM directory .................: $MODULESDIR"
1238 #endif SILC_DIST_SIM
1239 #ifdef SILC_DIST_INCLUDES
1240 echo " include directory .............: $s_includedir"
1241 #endif SILC_DIST_INCLUDES
1242 echo ""
1243
1244 #ifdef SILC_DIST_SERVER
1245 silcd="yes"
1246 #endif SILC_DIST_SERVER
1247
1248 #ifdef SILC_DIST_TOOLKIT
1249 if test x$without_irssi = xtrue; then
1250   irssi="no"
1251 fi
1252 if test x$without_silcd = xtrue; then
1253   silcd="no"
1254 fi
1255 #endif SILC_DIST_TOOLKIT
1256
1257 #ifdef SILC_DIST_CLIENT
1258 echo " Compile SILC Client ...........: $irssi"
1259 #endif SILC_DIST_CLIENT
1260
1261 #ifdef SILC_DIST_SERVER
1262 echo " Compile SILC Server ...........: $silcd"
1263 echo " Server configuration file .....: $summary_silcd_configfile"
1264 echo " Server PID file ...............: $PIDFILE"
1265 #endif SILC_DIST_SERVER
1266
1267 #ifdef SILC_DIST_SIM
1268 if test x$sim_support = xfalse; then
1269   sim_support="no"
1270 else
1271   sim_support="yes"
1272 fi
1273 echo " SIM support ...................: $sim_support"
1274 #endif SILC_DIST_SIM
1275
1276 echo " IPv6 support ..................: $summary_ipv6"
1277
1278 if test x$has_iconv = xfalse; then
1279   iconv_support="no"
1280 else
1281   iconv_support="yes"
1282 fi
1283 echo " Iconv support .................: $iconv_support"
1284
1285 if test x$want_asm = xfalse; then
1286   summary_asm="no"
1287 else
1288   summary_asm="yes"
1289 fi
1290 echo " Assembler optimizations .......: $summary_asm"
1291
1292 #ifdef SILC_DIST_MATH
1293 mp="MPI"
1294 if test x$mp_gmp = xtrue; then
1295   mp="GMP"
1296 fi
1297 echo " Arithmetic library ............: $mp"
1298 #endif SILC_DIST_MATH
1299
1300 threads="no"
1301 if test x$has_threads = xtrue; then
1302   threads="yes"
1303 fi
1304 echo " Multi-threads support .........: $threads"
1305 echo " Debugging enabled .............: $summary_debug"
1306 echo ""
1307 echo "Compile the sources with 'make' or 'gmake' command."
1308 #endif SILC_DIST_COMPILER
1309