configure.ad

   1 #
   2 #  configure.ad
   3 #
   4 #  Author: Pekka Riikonen <priikone@silcnet.org>
   5 #
   6 #  Copyright (C) 2000 - 2005 Pekka Riikonen
   7 #
   8 #  This program is free software; you can redistribute it and/or modify
   9 #  it under the terms of the GNU General Public License as published by
  10 #  the Free Software Foundation; version 2 of the License.
  11 #
  12 #  This program is distributed in the hope that it will be useful,
  13 #  but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #  GNU General Public License for more details.
  16 #
  17
  18 AD_INIT
  19 AC_CANONICAL_SYSTEM
  20 AM_INIT_AUTOMAKE
  21 AC_PREREQ(2.52)
  22 AC_CONFIG_HEADERS(silcdefs.h)
  23
  24 AC_PROG_INSTALL
  25 AC_PROG_MAKE_SET
  26
  27 AC_PROG_LN_S
  28 AC_PROG_EGREP
  29 AC_SUBST(LN_S)
  30 AC_PATH_PROG(sedpath, sed)
  31
  32 #ifdef SILC_DIST_COMPILER
  33 # Put here any platform specific stuff
  34 #
  35 case "$target" in
  36   *-*-freebsd*)
  37     check_threads=true
  38     ;;
  39   *-*-*bsd*)
  40     check_threads=false
  41     ;;
  42   *)
  43     check_threads=true
  44     ;;
  45 esac
  46
  47 CFLAGS=
  48 AC_PROG_CC
  49 AC_C_INLINE
  50 AC_C_CONST
  51
  52 __SILC_HAVE_PTHREAD=""
  53 __SILC_HAVE_SIM=""
  54 __SILC_ENABLE_DEBUG=""
  55
  56 AC_PROG_RANLIB
  57 AC_DISABLE_SHARED
  58 AC_PROG_LIBTOOL
  59
  60 # Header checking
  61 #
  62 AC_HEADER_STDC
  63 AC_HEADER_TIME
  64 AC_HEADER_STAT
  65
  66 # More header checking
  67 #
  68 AC_CHECK_HEADERS(unistd.h string.h getopt.h errno.h fcntl.h assert.h)
  69 AC_CHECK_HEADERS(sys/types.h sys/stat.h sys/time.h stddef.h)
  70 AC_CHECK_HEADERS(netinet/in.h netinet/tcp.h xti.h netdb.h sys/resource.h)
  71 AC_CHECK_HEADERS(pwd.h grp.h termcap.h paths.h)
  72 AC_CHECK_HEADERS(ncurses.h signal.h ctype.h utime.h)
  73 AC_CHECK_HEADERS(arpa/inet.h sys/mman.h limits.h termios.h locale.h langinfo.h)
  74
  75 # Data type checking
  76 #
  77 AC_TYPE_SIGNAL
  78 AC_TYPE_SIZE_T
  79 AC_TYPE_MODE_T
  80 AC_TYPE_UID_T
  81 AC_TYPE_PID_T
  82
  83 AC_CHECK_SIZEOF(long long, 0)
  84 AC_SUBST(SILC_SIZEOF_LONG_LONG, $ac_cv_sizeof_long_long)
  85 AC_CHECK_SIZEOF(long, 0)
  86 AC_SUBST(SILC_SIZEOF_LONG, $ac_cv_sizeof_long)
  87 AC_CHECK_SIZEOF(int, 0)
  88 AC_SUBST(SILC_SIZEOF_INT, $ac_cv_sizeof_int)
  89 AC_CHECK_SIZEOF(short, 0)
  90 AC_SUBST(SILC_SIZEOF_SHORT, $ac_cv_sizeof_short)
  91 AC_CHECK_SIZEOF(char, 0)
  92 AC_SUBST(SILC_SIZEOF_CHAR, $ac_cv_sizeof_char)
  93 AC_CHECK_SIZEOF(void *, 0)
  94 AC_SUBST(SILC_SIZEOF_VOID_P, $ac_cv_sizeof_void_p)
  95
  96 # Function and library checking
  97 #
  98 AC_CHECK_FUNC(gethostbyname, [],
  99   [
 100     AC_CHECK_LIB(nsl, gethostbyname, LIBS="$LIBS -lnsl")
 101     AC_CHECK_FUNC(res_gethostbyname, [],
 102        AC_CHECK_LIB(resolv, res_gethostbyname, LIBS="$LIBS -lresolv")
 103     )
 104   ])
 105 AC_CHECK_FUNC(socket, [],
 106   AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
 107 )
 108 AC_CHECK_FUNCS(gethostname gethostbyaddr getservbyname getservbyport)
 109 AC_CHECK_FUNCS(select listen bind shutdown close connect setsockopt)
 110 AC_CHECK_FUNCS(time ctime utime gettimeofday getrusage)
 111 AC_CHECK_FUNCS(chmod fcntl stat fstat getenv putenv strerror)
 112 AC_CHECK_FUNCS(getpid getgid getsid getpgid getpgrp getuid)
 113 AC_CHECK_FUNCS(setgroups initgroups nl_langinfo)
 114 AC_CHECK_FUNCS(strchr strstr strcpy strncpy memcpy memset memmove)
 115
 116 #ifdef SILC_DIST_SIM
 117 # SIM support checking
 118 # XXX These needs to be changed as more supported platforms appear.
 119 # XXX This probably needs to be made platform dependant check.
 120 #
 121 sim_support=false
 122 AC_MSG_CHECKING(for SIM support)
 123 AC_MSG_RESULT()
 124 AC_CHECK_HEADERS(dlfcn.h,
 125   [
 126     AC_CHECK_LIB(dl, dlopen,
 127       [
 128         AC_DEFINE([SILC_SIM], [], [HAVE_SIM])
 129         sim_support=true
 130         LIBS="$LIBS -ldl"
 131       ],
 132       [
 133         AC_CHECK_LIB(c, dlopen,
 134           [
 135             AC_DEFINE([SILC_SIM], [], [HAVE_SIM])
 136             sim_support=true
 137           ])
 138       ])
 139    ])
 140
 141 AM_CONDITIONAL(SILC_SIM, test x$sim_support = xtrue)
 142 if test x$sim_support = xtrue; then
 143   AC_MSG_RESULT(Enabled SIM support.)
 144   __SILC_HAVE_SIM="#define __SILC_HAVE_SIM 1"
 145 else
 146   AC_MSG_RESULT(No SIM support found.)
 147 fi
 148 #endif SILC_DIST_SIM
 149
 150 # lib/contrib conditionals
 151 #
 152 AC_CHECK_HEADER(regex.h,
 153   [
 154     AC_DEFINE([HAVE_REGEX], [], [HAVE_REGEX])
 155     have_regex=1
 156   ], have_regex=0
 157 )
 158 AM_CONDITIONAL(HAVE_REGEX, test x$have_regex = x1)
 159
 160 AC_CHECK_FUNC(getopt_long,
 161   [
 162     AC_DEFINE([HAVE_GETOPT_LONG], [], [HAVE_GETOPT_LONG])
 163     have_getopt_long=1
 164   ], have_getopt_long=0
 165 )
 166 AM_CONDITIONAL(HAVE_GETOPT_LONG, test x$have_getopt_long = x1)
 167
 168 ##
 169 ##  Enable/disable checking
 170 ##
 171
 172 # IPv6 support
 173 #
 174 AC_MSG_CHECKING(whether to enable IPv6 support)
 175 AC_ARG_ENABLE(ipv6,
 176   [  --enable-ipv6           enable IPv6 support],
 177   [
 178     case "${enableval}" in
 179       yes)
 180         want_ipv6=true
 181         check_ipv6=false
 182         summary_ipv6="yes"
 183         AC_DEFINE([HAVE_IPV6], [], [HAVE_IPV6])
 184         AC_MSG_RESULT(yes)
 185         ;;
 186       *)
 187         want_ipv6=false
 188         check_ipv6=false
 189         summary_ipv6="no"
 190         AC_MSG_RESULT(no)
 191         ;;
 192     esac
 193   ],
 194     check_ipv6=true
 195   )
 196
 197 if test x$check_ipv6 = xtrue; then
 198   summary_ipv6="no"
 199   AC_TRY_COMPILE(
 200     [
 201       #ifdef HAVE_SYS_TYPES_H
 202       #include <sys/types.h>
 203       #endif
 204       #ifdef HAVE_NETINET_TCP_H
 205       #include <netinet/tcp.h>
 206       #endif
 207       #ifdef HAVE_NETDB_H
 208       #include <netdb.h>
 209       #endif
 210       #include <sys/socket.h>
 211       #ifdef HAVE_NETINET_IN_H
 212       #include <netinet/in.h>
 213       #endif
 214     ],
 215     [
 216       struct sockaddr_in6 sin6;
 217       int family = AF_INET6;
 218     ],
 219     [
 220       AC_DEFINE([HAVE_IPV6], [], [HAVE_IPV6])
 221       AC_MSG_RESULT(yes)
 222       summary_ipv6="yes"
 223     ],
 224       AC_MSG_RESULT(no)
 225     )
 226 fi
 227
 228 # Debug checking
 229 #
 230 AC_MSG_CHECKING(whether to enable debugging)
 231 summary_debug="no"
 232 __SILC_ENABLE_DEBUG=""
 233 AC_ARG_ENABLE(debug,
 234   [  --enable-debug          enable debugging],
 235   [
 236     case "${enableval}" in
 237       yes)
 238         AC_MSG_RESULT(yes)
 239         AC_DEFINE([SILC_DEBUG], [], [enable-debug])
 240         summary_debug="yes"
 241         __SILC_ENABLE_DEBUG="#define __SILC_ENABLE_DEBUG 1"
 242         ;;
 243       *)
 244         AC_MSG_RESULT(no)
 245         ;;
 246     esac
 247   ],
 248   [
 249     AC_MSG_RESULT(no)
 250   ])
 251
 252 # Disable all assembler optimizations
 253 #
 254 AC_MSG_CHECKING(whether to enable assembler optimizations)
 255 want_asm=true
 256 AC_ARG_ENABLE(asm,
 257   [  --disable-asm           do not use assembler optimizations],
 258   [
 259     AC_MSG_RESULT(no)
 260     want_asm=false
 261   ],
 262   [
 263     AC_MSG_RESULT(yes)
 264     want_asm=true
 265   ])
 266
 267 ##
 268 ## Compiler and compiler flag checks
 269 ##
 270
 271 # Function to check if compiler flag works
 272 # Usage: SILC_ADD_CFLAGS(FLAGS, [ACTION-IF-FAILED])
 273 AC_DEFUN([SILC_ADD_CFLAGS],
 274 [ tmp_CFLAGS="$CFLAGS"
 275   CFLAGS="$CFLAGS $1"
 276   AC_MSG_CHECKING(whether $CC accepts $1 flag)
 277   AC_TRY_LINK([], [], [AC_MSG_RESULT(yes)], [AC_MSG_RESULT(no)
 278                                        CFLAGS="$tmp_CFLAGS"
 279                                        $2])
 280   unset tmp_CFLAGS
 281 ])
 282
 283 if test "$GCC"; then
 284   # GCC specific options
 285   if test "x$summary_debug" = "xyes"; then
 286     SILC_ADD_CFLAGS(-g -O)
 287   else
 288     SILC_ADD_CFLAGS(-g -O2)
 289   fi
 290   SILC_ADD_CFLAGS(-Wall -finline-functions)
 291 else
 292   # Other compilers
 293   case "$target" in
 294     alpha*-dec-osf*)
 295       SILC_ADD_CFLAGS(-g3 -O2, SILC_ADD_CFLAGS(-g3 -O, SILC_ADD_CFLAGS(-O)))
 296       ;;
 297     *)
 298       SILC_ADD_CFLAGS(-g)
 299       SILC_ADD_CFLAGS(-O2, SILC_ADD_CFLAGS(-O))
 300       ;;
 301   esac
 302
 303   # Intel C++ Compiler needs -restrict
 304   if test "x$CC" = "xicc"; then
 305     SILC_ADD_CFLAGS(-restrict)
 306   fi
 307 fi
 308
 309 #
 310 # Workaround a bug in GCC 2.x which causes memory exhaustion
 311 # when compiling sha1 with optimizations on UltraSPARC.
 312 #
 313 FIX_SHA1='#'
 314 if test "$GCC" -a "$host_cpu" = "sparc64"; then
 315   AC_MSG_CHECKING(whether to enable GCC 2.x workaround for SHA1)
 316   AC_TRY_COMPILE(
 317     [
 318       #if defined(__sparc64__) && (__GNUC__ == 2)
 319       #else
 320       choke me
 321       #endif
 322     ],
 323     [],
 324     [
 325       FIX_SHA1=''
 326       AC_MSG_RESULT(yes)
 327     ],
 328       AC_MSG_RESULT(no)
 329     )
 330 fi
 331 AC_SUBST(FIX_SHA1)
 332 #endif SILC_DIST_COMPILER
 333
 334 ##
 335 ##  Installation
 336 ##
 337
 338 # Default installation destination
 339 #
 340 #ifdef SILC_DIST_AUTODIST
 341 AC_PREFIX_DEFAULT(/usr/local)
 342 #else !SILC_DIST_AUTODIST
 343 AC_PREFIX_DEFAULT(/usr/local/silc)
 344 #endif SILC_DIST_AUTODIST
 345 if test "x$prefix" != xNONE; then
 346   silc_prefix="$prefix"
 347 else
 348   silc_prefix="$ac_default_prefix"
 349 fi
 350
 351 #ifndef SILC_DIST_AUTODIST
 352 # etc directory
 353 #
 354 if test "x$sysconfdir" != 'x${prefix}/etc'; then
 355   ETCDIR="$sysconfdir"
 356 else
 357   ETCDIR="$silc_prefix/etc"
 358 fi
 359
 360 AC_ARG_WITH(etcdir,
 361   [[  --with-etcdir=DIR       directory for system files [/etc/silc]]],
 362   [
 363     case "$withval" in
 364       no|yes)
 365         ;;
 366       *)
 367         ETCDIR="$withval"
 368         ;;
 369     esac
 370   ])
 371 AC_SUBST(ETCDIR)
 372 AC_DEFINE_UNQUOTED([SILC_ETCDIR], "$ETCDIR", [SILC_ETCDIR])
 373
 374 # doc directory
 375 #
 376 DOCDIR="$silc_prefix/doc"
 377 AC_ARG_WITH(docdir,
 378   [[  --with-docdir=DIR       directory for SILC documentation [PREFIX/doc]]],
 379   [
 380     case "$withval" in
 381       no|yes)
 382         ;;
 383       *)
 384         DOCDIR="$withval"
 385         ;;
 386     esac
 387   ])
 388 AC_SUBST(DOCDIR)
 389 AC_DEFINE_UNQUOTED([SILC_DOCDIR], "$DOCDIR", [SILC_DOCDIR])
 390 #endif SILC_DIST_AUTODIST
 391
 392 #ifdef SILC_DIST_CLIENT
 393 # help directory
 394 #
 395 HELPDIR="$silc_prefix/help"
 396 AC_ARG_WITH(helpdir,
 397   [[  --with-helpdir=DIR      directory for SILC help files [PREFIX/help]]],
 398   [
 399     case "$withval" in
 400       no|yes)
 401         ;;
 402       *)
 403        HELPDIR="$withval"
 404        ;;
 405     esac
 406   ])
 407 AC_SUBST(HELPDIR)
 408 AC_DEFINE_UNQUOTED([SILC_HELPDIR], "$HELPDIR", [SILC_HELPDIR])
 409 #endif SILC_DIST_CLIENT
 410
 411 #ifdef SILC_DIST_SIM
 412 # SIM modules directory
 413 #
 414 MODULESDIR="$silc_prefix/modules"
 415 AC_ARG_WITH(simdir,
 416   [[  --with-simdir=DIR       directory for SIM modules [PREFIX/modules]]],
 417   [
 418     case "$withval" in
 419       no|yes)
 420         ;;
 421       *)
 422         MODULESDIR="$withval"
 423         ;;
 424     esac
 425   ])
 426 AC_SUBST(MODULESDIR)
 427 AC_DEFINE_UNQUOTED([SILC_MODULESDIR], "$MODULESDIR", [SILC_MODULESDIR])
 428 #endif SILC_DIST_SIM
 429
 430 #ifdef SILC_DIST_SERVER
 431 # Logs directory
 432 #
 433 LOGSDIR="$silc_prefix/logs"
 434 AC_ARG_WITH(logsdir,
 435   [[  --with-logsdir=DIR      directory for SILC Server logs [PREFIX/logs]]],
 436   [
 437     case "$withval" in
 438       no|yes)
 439         ;;
 440       *)
 441         LOGSDIR="$withval"
 442         ;;
 443     esac
 444   ])
 445 AC_SUBST(LOGSDIR)
 446 AC_DEFINE_UNQUOTED([SILC_LOGSDIR], "$LOGSDIR", [SILC_LOGSDIR])
 447
 448 # silcd config file checking
 449 #
 450 summary_silcd_configfile="/etc/silc/silcd.conf"
 451 AC_ARG_WITH(silcd-config-file,
 452   [[  --with-silcd-config-file=FILE  use FILE as default configuration file
 453                                  for SILC Server [/etc/silc/silcd.conf]]],
 454     AC_DEFINE_UNQUOTED([SILC_SERVER_CONFIG_FILE], "$withval", [SILC_SERVER_CONFIG_FILE])
 455     summary_silcd_configfile="$withval"
 456   )
 457
 458 # silcd pid file checking
 459 #
 460 if test "x$localstatedir" != 'x${prefix}/var'; then
 461   PIDFILE="$localstatedir/silcd.pid"
 462 else
 463   PIDFILE="$silc_prefix/var/silcd.pid"
 464 fi
 465
 466 AC_ARG_WITH(silcd-pid-file,
 467   [[  --with-silcd-pid-file=FILE     use FILE as default pid file for SILC
 468                                  Server [/var/run/silcd.pid]]],
 469   [
 470     case "$withval" in
 471       no|yes)
 472         ;;
 473       *)
 474         PIDFILE="$withval"
 475         ;;
 476     esac
 477   ])
 478 AC_SUBST(PIDFILE)
 479 #endif SILC_DIST_SERVER
 480
 481 #ifdef SILC_DIST_COMPILER
 482 ##
 483 ##  With/without checkings
 484 ##
 485
 486 #
 487 # SILC library checking
 488 compile_libs=true
 489
 490 #ifndef SILC_DIST_TOOLKIT
 491 AC_ARG_WITH(silc-includes,
 492   [  --with-silc-includes=DIR SILC Toolkit includes [search in DIR]],
 493   [ac_silc_includes="$withval"], [ac_silc_includes="no"])
 494 AC_ARG_WITH(silc-libs,
 495   [  --with-silc-libs=DIR     SILC Toolkit libraries [search in DIR]],
 496   [ac_silc_libs="$withval"], [ac_silc_libs="no"])
 497
 498 if test -n "$with_silc_includes" || test -n "$with_silc_libs"; then
 499
 500   # Manually provided libs
 501   if test "$ac_silc_includes" != "no"; then
 502     compile_libs=false
 503     SILC_LIB_INCLUDES="-I$ac_silc_includes"
 504   fi
 505   if test "$ac_silc_libs" != "no"; then
 506     compile_libs=false
 507     LIBS="$LIBS -L$ac_silc_libs"
 508   fi
 509
 510   # Check libs to link against
 511   f=`$EGREP __SILC_HAVE_PTHREAD $ac_silc_includes/silcincludes.h`
 512   if test -n "$f"; then
 513     LIBS="$LIBS -lpthread"
 514   fi
 515   f=`$EGREP __SILC_HAVE_SIM $ac_silc_includes/silcincludes.h`
 516   if test -n "$f"; then
 517     LIBS="$LIBS -ldl"
 518   fi
 519
 520 else
 521   # pkg-config check
 522   PKG_CHECK_MODULES(SILC, silc, compile_libs=false, compile_libs=true)
 523   PKG_CHECK_MODULES(SILCCLIENT, silcclient, compile_libs=false, compile_libs=true)
 524
 525   LIBS="$LIBS $SILC_LIBS"
 526   CFLAGS="$CFLAGS $SILC_CFLAGS"
 527   LIBS="$LIBS $SILCCLIENT_LIBS"
 528   CFLAGS="$CFLAGS $SILCCLIENT_CFLAGS"
 529 fi
 530 #endif SILC_DIST_TOOLKIT
 531
 532 # SOCKS4 support checking
 533 #
 534 SAVE_LIBS="$LIBS"
 535 SAVE_CFLAGS="$CFLAGS"
 536 SAVE_LDFLAGS="$LDFLAGS"
 537 AC_MSG_CHECKING(whether to support SOCKS4)
 538 AC_ARG_WITH(socks4,
 539   [[  --with-socks4[=DIR]     with SOCKS4 support [search in DIR/lib and DIR/include]]],
 540   [
 541     case "$withval" in
 542       no)
 543         AC_MSG_RESULT(no)
 544         ;;
 545       *)
 546         AC_MSG_RESULT(yes)
 547         socks=4
 548
 549         if test -d "$withval/include"; then
 550           CFLAGS="$CFLAGS -I$withval/include"
 551         fi
 552         if test -d "$withval/lib"; then
 553           LDFLAGS="$LDFLAGS -L$withval/lib"
 554         fi
 555
 556         LIBS="-lsocks $LIBS"
 557         ;;
 558     esac
 559
 560     AC_TRY_LINK([],
 561       [
 562         Rconnect();
 563       ], [],
 564       [
 565         AC_MSG_ERROR(Could not find SOCKS4 library.)
 566         LIBS="$SAVE_LIBS"
 567         CFLAGS="$SAVE_CFLAGS"
 568         LDFLAGS="$SAVE_LDFLAGS"
 569       ])
 570   ],
 571     AC_MSG_RESULT(no)
 572   )
 573
 574 # SOCKS5 support checking
 575 #
 576 SAVE_LIBS="$LIBS"
 577 SAVE_CFLAGS="$CFLAGS"
 578 SAVE_LDFLAGS="$LDFLAGS"
 579 AC_MSG_CHECKING(whether to support SOCKS5)
 580 AC_ARG_WITH(socks5,
 581   [[  --with-socks5[=DIR]     with SOCKS5 support [search in DIR/lib and DIR/include]]],
 582   [
 583     case "$withval" in
 584       no)
 585         AC_MSG_RESULT(no)
 586         ;;
 587       *)
 588         AC_MSG_RESULT(yes)
 589         socks=5
 590
 591         if test -d "$withval/include"; then
 592           CFLAGS="$CFLAGS -I$withval/include"
 593         fi
 594         if test -d "$withval/lib"; then
 595           LDFLAGS="$LDFLAGS -L$withval/lib"
 596         fi
 597
 598         LIBS="-lsocks5 $LIBS"
 599         ;;
 600     esac
 601
 602     AC_TRY_LINK([],
 603       [
 604         SOCKSconnect();
 605       ], [],
 606       [
 607         AC_MSG_ERROR(Could not find SOCKS5 library.)
 608         LIBS="$SAVE_LIBS"
 609         CFLAGS="$SAVE_CFLAGS"
 610         LDFLAGS="$SAVE_LDFLAGS"
 611       ])
 612   ],
 613     AC_MSG_RESULT(no)
 614   )
 615
 616 if test "x$socks" = "x4"; then
 617   AC_DEFINE([SOCKS], [], [Socks])
 618   CFLAGS="$CFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 619 fi
 620
 621 if test "x$socks" = "x5"; then
 622   AC_DEFINE([SOCKS], [], [Socks])
 623   AC_DEFINE([SOCKS5], [], [Socks5])
 624   AC_DEFINE([Rconnect], [SOCKSconnect], [Socks])
 625   AC_DEFINE([Rgetsockname], [SOCKSgetsockname], [Socks])
 626   AC_DEFINE([Rgetpeername], [SOCKSgetpeername], [Socks])
 627   AC_DEFINE([Rbind], [SOCKSbind], [Socks])
 628   AC_DEFINE([Raccept], [SOCKSaccept], [Socks])
 629   AC_DEFINE([Rlisten], [SOCKSlisten], [Socks])
 630   AC_DEFINE([Rselect], [SOCKSselect], [Socks])
 631   AC_DEFINE([Rrecvfrom], [SOCKSrecvfrom], [Socks])
 632   AC_DEFINE([Rsendto], [SOCKSsendto], [Socks])
 633   AC_DEFINE([Rrecv], [SOCKSrecv], [Socks])
 634   AC_DEFINE([Rsend], [SOCKSsend], [Socks])
 635   AC_DEFINE([Rread], [SOCKSread], [Socks])
 636   AC_DEFINE([Rwrite], [SOCKSwrite], [Socks])
 637   AC_DEFINE([Rrresvport], [SOCKSrresvport], [Socks])
 638   AC_DEFINE([Rshutdown], [SOCKSshutdown], [Socks])
 639   AC_DEFINE([Rlisten], [SOCKSlisten], [Socks])
 640   AC_DEFINE([Rclose], [SOCKSclose], [Socks])
 641   AC_DEFINE([Rdup], [SOCKSdup], [Socks])
 642   AC_DEFINE([Rdup2], [SOCKSdup2], [Socks])
 643   AC_DEFINE([Rfclose], [SOCKSfclose], [Socks])
 644   AC_DEFINE([Rgethostbyname], [SOCKSgethostbyname], [Socks])
 645 fi
 646
 647 #ifdef SILC_DIST_MATH
 648 # MP library checking. First check whether user wants to use GMP and use
 649 # it if found. If not or not defined then compile the MPI library in the
 650 # source tree.
 651 #
 652 mp_gmp=false
 653 SAVE_LIBS="$LIBS"
 654 SAVE_CFLAGS="$CFLAGS"
 655 SAVE_LDFLAGS="$LDFLAGS"
 656 AC_MSG_CHECKING(whether to search for GMP)
 657 AC_ARG_WITH(gmp,
 658   [[  --with-gmp[=DIR]        use GMP instead of MPI [search in DIR/lib and DIR/include]]],
 659   [
 660     case "$withval" in
 661       no)
 662         AC_MSG_RESULT(no)
 663         ;;
 664       *)
 665         AC_MSG_RESULT(yes)
 666
 667         if test -d "$withval/include"; then
 668           CFLAGS="$CFLAGS -I$withval/include"
 669         fi
 670         if test -d "$withval/lib"; then
 671           LDFLAGS="$LDFLAGS -L$withval/lib"
 672         fi
 673
 674         LIBS="-lgmp $LIBS"
 675         ;;
 676     esac
 677
 678     AC_CHECK_LIB(gmp, __gmpz_init,
 679       [
 680         mp_gmp=true
 681         AC_DEFINE([SILC_MP_GMP], [], [GMP])
 682         AC_MSG_RESULT(Using GMP as a MP library.)
 683       ],
 684       [
 685         LIBS="$SAVE_LIBS"
 686         CFLAGS="$SAVE_CFLAGS"
 687         LDFLAGS="$SAVE_LDFLAGS"
 688       ])
 689   ],
 690     AC_MSG_RESULT(no)
 691   )
 692
 693 AM_CONDITIONAL(SILC_MP_GMP, test x$mp_gmp = xtrue)
 694 AM_CONDITIONAL(SILC_MP_NSS_MPI, test x$mp_gmp = xfalse)
 695 if test x$mp_gmp = xfalse; then
 696   AC_DEFINE([SILC_MP_NSS_MPI], [], [MPI])
 697   AC_MSG_RESULT(Using NSS MPI as a MP library.)
 698 fi
 699 #endif SILC_DIST_MATH
 700
 701 # iconv support
 702 #
 703 check_iconv=true
 704 has_iconv=false
 705 SAVE_LIBS="$LIBS"
 706 SAVE_CFLAGS="$CFLAGS"
 707 SAVE_LDFLAGS="$LDFLAGS"
 708 SAVE_CPPFLAGS="$CPPFLAGS"
 709 AC_MSG_CHECKING(whether to implicit search for libiconv)
 710 AC_ARG_WITH(iconv,
 711   [[  --with-iconv[=DIR]      use libiconv [search in DIR/include and DIR/lib]]],
 712   [
 713     case "${withval}" in
 714       no)
 715         AC_MSG_RESULT(no)
 716         AC_CHECK_HEADERS(iconv.h,
 717           [
 718             AC_CHECK_FUNC(iconv, has_iconv=true)
 719           ])
 720         check_iconv=false
 721         ;;
 722       *)
 723         AC_MSG_RESULT(yes)
 724         if test -d $withval/include; then
 725           CPPFLAGS="$CPPFLAGS -I$withval/include"
 726           CFLAGS="$CFLAGS -I$withval/include"
 727         fi
 728         if test -d $withval/lib; then
 729           LDFLAGS="$LDFLAGS -L$withval/lib"
 730         fi
 731         ;;
 732     esac
 733   ],
 734   [
 735     AC_MSG_RESULT(no)
 736     AC_CHECK_HEADERS(iconv.h,
 737       [
 738         AC_CHECK_FUNCS(iconv,
 739           [
 740             has_iconv=true
 741             check_iconv=false
 742           ])
 743       ])
 744   ])
 745
 746 if test x$check_iconv = xtrue; then
 747   AC_MSG_RESULT(Searching for iconv...)
 748
 749   # XXX
 750   unset ac_cv_header__iconv_h_ ac_cv_header_iconv_h || true
 751
 752   AC_CHECK_HEADERS(iconv.h,
 753     [
 754       LIBS="$LIBS -liconv"
 755       AC_MSG_CHECKING(for iconv in -liconv)
 756       AC_TRY_LINK(
 757         [
 758           #include <stdlib.h>
 759           #include <iconv.h>
 760         ],
 761         [
 762           iconv_t cd = iconv_open("", "");
 763           iconv(cd, NULL, NULL, NULL, NULL);
 764           iconv_close(cd);
 765         ],
 766         [
 767           echo "yes"
 768           AC_DEFINE([HAVE_ICONV], [], [Define if you have the iconv() function.])
 769           has_iconv=true
 770           check_iconv=false
 771         ],
 772         [
 773           echo "no"
 774           LIBS="$SAVE_LIBS"
 775           CFLAGS="$SAVE_CFLAGS"
 776           LDFLAGS="$SAVE_LDFLAGS"
 777           CPPFLAGS="$SAVE_CPPFLAGS"
 778         ])
 779      ])
 780 fi
 781
 782 if test x$check_iconv = xtrue; then
 783   # search for iconv library..
 784   SAVE_LIBS="$LIBS"
 785   SAVE_CFLAGS="$CFLAGS"
 786   SAVE_LDFLAGS="$LDFLAGS"
 787   SAVE_CPPFLAGS="$CPPFLAGS"
 788
 789   for dir in `echo "/usr/local /usr/pkg /usr/contrib"`; do
 790     if test x$has_iconv = xfalse; then
 791       AC_MSG_RESULT(searching in $dir...)
 792
 793       if test -d $dir/include; then
 794         CPPFLAGS="$CPPFLAGS -I$dir/include"
 795         CFLAGS="$CFLAGS -I$dir/include"
 796       fi
 797       if test -d $dir/lib; then
 798         LDFLAGS="$LDFLAGS -L$dir/lib"
 799       fi
 800
 801       # XXX
 802       unset ac_cv_header__iconv_h_ ac_cv_header_iconv_h || true
 803
 804       AC_CHECK_HEADERS(iconv.h,
 805         [
 806           LIBS="$LIBS -liconv"
 807           AC_MSG_CHECKING(for iconv in -liconv)
 808           AC_TRY_LINK(
 809             [
 810               #include <stdlib.h>
 811               #include <iconv.h>
 812             ],
 813             [
 814               iconv_t cd = iconv_open("", "");
 815               iconv(cd, NULL, NULL, NULL, NULL);
 816               iconv_close(cd);
 817             ],
 818             [
 819               echo "yes"
 820               has_iconv=true
 821               AC_DEFINE([HAVE_ICONV], [], [Define if you have the iconv() function.])
 822             ],
 823             [
 824               echo "no"
 825               has_iconv=false
 826
 827               LIBS="$SAVE_LIBS"
 828               CFLAGS="$SAVE_CFLAGS"
 829               LDFLAGS="$SAVE_LDFLAGS"
 830               CPPFLAGS="$SAVE_CPPFLAGS"
 831             ])
 832          ],
 833          [
 834            CFLAGS="$SAVE_CFLAGS"
 835            LDFLAGS="$SAVE_LDFLAGS"
 836            CPPFLAGS="$SAVE_CPPFLAGS"
 837          ])
 838       fi
 839     done
 840 fi
 841
 842 if test x$has_iconv = xtrue; then
 843   # (1) Some implementations of iconv won't convert from UTF-8 to UTF-8.
 844   # (2) In glibc-2.1.2 and earlier there is a bug that messes up ob and
 845   #     obl when args 2 and 3 are 0 (fixed in glibc-2.1.3).
 846   #
 847   AC_CACHE_CHECK([whether this iconv is good enough], ac_iconv_good,
 848     AC_TRY_RUN(
 849       [
 850         #include <iconv.h>
 851         int main() {
 852           iconv_t cd;
 853         changequote(, )dnl
 854           char buf[4];
 855         changequote([, ])dnl
 856           char *ob;
 857           size_t obl;
 858           ob = buf, obl = sizeof(buf);
 859           return ((cd = iconv_open("UTF-8", "UTF-8")) != (iconv_t)(-1) &&
 860                  (iconv(cd, 0, 0, &ob, &obl) ||
 861                  !(ob == buf && obl == sizeof(buf)) ||
 862                  iconv_close(cd)));
 863         }
 864       ],
 865       [
 866         ac_iconv_good=yes
 867       ],
 868       [
 869         ac_iconv_good=no
 870       ],
 871       [
 872         ac_iconv_good=yes
 873       ])
 874     )
 875
 876   if test x$ac_iconv_good = xno; then
 877     AC_MSG_RESULT(Try using libiconv instead.)
 878   fi
 879 fi
 880
 881 # POSIX threads support
 882 #
 883 has_threads=false
 884 AC_MSG_CHECKING(whether to search for POSIX threads)
 885 AC_ARG_WITH(pthreads,
 886   [[  --with-pthreads[=DIR]   use POSIX threads [search in DIR/include and DIR/lib]]],
 887   [
 888     case "${withval}" in
 889       no)
 890         check_threads=false
 891         ;;
 892       *)
 893         if test -d $withval/include; then
 894           CPPFLAGS="$CPPFLAGS -I$withval/include"
 895           CFLAGS="$CFLAGS -I$withval/include"
 896         fi
 897         if test -d $withval/lib; then
 898           LDFLAGS="$LDFLAGS -L$withval/lib"
 899         fi
 900
 901         check_threads=true
 902         ;;
 903     esac
 904   ])
 905
 906 if test x$check_threads = xtrue; then
 907   SAVE_LIBS="$LIBS"
 908   SAVE_CFLAGS="$CFLAGS"
 909   SAVE_LDFLAGS="$LDFLAGS"
 910   SAVE_CPPFLAGS="$CPPFLAGS"
 911
 912   AC_MSG_RESULT(yes)
 913   AC_CHECK_HEADERS(pthread.h,
 914     [
 915       LIBS="$LIBS -lpthread"
 916       AC_CHECK_LIB(pthread, pthread_attr_init, has_threads=true,
 917         [
 918           # FreeBSD
 919           case "${target}" in
 920             *-*-freebsd*)
 921               LIBS="$SAVE_LIBS -pthread"
 922               AC_CHECK_LIB(c_r, pthread_attr_init, has_threads=true, LIBS="$SAVE_LIBS")
 923               ;;
 924             *)
 925               LIBS="$SAVE_LIBS"
 926               ;;
 927           esac
 928         ])
 929     ],
 930     [
 931       # search for pthread library..
 932       for dir in `echo "/usr/local /usr/pkg /usr/contrib /usr/pkg/pthreads /usr/local/pthreads"`; do
 933         if test x$has_threads = xfalse; then
 934           AC_MSG_RESULT(searching in $dir...)
 935
 936           if test -d $dir/include; then
 937             CPPFLAGS="$CPPFLAGS -I$dir/include"
 938             CFLAGS="$CFLAGS -I$dir/include"
 939           fi
 940           if test -d $dir/lib; then
 941             LDFLAGS="$LDFLAGS -L$dir/lib"
 942           fi
 943
 944           # XXX
 945           unset ac_cv_header__pthread_h_ ac_cv_header_pthread_h || true
 946
 947           AC_CHECK_HEADERS(pthread.h,
 948             [
 949               LIBS="$LIBS -lpthread"
 950               AC_CHECK_LIB(pthread, pthread_attr_init, has_threads=true,
 951                 [
 952                   has_threads=false
 953
 954                   LIBS="$SAVE_LIBS"
 955                   CFLAGS="$SAVE_CFLAGS"
 956                   LDFLAGS="$SAVE_LDFLAGS"
 957                   CPPFLAGS="$SAVE_CPPFLAGS"
 958                 ])
 959             ],
 960             [
 961               CFLAGS="$SAVE_CFLAGS"
 962               LDFLAGS="$SAVE_LDFLAGS"
 963               CPPFLAGS="$SAVE_CPPFLAGS"
 964             ])
 965         fi
 966       done
 967     ])
 968 else
 969   AC_MSG_RESULT(no)
 970   has_threads=false
 971 fi
 972
 973 __SILC_HAVE_PTHREAD=""
 974 AM_CONDITIONAL(SILC_THREADS, test x$has_threads = xtrue)
 975 if test x$has_threads = xtrue; then
 976   CFLAGS="$CFLAGS -D_REENTRANT"
 977
 978   # XXX possibly incomplete
 979   case "${target}" in
 980     *-*-aix*)
 981       CFLAGS="$CFLAGS -D_THREAD_SAFE"
 982       if test x"$GCC" = xyes; then
 983         CFLAGS="$CFLAGS -mthreads"
 984       fi
 985       ;;
 986     *-*-freebsd*)
 987       CFLAGS="$CFLAGS -D_THREAD_SAFE"
 988       ;;
 989     *-*-sysv5uw7*)  # UnixWare 7
 990       if test "$GCC" != "yes"; then
 991         CFLAGS="$CFLAGS -Kthread"
 992       else
 993         CFLAGS="$CFLAGS -pthread"
 994       fi
 995       ;;
 996     *-dg-dgux*)  # DG/UX
 997       CFLAGS="$CFLAGS -D_POSIX4A_DRAFT10_SOURCE"
 998       ;;
 999    esac
