configure.ad

   1 #
   2 #  configure.ad
   3 #
   4 #  Author: Pekka Riikonen <priikone@silcnet.org>
   5 #
   6 #  Copyright (C) 2000 - 2007 Pekka Riikonen
   7 #
   8 #  This program is free software; you can redistribute it and/or modify
   9 #  it under the terms of the GNU General Public License as published by
  10 #  the Free Software Foundation; version 2 of the License.
  11 #
  12 #  This program is distributed in the hope that it will be useful,
  13 #  but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #  GNU General Public License for more details.
  16 #
  17
  18 AD_INIT
  19 AC_CANONICAL_SYSTEM
  20 AM_INIT_AUTOMAKE
  21 AC_PREREQ(2.52)
  22 AC_CONFIG_HEADERS(silcdefs.h)
  23
  24 AC_PROG_INSTALL
  25 AC_PROG_MAKE_SET
  26
  27 AC_PROG_LN_S
  28 AC_PROG_EGREP
  29 AC_SUBST(LN_S)
  30 AC_PATH_PROG(sedpath, sed)
  31
  32 #ifdef SILC_DIST_COMPILER
  33
  34 # Put here any platform specific stuff
  35 #
  36 case "$target" in
  37   *-*-linux*)
  38     check_threads=true
  39     CFLAGS=`echo $CFLAGS -D_GNU_SOURCE`
  40     ;;
  41   *-*-freebsd*)
  42     check_threads=true
  43     ;;
  44   *-*-netbsd*)
  45     check_threads=true
  46     ;;
  47   *-*-*bsd*)
  48     check_threads=false
  49     ;;
  50   *)
  51     check_threads=true
  52     ;;
  53 esac
  54
  55 # Get CPU
  56 SILC_SYSTEM_IS_SMP(AC_DEFINE([SILC_SMP], [], [SILC_SMP]), [],
  57                    AC_DEFINE([SILC_SMP], [], [SILC_SMP]))
  58 cpu_i386=false
  59 cpu_i486=false
  60 cpu_i586=false
  61 cpu_i686=false
  62 cpu_i786=false
  63 cpu_x86_64=false
  64 cpu_ppc=false
  65 cpu_ia64=false
  66 case "$host_cpu" in
  67   # All following Intels are considered 32-bit CPUs.
  68   i?86)
  69     # All CPUs of today are considered i386 and i486 compatible */
  70     AC_DEFINE([SILC_I386], [], [SILC_I386])
  71     AC_DEFINE([SILC_I486], [], [SILC_I486])
  72     cpu_i386=true
  73     cpu_i486=true
  74
  75     if test "x$host_cpu" = "xi586"; then
  76       AC_DEFINE([SILC_I586], [], [SILC_I586])
  77       cpu_i586=true
  78     fi
  79
  80     if test "x$host_cpu" = "xi686"; then
  81       AC_DEFINE([SILC_I586], [], [SILC_I586])
  82       AC_DEFINE([SILC_I686], [], [SILC_I686])
  83       cpu_i586=true
  84       cpu_i686=true
  85     fi
  86
  87     if test "x$host_cpu" = "xi786"; then
  88       AC_DEFINE([SILC_I586], [], [SILC_I586])
  89       AC_DEFINE([SILC_I686], [], [SILC_I686])
  90       AC_DEFINE([SILC_I786], [], [SILC_I786])
  91       cpu_i586=true
  92       cpu_i686=true
  93       cpu_i786=true
  94     fi
  95
  96     # Check for specific CPU features
  97     SILC_CPU_FLAG(mmx, AC_DEFINE([SILC_CPU_MMX], [], [SILC_CPU_MMX]), [])
  98     SILC_CPU_FLAG(sse2, AC_DEFINE([SILC_CPU_SSE2], [], [SILC_CPU_SSE2]), [])
  99     SILC_CPU_FLAG(pni, AC_DEFINE([SILC_CPU_SSE3], [], [SILC_CPU_SSE3]), [])
 100     SILC_CPU_FLAG(ssse3, AC_DEFINE([SILC_CPU_SSSE3], [], [SILC_CPU_SSSE3]), [])
 101     SILC_CPU_FLAG(sse4, AC_DEFINE([SILC_CPU_SSE4], [], [SILC_CPU_SSE4]), [])
 102     ;;
 103
 104   # Intel IA-64, 64-bit CPU (not x86_64 compatible)
 105   ia64)
 106     AC_DEFINE([SILC_IA64], [], [SILC_IA64])
 107     cpu_ia64=true
 108
 109     # Check for specific CPU features
 110     SILC_CPU_FLAG(mmx, AC_DEFINE([SILC_CPU_MMX], [], [SILC_CPU_MMX]), [])
 111     SILC_CPU_FLAG(sse2, AC_DEFINE([SILC_CPU_SSE2], [], [SILC_CPU_SSE2]), [])
 112     SILC_CPU_FLAG(pni, AC_DEFINE([SILC_CPU_SSE3], [], [SILC_CPU_SSE3]), [])
 113     SILC_CPU_FLAG(ssse3, AC_DEFINE([SILC_CPU_SSSE3], [], [SILC_CPU_SSSE3]), [])
 114     SILC_CPU_FLAG(sse4, AC_DEFINE([SILC_CPU_SSE4], [], [SILC_CPU_SSE4]), [])
 115     ;;
 116
 117   # AMD/Intel x86_64, 64-bit CPU
 118   x86_64)
 119     AC_DEFINE([SILC_X86_64], [], [SILC_X86_64])
 120     cpu_x86_64=true
 121
 122     # Check for specific CPU features
 123     SILC_CPU_FLAG(mmx, AC_DEFINE([SILC_CPU_MMX], [], [SILC_CPU_MMX]), [])
 124     SILC_CPU_FLAG(sse2, AC_DEFINE([SILC_CPU_SSE2], [], [SILC_CPU_SSE2]), [])
 125     SILC_CPU_FLAG(pni, AC_DEFINE([SILC_CPU_SSE3], [], [SILC_CPU_SSE3]), [])
 126     SILC_CPU_FLAG(ssse3, AC_DEFINE([SILC_CPU_SSSE3], [], [SILC_CPU_SSSE3]), [])
 127     SILC_CPU_FLAG(sse4, AC_DEFINE([SILC_CPU_SSE4], [], [SILC_CPU_SSE4]), [])
 128     ;;
 129
 130   # PowerPC, 32-bit and 64-bit CPUs
 131   powerpc*)
 132     AC_DEFINE([SILC_POWERPC], [], [SILC_POWERPC])
 133     cpu_ppc=true
 134     ;;
 135 esac
 136 AM_CONDITIONAL(SILC_I386, test x$cpu_i386 = xtrue)
 137 AM_CONDITIONAL(SILC_I486, test x$cpu_i486 = xtrue)
 138 AM_CONDITIONAL(SILC_I586, test x$cpu_i586 = xtrue)
 139 AM_CONDITIONAL(SILC_I686, test x$cpu_i686 = xtrue)
 140 AM_CONDITIONAL(SILC_7686, test x$cpu_i786 = xtrue)
 141 AM_CONDITIONAL(SILC_X86_64, test x$cpu_x86_64 = xtrue)
 142 AM_CONDITIONAL(SILC_POWERPC, test x$cpu_ppc = xtrue)
 143 AM_CONDITIONAL(SILC_IA64, test x$cpu_ia64 = xtrue)
 144
 145 # Control compiler optimizations
 146 CFLAGS=`echo $CFLAGS | sed 's/-O[ 0123456789s]*//g'`
 147
 148 AC_PROG_CC
 149 AC_C_INLINE
 150 AC_C_CONST
 151
 152 # Set some compiler options based on CPU
 153 if test "x$CC" = "xicc"; then
 154   # ICC flags
 155   if test x$x_have_cpu_sse2 = xtrue; then
 156     SILC_ADD_CFLAGS(-axW)
 157   fi
 158   if test x$x_have_cpu_sse3 = xtrue; then
 159     SILC_ADD_CFLAGS(-axP)
 160   fi
 161   if test x$x_have_cpu_ssse3 = xtrue; then
 162     SILC_ADD_CFLAGS(-axT)
 163   fi
 164   if test x$x_have_cpu_sse4 = xtrue; then
 165     SILC_ADD_CFLAGS(-axS)
 166   fi
 167 else
 168   # Other compilers
 169   if test x$x_have_cpu_sse2 = xtrue; then
 170     SILC_ADD_CFLAGS(-msse2)
 171   fi
 172   if test x$x_have_cpu_pni = xtrue; then
 173     SILC_ADD_CFLAGS(-msse3)
 174   fi
 175   if test x$x_have_cpu_ssse3 = xtrue; then
 176     SILC_ADD_CFLAGS(-mssse3)
 177   fi
 178   if test x$x_have_cpu_sse4 = xtrue; then
 179     SILC_ADD_CFLAGS(-msse3)
 180   fi
 181 fi
 182
 183 __SILC_HAVE_PTHREAD=""
 184 __SILC_HAVE_SIM=""
 185 __SILC_ENABLE_DEBUG=""
 186
 187 #ifdef SILC_DIST_TOOLKIT
 188 toolkitver=`echo $VERSION | sed 's/\./ /g'`
 189 maj=0
 190 min=0
 191 bld=0
 192 for v in $toolkitver
 193 do
 194   if test $maj -eq 0; then
 195     maj=$v
 196     continue
 197   fi
 198   if test $min -eq 0; then
 199     min=$v
 200     continue
 201   fi
 202   if test $bld -eq 0; then
 203     bld=$v
 204     continue
 205   fi
 206 done
 207 __SILC_PACKAGE_VERSION="#define __SILC_TOOLKIT_VERSION SILC_VERSION($maj,$min,$bld)"
 208 #endif SILC_DIST_TOOLKIT
 209
 210 AC_PROG_RANLIB
 211 #ifndef SILC_DIST_TOOLKIT
 212 AC_DISABLE_SHARED
 213 #endif SILC_DIST_TOOLKIT
 214 #ifdef SILC_DIST_INPLACE
 215 AC_DISABLE_SHARED
 216 #endif SILC_DIST_INPLACE
 217 AC_PROG_LIBTOOL
 218
 219 # Header checking
 220 #
 221 AC_HEADER_STDC
 222 AC_HEADER_TIME
 223 AC_HEADER_STAT
 224
 225 # More header checking
 226 #
 227 AC_CHECK_HEADERS(unistd.h string.h errno.h fcntl.h assert.h)
 228 AC_CHECK_HEADERS(sys/types.h sys/stat.h sys/time.h stddef.h)
 229 AC_CHECK_HEADERS(netinet/in.h netinet/tcp.h xti.h netdb.h sys/resource.h)
 230 AC_CHECK_HEADERS(pwd.h grp.h termcap.h paths.h)
 231 AC_CHECK_HEADERS(ncurses.h signal.h ctype.h utime.h)
 232 AC_CHECK_HEADERS(arpa/inet.h sys/mman.h limits.h termios.h locale.h langinfo.h)
 233
 234 # Data type checking
 235 #
 236 AC_TYPE_SIGNAL
 237 AC_TYPE_SIZE_T
 238 AC_TYPE_MODE_T
 239 AC_TYPE_UID_T
 240 AC_TYPE_PID_T
 241
 242 AC_CHECK_SIZEOF(long long, 0)
 243 AC_SUBST(SILC_SIZEOF_LONG_LONG, $ac_cv_sizeof_long_long)
 244 AC_CHECK_SIZEOF(long, 0)
 245 AC_SUBST(SILC_SIZEOF_LONG, $ac_cv_sizeof_long)
 246 AC_CHECK_SIZEOF(int, 0)
 247 AC_SUBST(SILC_SIZEOF_INT, $ac_cv_sizeof_int)
 248 AC_CHECK_SIZEOF(short, 0)
 249 AC_SUBST(SILC_SIZEOF_SHORT, $ac_cv_sizeof_short)
 250 AC_CHECK_SIZEOF(char, 0)
 251 AC_SUBST(SILC_SIZEOF_CHAR, $ac_cv_sizeof_char)
 252 AC_CHECK_SIZEOF(void *, 0)
 253 AC_SUBST(SILC_SIZEOF_VOID_P, $ac_cv_sizeof_void_p)
 254 AC_CHECK_TYPES(long long)
 255 AC_CHECK_TYPES(long double)
 256
 257 # Function and library checking
 258 #
 259 AC_CHECK_FUNC(gethostbyname, [],
 260   [
 261     AC_CHECK_LIB(nsl, gethostbyname, LIBS="$LIBS -lnsl")
 262     AC_CHECK_FUNC(res_gethostbyname, [],
 263        AC_CHECK_LIB(resolv, res_gethostbyname, LIBS="$LIBS -lresolv")
 264     )
 265   ])
 266 AC_CHECK_FUNC(socket, [],
 267   AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
 268 )
 269 AC_CHECK_FUNC(clock_gettime, [],
 270   [
 271     AC_CHECK_LIB(rt, clock_gettime,
 272                  [ LIBS="$LIBS -lrt"
 273                    AC_DEFINE([HAVE_CLOCK_GETTIME], [], [HAVE_CLOCK_GETTIME])])
 274   ])
 275 AC_CHECK_FUNCS(gethostname gethostbyaddr getservbyname getservbyport)
 276 AC_CHECK_FUNCS(poll select listen bind shutdown close connect setsockopt)
 277 AC_CHECK_FUNCS(setrlimit time ctime utime gettimeofday getrusage)
 278 AC_CHECK_FUNCS(chmod fcntl stat fstat getenv putenv strerror)
 279 AC_CHECK_FUNCS(getpid getgid getsid getpgid getpgrp getuid sched_yield)
 280 AC_CHECK_FUNCS(setgroups initgroups nl_langinfo nanosleep)
 281 AC_CHECK_FUNCS(strchr snprintf strstr strcpy strncpy memcpy memset memmove)
 282 AC_CHECK_FUNCS(setenv getenv putenv unsetenv clearenv)
 283
 284 # lib/contrib conditionals
 285 #
 286 AC_CHECK_HEADER(regex.h,
 287   [
 288     AC_DEFINE([HAVE_REGEX_H], [], [HAVE_REGEX_H])
 289     have_regex=1
 290   ], have_regex=0
 291 )
 292 AM_CONDITIONAL(HAVE_REGEX, test x$have_regex = x1)
 293
 294 AC_CHECK_FUNC(getopt_long,
 295   [
 296     AC_DEFINE([HAVE_GETOPT_LONG], [], [HAVE_GETOPT_LONG])
 297     have_getopt_long=1
 298   ], have_getopt_long=0
 299 )
 300
 301 ##
 302 ##  Enable/disable checking
 303 ##
 304
 305 # IPv6 support
 306 #
 307 AC_MSG_CHECKING(whether to enable IPv6 support)
 308 AC_ARG_ENABLE(ipv6,
 309   [  --enable-ipv6           enable IPv6 support],
 310   [
 311     case "${enableval}" in
 312       yes)
 313         want_ipv6=true
 314         check_ipv6=false
 315         summary_ipv6="yes"
 316         AC_DEFINE([HAVE_IPV6], [], [HAVE_IPV6])
 317         AC_MSG_RESULT(yes)
 318         ;;
 319       *)
 320         want_ipv6=false
 321         check_ipv6=false
 322         summary_ipv6="no"
 323         AC_MSG_RESULT(no)
 324         ;;
 325     esac
 326   ],
 327     check_ipv6=true
 328   )
 329
 330 if test x$check_ipv6 = xtrue; then
 331   summary_ipv6="no"
 332   AC_TRY_COMPILE(
 333     [
 334       #ifdef HAVE_SYS_TYPES_H
 335       #include <sys/types.h>
 336       #endif
 337       #ifdef HAVE_NETINET_TCP_H
 338       #include <netinet/tcp.h>
 339       #endif
 340       #ifdef HAVE_NETDB_H
 341       #include <netdb.h>
 342       #endif
 343       #include <sys/socket.h>
 344       #ifdef HAVE_NETINET_IN_H
 345       #include <netinet/in.h>
 346       #endif
 347     ],
 348     [
 349       struct sockaddr_in6 sin6;
 350       int family = AF_INET6;
 351     ],
 352     [
 353       AC_DEFINE([HAVE_IPV6], [], [HAVE_IPV6])
 354       AC_MSG_RESULT(yes)
 355       summary_ipv6="yes"
 356     ],
 357       AC_MSG_RESULT(no)
 358     )
 359 fi
 360
 361 # Debug checking
 362 #
 363 AC_MSG_CHECKING(whether to enable debugging)
 364 summary_debug="no"
 365 __SILC_ENABLE_DEBUG=""
 366 AC_ARG_ENABLE(debug,
 367   [  --enable-debug          enable debugging],
 368   [
 369     case "${enableval}" in
 370       yes)
 371         AC_MSG_RESULT(yes)
 372         AC_DEFINE([SILC_DEBUG], [], [enable-debug])
 373         summary_debug="yes"
 374         __SILC_ENABLE_DEBUG="#define __SILC_ENABLE_DEBUG 1"
 375         ;;
 376       *)
 377         AC_MSG_RESULT(no)
 378         ;;
 379     esac
 380   ],
 381   [
 382     AC_MSG_RESULT(no)
 383   ])
 384
 385 # Disable all compiler optimizations
 386 #
 387 AC_MSG_CHECKING(whether to enable compiler optimizations)
 388 want_cc_optimizations=true
 389 AC_ARG_ENABLE(optimizations,
 390   [  --disable-optimizations do not use any compiler optimizations],
 391   [
 392     AC_MSG_RESULT(no)
 393     AC_DEFINE([SILC_NO_CC_OPTIMIZATIONS], [], [SILC_NO_CC_OPTIMIZATIONS])
 394     want_cc_optimizations=false
 395   ],
 396   [
 397     AC_MSG_RESULT(yes)
 398     want_cc_optimizations=true
 399   ])
 400 AM_CONDITIONAL(SILC_NO_CC_OPTIMIZATIONS, test x$want_cc_optimizations = xfalse)
 401
 402 # Disable all assembler optimizations
 403 #
 404 AC_MSG_CHECKING(whether to enable assembler optimizations)
 405 want_asm=true
 406 AC_ARG_ENABLE(asm,
 407   [  --disable-asm           do not use assembler optimizations],
 408   [
 409     AC_MSG_RESULT(no)
 410     AC_DEFINE([SILC_NO_ASM], [], [SILC_NO_ASM])
 411     want_asm=false
 412   ],
 413   [
 414     AC_MSG_RESULT(yes)
 415     want_asm=true
 416   ])
 417 AM_CONDITIONAL(SILC_NO_ASM, test x$want_asm = xfalse)
 418
 419 # Check for assembler
 420 #
 421 SILC_ASSEMBLER=""
 422 have_assembler=false
 423 if test x$want_asm = xtrue; then
 424   AC_PATH_PROG([NASM], [nasm], [no])
 425   if test "x$NASM" != "xno"; then
 426     if test x$cpu_x86_64 = xtrue; then
 427       SILC_ASSEMBLER="$NASM -O2 -felf64"
 428     else
 429       SILC_ASSEMBLER="$NASM -O2 -felf"
 430     fi
 431     have_assembler=true
 432   fi
 433
 434   AC_PATH_PROG([YASM], [yasm], [no])
 435   if test "x$YASM" != "xno"; then
 436     if test x$cpu_x86_64 = xtrue; then
 437       SILC_ASSEMBLER="$YASM -Xgnu -felf64"
 438     else
 439       SILC_ASSEMBLER="$YASM -Xgnu -felf"
 440     fi
 441     have_assembler=true
 442   fi
 443 fi
 444 AC_SUBST(SILC_ASSEMBLER)
 445
 446 ##
 447 ## va_copy checks
 448 ##
 449 va_copy=false
 450 AC_MSG_CHECKING(for va_copy)
 451 AC_TRY_COMPILE(
 452   [
 453     #include <stdarg.h>
 454     #include <stdlib.h>
 455   ],
 456   [
 457     int t(int x, ...)
 458     {
 459       va_list va, cp;
 460       va_start(va, x);
 461       va_copy(cp, va);
 462       if (va_arg(cp, int) != 0xff11)
 463         return 1;
 464       va_end(va);
 465       va_end(cp);
 466       return 0;
 467     }
 468     int main()
 469     {
 470       return t(0, 0xff11);
 471     }
 472   ],
 473   [
 474     AC_DEFINE([HAVE_VA_COPY], [], [HAVE_VA_COPY])
 475     AC_MSG_RESULT(yes)
 476     va_copy=true
 477   ],
 478   [
 479     AC_MSG_RESULT(no)
 480     va_copy=false
 481   ]
 482 )
 483
 484 if test x$va_copy = xfalse; then
 485   AC_MSG_CHECKING(for __va_copy)
 486   AC_TRY_COMPILE(
 487   [
 488     #include <stdarg.h>
 489     #include <stdlib.h>
 490   ],
 491   [
 492     int t(int x, ...)
 493     {
 494       va_list va, cp;
 495       va_start(va, x);
 496       __va_copy(cp, va);
 497       if (va_arg(cp, int) != 0xff11)
 498         return 1;
 499       va_end(va);
 500       va_end(cp);
 501       return 0;
 502     }
 503     int main()
 504     {
 505       return t(0, 0xff11);
 506     }
 507   ],
 508   [
 509     AC_DEFINE([HAVE___VA_COPY], [], [HAVE___VA_COPY])
 510     AC_MSG_RESULT(yes)
 511     va_copy=true
 512   ],
 513   [
 514     AC_MSG_RESULT(no)
 515     va_copy=false
 516   ]
 517   )
 518 fi
 519
 520 if test x$va_copy = xfalse; then
 521   AC_RUN_IFELSE(
 522     [
 523       #include <stdarg.h>
 524       #include <stdlib.h>
 525       int t(int x, ...)
 526       {
 527         va_list va, cp;
 528         va_start(va, x);
 529         cp = va;
 530         if (va_arg(cp, int) != 0xff11)
 531           return 1;
 532         va_end(va);
 533         va_end(cp);
 534         return 0;
 535       }
 536       int main()
 537       {
 538         return t(0, 0xff11);
 539       }
 540     ],
 541     [va_copy=false],
 542     [
 543       AC_DEFINE([SILC_VA_COPY_ARRAY], [], [SILC_VA_COPY_ARRAY])
 544     ],
 545     [va=copy=false]
 546   )
 547 fi
 548
 549 ##
 550 ## Compiler and compiler flag checks
 551 ##
 552
 553 if test "$GCC"; then
 554   # GCC specific options
 555   if test "x$summary_debug" = "xyes"; then
 556     SILC_ADD_CFLAGS(-g)
 557   else
 558     SILC_ADD_CFLAGS(-g)
 559   fi
 560   SILC_ADD_CFLAGS(-Wall -finline-functions)
 561   SILC_ADD_CFLAGS(-Wno-pointer-sign)
 562 else
 563   # Other compilers
 564   case "$target" in
 565     alpha*-dec-osf*)
 566       SILC_ADD_CFLAGS(-g3)
 567       ;;
 568     mips*-sgi-irix*)
 569       SILC_ADD_CFLAGS(-g3)
 570       ;;
 571     *)
 572       SILC_ADD_CFLAGS(-g)
 573       ;;
 574   esac
 575
 576   # Intel C++ Compiler flags
 577   if test "x$CC" = "xicc"; then
 578     SILC_ADD_CFLAGS(-restrict)
 579     SILC_ADD_CFLAGS(-finline-functions)
 580
 581     # Don't define __GNUC__ except for system includes
 582     SILC_ADD_CFLAGS(-gcc-sys)
 583   fi
 584 fi
 585
 586 if test x$want_cc_optimizations = xtrue; then
 587   if test "$GCC"; then
 588     # GCC specific options
 589     if test "x$summary_debug" = "xyes"; then
 590       SILC_ADD_CFLAGS(-O)
 591     else
 592       SILC_ADD_CFLAGS(-O2)
 593     fi
 594   else
 595     # Other compilers
 596     case "$target" in
 597       alpha*-dec-osf*)
 598         SILC_ADD_CFLAGS(-O2, SILC_ADD_CFLAGS(-O))
 599         ;;
 600       mips*-sgi-irix*)
 601         SILC_ADD_CFLAGS(-O2, SILC_ADD_CFLAGS(-O))
 602         ;;
 603       *)
 604         SILC_ADD_CFLAGS(-O2, SILC_ADD_CFLAGS(-O))
 605         ;;
 606     esac
 607   fi
 608 fi
 609
 610 #
 611 # Workaround a bug in GCC 2.x which causes memory exhaustion
 612 # when compiling sha1 with optimizations on UltraSPARC.
 613 #
 614 FIX_SHA1='#'
 615 if test "$GCC" -a "$host_cpu" = "sparc64"; then
 616   AC_MSG_CHECKING(whether to enable GCC 2.x workaround for SHA1)
 617   AC_TRY_COMPILE(
 618     [
 619       #if defined(__sparc64__) && (__GNUC__ == 2)
 620       #else
 621       choke me
 622       #endif
 623     ],
 624     [],
 625     [
 626       FIX_SHA1=''
 627       AC_MSG_RESULT(yes)
 628     ],
 629       AC_MSG_RESULT(no)
 630     )
 631 fi
 632 AC_SUBST(FIX_SHA1)
 633 #endif SILC_DIST_COMPILER
 634
 635 ##
 636 ##  Installation
 637 ##
 638
 639 # Default installation destination
 640 #
 641 AC_PREFIX_DEFAULT(/usr/local)
 642 if test "x$prefix" != xNONE; then
 643   silc_prefix="$prefix"
 644 else
 645   silc_prefix="$ac_default_prefix"
 646   prefix="$silc_prefix"
 647 fi
 648
 649 #ifndef SILC_DIST_AUTODIST
 650 ETCDIR=`eval echo $sysconfdir`;ETCDIR=`eval echo $ETCDIR`
 651 AC_SUBST(ETCDIR)
 652 AC_DEFINE_UNQUOTED([SILC_ETCDIR], "$ETCDIR", [SILC_ETCDIR])
 653
 654 DOCDIR=`eval echo $docdir`;DOCDIR=`eval echo $DOCDIR`
 655 AC_SUBST(DOCDIR)
 656 AC_DEFINE_UNQUOTED([SILC_DOCDIR], "$DOCDIR", [SILC_DOCDIR])
 657 #endif SILC_DIST_AUTODIST
 658
 659 #ifdef SILC_DIST_COMPILER
 660 ##
 661 ##  With/without checkings
 662 ##
 663
 664 #
 665 # SILC library checking
 666 compile_libs=true
 667 LIBSUBDIR=lib
 668
 669 #ifndef SILC_DIST_TOOLKIT
 670 AC_ARG_WITH(silc-includes,
 671   [  --with-silc-includes=DIR SILC Toolkit includes [search in DIR]],
 672   [ac_silc_includes="$withval"], [ac_silc_includes="no"])
 673 AC_ARG_WITH(silc-libs,
 674   [  --with-silc-libs=DIR     SILC Toolkit libraries [search in DIR]],
 675   [ac_silc_libs="$withval"], [ac_silc_libs="no"])
 676
 677 if test -n "$with_silc_includes" || test -n "$with_silc_libs"; then
 678
 679   # Manually provided libs
 680   if test "$ac_silc_includes" != "no"; then
 681     compile_libs=false
 682     SILC_LIB_INCLUDES="-I$ac_silc_includes"
 683     LIBSUBDIR=
 684   fi
 685   if test "$ac_silc_libs" != "no"; then
 686     compile_libs=false
 687     LIBSUBDIR=
 688     LDFLAGS="-L$ac_silc_libs $LDFLAGS"
 689   else
 690     LDFLAGS="-L\$(silc_top_srcdir)/lib $LDFLAGS"
 691   fi
 692
 693   # Check libs to link against
 694   f=`$EGREP __SILC_HAVE_PTHREAD $ac_silc_includes/silc.h`
 695   if test -n "$f"; then
 696     LIBS="$LIBS -lpthread"
 697     check_threads=false
 698     has_threads=true
 699   fi
 700   f=`$EGREP __SILC_HAVE_SIM $ac_silc_includes/silc.h`
 701   if test -n "$f"; then
 702     LIBS="$LIBS -ldl"
 703   fi
 704
 705 else
 706   # pkg-config check
 707   PKG_CHECK_MODULES(SILC, [silc >= 1.1], compile_libs=false, compile_libs=true)
 708 #ifdef SILC_DIST_CLIENTLIB
 709   PKG_CHECK_MODULES(SILCCLIENT, [silcclient >= 1.1.1], compile_libs=false, compile_libs=true)
 710 #endif SILC_DIST_CLIENTLIB
 711 #ifdef SILC_DIST_SERVERLIB
 712   PKG_CHECK_MODULES(SILCSERVER, silcserver, compile_libs=false, compile_libs=true)
 713 #endif SILC_DIST_SERVERLIB
 714
 715   if test x$compile_libs = xfalse; then
 716     LIBSUBDIR=
 717     LIBS="$SILC_LIBS $LIBS"
 718     CFLAGS="$CFLAGS $SILC_CFLAGS"
 719 #ifdef SILC_DIST_CLIENTLIB
 720     LIBS="$SILCCLIENT_LIBS $LIBS"
 721     CFLAGS="$CFLAGS $SILCCLIENT_CFLAGS"
 722 #endif SILC_DIST_CLIENTLIB
 723 #ifdef SILC_DIST_SERVERLIB
 724     LIBS="$LIBS $SILCSERVER_LIBS"
 725     CFLAGS="$CFLAGS $SILCSERVER_CFLAGS"
 726 #endif SILC_DIST_SERVERLIB
 727   else
 728     LDFLAGS="-L\$(silc_top_srcdir)/lib $LDFLAGS"
 729   fi
 730 fi
 731
 732 #else SILC_DIST_TOOLKIT
 733 LDFLAGS="-L\$(silc_top_srcdir)/lib $LDFLAGS"
 734 #endif SILC_DIST_TOOLKIT
 735
 736 #ifdef SILC_DIST_SIM
 737 # SIM support checking
 738 # XXX These needs to be changed as more supported platforms appear.
 739 # XXX This probably needs to be made platform dependant check.
 740 #
 741 sim_support=false
 742 AC_MSG_CHECKING(for SIM support)
 743 AC_MSG_RESULT()
 744 AC_CHECK_HEADERS(dlfcn.h,
 745   [
 746     AC_CHECK_LIB(dl, dlopen,
 747       [
 748         AC_DEFINE([SILC_SIM], [], [HAVE_SIM])
 749         AC_DEFINE([HAVE_DLOPEN], [], [HAVE_DLOPEN])
 750         sim_support=true
 751         LIBS="$LIBS -ldl"
 752       ],
 753       [
 754         AC_CHECK_LIB(c, dlopen,
 755           [
 756             AC_DEFINE([SILC_SIM], [], [HAVE_SIM])
 757             AC_DEFINE([HAVE_DLOPEN], [], [HAVE_DLOPEN])
 758             sim_support=true
 759           ])
 760       ])
 761    ])
 762
 763 AM_CONDITIONAL(SILC_SIM, test x$sim_support = xtrue)
 764 if test x$sim_support = xtrue; then
 765   AC_MSG_RESULT(Enabled SIM support.)
 766   __SILC_HAVE_SIM="#define __SILC_HAVE_SIM 1"
 767 else
 768   AC_MSG_RESULT(No SIM support found.)
 769 fi
 770 #endif SILC_DIST_SIM
 771
 772 # SOCKS4 support checking
 773 #
 774 SAVE_LIBS="$LIBS"
 775 SAVE_CFLAGS="$CFLAGS"
 776 SAVE_LDFLAGS="$LDFLAGS"
 777 AC_MSG_CHECKING(whether to support SOCKS4)
 778 AC_ARG_WITH(socks4,
 779   [[  --with-socks4[=DIR]     with SOCKS4 support [search in DIR/lib and DIR/include]]],
 780   [
 781     case "$withval" in
 782       no)
 783         AC_MSG_RESULT(no)
 784         ;;
 785       *)
 786         AC_MSG_RESULT(yes)
 787         socks=4
 788
 789         if test -d "$withval/include"; then
 790           CFLAGS="$CFLAGS -I$withval/include"
 791         fi
 792         if test -d "$withval/lib"; then
 793           LDFLAGS="$LDFLAGS -L$withval/lib"
 794         fi
 795
 796         LIBS="-lsocks $LIBS"
 797         ;;
 798     esac
 799
 800     AC_TRY_LINK([],
 801       [
 802         Rconnect();
 803       ], [],
 804       [
 805         AC_MSG_ERROR(Could not find SOCKS4 library.)
 806         LIBS="$SAVE_LIBS"
 807         CFLAGS="$SAVE_CFLAGS"
 808         LDFLAGS="$SAVE_LDFLAGS"
 809       ])
 810   ],
 811     AC_MSG_RESULT(no)
 812   )
 813
 814 # SOCKS5 support checking
 815 #
 816 SAVE_LIBS="$LIBS"
 817 SAVE_CFLAGS="$CFLAGS"
 818 SAVE_LDFLAGS="$LDFLAGS"
 819 AC_MSG_CHECKING(whether to support SOCKS5)
 820 AC_ARG_WITH(socks5,
 821   [[  --with-socks5[=DIR]     with SOCKS5 support [search in DIR/lib and DIR/include]]],
 822   [
 823     case "$withval" in
 824       no)
 825         AC_MSG_RESULT(no)
 826         ;;
 827       *)
 828         AC_MSG_RESULT(yes)
 829         socks=5
 830
 831         if test -d "$withval/include"; then
 832           CFLAGS="$CFLAGS -I$withval/include"
 833         fi
 834         if test -d "$withval/lib"; then
 835           LDFLAGS="$LDFLAGS -L$withval/lib"
 836         fi
 837
 838         LIBS="-lsocks5 $LIBS"
 839         ;;
 840     esac
 841
 842     AC_TRY_LINK([],
 843       [
 844         SOCKSconnect();
 845       ], [],
 846       [
 847         AC_MSG_ERROR(Could not find SOCKS5 library.)
 848         LIBS="$SAVE_LIBS"
 849         CFLAGS="$SAVE_CFLAGS"
 850         LDFLAGS="$SAVE_LDFLAGS"
 851       ])
 852   ],
 853     AC_MSG_RESULT(no)
 854   )
 855
 856 if test "x$socks" = "x4"; then
 857   AC_DEFINE([SOCKS], [], [Socks])
 858   CFLAGS="$CFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 859 fi
 860
 861 if test "x$socks" = "x5"; then
 862   AC_DEFINE([SOCKS], [], [Socks])
 863   AC_DEFINE([SOCKS5], [], [Socks5])
 864   AC_DEFINE([Rconnect], [SOCKSconnect], [Socks])
 865   AC_DEFINE([Rgetsockname], [SOCKSgetsockname], [Socks])
 866   AC_DEFINE([Rgetpeername], [SOCKSgetpeername], [Socks])
 867   AC_DEFINE([Rbind], [SOCKSbind], [Socks])
 868   AC_DEFINE([Raccept], [SOCKSaccept], [Socks])
 869   AC_DEFINE([Rlisten], [SOCKSlisten], [Socks])
 870   AC_DEFINE([Rselect], [SOCKSselect], [Socks])
 871   AC_DEFINE([Rrecvfrom], [SOCKSrecvfrom], [Socks])
 872   AC_DEFINE([Rsendto], [SOCKSsendto], [Socks])
 873   AC_DEFINE([Rrecv], [SOCKSrecv], [Socks])
 874   AC_DEFINE([Rsend], [SOCKSsend], [Socks])
 875   AC_DEFINE([Rread], [SOCKSread], [Socks])
 876   AC_DEFINE([Rwrite], [SOCKSwrite], [Socks])
 877   AC_DEFINE([Rrresvport], [SOCKSrresvport], [Socks])
 878   AC_DEFINE([Rshutdown], [SOCKSshutdown], [Socks])
 879   AC_DEFINE([Rlisten], [SOCKSlisten], [Socks])
 880   AC_DEFINE([Rclose], [SOCKSclose], [Socks])
 881   AC_DEFINE([Rdup], [SOCKSdup], [Socks])
 882   AC_DEFINE([Rdup2], [SOCKSdup2], [Socks])
 883   AC_DEFINE([Rfclose], [SOCKSfclose], [Socks])
 884   AC_DEFINE([Rgethostbyname], [SOCKSgethostbyname], [Socks])
 885 fi
 886
 887 #ifdef SILC_DIST_MATH
 888 # MP library checking. First check whether user wants to use GMP and use
 889 # it if found. If not or not defined then compile the default library in the
 890 # source tree.
 891 #
 892 mp_gmp=false
 893 SAVE_LIBS="$LIBS"
 894 SAVE_CFLAGS="$CFLAGS"
 895 SAVE_LDFLAGS="$LDFLAGS"
 896 AC_MSG_CHECKING(whether to search for GMP)
 897 AC_ARG_WITH(gmp,
 898   [[  --with-gmp[=DIR]        use GMP instead of SILC Math [search in DIR/lib and DIR/include]]],
 899   [
 900     case "$withval" in
 901       no)
 902         AC_MSG_RESULT(no)
 903         ;;
 904       *)
 905         AC_MSG_RESULT(yes)
 906
 907         if test -d "$withval/include"; then
 908           CFLAGS="$CFLAGS -I$withval/include"
 909         fi
 910         if test -d "$withval/lib"; then
 911           LDFLAGS="$LDFLAGS -L$withval/lib"
 912         fi
 913
 914         LIBS="-lgmp $LIBS"
 915         ;;
 916     esac
 917
 918     AC_CHECK_LIB(gmp, __gmpz_init,
 919       [
 920         mp_gmp=true
 921         AC_DEFINE([SILC_MP_GMP], [], [GMP])
 922         AC_MSG_RESULT(Using GMP as a MP library.)
 923       ],
 924       [
 925         LIBS="$SAVE_LIBS"
 926         CFLAGS="$SAVE_CFLAGS"
 927         LDFLAGS="$SAVE_LDFLAGS"
 928       ])
 929   ],
 930     AC_MSG_RESULT(no)
 931   )
 932
 933 AM_CONDITIONAL(SILC_MP_GMP, test x$mp_gmp = xtrue)
 934 AM_CONDITIONAL(SILC_MP_SILCMATH, test x$mp_gmp = xfalse)
 935 if test x$mp_gmp = xfalse; then
 936   AC_DEFINE([SILC_MP_SILCMATH], [], [SILCMATH])
 937   AC_MSG_RESULT(Using SILC Math as a MP library.)
 938 fi
 939 #endif SILC_DIST_MATH
 940
 941 # iconv support
 942 #
 943 check_iconv=true
 944 has_iconv=false
 945 SAVE_LIBS="$LIBS"
 946 SAVE_CFLAGS="$CFLAGS"
 947 SAVE_LDFLAGS="$LDFLAGS"
 948 SAVE_CPPFLAGS="$CPPFLAGS"
 949 AC_MSG_CHECKING(whether to implicit search for libiconv)
 950 AC_ARG_WITH(iconv,
 951   [[  --with-iconv[=DIR]      use libiconv [search in DIR/include and DIR/lib]]],
 952   [
 953     case "${withval}" in
 954       no)
 955         AC_MSG_RESULT(no)
 956         AC_CHECK_HEADERS(iconv.h,
 957           [
 958             AC_CHECK_FUNC(iconv, has_iconv=true)
 959           ])
 960         check_iconv=false
 961         ;;
 962       *)
 963         AC_MSG_RESULT(yes)
 964         if test -d $withval/include; then
 965           CPPFLAGS="$CPPFLAGS -I$withval/include"
 966           CFLAGS="$CFLAGS -I$withval/include"
 967         fi
 968         if test -d $withval/lib; then
 969           LDFLAGS="$LDFLAGS -L$withval/lib"
 970         fi
 971         ;;
 972     esac
 973   ],
 974   [
 975     AC_MSG_RESULT(no)
 976     AC_CHECK_HEADERS(iconv.h,
 977       [
 978         AC_CHECK_FUNCS(iconv,
 979           [
 980             has_iconv=true
 981             check_iconv=false
 982           ])
 983       ])
 984   ])
 985
 986 if test x$check_iconv = xtrue; then
 987   AC_MSG_RESULT(Searching for iconv...)
 988
 989   # XXX
 990   unset ac_cv_header__iconv_h_ ac_cv_header_iconv_h || true
 991
 992   AC_CHECK_HEADERS(iconv.h,
 993     [
 994       LIBS="$LIBS -liconv"
 995       AC_MSG_CHECKING(for iconv in -liconv)
 996       AC_TRY_LINK(
 997         [
 998           #include <stdlib.h>
 999           #include <iconv.h>
1000         ],
1001         [
1002           iconv_t cd = iconv_open("", "");
1003           iconv(cd, NULL, NULL, NULL, NULL);
1004           iconv_close(cd);
1005         ],
1006         [
1007           echo "yes"
1008           AC_DEFINE([HAVE_ICONV], [], [Define if you have the iconv() function.])
1009           has_iconv=true
1010           check_iconv=false
1011         ],
1012         [
1013           echo "no"
1014           LIBS="$SAVE_LIBS"
1015           CFLAGS="$SAVE_CFLAGS"
1016           LDFLAGS="$SAVE_LDFLAGS"
1017           CPPFLAGS="$SAVE_CPPFLAGS"
1018         ])
1019      ])
1020 fi
1021
1022 if test x$check_iconv = xtrue; then
1023   # search for iconv library..
1024   SAVE_LIBS="$LIBS"
1025   SAVE_CFLAGS="$CFLAGS"
1026   SAVE_LDFLAGS="$LDFLAGS"
1027   SAVE_CPPFLAGS="$CPPFLAGS"
1028
1029   for dir in `echo "/usr/local /usr/pkg /usr/contrib"`; do
1030     if test x$has_iconv = xfalse; then
1031       AC_MSG_RESULT(searching in $dir...)
1032
1033       if test -d $dir/include; then
1034         CPPFLAGS="$CPPFLAGS -I$dir/include"
1035         CFLAGS="$CFLAGS -I$dir/include"
1036       fi
1037       if test -d $dir/lib; then
1038         LDFLAGS="$LDFLAGS -L$dir/lib"
1039       fi
1040
1041       # XXX
1042       unset ac_cv_header__iconv_h_ ac_cv_header_iconv_h || true
1043
1044       AC_CHECK_HEADERS(iconv.h,
1045         [
1046           LIBS="$LIBS -liconv"
1047           AC_MSG_CHECKING(for iconv in -liconv)
1048           AC_TRY_LINK(
1049             [
1050               #include <stdlib.h>
1051               #include <iconv.h>
1052             ],
1053             [
1054               iconv_t cd = iconv_open("", "");
1055               iconv(cd, NULL, NULL, NULL, NULL);
1056               iconv_close(cd);
1057             ],
1058             [
1059               echo "yes"
1060               has_iconv=true
1061               AC_DEFINE([HAVE_ICONV], [], [Define if you have the iconv() function.])
1062             ],
1063             [
1064               echo "no"
1065               has_iconv=false
1066
1067               LIBS="$SAVE_LIBS"
1068               CFLAGS="$SAVE_CFLAGS"
1069               LDFLAGS="$SAVE_LDFLAGS"
1070               CPPFLAGS="$SAVE_CPPFLAGS"
1071             ])
1072          ],
1073          [
1074            CFLAGS="$SAVE_CFLAGS"
1075            LDFLAGS="$SAVE_LDFLAGS"
1076            CPPFLAGS="$SAVE_CPPFLAGS"
1077          ])
1078       fi
1079     done
1080 fi
1081
1082 if test x$has_iconv = xtrue; then
1083   # (1) Some implementations of iconv won't convert from UTF-8 to UTF-8.
1084   # (2) In glibc-2.1.2 and earlier there is a bug that messes up ob and
1085   #     obl when args 2 and 3 are 0 (fixed in glibc-2.1.3).
1086   #
1087   AC_CACHE_CHECK([whether this iconv is good enough], ac_iconv_good,
1088     AC_TRY_RUN(
1089       [
1090         #include <iconv.h>
1091         int main() {
1092           iconv_t cd;
1093         changequote(, )dnl
1094           char buf[4];
1095         changequote([, ])dnl
1096           char *ob;
1097           size_t obl;
1098           ob = buf, obl = sizeof(buf);
1099           return ((cd = iconv_open("UTF-8", "UTF-8")) != (iconv_t)(-1) &&
1100                  (iconv(cd, 0, 0, &ob, &obl) ||
1101                  !(ob == buf && obl == sizeof(buf)) ||
1102                  iconv_close(cd)));
1103         }
1104       ],
1105       [
1106         ac_iconv_good=yes
1107       ],
1108       [
1109         ac_iconv_good=no
1110       ],
1111       [
1112         ac_iconv_good=yes
1113       ])
1114     )
1115
1116   if test x$ac_iconv_good = xno; then
1117     AC_MSG_RESULT(Try using libiconv instead.)
1118   fi
1119 fi
1120
1121 # POSIX threads support
1122 #
1123 AC_MSG_CHECKING(whether to search for POSIX threads)
1124 AC_ARG_WITH(pthreads,
1125   [[  --with-pthreads[=DIR]   use POSIX threads [search in DIR/include and DIR/lib]]],
1126   [
1127     case "${withval}" in
1128       no)
1129         check_threads=false
1130         ;;
1131       *)
1132         if test -d $withval/include; then
1133           CPPFLAGS="$CPPFLAGS -I$withval/include"
1134           CFLAGS="$CFLAGS -I$withval/include"
1135         fi
1136         if test -d $withval/lib; then
1137           LDFLAGS="$LDFLAGS -L$withval/lib"
1138         fi
1139
1140         check_threads=true
1141         ;;
1142     esac
1143   ])
1144
1145 if test x$check_threads = xtrue; then
1146   has_threads=false
1147   SAVE_LIBS="$LIBS"
1148   SAVE_CFLAGS="$CFLAGS"
1149   SAVE_LDFLAGS="$LDFLAGS"
1150   SAVE_CPPFLAGS="$CPPFLAGS"
1151
1152   AC_MSG_RESULT(yes)
1153   AC_CHECK_HEADERS(pthread.h,
1154     [
1155       LIBS="$LIBS -lpthread"
1156       AC_CHECK_LIB(pthread, pthread_attr_init, has_threads=true,
1157         [
1158           # FreeBSD
1159           case "${target}" in
1160             *-*-freebsd*)
1161               LIBS="$SAVE_LIBS -pthread"
1162               AC_CHECK_LIB(c_r, pthread_attr_init, has_threads=true, LIBS="$SAVE_LIBS")
1163               ;;
1164             *)
1165               LIBS="$SAVE_LIBS"
1166               ;;
1167           esac
1168         ])
1169     ],
1170     [
1171       # search for pthread library..
1172       for dir in `echo "/usr/local /usr/pkg /usr/contrib /usr/pkg/pthreads /usr/local/pthreads"`; do
1173         if test x$has_threads = xfalse; then
1174           AC_MSG_RESULT(searching in $dir...)
1175
1176           if test -d $dir/include; then
1177             CPPFLAGS="$CPPFLAGS -I$dir/include"
1178             CFLAGS="$CFLAGS -I$dir/include"
1179           fi
1180           if test -d $dir/lib; then
1181             LDFLAGS="$LDFLAGS -L$dir/lib"
1182           fi
1183
1184           # XXX
1185           unset ac_cv_header__pthread_h_ ac_cv_header_pthread_h || true
1186
1187           AC_CHECK_HEADERS(pthread.h,
1188             [
1189               LIBS="$LIBS -lpthread"
1190               AC_CHECK_LIB(pthread, pthread_attr_init, has_threads=true,
1191                 [
1192                   has_threads=false
1193
1194                   LIBS="$SAVE_LIBS"
1195                   CFLAGS="$SAVE_CFLAGS"
1196                   LDFLAGS="$SAVE_LDFLAGS"
1197                   CPPFLAGS="$SAVE_CPPFLAGS"
1198                 ])
1199             ],
1200             [
1201               CFLAGS="$SAVE_CFLAGS"
1202               LDFLAGS="$SAVE_LDFLAGS"
1203               CPPFLAGS="$SAVE_CPPFLAGS"
1204             ])
1205         fi
1206       done
1207     ])
1208 else
1209   AC_MSG_RESULT(no)
1210   has_threads=false
1211 fi
1212
1213 __SILC_HAVE_PTHREAD=""
1214 AM_CONDITIONAL(SILC_THREADS, test x$has_threads = xtrue)
1215 if test x$has_threads = xtrue; then
1216   CFLAGS="$CFLAGS -D_REENTRANT"
1217
1218   # XXX possibly incomplete
1219   case "${target}" in
1220     *-*-aix*)
1221       CFLAGS="$CFLAGS -D_THREAD_SAFE"
1222       if test x"$GCC" = xyes; then
1223         CFLAGS="$CFLAGS -mthreads"
1224       fi
1225       ;;
1226     *-*-freebsd*)
1227       CFLAGS="$CFLAGS -D_THREAD_SAFE"
1228       ;;
1229     *-*-sysv5uw7*)  # UnixWare 7
1230       if test "$GCC" != "yes"; then
1231         CFLAGS="$CFLAGS -Kthread"
1232       else
1233         CFLAGS="$CFLAGS -pthread"
1234       fi
1235       ;;
1236     *-dg-dgux*)  # DG/UX
1237       CFLAGS="$CFLAGS -D_POSIX4A_DRAFT10_SOURCE"
1238       ;;
1239    esac
1240
1241   # Check for threads
1242   AC_CHECK_FUNCS(pthread_create pthread_key_create pthread_once)
1243
1244   # Check for read/write locks
1245   AC_CHECK_FUNC(pthread_rwlock_init,
1246   [
1247     AC_RUN_IFELSE(
1248       [
1249         #include <pthread.h>
1250         int main()
1251         {
1252           pthread_rwlock_t rwlock;
1253           pthread_rwlock_init(&rwlock, NULL);
1254           pthread_rwlock_destroy(&rwlock);
1255           return 0;
1256         }
1257       ],
1258       [],
1259       [
1260         # Rwlock not defined
1261         CFLAGS="$CFLAGS -D_XOPEN_SOURCE=600"
1262       ]
1263     )
1264   ],
1265   [
1266     # Rwlock not defined
1267     CFLAGS="$CFLAGS -D_XOPEN_SOURCE=600"
1268   ])
1269
1270   AC_DEFINE([SILC_HAVE_PTHREAD], [], [HAVE_PTHREAD])
1271   AC_DEFINE([SILC_THREADS], [], [HAVE_THREAD])
1272   __SILC_HAVE_PTHREAD="#define __SILC_HAVE_PTHREAD 1"
1273 fi
1274
1275 #
1276 # Check for timezone and tm_gmtoff for timezone information
1277 #
1278 AC_MSG_CHECKING(whether system has timezone)
1279 AC_RUN_IFELSE(
1280   [
1281     #include <stdio.h>
1282     #include <time.h>
1283     int main()
1284     {
1285       timezone = 0;
1286       return 0;
1287     }
1288   ],
1289   [ AC_MSG_RESULT(yes)
1290     AC_DEFINE([HAVE_TIMEZONE], [], [HAVE_TIMEZONE]) ],
1291   [ AC_MSG_RESULT(no) ],
1292   [ AC_MSG_RESULT(no) ]
1293 )
1294 AC_MSG_CHECKING(whether system has tm_gmtoff)
1295 AC_RUN_IFELSE(
1296   [
1297     #include <stdio.h>
1298     #include <time.h>
1299     int main()
1300     {
1301       struct tm tm;
1302       tm.tm_gmtoff = 0;
1303       return 0;
1304     }
1305   ],
1306   [ AC_MSG_RESULT(yes)
1307     AC_DEFINE([HAVE_TM_GMTOFF], [], [HAVE_TM_GMTOFF]) ],
1308   [ AC_MSG_RESULT(no) ],
1309   [ AC_MSG_RESULT(no) ]
1310 )
1311 AC_MSG_CHECKING(whether system has __tm_gmtoff)
1312 AC_RUN_IFELSE(
1313   [
1314     #include <stdio.h>
1315     #include <time.h>
1316     int main()
1317     {
1318       struct tm tm;
1319       tm.__tm_gmtoff = 0;
1320       return 0;
1321     }
1322   ],
1323   [ AC_MSG_RESULT(yes)
1324     AC_DEFINE([HAVE___TM_GMTOFF], [], [HAVE___TM_GMTOFF]) ],
1325   [ AC_MSG_RESULT(no) ],
1326   [ AC_MSG_RESULT(no) ]
1327 )
1328 AC_MSG_CHECKING(whether system has __tm_gmtoff__)
1329 AC_RUN_IFELSE(
1330   [
1331     #include <stdio.h>
1332     #include <time.h>
1333     int main()
1334     {
1335       struct tm tm;
1336       tm.__tm_gmtoff__ = 0;
1337       return 0;
1338     }
1339   ],
1340   [ AC_MSG_RESULT(yes)
1341     AC_DEFINE([HAVE___TM_GMTOFF__], [], [HAVE___TM_GMTOFF__]) ],
1342   [ AC_MSG_RESULT(no) ],
1343   [ AC_MSG_RESULT(no) ]
1344 )
1345
1346 # Native WIN32 compilation under cygwin
1347 #
1348 AC_MSG_CHECKING(whether to compile native WIN32 code)
1349 AC_ARG_WITH(win32,
1350   [  --with-win32            compile native WIN32 (MinGW) code (-mno-cygwin)],
1351   [
1352     AC_MSG_RESULT(yes)
1353     AC_DEFINE([SILC_WIN32], [], [SILC_WIN32])
1354     win32_support=true
1355     CFLAGS="-mno-cygwin $CFLAGS"
1356     LIBS="$LIBS -lwsock32"
1357   ],
1358   [
1359     AC_MSG_RESULT(no)
1360   ])
1361 AM_CONDITIONAL(SILC_WIN32, test x$win32_support = xtrue)
1362
1363 # Native Symbian OS support (disabled by default)
1364 #
1365 AM_CONDITIONAL(SILC_SYMBIAN, test xfalse = xtrue)
1366
1367 # Native BeOS support (disabled by default)
1368 #
1369 AM_CONDITIONAL(SILC_BEOS, test xfalse = xtrue)
1370
1371 # Native OS2 support (disabled by default)
1372 #
1373 AM_CONDITIONAL(SILC_OS2, test xfalse = xtrue)
1374
1375 #ifdef SILC_DIST_SERVER
1376 without_silcd=false
1377 #endif SILC_DIST_SERVER
1378 #ifdef SILC_DIST_CLIENT
1379 AM_CONDITIONAL(with_irssi, true)
1380 #endif SILC_DIST_CLIENT
1381 #ifdef SILC_DIST_INPLACE
1382 without_irssi=false
1383 without_silcd=false
1384 #endif SILC_DIST_INPLACE
1385
1386 libtoolfix=true
1387 AC_MSG_CHECKING(whether to do libtoolfix)
1388 AC_ARG_WITH(libtoolfix,
1389   [  --without-libtoolfix    Do not fix libtool, for package builders],
1390   [
1391     AC_MSG_RESULT(no)
1392     libtoolfix=false
1393   ],
1394   [
1395     AC_MSG_RESULT(yes)
1396   ])
1397
1398 AC_SUBST(ETCDIR)
1399 AC_DEFINE_UNQUOTED([SILC_ETCDIR], "$ETCDIR", [SILC_ETCDIR])
1400 #endif SILC_DIST_COMPILER
1401
1402 ##
1403 ##  Misc
1404 ##
1405
1406 # Make enable-shared aware
1407 AM_CONDITIONAL(SILC_ENABLE_SHARED, test "$enable_shared" = yes)
1408
1409 SILC_TOP_SRCDIR=`pwd`
1410
1411 # Included configure scripts
1412 AD_INCLUDE_CONFIGURE
1413
1414 #ifdef SILC_DIST_COMPILER
1415 #
1416 # Substitutions
1417 #
1418 AC_SUBST(LIBSUBDIR)
1419 AC_SUBST(SILC_TOP_SRCDIR)
1420 AC_SUBST(LDFLAGS)
1421 AC_SUBST(LIBS)
1422 AC_SUBST(SILC_LIB_INCLUDES)
1423 AC_SUBST(__SILC_HAVE_PTHREAD)
1424 AC_SUBST(__SILC_HAVE_SIM)
1425 AC_SUBST(__SILC_ENABLE_DEBUG)
1426 AC_SUBST(__SILC_PACKAGE_VERSION)
1427
1428 #
1429 # Fix the libtool to support run-time configuration.  This allows us
1430 # to in run-time specify when to compile shared/static libraries without
1431 # need to reconfigure the entire libtool.
1432 #
1433 if test x$libtoolfix = xtrue; then
1434   ./libtoolfix $SILC_TOP_SRCDIR/ltmain.sh
1435 fi
1436 AM_CONDITIONAL(SILC_LIBTOOLFIX, test x$libtoolfix = xtrue)
1437
1438 INCLUDE_DEFINES_INT="include \$(top_srcdir)/Makefile.defines_int"
1439 AC_SUBST(INCLUDE_DEFINES_INT)
1440
1441 #endif SILC_DIST_COMPILER
1442
1443 #
1444 # Makefile outputs
1445 #
1446 AC_CONFIG_FILES(
1447 Makefile
1448 #ifdef SILC_DIST_DOC
1449 doc/Makefile
1450 #endif SILC_DIST_DOC
1451 #ifdef SILC_DIST_COMPILER
1452 Makefile.defines
1453 Makefile.defines_int
1454 includes/Makefile
1455 includes/silcversion.h
1456 includes/silc.h
1457 #endif SILC_DIST_COMPILER
1458 #ifdef SILC_DIST_APPS
1459 apps/Makefile
1460 #endif SILC_DIST_APPS
1461 )
1462
1463 #ifdef SILC_DIST_TOOLKIT
1464 AC_CONFIG_FILES(
1465 win32/Makefile
1466 win32/libsilc/Makefile
1467 win32/libsilcclient/Makefile
1468 tutorial/Makefile
1469 tutorial/Makefile.defines
1470 tutorial/Makefile.defines_int
1471 )
1472 #endif SILC_DIST_TOOLKIT
1473
1474 AC_OUTPUT
1475
1476 #ifdef SILC_DIST_COMPILER
1477 s_bindir=`eval echo $bindir`;s_bindir=`eval echo $s_bindir`
1478 s_sbindir=`eval echo $sbindir`;s_sbindir=`eval echo $s_sbindir`
1479 s_mandir=`eval echo $mandir`;s_mandir=`eval echo $s_mandir`
1480 s_includedir=`eval echo $includedir`;s_includedir=`eval echo $s_includedir`
1481
1482 echo ""
1483 echo "$PACKAGE Configuration Summary:"
1484 echo "---------------------------"
1485 echo " Target host ...................: $target"
1486 echo " Compiler ......................: $CC"
1487 echo " CFLAGS ........................: $CFLAGS"
1488 echo " LDFLAGS .......................: $LDFLAGS"
1489 echo " LIBS ..........................: $LIBS"
1490 echo ""
1491 echo " Installation prefix ...........: $prefix"
1492 echo " bin directory .................: $s_bindir"
1493 echo " sbin directory ................: $s_sbindir"
1494 echo " etc directory .................: $ETCDIR"
1495 echo " man directory .................: $s_mandir"
1496 echo " doc directory .................: $DOCDIR"
1497 #ifdef SILC_DIST_SIM
1498 echo " SIM directory .................: $MODULESDIR"
1499 #endif SILC_DIST_SIM
1500 #ifdef SILC_DIST_INCLUDES
1501 echo " include directory .............: $s_includedir"
1502 #endif SILC_DIST_INCLUDES
1503 echo ""
1504
1505 #ifdef SILC_DIST_CLIENT
1506 if test x$without_irssi = xtrue; then
1507   irssi="no"
1508 fi
1509 echo " Compile SILC Client ...........: $irssi"
1510 #endif SILC_DIST_CLIENT
1511
1512 #ifdef SILC_DIST_SERVER
1513 if test x$without_silcd = xtrue; then
1514   silcd="no"
1515 fi
1516 echo " Compile SILC Server ...........: $silcd"
1517 #endif SILC_DIST_SERVER
1518
1519 #ifdef SILC_DIST_SIM
1520 if test x$sim_support = xfalse; then
1521   sim_support="no"
1522 else
1523   sim_support="yes"
1524 fi
1525 echo " SIM support ...................: $sim_support"
1526 #endif SILC_DIST_SIM
1527
1528 echo " IPv6 support ..................: $summary_ipv6"
1529
1530 if test x$has_iconv = xfalse; then
1531   iconv_support="no"
1532 else
1533   iconv_support="yes"
1534 fi
1535 echo " Iconv support .................: $iconv_support"
1536
1537 if test x$want_asm = xfalse; then
1538   summary_asm="no"
1539 else
1540   summary_asm="yes"
1541 fi
1542 echo " Assembler optimizations .......: $summary_asm"
1543
1544 #ifdef SILC_DIST_MATH
1545 if test x$mp_gmp = xtrue; then
1546   echo " Arithmetic library ............: GMP"
1547 fi
1548 #endif SILC_DIST_MATH
1549
1550 threads="no"
1551 if test x$has_threads = xtrue; then
1552   threads="yes"
1553 fi
1554 echo " Multi-threads support .........: $threads"
1555 echo " Debugging enabled .............: $summary_debug"
1556 echo ""
1557 echo "Compile the sources with 'make' or 'gmake' command."
1558 #endif SILC_DIST_COMPILER