configure.ad

   1 #
   2 #  configure.ad
   3 #
   4 #  Author: Pekka Riikonen <priikone@silcnet.org>
   5 #
   6 #  Copyright (C) 2000 - 2005 Pekka Riikonen
   7 #
   8 #  This program is free software; you can redistribute it and/or modify
   9 #  it under the terms of the GNU General Public License as published by
  10 #  the Free Software Foundation; version 2 of the License.
  11 #
  12 #  This program is distributed in the hope that it will be useful,
  13 #  but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #  GNU General Public License for more details.
  16 #
  17
  18 AD_INIT
  19 AC_CANONICAL_SYSTEM
  20 AM_INIT_AUTOMAKE
  21 AC_PREREQ(2.52)
  22 AC_CONFIG_HEADERS(silcdefs.h)
  23
  24 AC_PROG_INSTALL
  25 AC_PROG_MAKE_SET
  26
  27 AC_PROG_LN_S
  28 AC_PROG_EGREP
  29 AC_SUBST(LN_S)
  30 AC_PATH_PROG(sedpath, sed)
  31
  32 #ifdef SILC_DIST_COMPILER
  33 # Put here any platform specific stuff
  34 #
  35 case "$target" in
  36   *-*-freebsd*)
  37     check_threads=true
  38     ;;
  39   *-*-*bsd*)
  40     check_threads=false
  41     ;;
  42   *)
  43     check_threads=true
  44     ;;
  45 esac
  46
  47 CFLAGS=
  48 AC_PROG_CC
  49 AC_C_INLINE
  50 AC_C_CONST
  51
  52 __SILC_HAVE_PTHREAD=""
  53 __SILC_HAVE_SIM=""
  54 __SILC_ENABLE_DEBUG=""
  55
  56 AC_PROG_RANLIB
  57 AC_DISABLE_SHARED
  58 AC_PROG_LIBTOOL
  59
  60 # Header checking
  61 #
  62 AC_HEADER_STDC
  63 AC_HEADER_TIME
  64 AC_HEADER_STAT
  65
  66 # More header checking
  67 #
  68 AC_CHECK_HEADERS(unistd.h string.h getopt.h errno.h fcntl.h assert.h)
  69 AC_CHECK_HEADERS(sys/types.h sys/stat.h sys/time.h stddef.h)
  70 AC_CHECK_HEADERS(netinet/in.h netinet/tcp.h xti.h netdb.h sys/resource.h)
  71 AC_CHECK_HEADERS(pwd.h grp.h termcap.h paths.h)
  72 AC_CHECK_HEADERS(ncurses.h signal.h ctype.h utime.h)
  73 AC_CHECK_HEADERS(arpa/inet.h sys/mman.h limits.h termios.h locale.h langinfo.h)
  74
  75 # Data type checking
  76 #
  77 AC_TYPE_SIGNAL
  78 AC_TYPE_SIZE_T
  79 AC_TYPE_MODE_T
  80 AC_TYPE_UID_T
  81 AC_TYPE_PID_T
  82
  83 AC_CHECK_SIZEOF(long long, 0)
  84 AC_SUBST(SILC_SIZEOF_LONG_LONG, $ac_cv_sizeof_long_long)
  85 AC_CHECK_SIZEOF(long, 0)
  86 AC_SUBST(SILC_SIZEOF_LONG, $ac_cv_sizeof_long)
  87 AC_CHECK_SIZEOF(int, 0)
  88 AC_SUBST(SILC_SIZEOF_INT, $ac_cv_sizeof_int)
  89 AC_CHECK_SIZEOF(short, 0)
  90 AC_SUBST(SILC_SIZEOF_SHORT, $ac_cv_sizeof_short)
  91 AC_CHECK_SIZEOF(char, 0)
  92 AC_SUBST(SILC_SIZEOF_CHAR, $ac_cv_sizeof_char)
  93 AC_CHECK_SIZEOF(void *, 0)
  94 AC_SUBST(SILC_SIZEOF_VOID_P, $ac_cv_sizeof_void_p)
  95
  96 # Function and library checking
  97 #
  98 AC_CHECK_FUNC(gethostbyname, [],
  99   [
 100     AC_CHECK_LIB(nsl, gethostbyname, LIBS="$LIBS -lnsl")
 101     AC_CHECK_FUNC(res_gethostbyname, [],
 102        AC_CHECK_LIB(resolv, res_gethostbyname, LIBS="$LIBS -lresolv")
 103     )
 104   ])
 105 AC_CHECK_FUNC(socket, [],
 106   AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
 107 )
 108 AC_CHECK_FUNCS(gethostname gethostbyaddr getservbyname getservbyport)
 109 AC_CHECK_FUNCS(select listen bind shutdown close connect setsockopt)
 110 AC_CHECK_FUNCS(time ctime utime gettimeofday getrusage)
 111 AC_CHECK_FUNCS(chmod fcntl stat fstat getenv putenv strerror)
 112 AC_CHECK_FUNCS(getpid getgid getsid getpgid getpgrp getuid)
 113 AC_CHECK_FUNCS(setgroups initgroups nl_langinfo)
 114 AC_CHECK_FUNCS(strchr strstr strcpy strncpy memcpy memset memmove)
 115
 116 #ifdef SILC_DIST_SIM
 117 # SIM support checking
 118 # XXX These needs to be changed as more supported platforms appear.
 119 # XXX This probably needs to be made platform dependant check.
 120 #
 121 sim_support=false
 122 AC_MSG_CHECKING(for SIM support)
 123 AC_MSG_RESULT()
 124 AC_CHECK_HEADERS(dlfcn.h,
 125   [
 126     AC_CHECK_LIB(dl, dlopen,
 127       [
 128         AC_DEFINE([SILC_SIM], [], [HAVE_SIM])
 129         sim_support=true
 130         LIBS="$LIBS -ldl"
 131       ],
 132       [
 133         AC_CHECK_LIB(c, dlopen,
 134           [
 135             AC_DEFINE([SILC_SIM], [], [HAVE_SIM])
 136             sim_support=true
 137           ])
 138       ])
 139    ])
 140
 141 AM_CONDITIONAL(SILC_SIM, test x$sim_support = xtrue)
 142 if test x$sim_support = xtrue; then
 143   AC_MSG_RESULT(Enabled SIM support.)
 144   __SILC_HAVE_SIM="#define __SILC_HAVE_SIM 1"
 145 else
 146   AC_MSG_RESULT(No SIM support found.)
 147 fi
 148 #endif SILC_DIST_SIM
 149
 150 # lib/contrib conditionals
 151 #
 152 AC_CHECK_HEADER(regex.h,
 153   [
 154     AC_DEFINE([HAVE_REGEX], [], [HAVE_REGEX])
 155     have_regex=1
 156   ], have_regex=0
 157 )
 158 AM_CONDITIONAL(HAVE_REGEX, test x$have_regex = x1)
 159
 160 AC_CHECK_FUNC(getopt_long,
 161   [
 162     AC_DEFINE([HAVE_GETOPT_LONG], [], [HAVE_GETOPT_LONG])
 163     have_getopt_long=1
 164   ], have_getopt_long=0
 165 )
 166 AM_CONDITIONAL(HAVE_GETOPT_LONG, test x$have_getopt_long = x1)
 167
 168 ##
 169 ##  Enable/disable checking
 170 ##
 171
 172 # IPv6 support
 173 #
 174 AC_MSG_CHECKING(whether to enable IPv6 support)
 175 AC_ARG_ENABLE(ipv6,
 176   [  --enable-ipv6           enable IPv6 support],
 177   [
 178     case "${enableval}" in
 179       yes)
 180         want_ipv6=true
 181         check_ipv6=false
 182         summary_ipv6="yes"
 183         AC_DEFINE([HAVE_IPV6], [], [HAVE_IPV6])
 184         AC_MSG_RESULT(yes)
 185         ;;
 186       *)
 187         want_ipv6=false
 188         check_ipv6=false
 189         summary_ipv6="no"
 190         AC_MSG_RESULT(no)
 191         ;;
 192     esac
 193   ],
 194     check_ipv6=true
 195   )
 196
 197 if test x$check_ipv6 = xtrue; then
 198   summary_ipv6="no"
 199   AC_TRY_COMPILE(
 200     [
 201       #ifdef HAVE_SYS_TYPES_H
 202       #include <sys/types.h>
 203       #endif
 204       #ifdef HAVE_NETINET_TCP_H
 205       #include <netinet/tcp.h>
 206       #endif
 207       #ifdef HAVE_NETDB_H
 208       #include <netdb.h>
 209       #endif
 210       #include <sys/socket.h>
 211       #ifdef HAVE_NETINET_IN_H
 212       #include <netinet/in.h>
 213       #endif
 214     ],
 215     [
 216       struct sockaddr_in6 sin6;
 217       int family = AF_INET6;
 218     ],
 219     [
 220       AC_DEFINE([HAVE_IPV6], [], [HAVE_IPV6])
 221       AC_MSG_RESULT(yes)
 222       summary_ipv6="yes"
 223     ],
 224       AC_MSG_RESULT(no)
 225     )
 226 fi
 227
 228 # Debug checking
 229 #
 230 AC_MSG_CHECKING(whether to enable debugging)
 231 summary_debug="no"
 232 __SILC_ENABLE_DEBUG=""
 233 AC_ARG_ENABLE(debug,
 234   [  --enable-debug          enable debugging],
 235   [
 236     case "${enableval}" in
 237       yes)
 238         AC_MSG_RESULT(yes)
 239         AC_DEFINE([SILC_DEBUG], [], [enable-debug])
 240         summary_debug="yes"
 241         __SILC_ENABLE_DEBUG="#define __SILC_ENABLE_DEBUG 1"
 242         ;;
 243       *)
 244         AC_MSG_RESULT(no)
 245         ;;
 246     esac
 247   ],
 248   [
 249     AC_MSG_RESULT(no)
 250   ])
 251
 252 # Disable all assembler optimizations
 253 #
 254 AC_MSG_CHECKING(whether to enable assembler optimizations)
 255 want_asm=true
 256 AC_ARG_ENABLE(asm,
 257   [  --disable-asm           do not use assembler optimizations],
 258   [
 259     AC_MSG_RESULT(no)
 260     want_asm=false
 261   ],
 262   [
 263     AC_MSG_RESULT(yes)
 264     want_asm=true
 265   ])
 266
 267 ##
 268 ## Compiler and compiler flag checks
 269 ##
 270
 271 # Function to check if compiler flag works
 272 # Usage: SILC_ADD_CFLAGS(FLAGS, [ACTION-IF-FAILED])
 273 AC_DEFUN([SILC_ADD_CFLAGS],
 274 [ tmp_CFLAGS="$CFLAGS"
 275   CFLAGS="$CFLAGS $1"
 276   AC_MSG_CHECKING(whether $CC accepts $1 flag)
 277   AC_TRY_LINK([], [], [AC_MSG_RESULT(yes)], [AC_MSG_RESULT(no)
 278                                        CFLAGS="$tmp_CFLAGS"
 279                                        $2])
 280   unset tmp_CFLAGS
 281 ])
 282
 283 if test "$GCC"; then
 284   # GCC specific options
 285   if test "x$summary_debug" = "xyes"; then
 286     SILC_ADD_CFLAGS(-g -O)
 287   else
 288     SILC_ADD_CFLAGS(-g -O2)
 289   fi
 290   SILC_ADD_CFLAGS(-Wall -finline-functions)
 291 else
 292   # Other compilers
 293   case "$target" in
 294     alpha*-dec-osf*)
 295       SILC_ADD_CFLAGS(-g3 -O2, SILC_ADD_CFLAGS(-g3 -O, SILC_ADD_CFLAGS(-O)))
 296       ;;
 297     *)
 298       SILC_ADD_CFLAGS(-g)
 299       SILC_ADD_CFLAGS(-O2, SILC_ADD_CFLAGS(-O))
 300       ;;
 301   esac
 302
 303   # Intel C++ Compiler needs -restrict
 304   if test "x$CC" = "xicc"; then
 305     SILC_ADD_CFLAGS(-restrict)
 306   fi
 307 fi
 308
 309 #
 310 # Workaround a bug in GCC 2.x which causes memory exhaustion
 311 # when compiling sha1 with optimizations on UltraSPARC.
 312 #
 313 FIX_SHA1='#'
 314 if test "$GCC" -a "$host_cpu" = "sparc64"; then
 315   AC_MSG_CHECKING(whether to enable GCC 2.x workaround for SHA1)
 316   AC_TRY_COMPILE(
 317     [
 318       #if defined(__sparc64__) && (__GNUC__ == 2)
 319       #else
 320       choke me
 321       #endif
 322     ],
 323     [],
 324     [
 325       FIX_SHA1=''
 326       AC_MSG_RESULT(yes)
 327     ],
 328       AC_MSG_RESULT(no)
 329     )
 330 fi
 331 AC_SUBST(FIX_SHA1)
 332 #endif SILC_DIST_COMPILER
 333
 334 ##
 335 ##  Installation
 336 ##
 337
 338 # Default installation destination
 339 #
 340 #ifdef SILC_DIST_AUTODIST
 341 AC_PREFIX_DEFAULT(/usr/local)
 342 #else !SILC_DIST_AUTODIST
 343 AC_PREFIX_DEFAULT(/usr/local/silc)
 344 #endif SILC_DIST_AUTODIST
 345 if test "x$prefix" != xNONE; then
 346   silc_prefix="$prefix"
 347 else
 348   silc_prefix="$ac_default_prefix"
 349 fi
 350
 351 #ifndef SILC_DIST_AUTODIST
 352 # etc directory
 353 #
 354 if test "x$sysconfdir" != 'x${prefix}/etc'; then
 355   ETCDIR="$sysconfdir"
 356 else
 357   ETCDIR="$silc_prefix/etc"
 358 fi
 359
 360 AC_ARG_WITH(etcdir,
 361   [[  --with-etcdir=DIR       directory for system files [/etc/silc]]],
 362   [
 363     case "$withval" in
 364       no|yes)
 365         ;;
 366       *)
 367         ETCDIR="$withval"
 368         ;;
 369     esac
 370   ])
 371 AC_SUBST(ETCDIR)
 372 AC_DEFINE_UNQUOTED([SILC_ETCDIR], "$ETCDIR", [SILC_ETCDIR])
 373
 374 # doc directory
 375 #
 376 DOCDIR="$silc_prefix/doc"
 377 AC_ARG_WITH(docdir,
 378   [[  --with-docdir=DIR       directory for SILC documentation [PREFIX/doc]]],
 379   [
 380     case "$withval" in
 381       no|yes)
 382         ;;
 383       *)
 384         DOCDIR="$withval"
 385         ;;
 386     esac
 387   ])
 388 AC_SUBST(DOCDIR)
 389 AC_DEFINE_UNQUOTED([SILC_DOCDIR], "$DOCDIR", [SILC_DOCDIR])
 390 #endif SILC_DIST_AUTODIST
 391
 392 #ifdef SILC_DIST_CLIENT
 393 # help directory
 394 #
 395 HELPDIR="$silc_prefix/help"
 396 AC_ARG_WITH(helpdir,
 397   [[  --with-helpdir=DIR      directory for SILC help files [PREFIX/help]]],
 398   [
 399     case "$withval" in
 400       no|yes)
 401         ;;
 402       *)
 403        HELPDIR="$withval"
 404        ;;
 405     esac
 406   ])
 407 AC_SUBST(HELPDIR)
 408 AC_DEFINE_UNQUOTED([SILC_HELPDIR], "$HELPDIR", [SILC_HELPDIR])
 409 #endif SILC_DIST_CLIENT
 410
 411 #ifdef SILC_DIST_SIM
 412 # SIM modules directory
 413 #
 414 MODULESDIR="$silc_prefix/modules"
 415 AC_ARG_WITH(simdir,
 416   [[  --with-simdir=DIR       directory for SIM modules [PREFIX/modules]]],
 417   [
 418     case "$withval" in
 419       no|yes)
 420         ;;
 421       *)
 422         MODULESDIR="$withval"
 423         ;;
 424     esac
 425   ])
 426 AC_SUBST(MODULESDIR)
 427 AC_DEFINE_UNQUOTED([SILC_MODULESDIR], "$MODULESDIR", [SILC_MODULESDIR])
 428 #endif SILC_DIST_SIM
 429
 430 #ifdef SILC_DIST_COMPILER
 431 ##
 432 ##  With/without checkings
 433 ##
 434
 435 #
 436 # SILC library checking
 437 compile_libs=true
 438
 439 #ifndef SILC_DIST_TOOLKIT
 440 AC_ARG_WITH(silc-includes,
 441   [  --with-silc-includes=DIR SILC Toolkit includes [search in DIR]],
 442   [ac_silc_includes="$withval"], [ac_silc_includes="no"])
 443 AC_ARG_WITH(silc-libs,
 444   [  --with-silc-libs=DIR     SILC Toolkit libraries [search in DIR]],
 445   [ac_silc_libs="$withval"], [ac_silc_libs="no"])
 446
 447 if test -n "$with_silc_includes" || test -n "$with_silc_libs"; then
 448
 449   # Manually provided libs
 450   if test "$ac_silc_includes" != "no"; then
 451     compile_libs=false
 452     SILC_LIB_INCLUDES="-I$ac_silc_includes"
 453   fi
 454   if test "$ac_silc_libs" != "no"; then
 455     compile_libs=false
 456     LIBS="$LIBS -L$ac_silc_libs"
 457   fi
 458
 459   # Check libs to link against
 460   f=`$EGREP __SILC_HAVE_PTHREAD $ac_silc_includes/silcincludes.h`
 461   if test -n "$f"; then
 462     LIBS="$LIBS -lpthread"
 463     check_threads=false
 464     has_threads=true
 465   fi
 466   f=`$EGREP __SILC_HAVE_SIM $ac_silc_includes/silcincludes.h`
 467   if test -n "$f"; then
 468     LIBS="$LIBS -ldl"
 469   fi
 470
 471 else
 472   # pkg-config check
 473   PKG_CHECK_MODULES(SILC, silc, compile_libs=false, compile_libs=true)
 474   PKG_CHECK_MODULES(SILCCLIENT, silcclient, compile_libs=false, compile_libs=true)
 475
 476   if test x$compile_libs = xfalse; then
 477     LIBS="$LIBS $SILC_LIBS"
 478     CFLAGS="$CFLAGS $SILC_CFLAGS"
 479     LIBS="$LIBS $SILCCLIENT_LIBS"
 480     CFLAGS="$CFLAGS $SILCCLIENT_CFLAGS"
 481   fi
 482 fi
 483 #endif SILC_DIST_TOOLKIT
 484
 485 # SOCKS4 support checking
 486 #
 487 SAVE_LIBS="$LIBS"
 488 SAVE_CFLAGS="$CFLAGS"
 489 SAVE_LDFLAGS="$LDFLAGS"
 490 AC_MSG_CHECKING(whether to support SOCKS4)
 491 AC_ARG_WITH(socks4,
 492   [[  --with-socks4[=DIR]     with SOCKS4 support [search in DIR/lib and DIR/include]]],
 493   [
 494     case "$withval" in
 495       no)
 496         AC_MSG_RESULT(no)
 497         ;;
 498       *)
 499         AC_MSG_RESULT(yes)
 500         socks=4
 501
 502         if test -d "$withval/include"; then
 503           CFLAGS="$CFLAGS -I$withval/include"
 504         fi
 505         if test -d "$withval/lib"; then
 506           LDFLAGS="$LDFLAGS -L$withval/lib"
 507         fi
 508
 509         LIBS="-lsocks $LIBS"
 510         ;;
 511     esac
 512
 513     AC_TRY_LINK([],
 514       [
 515         Rconnect();
 516       ], [],
 517       [
 518         AC_MSG_ERROR(Could not find SOCKS4 library.)
 519         LIBS="$SAVE_LIBS"
 520         CFLAGS="$SAVE_CFLAGS"
 521         LDFLAGS="$SAVE_LDFLAGS"
 522       ])
 523   ],
 524     AC_MSG_RESULT(no)
 525   )
 526
 527 # SOCKS5 support checking
 528 #
 529 SAVE_LIBS="$LIBS"
 530 SAVE_CFLAGS="$CFLAGS"
 531 SAVE_LDFLAGS="$LDFLAGS"
 532 AC_MSG_CHECKING(whether to support SOCKS5)
 533 AC_ARG_WITH(socks5,
 534   [[  --with-socks5[=DIR]     with SOCKS5 support [search in DIR/lib and DIR/include]]],
 535   [
 536     case "$withval" in
 537       no)
 538         AC_MSG_RESULT(no)
 539         ;;
 540       *)
 541         AC_MSG_RESULT(yes)
 542         socks=5
 543
 544         if test -d "$withval/include"; then
 545           CFLAGS="$CFLAGS -I$withval/include"
 546         fi
 547         if test -d "$withval/lib"; then
 548           LDFLAGS="$LDFLAGS -L$withval/lib"
 549         fi
 550
 551         LIBS="-lsocks5 $LIBS"
 552         ;;
 553     esac
 554
 555     AC_TRY_LINK([],
 556       [
 557         SOCKSconnect();
 558       ], [],
 559       [
 560         AC_MSG_ERROR(Could not find SOCKS5 library.)
 561         LIBS="$SAVE_LIBS"
 562         CFLAGS="$SAVE_CFLAGS"
 563         LDFLAGS="$SAVE_LDFLAGS"
 564       ])
 565   ],
 566     AC_MSG_RESULT(no)
 567   )
 568
 569 if test "x$socks" = "x4"; then
 570   AC_DEFINE([SOCKS], [], [Socks])
 571   CFLAGS="$CFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 572 fi
 573
 574 if test "x$socks" = "x5"; then
 575   AC_DEFINE([SOCKS], [], [Socks])
 576   AC_DEFINE([SOCKS5], [], [Socks5])
 577   AC_DEFINE([Rconnect], [SOCKSconnect], [Socks])
 578   AC_DEFINE([Rgetsockname], [SOCKSgetsockname], [Socks])
 579   AC_DEFINE([Rgetpeername], [SOCKSgetpeername], [Socks])
 580   AC_DEFINE([Rbind], [SOCKSbind], [Socks])
 581   AC_DEFINE([Raccept], [SOCKSaccept], [Socks])
 582   AC_DEFINE([Rlisten], [SOCKSlisten], [Socks])
 583   AC_DEFINE([Rselect], [SOCKSselect], [Socks])
 584   AC_DEFINE([Rrecvfrom], [SOCKSrecvfrom], [Socks])
 585   AC_DEFINE([Rsendto], [SOCKSsendto], [Socks])
 586   AC_DEFINE([Rrecv], [SOCKSrecv], [Socks])
 587   AC_DEFINE([Rsend], [SOCKSsend], [Socks])
 588   AC_DEFINE([Rread], [SOCKSread], [Socks])
 589   AC_DEFINE([Rwrite], [SOCKSwrite], [Socks])
 590   AC_DEFINE([Rrresvport], [SOCKSrresvport], [Socks])
 591   AC_DEFINE([Rshutdown], [SOCKSshutdown], [Socks])
 592   AC_DEFINE([Rlisten], [SOCKSlisten], [Socks])
 593   AC_DEFINE([Rclose], [SOCKSclose], [Socks])
 594   AC_DEFINE([Rdup], [SOCKSdup], [Socks])
 595   AC_DEFINE([Rdup2], [SOCKSdup2], [Socks])
 596   AC_DEFINE([Rfclose], [SOCKSfclose], [Socks])
 597   AC_DEFINE([Rgethostbyname], [SOCKSgethostbyname], [Socks])
 598 fi
 599
 600 #ifdef SILC_DIST_MATH
 601 # MP library checking. First check whether user wants to use GMP and use
 602 # it if found. If not or not defined then compile the MPI library in the
 603 # source tree.
 604 #
 605 mp_gmp=false
 606 SAVE_LIBS="$LIBS"
 607 SAVE_CFLAGS="$CFLAGS"
 608 SAVE_LDFLAGS="$LDFLAGS"
 609 AC_MSG_CHECKING(whether to search for GMP)
 610 AC_ARG_WITH(gmp,
 611   [[  --with-gmp[=DIR]        use GMP instead of MPI [search in DIR/lib and DIR/include]]],
 612   [
 613     case "$withval" in
 614       no)
 615         AC_MSG_RESULT(no)
 616         ;;
 617       *)
 618         AC_MSG_RESULT(yes)
 619
 620         if test -d "$withval/include"; then
 621           CFLAGS="$CFLAGS -I$withval/include"
 622         fi
 623         if test -d "$withval/lib"; then
 624           LDFLAGS="$LDFLAGS -L$withval/lib"
 625         fi
 626
 627         LIBS="-lgmp $LIBS"
 628         ;;
 629     esac
 630
 631     AC_CHECK_LIB(gmp, __gmpz_init,
 632       [
 633         mp_gmp=true
 634         AC_DEFINE([SILC_MP_GMP], [], [GMP])
 635         AC_MSG_RESULT(Using GMP as a MP library.)
 636       ],
 637       [
 638         LIBS="$SAVE_LIBS"
 639         CFLAGS="$SAVE_CFLAGS"
 640         LDFLAGS="$SAVE_LDFLAGS"
 641       ])
 642   ],
 643     AC_MSG_RESULT(no)
 644   )
 645
 646 AM_CONDITIONAL(SILC_MP_GMP, test x$mp_gmp = xtrue)
 647 AM_CONDITIONAL(SILC_MP_NSS_MPI, test x$mp_gmp = xfalse)
 648 if test x$mp_gmp = xfalse; then
 649   AC_DEFINE([SILC_MP_NSS_MPI], [], [MPI])
 650   AC_MSG_RESULT(Using NSS MPI as a MP library.)
 651 fi
 652 #endif SILC_DIST_MATH
 653
 654 # iconv support
 655 #
 656 check_iconv=true
 657 has_iconv=false
 658 SAVE_LIBS="$LIBS"
 659 SAVE_CFLAGS="$CFLAGS"
 660 SAVE_LDFLAGS="$LDFLAGS"
 661 SAVE_CPPFLAGS="$CPPFLAGS"
 662 AC_MSG_CHECKING(whether to implicit search for libiconv)
 663 AC_ARG_WITH(iconv,
 664   [[  --with-iconv[=DIR]      use libiconv [search in DIR/include and DIR/lib]]],
 665   [
 666     case "${withval}" in
 667       no)
 668         AC_MSG_RESULT(no)
 669         AC_CHECK_HEADERS(iconv.h,
 670           [
 671             AC_CHECK_FUNC(iconv, has_iconv=true)
 672           ])
 673         check_iconv=false
 674         ;;
 675       *)
 676         AC_MSG_RESULT(yes)
 677         if test -d $withval/include; then
 678           CPPFLAGS="$CPPFLAGS -I$withval/include"
 679           CFLAGS="$CFLAGS -I$withval/include"
 680         fi
 681         if test -d $withval/lib; then
 682           LDFLAGS="$LDFLAGS -L$withval/lib"
 683         fi
 684         ;;
 685     esac
 686   ],
 687   [
 688     AC_MSG_RESULT(no)
 689     AC_CHECK_HEADERS(iconv.h,
 690       [
 691         AC_CHECK_FUNCS(iconv,
 692           [
 693             has_iconv=true
 694             check_iconv=false
 695           ])
 696       ])
 697   ])
 698
 699 if test x$check_iconv = xtrue; then
 700   AC_MSG_RESULT(Searching for iconv...)
 701
 702   # XXX
 703   unset ac_cv_header__iconv_h_ ac_cv_header_iconv_h || true
 704
 705   AC_CHECK_HEADERS(iconv.h,
 706     [
 707       LIBS="$LIBS -liconv"
 708       AC_MSG_CHECKING(for iconv in -liconv)
 709       AC_TRY_LINK(
 710         [
 711           #include <stdlib.h>
 712           #include <iconv.h>
 713         ],
 714         [
 715           iconv_t cd = iconv_open("", "");
 716           iconv(cd, NULL, NULL, NULL, NULL);
 717           iconv_close(cd);
 718         ],
 719         [
 720           echo "yes"
 721           AC_DEFINE([HAVE_ICONV], [], [Define if you have the iconv() function.])
 722           has_iconv=true
 723           check_iconv=false
 724         ],
 725         [
 726           echo "no"
 727           LIBS="$SAVE_LIBS"
 728           CFLAGS="$SAVE_CFLAGS"
 729           LDFLAGS="$SAVE_LDFLAGS"
 730           CPPFLAGS="$SAVE_CPPFLAGS"
 731         ])
 732      ])
 733 fi
 734
 735 if test x$check_iconv = xtrue; then
 736   # search for iconv library..
 737   SAVE_LIBS="$LIBS"
 738   SAVE_CFLAGS="$CFLAGS"
 739   SAVE_LDFLAGS="$LDFLAGS"
 740   SAVE_CPPFLAGS="$CPPFLAGS"
 741
 742   for dir in `echo "/usr/local /usr/pkg /usr/contrib"`; do
 743     if test x$has_iconv = xfalse; then
 744       AC_MSG_RESULT(searching in $dir...)
 745
 746       if test -d $dir/include; then
 747         CPPFLAGS="$CPPFLAGS -I$dir/include"
 748         CFLAGS="$CFLAGS -I$dir/include"
 749       fi
 750       if test -d $dir/lib; then
 751         LDFLAGS="$LDFLAGS -L$dir/lib"
 752       fi
 753
 754       # XXX
 755       unset ac_cv_header__iconv_h_ ac_cv_header_iconv_h || true
 756
 757       AC_CHECK_HEADERS(iconv.h,
 758         [
 759           LIBS="$LIBS -liconv"
 760           AC_MSG_CHECKING(for iconv in -liconv)
 761           AC_TRY_LINK(
 762             [
 763               #include <stdlib.h>
 764               #include <iconv.h>
 765             ],
 766             [
 767               iconv_t cd = iconv_open("", "");
 768               iconv(cd, NULL, NULL, NULL, NULL);
 769               iconv_close(cd);
 770             ],
 771             [
 772               echo "yes"
 773               has_iconv=true
 774               AC_DEFINE([HAVE_ICONV], [], [Define if you have the iconv() function.])
 775             ],
 776             [
 777               echo "no"
 778               has_iconv=false
 779
 780               LIBS="$SAVE_LIBS"
 781               CFLAGS="$SAVE_CFLAGS"
 782               LDFLAGS="$SAVE_LDFLAGS"
 783               CPPFLAGS="$SAVE_CPPFLAGS"
 784             ])
 785          ],
 786          [
 787            CFLAGS="$SAVE_CFLAGS"
 788            LDFLAGS="$SAVE_LDFLAGS"
 789            CPPFLAGS="$SAVE_CPPFLAGS"
 790          ])
 791       fi
 792     done
 793 fi
 794
 795 if test x$has_iconv = xtrue; then
 796   # (1) Some implementations of iconv won't convert from UTF-8 to UTF-8.
 797   # (2) In glibc-2.1.2 and earlier there is a bug that messes up ob and
 798   #     obl when args 2 and 3 are 0 (fixed in glibc-2.1.3).
 799   #
 800   AC_CACHE_CHECK([whether this iconv is good enough], ac_iconv_good,
 801     AC_TRY_RUN(
 802       [
 803         #include <iconv.h>
 804         int main() {
 805           iconv_t cd;
 806         changequote(, )dnl
 807           char buf[4];
 808         changequote([, ])dnl
 809           char *ob;
 810           size_t obl;
 811           ob = buf, obl = sizeof(buf);
 812           return ((cd = iconv_open("UTF-8", "UTF-8")) != (iconv_t)(-1) &&
 813                  (iconv(cd, 0, 0, &ob, &obl) ||
 814                  !(ob == buf && obl == sizeof(buf)) ||
 815                  iconv_close(cd)));
 816         }
 817       ],
 818       [
 819         ac_iconv_good=yes
 820       ],
 821       [
 822         ac_iconv_good=no
 823       ],
 824       [
 825         ac_iconv_good=yes
 826       ])
 827     )
 828
 829   if test x$ac_iconv_good = xno; then
 830     AC_MSG_RESULT(Try using libiconv instead.)
 831   fi
 832 fi
 833
 834 # POSIX threads support
 835 #
 836 AC_MSG_CHECKING(whether to search for POSIX threads)
 837 AC_ARG_WITH(pthreads,
 838   [[  --with-pthreads[=DIR]   use POSIX threads [search in DIR/include and DIR/lib]]],
 839   [
 840     case "${withval}" in
 841       no)
 842         check_threads=false
 843         ;;
 844       *)
 845         if test -d $withval/include; then
 846           CPPFLAGS="$CPPFLAGS -I$withval/include"
 847           CFLAGS="$CFLAGS -I$withval/include"
 848         fi
 849         if test -d $withval/lib; then
 850           LDFLAGS="$LDFLAGS -L$withval/lib"
 851         fi
 852
 853         check_threads=true
 854         ;;
 855     esac
 856   ])
 857
 858 if test x$check_threads = xtrue; then
 859   has_threads=false
 860   SAVE_LIBS="$LIBS"
 861   SAVE_CFLAGS="$CFLAGS"
 862   SAVE_LDFLAGS="$LDFLAGS"
 863   SAVE_CPPFLAGS="$CPPFLAGS"
 864
 865   AC_MSG_RESULT(yes)
 866   AC_CHECK_HEADERS(pthread.h,
 867     [
 868       LIBS="$LIBS -lpthread"
 869       AC_CHECK_LIB(pthread, pthread_attr_init, has_threads=true,
 870         [
 871           # FreeBSD
 872           case "${target}" in
 873             *-*-freebsd*)
 874               LIBS="$SAVE_LIBS -pthread"
 875               AC_CHECK_LIB(c_r, pthread_attr_init, has_threads=true, LIBS="$SAVE_LIBS")
 876               ;;
 877             *)
 878               LIBS="$SAVE_LIBS"
 879               ;;
 880           esac
 881         ])
 882     ],
 883     [
 884       # search for pthread library..
 885       for dir in `echo "/usr/local /usr/pkg /usr/contrib /usr/pkg/pthreads /usr/local/pthreads"`; do
 886         if test x$has_threads = xfalse; then
 887           AC_MSG_RESULT(searching in $dir...)
 888
 889           if test -d $dir/include; then
 890             CPPFLAGS="$CPPFLAGS -I$dir/include"
 891             CFLAGS="$CFLAGS -I$dir/include"
 892           fi
 893           if test -d $dir/lib; then
 894             LDFLAGS="$LDFLAGS -L$dir/lib"
 895           fi
 896
 897           # XXX
 898           unset ac_cv_header__pthread_h_ ac_cv_header_pthread_h || true
 899
 900           AC_CHECK_HEADERS(pthread.h,
 901             [
 902               LIBS="$LIBS -lpthread"
 903               AC_CHECK_LIB(pthread, pthread_attr_init, has_threads=true,
 904                 [
 905                   has_threads=false
 906
 907                   LIBS="$SAVE_LIBS"
 908                   CFLAGS="$SAVE_CFLAGS"
 909                   LDFLAGS="$SAVE_LDFLAGS"
 910                   CPPFLAGS="$SAVE_CPPFLAGS"
 911                 ])
 912             ],
 913             [
 914               CFLAGS="$SAVE_CFLAGS"
 915               LDFLAGS="$SAVE_LDFLAGS"
 916               CPPFLAGS="$SAVE_CPPFLAGS"
 917             ])
 918         fi
 919       done
 920     ])
 921 else
 922   AC_MSG_RESULT(no)
 923   has_threads=false
 924 fi
 925
 926 __SILC_HAVE_PTHREAD=""
 927 AM_CONDITIONAL(SILC_THREADS, test x$has_threads = xtrue)
 928 if test x$has_threads = xtrue; then
 929   CFLAGS="$CFLAGS -D_REENTRANT"
 930
 931   # XXX possibly incomplete
 932   case "${target}" in
 933     *-*-aix*)
 934       CFLAGS="$CFLAGS -D_THREAD_SAFE"
 935       if test x"$GCC" = xyes; then
 936         CFLAGS="$CFLAGS -mthreads"
 937       fi
 938       ;;
 939     *-*-freebsd*)
 940       CFLAGS="$CFLAGS -D_THREAD_SAFE"
 941       ;;
 942     *-*-sysv5uw7*)  # UnixWare 7
 943       if test "$GCC" != "yes"; then
 944         CFLAGS="$CFLAGS -Kthread"
 945       else
 946         CFLAGS="$CFLAGS -pthread"
 947       fi
 948       ;;
 949     *-dg-dgux*)  # DG/UX
 950       CFLAGS="$CFLAGS -D_POSIX4A_DRAFT10_SOURCE"
 951       ;;
 952    esac
 953
 954   AC_CHECK_FUNC(pthread_create)
 955   AC_DEFINE([SILC_HAVE_PTHREAD], [], [HAVE_PTHREAD])
 956   AC_DEFINE([SILC_THREADS], [], [HAVE_THREAD])
 957   __SILC_HAVE_PTHREAD="#define __SILC_HAVE_PTHREAD 1"
 958 fi
 959
 960 # Native WIN32 compilation under cygwin
 961 #
 962 AC_MSG_CHECKING(whether to compile native WIN32 code)
 963 AC_ARG_WITH(win32,
 964   [  --with-win32            compile native WIN32 (MinGW) code (-mno-cygwin)],
 965   [
 966     AC_MSG_RESULT(yes)
 967     AC_DEFINE([SILC_WIN32], [], [SILC_WIN32])
 968     win32_support=true
 969     CFLAGS="-mno-cygwin $CFLAGS"
 970     LIBS="$LIBS -lwsock32"
 971   ],
 972   [
 973     AC_MSG_RESULT(no)
 974   ])
 975 AM_CONDITIONAL(SILC_WIN32, test x$win32_support = xtrue)
 976
 977 # Native EPOC support (disabled by default)
 978 #
 979 AM_CONDITIONAL(SILC_EPOC, test xfalse = xtrue)
 980
 981 # Native BeOS support (disabled by default)
 982 #
 983 AM_CONDITIONAL(SILC_BEOS, test xfalse = xtrue)
 984
 985 # Native OS2 support (disabled by default)
 986 #
 987 AM_CONDITIONAL(SILC_OS2, test xfalse = xtrue)
 988
 989 #ifdef SILC_DIST_TOOLKIT
 990 # --without-irssi
 991 #
 992 without_irssi=false
 993 AC_MSG_CHECKING(whether to compile Irssi SILC Client)
 994 AC_ARG_WITH(irssi,
 995   [  --without-irssi         compile without Irssi SILC Client],
 996   [
 997     AC_MSG_RESULT(no)
 998     without_irssi=true
 999   ],
1000   [
1001     AC_MSG_RESULT(yes)
1002   ])
1003
1004 # --without-silcd
1005 #
1006 without_silcd=false
1007 AC_MSG_CHECKING(whether to compile SILC Server)
1008 AC_ARG_WITH(silcd,
1009   [  --without-silcd         compile without SILC Server],
1010   [
1011     AC_MSG_RESULT(no)
1012     without_silcd=true
1013   ],
1014   [
1015     AC_MSG_RESULT(yes)
1016   ])
1017 #endif SILC_DIST_TOOLKIT
1018
1019 #ifdef SILC_DIST_CLIENT
1020 # Irssi perl support
1021 #
1022 AC_ARG_WITH(perl,
1023   [[  --with-perl[=yes|no|module]  Build with Perl support - also specifies
1024                                if it should be built into main silc binary
1025                                (static, default) or as a module]])
1026 #endif SILC_DIST_CLIENT
1027
1028 libtoolfix=true
1029 AC_MSG_CHECKING(whether to do libtoolfix)
1030 AC_ARG_WITH(libtoolfix,
1031   [  --without-libtoolfix    Do not fix libtool, for package builders],
1032   [
1033     AC_MSG_RESULT(no)
1034     libtoolfix=false
1035   ],
1036   [
1037     AC_MSG_RESULT(yes)
1038   ])
1039
1040 AC_SUBST(ETCDIR)
1041 AC_DEFINE_UNQUOTED([SILC_ETCDIR], "$ETCDIR", [SILC_ETCDIR])
1042
1043 #endif SILC_DIST_COMPILER
1044
1045 ##
1046 ##  Misc
1047 ##
1048
1049 # Make enable-shared aware
1050 AM_CONDITIONAL(SILC_ENABLE_SHARED, test "$enable_shared" = yes)
1051
1052 # Other configure scripts
1053 #
1054
1055 #ifdef SILC_DIST_TOOLKIT
1056 if test x$without_irssi = xfalse; then
1057 #endif SILC_DIST_TOOLKIT
1058 #ifdef SILC_DIST_CLIENT
1059   AC_CONFIG_SUBDIRS(irssi)
1060   irssi="yes"
1061 #endif SILC_DIST_CLIENT
1062 #ifdef SILC_DIST_TOOLKIT
1063 fi
1064 #endif SILC_DIST_TOOLKIT
1065
1066 SILC_TOP_SRCDIR=`pwd`
1067
1068 # Included configure scripts
1069 AD_INCLUDE_CONFIGURE
1070
1071 #ifdef SILC_DIST_COMPILER
1072 #
1073 # Substitutions
1074 #
1075 AC_SUBST(SILC_TOP_SRCDIR)
1076 AC_SUBST(LIBS)
1077 AC_SUBST(SILC_LIB_INCLUDES)
1078 AC_SUBST(__SILC_HAVE_PTHREAD)
1079 AC_SUBST(__SILC_HAVE_SIM)
1080 AC_SUBST(__SILC_ENABLE_DEBUG)
1081
1082 #
1083 # Fix the libtool to support run-time configuration.  This allows us
1084 # to in run-time specify when to compile shared/static libraries without
1085 # need to reconfigure the entire libtool.
1086 #
1087 if test x$libtoolfix = xtrue; then
1088   ./libtoolfix $SILC_TOP_SRCDIR/ltmain.sh
1089 fi
1090 AM_CONDITIONAL(SILC_LIBTOOLFIX, test x$libtoolfix = xtrue)
1091
1092 INCLUDE_DEFINES_INT="include \$(top_srcdir)/Makefile.defines_int"
1093 AC_SUBST(INCLUDE_DEFINES_INT)
1094
1095 #endif SILC_DIST_COMPILER
1096
1097 #
1098 # Makefile outputs
1099 #
1100 AC_CONFIG_FILES(
1101 Makefile
1102 #ifdef SILC_DIST_DOC
1103 doc/Makefile
1104 #endif SILC_DIST_DOC
1105 #ifdef SILC_DIST_COMPILER
1106 Makefile.defines
1107 Makefile.defines_int
1108 includes/Makefile
1109 includes/silcversion.h
1110 includes/silcincludes.h
1111 #endif SILC_DIST_COMPILER
1112 #ifdef SILC_DIST_APPS
1113 apps/Makefile
1114 #endif SILC_DIST_APPS
1115 )
1116
1117 #ifdef SILC_DIST_TOOLKIT
1118 if test x$without_irssi = xfalse ; then
1119 #endif SILC_DIST_TOOLKIT
1120 #ifdef SILC_DIST_CLIENT
1121   AC_CONFIG_FILES(
1122 irssi/Makefile.defines
1123 irssi/Makefile.defines_int
1124 )
1125 #endif SILC_DIST_CLIENT
1126 #ifdef SILC_DIST_TOOLKIT
1127 fi
1128 #endif SILC_DIST_TOOLKIT
1129
1130 #ifdef SILC_DIST_TOOLKIT
1131 AC_CONFIG_FILES(
1132 silc/Makefile
1133 win32/Makefile
1134 win32/libsilc/Makefile
1135 win32/libsilcclient/Makefile
1136 tutorial/Makefile
1137 tutorial/Makefile.defines
1138 tutorial/Makefile.defines_int
1139 )
1140 #endif SILC_DIST_TOOLKIT
1141
1142 AC_OUTPUT
1143
1144 #ifdef SILC_DIST_COMPILER
1145 s_bindir=`eval echo $bindir`;s_bindir=`eval echo $s_bindir`
1146 s_sbindir=`eval echo $sbindir`;s_sbindir=`eval echo $s_sbindir`
1147 s_mandir=`eval echo $mandir`;s_mandir=`eval echo $s_mandir`
1148 s_includedir=`eval echo $includedir`;s_includedir=`eval echo $s_includedir`
1149
1150 echo ""
1151 echo "$PACKAGE Configuration Summary:"
1152 echo "---------------------------"
1153 echo " Target host ...................: $target"
1154 echo " Compiler ......................: $CC"
1155 echo " CFLAGS ........................: $CFLAGS"
1156 echo " LDFLAGS .......................: $LDFLAGS"
1157 echo " LIBS ..........................: $LIBS"
1158 echo ""
1159 echo " Installation prefix ...........: $prefix"
1160 echo " bin directory .................: $s_bindir"
1161 echo " sbin directory ................: $s_sbindir"
1162 echo " etc directory .................: $ETCDIR"
1163 echo " man directory .................: $s_mandir"
1164 echo " doc directory .................: $DOCDIR"
1165 #ifdef SILC_DIST_CLIENT
1166 echo " help directory ................: $HELPDIR"
1167 #endif SILC_DIST_CLIENT
1168 #ifdef SILC_DIST_SERVER
1169 echo " logs directory ................: $LOGSDIR"
1170 #endif SILC_DIST_SERVER
1171 #ifdef SILC_DIST_SIM
1172 echo " SIM directory .................: $MODULESDIR"
1173 #endif SILC_DIST_SIM
1174 #ifdef SILC_DIST_INCLUDES
1175 echo " include directory .............: $s_includedir"
1176 #endif SILC_DIST_INCLUDES
1177 echo ""
1178
1179 #ifdef SILC_DIST_TOOLKIT
1180 if test x$without_irssi = xtrue; then
1181   irssi="no"
1182 fi
1183 if test x$without_silcd = xtrue; then
1184   silcd="no"
1185 fi
1186 #endif SILC_DIST_TOOLKIT
1187
1188 #ifdef SILC_DIST_CLIENT
1189 echo " Compile SILC Client ...........: $irssi"
1190 #endif SILC_DIST_CLIENT
1191
1192 #ifdef SILC_DIST_SERVER
1193 echo " Compile SILC Server ...........: $silcd"
1194 echo " Server configuration file .....: $summary_silcd_configfile"
1195 echo " Server PID file ...............: $PIDFILE"
1196 #endif SILC_DIST_SERVER
1197
1198 #ifdef SILC_DIST_SIM
1199 if test x$sim_support = xfalse; then
1200   sim_support="no"
1201 else
1202   sim_support="yes"
1203 fi
1204 echo " SIM support ...................: $sim_support"
1205 #endif SILC_DIST_SIM
1206
1207 echo " IPv6 support ..................: $summary_ipv6"
1208
1209 if test x$has_iconv = xfalse; then
1210   iconv_support="no"
1211 else
1212   iconv_support="yes"
1213 fi
1214 echo " Iconv support .................: $iconv_support"
1215
1216 if test x$want_asm = xfalse; then
1217   summary_asm="no"
1218 else
1219   summary_asm="yes"
1220 fi
1221 echo " Assembler optimizations .......: $summary_asm"
1222
1223 #ifdef SILC_DIST_MATH
1224 mp="MPI"
1225 if test x$mp_gmp = xtrue; then
1226   mp="GMP"
1227 fi
1228 echo " Arithmetic library ............: $mp"
1229 #endif SILC_DIST_MATH
1230
1231 threads="no"
1232 if test x$has_threads = xtrue; then
1233   threads="yes"
1234 fi
1235 echo " Multi-threads support .........: $threads"
1236 echo " Debugging enabled .............: $summary_debug"
1237 echo ""
1238 echo "Compile the sources with 'make' or 'gmake' command."
1239 #endif SILC_DIST_COMPILER
1240