configure.ad

   1 #
   2 #  configure.ad
   3 #
   4 #  Author: Pekka Riikonen <priikone@silcnet.org>
   5 #
   6 #  Copyright (C) 2000 - 2005 Pekka Riikonen
   7 #
   8 #  This program is free software; you can redistribute it and/or modify
   9 #  it under the terms of the GNU General Public License as published by
  10 #  the Free Software Foundation; version 2 of the License.
  11 #
  12 #  This program is distributed in the hope that it will be useful,
  13 #  but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #  GNU General Public License for more details.
  16 #
  17
  18 AD_INIT
  19 AC_CANONICAL_SYSTEM
  20 AM_INIT_AUTOMAKE
  21 AC_PREREQ(2.52)
  22 AC_CONFIG_HEADERS(silcdefs.h)
  23
  24 AC_PROG_INSTALL
  25 AC_PROG_MAKE_SET
  26
  27 AC_PROG_LN_S
  28 AC_PROG_EGREP
  29 AC_SUBST(LN_S)
  30 AC_PATH_PROG(sedpath, sed)
  31
  32 #ifdef SILC_DIST_COMPILER
  33 # Put here any platform specific stuff
  34 #
  35 case "$target" in
  36   *-*-freebsd*)
  37     check_threads=true
  38     ;;
  39   *-*-*bsd*)
  40     check_threads=false
  41     ;;
  42   *)
  43     check_threads=true
  44     ;;
  45 esac
  46
  47 # Control compiler optimizations
  48 CFLAGS=`echo $CFLAGS | sed 's/-O[ 0123456789s]*//g'`
  49
  50 AC_PROG_CC
  51 AC_C_INLINE
  52 AC_C_CONST
  53
  54 __SILC_HAVE_PTHREAD=""
  55 __SILC_HAVE_SIM=""
  56 __SILC_ENABLE_DEBUG=""
  57
  58 AC_PROG_RANLIB
  59 AC_DISABLE_SHARED
  60 AC_PROG_LIBTOOL
  61
  62 # Header checking
  63 #
  64 AC_HEADER_STDC
  65 AC_HEADER_TIME
  66 AC_HEADER_STAT
  67
  68 # More header checking
  69 #
  70 AC_CHECK_HEADERS(unistd.h string.h getopt.h errno.h fcntl.h assert.h)
  71 AC_CHECK_HEADERS(sys/types.h sys/stat.h sys/time.h stddef.h)
  72 AC_CHECK_HEADERS(netinet/in.h netinet/tcp.h xti.h netdb.h sys/resource.h)
  73 AC_CHECK_HEADERS(pwd.h grp.h termcap.h paths.h)
  74 AC_CHECK_HEADERS(ncurses.h signal.h ctype.h utime.h)
  75 AC_CHECK_HEADERS(arpa/inet.h sys/mman.h limits.h termios.h locale.h langinfo.h)
  76
  77 # Data type checking
  78 #
  79 AC_TYPE_SIGNAL
  80 AC_TYPE_SIZE_T
  81 AC_TYPE_MODE_T
  82 AC_TYPE_UID_T
  83 AC_TYPE_PID_T
  84
  85 AC_CHECK_SIZEOF(long long, 0)
  86 AC_SUBST(SILC_SIZEOF_LONG_LONG, $ac_cv_sizeof_long_long)
  87 AC_CHECK_SIZEOF(long, 0)
  88 AC_SUBST(SILC_SIZEOF_LONG, $ac_cv_sizeof_long)
  89 AC_CHECK_SIZEOF(int, 0)
  90 AC_SUBST(SILC_SIZEOF_INT, $ac_cv_sizeof_int)
  91 AC_CHECK_SIZEOF(short, 0)
  92 AC_SUBST(SILC_SIZEOF_SHORT, $ac_cv_sizeof_short)
  93 AC_CHECK_SIZEOF(char, 0)
  94 AC_SUBST(SILC_SIZEOF_CHAR, $ac_cv_sizeof_char)
  95 AC_CHECK_SIZEOF(void *, 0)
  96 AC_SUBST(SILC_SIZEOF_VOID_P, $ac_cv_sizeof_void_p)
  97
  98 # Function and library checking
  99 #
 100 AC_CHECK_FUNC(gethostbyname, [],
 101   [
 102     AC_CHECK_LIB(nsl, gethostbyname, LIBS="$LIBS -lnsl")
 103     AC_CHECK_FUNC(res_gethostbyname, [],
 104        AC_CHECK_LIB(resolv, res_gethostbyname, LIBS="$LIBS -lresolv")
 105     )
 106   ])
 107 AC_CHECK_FUNC(socket, [],
 108   AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
 109 )
 110 AC_CHECK_FUNCS(gethostname gethostbyaddr getservbyname getservbyport)
 111 AC_CHECK_FUNCS(select listen bind shutdown close connect setsockopt)
 112 AC_CHECK_FUNCS(time ctime utime gettimeofday getrusage)
 113 AC_CHECK_FUNCS(chmod fcntl stat fstat getenv putenv strerror)
 114 AC_CHECK_FUNCS(getpid getgid getsid getpgid getpgrp getuid)
 115 AC_CHECK_FUNCS(setgroups initgroups nl_langinfo)
 116 AC_CHECK_FUNCS(strchr strstr strcpy strncpy memcpy memset memmove)
 117
 118 #ifdef SILC_DIST_SIM
 119 # SIM support checking
 120 # XXX These needs to be changed as more supported platforms appear.
 121 # XXX This probably needs to be made platform dependant check.
 122 #
 123 sim_support=false
 124 AC_MSG_CHECKING(for SIM support)
 125 AC_MSG_RESULT()
 126 AC_CHECK_HEADERS(dlfcn.h,
 127   [
 128     AC_CHECK_LIB(dl, dlopen,
 129       [
 130         AC_DEFINE([SILC_SIM], [], [HAVE_SIM])
 131         sim_support=true
 132         LIBS="$LIBS -ldl"
 133       ],
 134       [
 135         AC_CHECK_LIB(c, dlopen,
 136           [
 137             AC_DEFINE([SILC_SIM], [], [HAVE_SIM])
 138             sim_support=true
 139           ])
 140       ])
 141    ])
 142
 143 AM_CONDITIONAL(SILC_SIM, test x$sim_support = xtrue)
 144 if test x$sim_support = xtrue; then
 145   AC_MSG_RESULT(Enabled SIM support.)
 146   __SILC_HAVE_SIM="#define __SILC_HAVE_SIM 1"
 147 else
 148   AC_MSG_RESULT(No SIM support found.)
 149 fi
 150 #endif SILC_DIST_SIM
 151
 152 # lib/contrib conditionals
 153 #
 154 AC_CHECK_HEADER(regex.h,
 155   [
 156     AC_DEFINE([HAVE_REGEX], [], [HAVE_REGEX])
 157     have_regex=1
 158   ], have_regex=0
 159 )
 160 AM_CONDITIONAL(HAVE_REGEX, test x$have_regex = x1)
 161
 162 AC_CHECK_FUNC(getopt_long,
 163   [
 164     AC_DEFINE([HAVE_GETOPT_LONG], [], [HAVE_GETOPT_LONG])
 165     have_getopt_long=1
 166   ], have_getopt_long=0
 167 )
 168
 169 ##
 170 ##  Enable/disable checking
 171 ##
 172
 173 # IPv6 support
 174 #
 175 AC_MSG_CHECKING(whether to enable IPv6 support)
 176 AC_ARG_ENABLE(ipv6,
 177   [  --enable-ipv6           enable IPv6 support],
 178   [
 179     case "${enableval}" in
 180       yes)
 181         want_ipv6=true
 182         check_ipv6=false
 183         summary_ipv6="yes"
 184         AC_DEFINE([HAVE_IPV6], [], [HAVE_IPV6])
 185         AC_MSG_RESULT(yes)
 186         ;;
 187       *)
 188         want_ipv6=false
 189         check_ipv6=false
 190         summary_ipv6="no"
 191         AC_MSG_RESULT(no)
 192         ;;
 193     esac
 194   ],
 195     check_ipv6=true
 196   )
 197
 198 if test x$check_ipv6 = xtrue; then
 199   summary_ipv6="no"
 200   AC_TRY_COMPILE(
 201     [
 202       #ifdef HAVE_SYS_TYPES_H
 203       #include <sys/types.h>
 204       #endif
 205       #ifdef HAVE_NETINET_TCP_H
 206       #include <netinet/tcp.h>
 207       #endif
 208       #ifdef HAVE_NETDB_H
 209       #include <netdb.h>
 210       #endif
 211       #include <sys/socket.h>
 212       #ifdef HAVE_NETINET_IN_H
 213       #include <netinet/in.h>
 214       #endif
 215     ],
 216     [
 217       struct sockaddr_in6 sin6;
 218       int family = AF_INET6;
 219     ],
 220     [
 221       AC_DEFINE([HAVE_IPV6], [], [HAVE_IPV6])
 222       AC_MSG_RESULT(yes)
 223       summary_ipv6="yes"
 224     ],
 225       AC_MSG_RESULT(no)
 226     )
 227 fi
 228
 229 # Debug checking
 230 #
 231 AC_MSG_CHECKING(whether to enable debugging)
 232 summary_debug="no"
 233 __SILC_ENABLE_DEBUG=""
 234 AC_ARG_ENABLE(debug,
 235   [  --enable-debug          enable debugging],
 236   [
 237     case "${enableval}" in
 238       yes)
 239         AC_MSG_RESULT(yes)
 240         AC_DEFINE([SILC_DEBUG], [], [enable-debug])
 241         summary_debug="yes"
 242         __SILC_ENABLE_DEBUG="#define __SILC_ENABLE_DEBUG 1"
 243         ;;
 244       *)
 245         AC_MSG_RESULT(no)
 246         ;;
 247     esac
 248   ],
 249   [
 250     AC_MSG_RESULT(no)
 251   ])
 252
 253 # Disable all assembler optimizations
 254 #
 255 AC_MSG_CHECKING(whether to enable assembler optimizations)
 256 want_asm=true
 257 AC_ARG_ENABLE(asm,
 258   [  --disable-asm           do not use assembler optimizations],
 259   [
 260     AC_MSG_RESULT(no)
 261     want_asm=false
 262   ],
 263   [
 264     AC_MSG_RESULT(yes)
 265     want_asm=true
 266   ])
 267
 268 ##
 269 ## Compiler and compiler flag checks
 270 ##
 271
 272 # Function to check if compiler flag works
 273 # Usage: SILC_ADD_CFLAGS(FLAGS, [ACTION-IF-FAILED])
 274 AC_DEFUN([SILC_ADD_CFLAGS],
 275 [ tmp_CFLAGS="$CFLAGS"
 276   CFLAGS="$CFLAGS $1"
 277   AC_MSG_CHECKING(whether $CC accepts $1 flag)
 278   AC_TRY_LINK([], [], [AC_MSG_RESULT(yes)], [AC_MSG_RESULT(no)
 279                                        CFLAGS="$tmp_CFLAGS"
 280                                        $2])
 281   unset tmp_CFLAGS
 282 ])
 283
 284 # Function to check if compiler flag works, destination specifiable
 285 # Usage: SILC_ADD_CC_FLAGS(VAR, FLAGS, [ACTION-IF-FAILED])
 286 AC_DEFUN([SILC_ADD_CC_FLAGS],
 287 [ tmp_CFLAGS="$1_CFLAGS"
 288   $1_CFLAGS="${$1_CFLAGS} $2"
 289   AC_MSG_CHECKING(whether $CC accepts $2 flag)
 290   AC_TRY_LINK([], [], [AC_MSG_RESULT(yes)], [AC_MSG_RESULT(no)
 291                                        $1_CFLAGS="$tmp_CFLAGS"
 292                                        $3])
 293   unset tmp_CFLAGS
 294 ])
 295
 296 if test "$GCC"; then
 297   # GCC specific options
 298   if test "x$summary_debug" = "xyes"; then
 299     SILC_ADD_CFLAGS(-g -O)
 300   else
 301     SILC_ADD_CFLAGS(-g -O2)
 302   fi
 303   SILC_ADD_CFLAGS(-Wall -finline-functions)
 304   SILC_ADD_CFLAGS(-Wno-pointer-sign)
 305 else
 306   # Other compilers
 307   case "$target" in
 308     alpha*-dec-osf*)
 309       SILC_ADD_CFLAGS(-g3 -O2, SILC_ADD_CFLAGS(-g3 -O, SILC_ADD_CFLAGS(-O)))
 310       ;;
 311     *)
 312       SILC_ADD_CFLAGS(-g)
 313       SILC_ADD_CFLAGS(-O2, SILC_ADD_CFLAGS(-O))
 314       ;;
 315   esac
 316
 317   # Intel C++ Compiler needs -restrict
 318   if test "x$CC" = "xicc"; then
 319     SILC_ADD_CFLAGS(-restrict)
 320   fi
 321 fi
 322
 323 #
 324 # Workaround a bug in GCC 2.x which causes memory exhaustion
 325 # when compiling sha1 with optimizations on UltraSPARC.
 326 #
 327 FIX_SHA1='#'
 328 if test "$GCC" -a "$host_cpu" = "sparc64"; then
 329   AC_MSG_CHECKING(whether to enable GCC 2.x workaround for SHA1)
 330   AC_TRY_COMPILE(
 331     [
 332       #if defined(__sparc64__) && (__GNUC__ == 2)
 333       #else
 334       choke me
 335       #endif
 336     ],
 337     [],
 338     [
 339       FIX_SHA1=''
 340       AC_MSG_RESULT(yes)
 341     ],
 342       AC_MSG_RESULT(no)
 343     )
 344 fi
 345 AC_SUBST(FIX_SHA1)
 346 #endif SILC_DIST_COMPILER
 347
 348 ##
 349 ##  Installation
 350 ##
 351
 352 # Default installation destination
 353 #
 354 #ifdef SILC_DIST_AUTODIST
 355 AC_PREFIX_DEFAULT(/usr/local)
 356 #else !SILC_DIST_AUTODIST
 357 AC_PREFIX_DEFAULT(/usr/local/silc)
 358 #endif SILC_DIST_AUTODIST
 359 if test "x$prefix" != xNONE; then
 360   silc_prefix="$prefix"
 361 else
 362   silc_prefix="$ac_default_prefix"
 363 fi
 364
 365 #ifndef SILC_DIST_AUTODIST
 366 # etc directory
 367 #
 368 if test "x$sysconfdir" != 'x${prefix}/etc'; then
 369   ETCDIR="$sysconfdir"
 370 else
 371   ETCDIR="$silc_prefix/etc"
 372 fi
 373
 374 AC_ARG_WITH(etcdir,
 375   [[  --with-etcdir=DIR       directory for system files [/etc/silc]]],
 376   [
 377     case "$withval" in
 378       no|yes)
 379         ;;
 380       *)
 381         ETCDIR="$withval"
 382         ;;
 383     esac
 384   ])
 385 AC_SUBST(ETCDIR)
 386 AC_DEFINE_UNQUOTED([SILC_ETCDIR], "$ETCDIR", [SILC_ETCDIR])
 387
 388 # doc directory
 389 #
 390 DOCDIR="$silc_prefix/doc"
 391 AC_ARG_WITH(docdir,
 392   [[  --with-docdir=DIR       directory for SILC documentation [PREFIX/doc]]],
 393   [
 394     case "$withval" in
 395       no|yes)
 396         ;;
 397       *)
 398         DOCDIR="$withval"
 399         ;;
 400     esac
 401   ])
 402 AC_SUBST(DOCDIR)
 403 AC_DEFINE_UNQUOTED([SILC_DOCDIR], "$DOCDIR", [SILC_DOCDIR])
 404 #endif SILC_DIST_AUTODIST
 405
 406 #ifdef SILC_DIST_COMPILER
 407 ##
 408 ##  With/without checkings
 409 ##
 410
 411 #
 412 # SILC library checking
 413 compile_libs=true
 414
 415 #ifndef SILC_DIST_TOOLKIT
 416 AC_ARG_WITH(silc-includes,
 417   [  --with-silc-includes=DIR SILC Toolkit includes [search in DIR]],
 418   [ac_silc_includes="$withval"], [ac_silc_includes="no"])
 419 AC_ARG_WITH(silc-libs,
 420   [  --with-silc-libs=DIR     SILC Toolkit libraries [search in DIR]],
 421   [ac_silc_libs="$withval"], [ac_silc_libs="no"])
 422
 423 if test -n "$with_silc_includes" || test -n "$with_silc_libs"; then
 424
 425   # Manually provided libs
 426   if test "$ac_silc_includes" != "no"; then
 427     compile_libs=false
 428     SILC_LIB_INCLUDES="-I$ac_silc_includes"
 429   fi
 430   if test "$ac_silc_libs" != "no"; then
 431     compile_libs=false
 432     LIBS="$LIBS -L$ac_silc_libs"
 433   fi
 434
 435   # Check libs to link against
 436   f=`$EGREP __SILC_HAVE_PTHREAD $ac_silc_includes/silcincludes.h`
 437   if test -n "$f"; then
 438     LIBS="$LIBS -lpthread"
 439     check_threads=false
 440     has_threads=true
 441   fi
 442   f=`$EGREP __SILC_HAVE_SIM $ac_silc_includes/silcincludes.h`
 443   if test -n "$f"; then
 444     LIBS="$LIBS -ldl"
 445   fi
 446
 447 else
 448   # pkg-config check
 449   PKG_CHECK_MODULES(SILC, silc, compile_libs=false, compile_libs=true)
 450   PKG_CHECK_MODULES(SILCCLIENT, silcclient, compile_libs=false, compile_libs=true)
 451
 452   if test x$compile_libs = xfalse; then
 453     LIBS="$LIBS $SILC_LIBS"
 454     CFLAGS="$CFLAGS $SILC_CFLAGS"
 455     LIBS="$LIBS $SILCCLIENT_LIBS"
 456     CFLAGS="$CFLAGS $SILCCLIENT_CFLAGS"
 457   fi
 458 fi
 459 #endif SILC_DIST_TOOLKIT
 460
 461 # SOCKS4 support checking
 462 #
 463 SAVE_LIBS="$LIBS"
 464 SAVE_CFLAGS="$CFLAGS"
 465 SAVE_LDFLAGS="$LDFLAGS"
 466 AC_MSG_CHECKING(whether to support SOCKS4)
 467 AC_ARG_WITH(socks4,
 468   [[  --with-socks4[=DIR]     with SOCKS4 support [search in DIR/lib and DIR/include]]],
 469   [
 470     case "$withval" in
 471       no)
 472         AC_MSG_RESULT(no)
 473         ;;
 474       *)
 475         AC_MSG_RESULT(yes)
 476         socks=4
 477
 478         if test -d "$withval/include"; then
 479           CFLAGS="$CFLAGS -I$withval/include"
 480         fi
 481         if test -d "$withval/lib"; then
 482           LDFLAGS="$LDFLAGS -L$withval/lib"
 483         fi
 484
 485         LIBS="-lsocks $LIBS"
 486         ;;
 487     esac
 488
 489     AC_TRY_LINK([],
 490       [
 491         Rconnect();
 492       ], [],
 493       [
 494         AC_MSG_ERROR(Could not find SOCKS4 library.)
 495         LIBS="$SAVE_LIBS"
 496         CFLAGS="$SAVE_CFLAGS"
 497         LDFLAGS="$SAVE_LDFLAGS"
 498       ])
 499   ],
 500     AC_MSG_RESULT(no)
 501   )
 502
 503 # SOCKS5 support checking
 504 #
 505 SAVE_LIBS="$LIBS"
 506 SAVE_CFLAGS="$CFLAGS"
 507 SAVE_LDFLAGS="$LDFLAGS"
 508 AC_MSG_CHECKING(whether to support SOCKS5)
 509 AC_ARG_WITH(socks5,
 510   [[  --with-socks5[=DIR]     with SOCKS5 support [search in DIR/lib and DIR/include]]],
 511   [
 512     case "$withval" in
 513       no)
 514         AC_MSG_RESULT(no)
 515         ;;
 516       *)
 517         AC_MSG_RESULT(yes)
 518         socks=5
 519
 520         if test -d "$withval/include"; then
 521           CFLAGS="$CFLAGS -I$withval/include"
 522         fi
 523         if test -d "$withval/lib"; then
 524           LDFLAGS="$LDFLAGS -L$withval/lib"
 525         fi
 526
 527         LIBS="-lsocks5 $LIBS"
 528         ;;
 529     esac
 530
 531     AC_TRY_LINK([],
 532       [
 533         SOCKSconnect();
 534       ], [],
 535       [
 536         AC_MSG_ERROR(Could not find SOCKS5 library.)
 537         LIBS="$SAVE_LIBS"
 538         CFLAGS="$SAVE_CFLAGS"
 539         LDFLAGS="$SAVE_LDFLAGS"
 540       ])
 541   ],
 542     AC_MSG_RESULT(no)
 543   )
 544
 545 if test "x$socks" = "x4"; then
 546   AC_DEFINE([SOCKS], [], [Socks])
 547   CFLAGS="$CFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 548 fi
 549
 550 if test "x$socks" = "x5"; then
 551   AC_DEFINE([SOCKS], [], [Socks])
 552   AC_DEFINE([SOCKS5], [], [Socks5])
 553   AC_DEFINE([Rconnect], [SOCKSconnect], [Socks])
 554   AC_DEFINE([Rgetsockname], [SOCKSgetsockname], [Socks])
 555   AC_DEFINE([Rgetpeername], [SOCKSgetpeername], [Socks])
 556   AC_DEFINE([Rbind], [SOCKSbind], [Socks])
 557   AC_DEFINE([Raccept], [SOCKSaccept], [Socks])
 558   AC_DEFINE([Rlisten], [SOCKSlisten], [Socks])
 559   AC_DEFINE([Rselect], [SOCKSselect], [Socks])
 560   AC_DEFINE([Rrecvfrom], [SOCKSrecvfrom], [Socks])
 561   AC_DEFINE([Rsendto], [SOCKSsendto], [Socks])
 562   AC_DEFINE([Rrecv], [SOCKSrecv], [Socks])
 563   AC_DEFINE([Rsend], [SOCKSsend], [Socks])
 564   AC_DEFINE([Rread], [SOCKSread], [Socks])
 565   AC_DEFINE([Rwrite], [SOCKSwrite], [Socks])
 566   AC_DEFINE([Rrresvport], [SOCKSrresvport], [Socks])
 567   AC_DEFINE([Rshutdown], [SOCKSshutdown], [Socks])
 568   AC_DEFINE([Rlisten], [SOCKSlisten], [Socks])
 569   AC_DEFINE([Rclose], [SOCKSclose], [Socks])
 570   AC_DEFINE([Rdup], [SOCKSdup], [Socks])
 571   AC_DEFINE([Rdup2], [SOCKSdup2], [Socks])
 572   AC_DEFINE([Rfclose], [SOCKSfclose], [Socks])
 573   AC_DEFINE([Rgethostbyname], [SOCKSgethostbyname], [Socks])
 574 fi
 575
 576 #ifdef SILC_DIST_MATH
 577 # MP library checking. First check whether user wants to use GMP and use
 578 # it if found. If not or not defined then compile the default library in the
 579 # source tree.
 580 #
 581 mp_gmp=false
 582 SAVE_LIBS="$LIBS"
 583 SAVE_CFLAGS="$CFLAGS"
 584 SAVE_LDFLAGS="$LDFLAGS"
 585 AC_MSG_CHECKING(whether to search for GMP)
 586 AC_ARG_WITH(gmp,
 587   [[  --with-gmp[=DIR]        use GMP instead of SILC Math [search in DIR/lib and DIR/include]]],
 588   [
 589     case "$withval" in
 590       no)
 591         AC_MSG_RESULT(no)
 592         ;;
 593       *)
 594         AC_MSG_RESULT(yes)
 595
 596         if test -d "$withval/include"; then
 597           CFLAGS="$CFLAGS -I$withval/include"
 598         fi
 599         if test -d "$withval/lib"; then
 600           LDFLAGS="$LDFLAGS -L$withval/lib"
 601         fi
 602
 603         LIBS="-lgmp $LIBS"
 604         ;;
 605     esac
 606
 607     AC_CHECK_LIB(gmp, __gmpz_init,
 608       [
 609         mp_gmp=true
 610         AC_DEFINE([SILC_MP_GMP], [], [GMP])
 611         AC_MSG_RESULT(Using GMP as a MP library.)
 612       ],
 613       [
 614         LIBS="$SAVE_LIBS"
 615         CFLAGS="$SAVE_CFLAGS"
 616         LDFLAGS="$SAVE_LDFLAGS"
 617       ])
 618   ],
 619     AC_MSG_RESULT(no)
 620   )
 621
 622 AM_CONDITIONAL(SILC_MP_GMP, test x$mp_gmp = xtrue)
 623 AM_CONDITIONAL(SILC_MP_SILCMATH, test x$mp_gmp = xfalse)
 624 if test x$mp_gmp = xfalse; then
 625   AC_DEFINE([SILC_MP_SILCMAP], [], [SILCMATH])
 626   AC_MSG_RESULT(Using SILC Math as a MP library.)
 627 fi
 628 #endif SILC_DIST_MATH
 629
 630 # iconv support
 631 #
 632 check_iconv=true
 633 has_iconv=false
 634 SAVE_LIBS="$LIBS"
 635 SAVE_CFLAGS="$CFLAGS"
 636 SAVE_LDFLAGS="$LDFLAGS"
 637 SAVE_CPPFLAGS="$CPPFLAGS"
 638 AC_MSG_CHECKING(whether to implicit search for libiconv)
 639 AC_ARG_WITH(iconv,
 640   [[  --with-iconv[=DIR]      use libiconv [search in DIR/include and DIR/lib]]],
 641   [
 642     case "${withval}" in
 643       no)
 644         AC_MSG_RESULT(no)
 645         AC_CHECK_HEADERS(iconv.h,
 646           [
 647             AC_CHECK_FUNC(iconv, has_iconv=true)
 648           ])
 649         check_iconv=false
 650         ;;
 651       *)
 652         AC_MSG_RESULT(yes)
 653         if test -d $withval/include; then
 654           CPPFLAGS="$CPPFLAGS -I$withval/include"
 655           CFLAGS="$CFLAGS -I$withval/include"
 656         fi
 657         if test -d $withval/lib; then
 658           LDFLAGS="$LDFLAGS -L$withval/lib"
 659         fi
 660         ;;
 661     esac
 662   ],
 663   [
 664     AC_MSG_RESULT(no)
 665     AC_CHECK_HEADERS(iconv.h,
 666       [
 667         AC_CHECK_FUNCS(iconv,
 668           [
 669             has_iconv=true
 670             check_iconv=false
 671           ])
 672       ])
 673   ])
 674
 675 if test x$check_iconv = xtrue; then
 676   AC_MSG_RESULT(Searching for iconv...)
 677
 678   # XXX
 679   unset ac_cv_header__iconv_h_ ac_cv_header_iconv_h || true
 680
 681   AC_CHECK_HEADERS(iconv.h,
 682     [
 683       LIBS="$LIBS -liconv"
 684       AC_MSG_CHECKING(for iconv in -liconv)
 685       AC_TRY_LINK(
 686         [
 687           #include <stdlib.h>
 688           #include <iconv.h>
 689         ],
 690         [
 691           iconv_t cd = iconv_open("", "");
 692           iconv(cd, NULL, NULL, NULL, NULL);
 693           iconv_close(cd);
 694         ],
 695         [
 696           echo "yes"
 697           AC_DEFINE([HAVE_ICONV], [], [Define if you have the iconv() function.])
 698           has_iconv=true
 699           check_iconv=false
 700         ],
 701         [
 702           echo "no"
 703           LIBS="$SAVE_LIBS"
 704           CFLAGS="$SAVE_CFLAGS"
 705           LDFLAGS="$SAVE_LDFLAGS"
 706           CPPFLAGS="$SAVE_CPPFLAGS"
 707         ])
 708      ])
 709 fi
 710
 711 if test x$check_iconv = xtrue; then
 712   # search for iconv library..
 713   SAVE_LIBS="$LIBS"
 714   SAVE_CFLAGS="$CFLAGS"
 715   SAVE_LDFLAGS="$LDFLAGS"
 716   SAVE_CPPFLAGS="$CPPFLAGS"
 717
 718   for dir in `echo "/usr/local /usr/pkg /usr/contrib"`; do
 719     if test x$has_iconv = xfalse; then
 720       AC_MSG_RESULT(searching in $dir...)
 721
 722       if test -d $dir/include; then
 723         CPPFLAGS="$CPPFLAGS -I$dir/include"
 724         CFLAGS="$CFLAGS -I$dir/include"
 725       fi
 726       if test -d $dir/lib; then
 727         LDFLAGS="$LDFLAGS -L$dir/lib"
 728       fi
 729
 730       # XXX
 731       unset ac_cv_header__iconv_h_ ac_cv_header_iconv_h || true
 732
 733       AC_CHECK_HEADERS(iconv.h,
 734         [
 735           LIBS="$LIBS -liconv"
 736           AC_MSG_CHECKING(for iconv in -liconv)
 737           AC_TRY_LINK(
 738             [
 739               #include <stdlib.h>
 740               #include <iconv.h>
 741             ],
 742             [
 743               iconv_t cd = iconv_open("", "");
 744               iconv(cd, NULL, NULL, NULL, NULL);
 745               iconv_close(cd);
 746             ],
 747             [
 748               echo "yes"
 749               has_iconv=true
 750               AC_DEFINE([HAVE_ICONV], [], [Define if you have the iconv() function.])
 751             ],
 752             [
 753               echo "no"
 754               has_iconv=false
 755
 756               LIBS="$SAVE_LIBS"
 757               CFLAGS="$SAVE_CFLAGS"
 758               LDFLAGS="$SAVE_LDFLAGS"
 759               CPPFLAGS="$SAVE_CPPFLAGS"
 760             ])
 761          ],
 762          [
 763            CFLAGS="$SAVE_CFLAGS"
 764            LDFLAGS="$SAVE_LDFLAGS"
 765            CPPFLAGS="$SAVE_CPPFLAGS"
 766          ])
 767       fi
 768     done
 769 fi
 770
 771 if test x$has_iconv = xtrue; then
 772   # (1) Some implementations of iconv won't convert from UTF-8 to UTF-8.
 773   # (2) In glibc-2.1.2 and earlier there is a bug that messes up ob and
 774   #     obl when args 2 and 3 are 0 (fixed in glibc-2.1.3).
 775   #
 776   AC_CACHE_CHECK([whether this iconv is good enough], ac_iconv_good,
 777     AC_TRY_RUN(
 778       [
 779         #include <iconv.h>
 780         int main() {
 781           iconv_t cd;
 782         changequote(, )dnl
 783           char buf[4];
 784         changequote([, ])dnl
 785           char *ob;
 786           size_t obl;
 787           ob = buf, obl = sizeof(buf);
 788           return ((cd = iconv_open("UTF-8", "UTF-8")) != (iconv_t)(-1) &&
 789                  (iconv(cd, 0, 0, &ob, &obl) ||
 790                  !(ob == buf && obl == sizeof(buf)) ||
 791                  iconv_close(cd)));
 792         }
 793       ],
 794       [
 795         ac_iconv_good=yes
 796       ],
 797       [
 798         ac_iconv_good=no
 799       ],
 800       [
 801         ac_iconv_good=yes
 802       ])
 803     )
 804
 805   if test x$ac_iconv_good = xno; then
 806     AC_MSG_RESULT(Try using libiconv instead.)
 807   fi
 808 fi
 809
 810 # POSIX threads support
 811 #
 812 AC_MSG_CHECKING(whether to search for POSIX threads)
 813 AC_ARG_WITH(pthreads,
 814   [[  --with-pthreads[=DIR]   use POSIX threads [search in DIR/include and DIR/lib]]],
 815   [
 816     case "${withval}" in
 817       no)
 818         check_threads=false
 819         ;;
 820       *)
 821         if test -d $withval/include; then
 822           CPPFLAGS="$CPPFLAGS -I$withval/include"
 823           CFLAGS="$CFLAGS -I$withval/include"
 824         fi
 825         if test -d $withval/lib; then
 826           LDFLAGS="$LDFLAGS -L$withval/lib"
 827         fi
 828
 829         check_threads=true
 830         ;;
 831     esac
 832   ])
 833
 834 if test x$check_threads = xtrue; then
 835   has_threads=false
 836   SAVE_LIBS="$LIBS"
 837   SAVE_CFLAGS="$CFLAGS"
 838   SAVE_LDFLAGS="$LDFLAGS"
 839   SAVE_CPPFLAGS="$CPPFLAGS"
 840
 841   AC_MSG_RESULT(yes)
 842   AC_CHECK_HEADERS(pthread.h,
 843     [
 844       LIBS="$LIBS -lpthread"
 845       AC_CHECK_LIB(pthread, pthread_attr_init, has_threads=true,
 846         [
 847           # FreeBSD
 848           case "${target}" in
 849             *-*-freebsd*)
 850               LIBS="$SAVE_LIBS -pthread"
 851               AC_CHECK_LIB(c_r, pthread_attr_init, has_threads=true, LIBS="$SAVE_LIBS")
 852               ;;
 853             *)
 854               LIBS="$SAVE_LIBS"
 855               ;;
 856           esac
 857         ])
 858     ],
 859     [
 860       # search for pthread library..
 861       for dir in `echo "/usr/local /usr/pkg /usr/contrib /usr/pkg/pthreads /usr/local/pthreads"`; do
 862         if test x$has_threads = xfalse; then
 863           AC_MSG_RESULT(searching in $dir...)
 864
 865           if test -d $dir/include; then
 866             CPPFLAGS="$CPPFLAGS -I$dir/include"
 867             CFLAGS="$CFLAGS -I$dir/include"
 868           fi
 869           if test -d $dir/lib; then
 870             LDFLAGS="$LDFLAGS -L$dir/lib"
 871           fi
 872
 873           # XXX
 874           unset ac_cv_header__pthread_h_ ac_cv_header_pthread_h || true
 875
 876           AC_CHECK_HEADERS(pthread.h,
 877             [
 878               LIBS="$LIBS -lpthread"
 879               AC_CHECK_LIB(pthread, pthread_attr_init, has_threads=true,
 880                 [
 881                   has_threads=false
 882
 883                   LIBS="$SAVE_LIBS"
 884                   CFLAGS="$SAVE_CFLAGS"
 885                   LDFLAGS="$SAVE_LDFLAGS"
 886                   CPPFLAGS="$SAVE_CPPFLAGS"
 887                 ])
 888             ],
 889             [
 890               CFLAGS="$SAVE_CFLAGS"
 891               LDFLAGS="$SAVE_LDFLAGS"
 892               CPPFLAGS="$SAVE_CPPFLAGS"
 893             ])
 894         fi
 895       done
 896     ])
 897 else
 898   AC_MSG_RESULT(no)
 899   has_threads=false
 900 fi
 901
 902 __SILC_HAVE_PTHREAD=""
 903 AM_CONDITIONAL(SILC_THREADS, test x$has_threads = xtrue)
 904 if test x$has_threads = xtrue; then
 905   CFLAGS="$CFLAGS -D_REENTRANT"
 906
 907   # XXX possibly incomplete
 908   case "${target}" in
 909     *-*-aix*)
 910       CFLAGS="$CFLAGS -D_THREAD_SAFE"
 911       if test x"$GCC" = xyes; then
 912         CFLAGS="$CFLAGS -mthreads"
 913       fi
 914       ;;
 915     *-*-freebsd*)
 916       CFLAGS="$CFLAGS -D_THREAD_SAFE"
 917       ;;
 918     *-*-sysv5uw7*)  # UnixWare 7
 919       if test "$GCC" != "yes"; then
 920         CFLAGS="$CFLAGS -Kthread"
 921       else
 922         CFLAGS="$CFLAGS -pthread"
 923       fi
 924       ;;
 925     *-dg-dgux*)  # DG/UX
 926       CFLAGS="$CFLAGS -D_POSIX4A_DRAFT10_SOURCE"
 927       ;;
 928    esac
 929
 930   AC_CHECK_FUNC(pthread_create)
 931   AC_DEFINE([SILC_HAVE_PTHREAD], [], [HAVE_PTHREAD])
 932   AC_DEFINE([SILC_THREADS], [], [HAVE_THREAD])
 933   __SILC_HAVE_PTHREAD="#define __SILC_HAVE_PTHREAD 1"
 934 fi
 935
 936 # Native WIN32 compilation under cygwin
 937 #
 938 AC_MSG_CHECKING(whether to compile native WIN32 code)
 939 AC_ARG_WITH(win32,
 940   [  --with-win32            compile native WIN32 (MinGW) code (-mno-cygwin)],
 941   [
 942     AC_MSG_RESULT(yes)
 943     AC_DEFINE([SILC_WIN32], [], [SILC_WIN32])
 944     win32_support=true
 945     CFLAGS="-mno-cygwin $CFLAGS"
 946     LIBS="$LIBS -lwsock32"
 947   ],
 948   [
 949     AC_MSG_RESULT(no)
 950   ])
 951 AM_CONDITIONAL(SILC_WIN32, test x$win32_support = xtrue)
 952
 953 # Native EPOC support (disabled by default)
 954 #
 955 AM_CONDITIONAL(SILC_EPOC, test xfalse = xtrue)
 956
 957 # Native BeOS support (disabled by default)
 958 #
 959 AM_CONDITIONAL(SILC_BEOS, test xfalse = xtrue)
 960
 961 # Native OS2 support (disabled by default)
 962 #
 963 AM_CONDITIONAL(SILC_OS2, test xfalse = xtrue)
 964
 965 #ifdef SILC_DIST_TOOLKIT
 966 # --without-irssi
 967 #
 968 without_irssi=false
 969 AC_MSG_CHECKING(whether to compile Irssi SILC Client)
 970 AC_ARG_WITH(irssi,
 971   [  --without-irssi         compile without Irssi SILC Client],
 972   [
 973     AC_MSG_RESULT(no)
 974     without_irssi=true
 975   ],
 976   [
 977     AC_MSG_RESULT(yes)
 978   ])
 979
 980 # --without-silcd
 981 #
 982 without_silcd=false
 983 AC_MSG_CHECKING(whether to compile SILC Server)
 984 AC_ARG_WITH(silcd,
 985   [  --without-silcd         compile without SILC Server],
 986   [
 987     AC_MSG_RESULT(no)
 988     without_silcd=true
 989   ],
 990   [
 991     AC_MSG_RESULT(yes)
 992   ])
 993 #endif SILC_DIST_TOOLKIT
 994
 995 libtoolfix=true
 996 AC_MSG_CHECKING(whether to do libtoolfix)
 997 AC_ARG_WITH(libtoolfix,
 998   [  --without-libtoolfix    Do not fix libtool, for package builders],
 999   [
1000     AC_MSG_RESULT(no)
1001     libtoolfix=false
1002   ],
1003   [
1004     AC_MSG_RESULT(yes)
1005   ])
1006
1007 AC_SUBST(ETCDIR)
1008 AC_DEFINE_UNQUOTED([SILC_ETCDIR], "$ETCDIR", [SILC_ETCDIR])
1009 #endif SILC_DIST_COMPILER
1010
1011 ##
1012 ##  Misc
1013 ##
1014
1015 # Make enable-shared aware
1016 AM_CONDITIONAL(SILC_ENABLE_SHARED, test "$enable_shared" = yes)
1017
1018 SILC_TOP_SRCDIR=`pwd`
1019
1020 # Included configure scripts
1021 AD_INCLUDE_CONFIGURE
1022
1023 #ifdef SILC_DIST_COMPILER
1024 #
1025 # Substitutions
1026 #
1027 AC_SUBST(SILC_TOP_SRCDIR)
1028 AC_SUBST(LIBS)
1029 AC_SUBST(SILC_LIB_INCLUDES)
1030 AC_SUBST(__SILC_HAVE_PTHREAD)
1031 AC_SUBST(__SILC_HAVE_SIM)
1032 AC_SUBST(__SILC_ENABLE_DEBUG)
1033
1034 #
1035 # Fix the libtool to support run-time configuration.  This allows us
1036 # to in run-time specify when to compile shared/static libraries without
1037 # need to reconfigure the entire libtool.
1038 #
1039 if test x$libtoolfix = xtrue; then
1040   ./libtoolfix $SILC_TOP_SRCDIR/ltmain.sh
1041 fi
1042 AM_CONDITIONAL(SILC_LIBTOOLFIX, test x$libtoolfix = xtrue)
1043
1044 INCLUDE_DEFINES_INT="include \$(top_srcdir)/Makefile.defines_int"
1045 AC_SUBST(INCLUDE_DEFINES_INT)
1046
1047 #endif SILC_DIST_COMPILER
1048
1049 #
1050 # Makefile outputs
1051 #
1052 AC_CONFIG_FILES(
1053 Makefile
1054 #ifdef SILC_DIST_DOC
1055 doc/Makefile
1056 #endif SILC_DIST_DOC
1057 #ifdef SILC_DIST_COMPILER
1058 Makefile.defines
1059 Makefile.defines_int
1060 includes/Makefile
1061 includes/silcversion.h
1062 includes/silcincludes.h
1063 #endif SILC_DIST_COMPILER
1064 #ifdef SILC_DIST_APPS
1065 apps/Makefile
1066 #endif SILC_DIST_APPS
1067 )
1068
1069 #ifdef SILC_DIST_TOOLKIT
1070 AC_CONFIG_FILES(
1071 win32/Makefile
1072 win32/libsilc/Makefile
1073 win32/libsilcclient/Makefile
1074 tutorial/Makefile
1075 tutorial/Makefile.defines
1076 tutorial/Makefile.defines_int
1077 )
1078 #endif SILC_DIST_TOOLKIT
1079
1080 AC_OUTPUT
1081
1082 #ifdef SILC_DIST_COMPILER
1083 s_bindir=`eval echo $bindir`;s_bindir=`eval echo $s_bindir`
1084 s_sbindir=`eval echo $sbindir`;s_sbindir=`eval echo $s_sbindir`
1085 s_mandir=`eval echo $mandir`;s_mandir=`eval echo $s_mandir`
1086 s_includedir=`eval echo $includedir`;s_includedir=`eval echo $s_includedir`
1087
1088 echo ""
1089 echo "$PACKAGE Configuration Summary:"
1090 echo "---------------------------"
1091 echo " Target host ...................: $target"
1092 echo " Compiler ......................: $CC"
1093 echo " CFLAGS ........................: $CFLAGS"
1094 echo " LDFLAGS .......................: $LDFLAGS"
1095 echo " LIBS ..........................: $LIBS"
1096 echo ""
1097 echo " Installation prefix ...........: $prefix"
1098 echo " bin directory .................: $s_bindir"
1099 echo " sbin directory ................: $s_sbindir"
1100 echo " etc directory .................: $ETCDIR"
1101 echo " man directory .................: $s_mandir"
1102 echo " doc directory .................: $DOCDIR"
1103 #ifdef SILC_DIST_CLIENT
1104 echo " help directory ................: $HELPDIR"
1105 #endif SILC_DIST_CLIENT
1106 #ifdef SILC_DIST_SERVER
1107 echo " logs directory ................: $LOGSDIR"
1108 #endif SILC_DIST_SERVER
1109 #ifdef SILC_DIST_SIM
1110 echo " SIM directory .................: $MODULESDIR"
1111 #endif SILC_DIST_SIM
1112 #ifdef SILC_DIST_INCLUDES
1113 echo " include directory .............: $s_includedir"
1114 #endif SILC_DIST_INCLUDES
1115 echo ""
1116
1117 #ifdef SILC_DIST_TOOLKIT
1118 if test x$without_irssi = xtrue; then
1119   irssi="no"
1120 fi
1121 if test x$without_silcd = xtrue; then
1122   silcd="no"
1123 fi
1124 #endif SILC_DIST_TOOLKIT
1125
1126 #ifdef SILC_DIST_CLIENT
1127 echo " Compile SILC Client ...........: $irssi"
1128 #endif SILC_DIST_CLIENT
1129
1130 #ifdef SILC_DIST_SERVER
1131 echo " Compile SILC Server ...........: $silcd"
1132 echo " Server configuration file .....: $summary_silcd_configfile"
1133 echo " Server PID file ...............: $PIDFILE"
1134 #endif SILC_DIST_SERVER
1135
1136 #ifdef SILC_DIST_SIM
1137 if test x$sim_support = xfalse; then
1138   sim_support="no"
1139 else
1140   sim_support="yes"
1141 fi
1142 echo " SIM support ...................: $sim_support"
1143 #endif SILC_DIST_SIM
1144
1145 echo " IPv6 support ..................: $summary_ipv6"
1146
1147 if test x$has_iconv = xfalse; then
1148   iconv_support="no"
1149 else
1150   iconv_support="yes"
1151 fi
1152 echo " Iconv support .................: $iconv_support"
1153
1154 if test x$want_asm = xfalse; then
1155   summary_asm="no"
1156 else
1157   summary_asm="yes"
1158 fi
1159 echo " Assembler optimizations .......: $summary_asm"
1160
1161 #ifdef SILC_DIST_MATH
1162 if test x$mp_gmp = xtrue; then
1163   echo " Arithmetic library ............: GMP"
1164 fi
1165 #endif SILC_DIST_MATH
1166
1167 threads="no"
1168 if test x$has_threads = xtrue; then
1169   threads="yes"
1170 fi
1171 echo " Multi-threads support .........: $threads"
1172 echo " Debugging enabled .............: $summary_debug"
1173 echo ""
1174 echo "Compile the sources with 'make' or 'gmake' command."
1175 #endif SILC_DIST_COMPILER
1176