1000
1001   AC_CHECK_FUNC(pthread_create)
1002   AC_DEFINE([SILC_HAVE_PTHREAD], [], [HAVE_PTHREAD])
1003   AC_DEFINE([SILC_THREADS], [], [HAVE_THREAD])
1004   __SILC_HAVE_PTHREAD="#define __SILC_HAVE_PTHREAD 1"
1005 fi
1006
1007 # Native WIN32 compilation under cygwin
1008 #
1009 AC_MSG_CHECKING(whether to compile native WIN32 code)
1010 AC_ARG_WITH(win32,
1011   [  --with-win32            compile native WIN32 (MinGW) code (-mno-cygwin)],
1012   [
1013     AC_MSG_RESULT(yes)
1014     AC_DEFINE([SILC_WIN32], [], [SILC_WIN32])
1015     win32_support=true
1016     CFLAGS="-mno-cygwin $CFLAGS"
1017     LIBS="$LIBS -lwsock32"
1018   ],
1019   [
1020     AC_MSG_RESULT(no)
1021   ])
1022 AM_CONDITIONAL(SILC_WIN32, test x$win32_support = xtrue)
1023
1024 # Native EPOC support (disabled by default)
1025 #
1026 AM_CONDITIONAL(SILC_EPOC, test xfalse = xtrue)
1027
1028 # Native BeOS support (disabled by default)
1029 #
1030 AM_CONDITIONAL(SILC_BEOS, test xfalse = xtrue)
1031
1032 # Native OS2 support (disabled by default)
1033 #
1034 AM_CONDITIONAL(SILC_OS2, test xfalse = xtrue)
1035
1036 #ifdef SILC_DIST_TOOLKIT
1037
1038 # --without-irssi
1039 #
1040 without_irssi=false
1041 AC_MSG_CHECKING(whether to compile Irssi SILC Client)
1042 AC_ARG_WITH(irssi,
1043   [  --without-irssi         compile without Irssi SILC Client],
1044   [
1045     AC_MSG_RESULT(no)
1046     without_irssi=true
1047   ],
1048   [
1049     AC_MSG_RESULT(yes)
1050   ])
1051
1052 # --without-silcd
1053 #
1054 without_silcd=false
1055 AC_MSG_CHECKING(whether to compile SILC Server)
1056 AC_ARG_WITH(silcd,
1057   [  --without-silcd         compile without SILC Server],
1058   [
1059     AC_MSG_RESULT(no)
1060     without_silcd=true
1061   ],
1062   [
1063     AC_MSG_RESULT(yes)
1064   ])
1065
1066 #endif SILC_DIST_TOOLKIT
1067
1068 #ifdef SILC_DIST_CLIENT
1069 # Irssi perl support
1070 #
1071 AC_ARG_WITH(perl,
1072   [[  --with-perl[=yes|no|module]  Build with Perl support - also specifies
1073                                if it should be built into main silc binary
1074                                (static, default) or as a module]])
1075 #endif SILC_DIST_CLIENT
1076
1077 libtoolfix=true
1078 AC_MSG_CHECKING(whether to do libtoolfix)
1079 AC_ARG_WITH(libtoolfix,
1080   [  --without-libtoolfix    Do not fix libtool, for package builders],
1081   [
1082     AC_MSG_RESULT(no)
1083     libtoolfix=false
1084   ],
1085   [
1086     AC_MSG_RESULT(yes)
1087   ])
1088
1089 AC_SUBST(ETCDIR)
1090 AC_DEFINE_UNQUOTED([SILC_ETCDIR], "$ETCDIR", [SILC_ETCDIR])
1091
1092 #endif SILC_DIST_COMPILER
1093
1094 ##
1095 ##  Misc
1096 ##
1097
1098 # Make enable-shared aware
1099 AM_CONDITIONAL(SILC_ENABLE_SHARED, test "$enable_shared" = yes)
1100
1101 # Other configure scripts
1102 #
1103
1104 #ifdef SILC_DIST_TOOLKIT
1105 if test x$without_irssi = xfalse; then
1106 #endif SILC_DIST_TOOLKIT
1107 #ifdef SILC_DIST_CLIENT
1108   AC_CONFIG_SUBDIRS(irssi)
1109   irssi="yes"
1110 #endif SILC_DIST_CLIENT
1111 #ifdef SILC_DIST_TOOLKIT
1112 fi
1113 #endif SILC_DIST_TOOLKIT
1114
1115 SILC_TOP_SRCDIR=`pwd`
1116
1117 # Included configure scripts
1118 AD_INCLUDE_CONFIGURE
1119
1120 #ifdef SILC_DIST_COMPILER
1121 #
1122 # Substitutions
1123 #
1124 AC_SUBST(SILC_TOP_SRCDIR)
1125 AC_SUBST(LIBS)
1126 AC_SUBST(SILC_LIB_INCLUDES)
1127 AC_SUBST(__SILC_HAVE_PTHREAD)
1128 AC_SUBST(__SILC_HAVE_SIM)
1129 AC_SUBST(__SILC_ENABLE_DEBUG)
1130
1131 #
1132 # Fix the libtool to support run-time configuration.  This allows us
1133 # to in run-time specify when to compile shared/static libraries without
1134 # need to reconfigure the entire libtool.
1135 #
1136 if test x$libtoolfix = xtrue; then
1137   ./libtoolfix $SILC_TOP_SRCDIR/ltmain.sh
1138 fi
1139 AM_CONDITIONAL(SILC_LIBTOOLFIX, test x$libtoolfix = xtrue)
1140
1141 INCLUDE_DEFINES_INT="include \$(top_srcdir)/Makefile.defines_int"
1142 AC_SUBST(INCLUDE_DEFINES_INT)
1143
1144 #endif SILC_DIST_COMPILER
1145
1146 #
1147 # Makefile outputs
1148 #
1149 AC_CONFIG_FILES(
1150 Makefile
1151 #ifdef SILC_DIST_DOC
1152 doc/Makefile
1153 #endif SILC_DIST_DOC
1154 #ifdef SILC_DIST_COMPILER
1155 Makefile.defines
1156 Makefile.defines_int
1157 includes/Makefile
1158 includes/silcversion.h
1159 includes/silcincludes.h
1160 #endif SILC_DIST_COMPILER
1161 #ifdef SILC_DIST_APPS
1162 apps/Makefile
1163 #endif SILC_DIST_APPS
1164 )
1165
1166 #ifdef SILC_DIST_TOOLKIT
1167 if test x$without_irssi = xfalse ; then
1168 #endif SILC_DIST_TOOLKIT
1169 #ifdef SILC_DIST_CLIENT
1170   AC_CONFIG_FILES(
1171 irssi/Makefile.defines
1172 irssi/Makefile.defines_int
1173 )
1174 #endif SILC_DIST_CLIENT
1175 #ifdef SILC_DIST_TOOLKIT
1176 fi
1177 #endif SILC_DIST_TOOLKIT
1178
1179 #ifdef SILC_DIST_TOOLKIT
1180 if test x$without_silcd = xfalse ; then
1181 #endif SILC_DIST_TOOLKIT
1182 #ifdef SILC_DIST_SERVER
1183   AC_CONFIG_FILES(
1184 silcd/Makefile
1185 doc/example_silcd.conf
1186 )
1187 #endif SILC_DIST_SERVER
1188 #ifdef SILC_DIST_TOOLKIT
1189 fi
1190 #endif SILC_DIST_TOOLKIT
1191
1192 #ifdef SILC_DIST_TOOLKIT
1193 AC_CONFIG_FILES(
1194 silc/Makefile
1195 win32/Makefile
1196 win32/libsilc/Makefile
1197 win32/libsilcclient/Makefile
1198 tutorial/Makefile
1199 tutorial/Makefile.defines
1200 tutorial/Makefile.defines_int
1201 )
1202 #endif SILC_DIST_TOOLKIT
1203
1204 AC_OUTPUT
1205
1206 #ifdef SILC_DIST_COMPILER
1207 s_bindir=`eval echo $bindir`;s_bindir=`eval echo $s_bindir`
1208 s_sbindir=`eval echo $sbindir`;s_sbindir=`eval echo $s_sbindir`
1209 s_mandir=`eval echo $mandir`;s_mandir=`eval echo $s_mandir`
1210 s_includedir=`eval echo $includedir`;s_includedir=`eval echo $s_includedir`
1211
1212 echo ""
1213 echo "$PACKAGE Configuration Summary:"
1214 echo "---------------------------"
1215 echo " Target host ...................: $target"
1216 echo " Compiler ......................: $CC"
1217 echo " CFLAGS ........................: $CFLAGS"
1218 echo " CPPFLAGS ......................: $CPPFLAGS"
1219 echo " LDFLAGS .......................: $LDFLAGS"
1220 echo " LIBS ..........................: $LIBS"
1221 echo ""
1222 echo " Installation prefix ...........: $prefix"
1223 echo " bin directory .................: $s_bindir"
1224 echo " sbin directory ................: $s_sbindir"
1225 echo " etc directory .................: $ETCDIR"
1226 echo " man directory .................: $s_mandir"
1227 echo " doc directory .................: $DOCDIR"
1228 #ifdef SILC_DIST_CLIENT
1229 echo " help directory ................: $HELPDIR"
1230 #endif SILC_DIST_CLIENT
1231 #ifdef SILC_DIST_SERVER
1232 echo " logs directory ................: $LOGSDIR"
1233 #endif SILC_DIST_SERVER
1234 #ifdef SILC_DIST_SIM
1235 echo " SIM directory .................: $MODULESDIR"
1236 #endif SILC_DIST_SIM
1237 #ifdef SILC_DIST_INCLUDES
1238 echo " include directory .............: $s_includedir"
1239 #endif SILC_DIST_INCLUDES
1240 echo ""
1241
1242 #ifdef SILC_DIST_SERVER
1243 silcd="yes"
1244 #endif SILC_DIST_SERVER
1245
1246 #ifdef SILC_DIST_TOOLKIT
1247 if test x$without_irssi = xtrue; then
1248   irssi="no"
1249 fi
1250 if test x$without_silcd = xtrue; then
1251   silcd="no"
1252 fi
1253 #endif SILC_DIST_TOOLKIT
1254
1255 #ifdef SILC_DIST_CLIENT
1256 echo " Compile SILC Client ...........: $irssi"
1257 #endif SILC_DIST_CLIENT
1258
1259 #ifdef SILC_DIST_SERVER
1260 echo " Compile SILC Server ...........: $silcd"
1261 echo " Server configuration file .....: $summary_silcd_configfile"
1262 echo " Server PID file ...............: $PIDFILE"
1263 #endif SILC_DIST_SERVER
1264
1265 #ifdef SILC_DIST_SIM
1266 if test x$sim_support = xfalse; then
1267   sim_support="no"
1268 else
1269   sim_support="yes"
1270 fi
1271 echo " SIM support ...................: $sim_support"
1272 #endif SILC_DIST_SIM
1273
1274 echo " IPv6 support ..................: $summary_ipv6"
1275
1276 if test x$has_iconv = xfalse; then
1277   iconv_support="no"
1278 else
1279   iconv_support="yes"
1280 fi
1281 echo " Iconv support .................: $iconv_support"
1282
1283 if test x$want_asm = xfalse; then
1284   summary_asm="no"
1285 else
1286   summary_asm="yes"
1287 fi
1288 echo " Assembler optimizations .......: $summary_asm"
1289
1290 #ifdef SILC_DIST_MATH
1291 mp="MPI"
1292 if test x$mp_gmp = xtrue; then
1293   mp="GMP"
1294 fi
1295 echo " Arithmetic library ............: $mp"
1296 #endif SILC_DIST_MATH
1297
1298 threads="no"
1299 if test x$has_threads = xtrue; then
1300   threads="yes"
1301 fi
1302 echo " Multi-threads support .........: $threads"
1303 echo " Debugging enabled .............: $summary_debug"
1304 echo ""
1305 echo "Compile the sources with 'make' or 'gmake' command."
1306 #endif SILC_DIST_COMPILER
1307