apps/irssi/configure.in

   1 AC_INIT(src)
   2
   3 # we don't want VERSION in our config.h
   4 if test -n "`grep '^#undef VERSION' config.h.in`"; then
   5   grep -v '^#undef VERSION' config.h.in > config.h.in.temp
   6   mv -f config.h.in.temp config.h.in
   7 fi
   8
   9 AM_CONFIG_HEADER(config.h)
  10 AM_INIT_AUTOMAKE(Irssi-SILC, 0.8.5+)
  11
  12 AM_MAINTAINER_MODE
  13
  14 AC_ISC_POSIX
  15 AC_PROG_CC
  16 AC_PROG_CPP
  17 AC_STDC_HEADERS
  18 AM_PROG_LIBTOOL
  19
  20 AC_PATH_PROG(sedpath, sed)
  21 AC_PATH_PROG(perlpath, perl)
  22
  23 dnl * --disable-static isn't a good idea, complain if it's used
  24 if test "x$enable_static" = "xno"; then
  25         AC_ERROR([Don't give --disable-static option to configure])
  26 fi
  27
  28 AC_CHECK_HEADERS(string.h stdlib.h unistd.h dirent.h sys/ioctl.h sys/resource.h)
  29
  30 # check posix headers..
  31 AC_CHECK_HEADERS(sys/time.h sys/utsname.h regex.h)
  32
  33 AC_ARG_WITH(socks,
  34 [  --with-socks            Build with socks support],
  35         if test x$withval = xyes; then
  36                 want_socks=yes
  37         else
  38                 if test "x$withval" = xno; then
  39                         want_socks=no
  40                 else
  41                         want_socks=yes
  42                 fi
  43         fi,
  44         want_socks=no)
  45
  46 AC_ARG_WITH(textui,
  47 [  --with-textui           Build text frontend],
  48         if test x$withval = xyes; then
  49                 want_textui=yes
  50         else
  51                 if test "x$withval" = xno; then
  52                         want_textui=no
  53                 else
  54                         want_textui=yes
  55                 fi
  56         fi,
  57         want_textui=yes)
  58
  59 AC_ARG_WITH(bot,
  60 [  --with-bot              Build irssi-bot],
  61         if test x$withval = xyes; then
  62                 want_irssibot=yes
  63         else
  64                 if test "x$withval" = xno; then
  65                         want_irssibot=no
  66                 else
  67                         want_irssibot=yes
  68                 fi
  69         fi,
  70         want_irssibot=no)
  71
  72 AC_ARG_WITH(proxy,
  73 [  --with-proxy            Build irssi-proxy],
  74         if test x$withval = xyes; then
  75                 want_irssiproxy=yes
  76         else
  77                 if test "x$withval" = xno; then
  78                         want_irssiproxy=no
  79                 else
  80                         want_irssiproxy=yes
  81                 fi
  82         fi,
  83         want_irssiproxy=no)
  84
  85 AC_ARG_WITH(terminfo,
  86 [  --with-terminfo         Use terminfo directly instead of curses],
  87         if test x$withval = xyes; then
  88                 want_terminfo=yes
  89         else
  90                 if test "x$withval" = xno; then
  91                         want_terminfo=no
  92                 else
  93                         want_terminfo=yes
  94                 fi
  95         fi,
  96         want_terminfo=yes)
  97
  98 AC_ARG_WITH(modules,
  99 [  --with-modules          Specify what modules to build in binary],
 100         if test x$withval != xyes -a x$withval != xno; then
 101                 build_modules="$withval"
 102         fi)
 103
 104 if test "x$prefix" != "xNONE"; then
 105         prefix=`eval echo $prefix`
 106         PERL_MM_PARAMS="INSTALLDIRS=perl PREFIX=$prefix"
 107         perl_library_dir="PERL_USE_LIB"
 108         perl_set_use_lib=yes
 109
 110         perl_prefix_note=yes
 111 fi
 112
 113 AC_ARG_WITH(tests,
 114 [  --with-glib2           Use GLIB 2.0 instead of 1.2],
 115         if test x$withval = xyes; then
 116                 want_glib2=yes
 117         else
 118                 if test "x$withval" = xno; then
 119                         want_glib2=no
 120                 else
 121                         want_glib2=yes
 122                 fi
 123         fi,
 124         want_glib2=yes)
 125
 126 AC_ARG_WITH(perl-staticlib,
 127 [  --with-perl-staticlib   Specify that we want to link perl libraries
 128                         statically in irssi, default is no],
 129         if test x$withval = xyes; then
 130                 want_staticperllib=yes
 131         else
 132                 if test "x$withval" = xno; then
 133                         want_staticperllib=no
 134                 else
 135                         want_staticperllib=yes
 136                 fi
 137         fi,
 138         want_staticperllib=no)
 139
 140
 141 AC_ARG_WITH(perl-lib,
 142 [  --with-perl-lib=[site|vendor|DIR]  Specify where to install the
 143                         Perl libraries for irssi, default is site],
 144         if test "x$withval" = xyes; then
 145                 want_perl=yes
 146         elif test "x$withval" = xno; then
 147                 want_perl=no
 148         elif test "x$withval" = xsite; then
 149                 want_perl=yes
 150                 perl_prefix_note=no
 151                 PERL_MM_PARAMS=""
 152         elif test "x$withval" = xvendor; then
 153                 want_perl=yes
 154                 perl_prefix_note=no
 155                 if test -z "`$perlpath -v|grep '5\.0'`"; then
 156                         PERL_MM_PARAMS="INSTALLDIRS=vendor"
 157                 else
 158                         PERL_MM_PARAMS="INSTALLDIRS=perl PREFIX=`perl -e 'use Config; print $Config{prefix}'`"
 159                 fi
 160                 perl_library_dir="(vendor default - `$perlpath -e 'use Config; print $Config{archlib}'`)"
 161         else
 162                 want_perl=yes
 163                 perl_prefix_note=no
 164                 PERL_MM_PARAMS="INSTALLDIRS=perl LIB=$withval"
 165                 perl_library_dir="PERL_USE_LIB"
 166                 perl_set_use_lib=yes
 167         fi,
 168         want_perl=yes)
 169
 170 AC_ARG_WITH(perl,
 171 [  --with-perl[=yes|no|module]  Build with Perl support - also specifies
 172                         if it should be built into main irssi binary
 173                         (static, default) or as module],
 174         if test x$withval = xyes; then
 175                 want_perl=static
 176         elif test x$withval = xstatic; then
 177                 want_perl=static
 178         elif test x$withval = xmodule; then
 179                 want_perl=module
 180         else
 181                 want_perl=no
 182         fi,
 183         want_perl=static)
 184
 185 AC_ARG_WITH(tests,
 186 [  --with-tests           Run all the tests],
 187         if test x$withval != xno; then
 188                 TEST_DIR=test
 189         fi,
 190         TEST_DIR=)
 191 AC_SUBST(TEST_DIR)
 192
 193 AC_ARG_ENABLE(ipv6,
 194 [  --enable-ipv6           Enable IPv6 support],
 195         if test x$enableval = xyes; then
 196                 want_ipv6=yes
 197         else
 198                 if test "x$enableval" = xno; then
 199                         want_ipv6=no
 200                 else
 201                         want_ipv6=yes
 202                 fi
 203         fi,
 204         want_ipv6=no)
 205
 206 dnl **
 207 dnl ** just some generic stuff...
 208 dnl **
 209
 210 dnl * OS specific options
 211 case "$host_os" in
 212   hpux*)
 213     CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
 214     ;;
 215   *)
 216     ;;
 217 esac
 218
 219
 220 AC_CHECK_FUNCS(mkfifo fcntl nl_langinfo)
 221
 222 AC_CHECK_FUNC(socket, [], [
 223         AC_CHECK_LIB(socket, socket, [
 224                 LIBS="$LIBS -lsocket"
 225         ])
 226 ])
 227
 228 AC_CHECK_FUNC(inet_addr, [], [
 229         AC_CHECK_LIB(nsl, inet_addr, [
 230                 LIBS="$LIBS -lnsl"
 231         ], -lsocket)
 232 ])
 233
 234 dnl * gcc specific options
 235 if test "x$ac_cv_prog_gcc" = "xyes"; then
 236   CFLAGS="$CFLAGS -Wall"
 237 fi
 238
 239 dnl * socklen_t - AC_CHECK_TYPE() would be _really_ useful if it only would
 240 dnl * accept header files where to find the typedef..
 241 AC_MSG_CHECKING([for socklen_t])
 242 AC_CACHE_VAL(irssi_cv_type_socklen_t,
 243 [AC_TRY_COMPILE([
 244 #include <sys/types.h>
 245 #include <sys/socket.h>],
 246 [socklen_t t;],
 247 irssi_cv_type_socklen_t=yes,
 248 irssi_cv_type_socklen_t=no,
 249 )])
 250 if test $irssi_cv_type_socklen_t = no; then
 251 AC_DEFINE(socklen_t, int, Define to 'int' if <sys/socket.h> doesn't define.)
 252 fi
 253 AC_MSG_RESULT($irssi_cv_type_socklen_t)
 254
 255 dnl **
 256 dnl ** check for socks
 257 dnl **
 258
 259 if test "x$want_socks" = "xyes"; then
 260         AC_CHECK_LIB(socks, connect, [
 261                 LIBS="$LIBS -lsocks"
 262                 AC_CHECK_HEADER(socks.h, [
 263                         AC_DEFINE(HAVE_SOCKS_H)
 264                         CFLAGS="$CFLAGS -DSOCKS"
 265                         AC_MSG_RESULT(["socks5 library found, building with it"])
 266                 ], [
 267                         AC_MSG_RESULT(["socks4 library found, building with it"])
 268                         CFLAGS="$CFLAGS -Dconnect=Rconnect -Dgetsockname=Rgetsockname -Dgetpeername=Rgetpeername -Dbind=Rbind -Daccept=Raccept -Dlisten=Rlisten -Dselect=Rselect"
 269                 ])
 270         ])
 271 fi
 272
 273 dnl **
 274 dnl ** fe-text checks
 275 dnl **
 276
 277 AC_DEFUN(AC_CHECK_GLIBDIR,[
 278   AC_MSG_CHECKING([whether GLib is unpacked to irssi dir])
 279
 280   GLIB_DIR=`for d in *; do test -f $d/glib.h && echo $d; done`
 281   if test -n "$GLIB_DIR"; then
 282     dnl * glib in irssi directory, use it
 283     AC_MSG_RESULT([yes, using it])
 284
 285     dnl * we have to do this at this point so we know what libs gmodule needs
 286     if test ! -f $GLIB_DIR/.libs/libglib.a; then
 287       echo
 288       echo "configuring GLib ..."
 289       echo
 290       cd $GLIB_DIR
 291       if test ! -f glib-config; then
 292         ./configure
 293       fi
 294       ${MAKE-make}
 295       cd ..
 296       echo
 297     fi
 298
 299     GLIB_LDEXTRA=`$GLIB_DIR/glib-config --libs gmodule|$sedpath -e 's/-lglib//' -e 's/-lgmodule//' -e 's,-L/usr/local/lib ,,'|$sedpath 's/ \+/ /g'`
 300     full_glib_dir="`pwd`/$GLIB_DIR"
 301     GLIB_CFLAGS="-I$full_glib_dir -I$full_glib_dir/gmodule"
 302     if test -f $full_glib_dir/.libs/libglib.a; then
 303       GLIB_LIBS="$full_glib_dir/.libs/libglib.a $GLIB_LDEXTRA"
 304       if test -f $full_glib_dir/gmodule/.libs/libgmodule.a; then
 305         GLIB_LIBS="$GLIB_LIBS $full_glib_dir/gmodule/.libs/libgmodule.a"
 306         AC_DEFINE(HAVE_GMODULE)
 307         have_gmodule=yes
 308       fi
 309     else
 310       GLIB_LIBS="$full_glib_dir/libglib.a $GLIB_LDEXTRA"
 311       if test -f $full_glib_dir/gmodule/libgmodule.a; then
 312         GLIB_LIBS="$GLIB_LIBS $full_glib_dir/gmodule/libgmodule.a"
 313         AC_DEFINE(HAVE_GMODULE)
 314         have_gmodule=yes
 315       fi
 316     fi
 317     AC_SUBST(GLIB_CFLAGS)
 318     AC_SUBST(GLIB_LIBS)
 319   else
 320     AC_MSG_RESULT([no])
 321   fi
 322 ])
 323
 324 AC_CHECK_GLIBDIR
 325
 326 if test -z "$GLIB_DIR"; then
 327   if test "x$with_glib2" = "xyes"; then
 328     dnl * check only for glib2
 329     checks="3 4"
 330   else
 331     dnl * check glib1 then glib2
 332     checks="1 2 3 4"
 333   fi
 334
 335   for try in $checks; do
 336     glib_config_args=
 337     if test $try = 1 -o $try = 3; then
 338       glib_modules=gmodule
 339     else
 340       echo "*** trying without -lgmodule"
 341       glib_modules=
 342     fi
 343     if test $try = 1 -o $try = 2; then
 344       glib_version=1.2.0
 345     else
 346       glib_version=2.0.0
 347     fi
 348     AM_PATH_GLIB($glib_version,[],[], [$glib_modules])
 349     if test "$GLIB_LIBS"; then
 350       if test $glib_modules = gmodule; then
 351         AC_DEFINE(HAVE_GMODULE)
 352         have_gmodule=yes
 353       fi
 354       break
 355     fi
 356   done
 357
 358   if test -z "$GLIB_LIBS"; then
 359     echo
 360     echo "*** If you don't have GLIB, you can get it from ftp://ftp.gtk.org"
 361     echo "*** If you can't install GLIB anywhere or if you don't want to,"
 362     echo "*** you can just unpack it to Irssi's source directory and"
 363     echo "*** Irssi will automatically compile and use it."
 364     echo
 365
 366     dnl * I think it's pretty safe to assume GLib 1.2.9 since the next
 367     dnl * will be 2.0 (or 1.4?) and it's not sure if irssi compiles
 368     dnl * with it (yea, just a few weeks after I put this text for 1.2.8
 369     dnl * the 1.2.9 came :) .. and then .10
 370     glib_file=glib-1.2.10.tar.gz
 371
 372     dlcmd=
 373     if test -n "`ncftpget 2>/dev/null|grep -i ncftp`"; then
 374       dlcmd="ncftpget ftp://ftp.gtk.org/pub/gtk/v1.2/$glib_file"
 375     fi
 376     if test -n "`wget 2>/dev/null|grep -i wget`"; then
 377       dlcmd="wget http://irssi.org/files/$glib_file"
 378     fi
 379     if test -n "$dlcmd"; then
 380       echo "*** I can download GLib for you now. If you don't want to, press CTRL-C now."
 381       echo
 382       echo "*** Press ENTER to continue"
 383       read answer
 384       eval $dlcmd
 385       if `gunzip $glib_file`; then
 386         glib_file=`echo $glib_file|$sedpath s/\.gz$//`
 387         if `tar xf $glib_file`; then
 388           rm -f $glib_file
 389           AC_CHECK_GLIBDIR
 390         fi
 391       fi
 392     fi
 393
 394     if test -z "$GLIB_LIBS"; then
 395       AC_ERROR([GLIB is required to build irssi.])
 396     fi
 397   fi
 398 fi
 399
 400 LIBS="$LIBS $GLIB_LIBS"
 401
 402 dnl **
 403 dnl ** check if we can link dynamic libraries to modules
 404 dnl ** also checks if libraries are built to .libs dir
 405 dnl **
 406
 407 AC_MSG_CHECKING([if we can link dynamic libraries with modules])
 408 DYNLIB_MODULES=no
 409
 410 dnl ** compile object file
 411 cat > conftest.c <<EOF
 412 #include <math.h>
 413 int modfunc(){return (int)floor(1.2);}
 414 EOF
 415
 416 ./libtool --mode=compile $CC $CFLAGS -c conftest.c 2> /dev/null > /dev/null
 417 if test ! -s conftest.lo; then
 418   AC_ERROR([error compiling test module])
 419 fi
 420
 421 dnl ** link to library
 422 ./libtool --mode=link $CC $CFLAGS $LDFLAGS -rpath /usr/lib conftest.lo -lm -o libconftest.la > /dev/null
 423 if test ! -s .libs/libconftest.a; then
 424   AC_ERROR([error, can't even find .a library])
 425 fi
 426
 427 dnl ** check if dynamic linking worked
 428 libfile=`grep '^library_names' libconftest.la|$sedpath "s/library_names='\(.*\)'.*/\1/"|$sedpath 's/.* \([[^ ]]*\)$/\1/'`
 429 if test ! -s .libs/$libfile; then
 430   AC_MSG_RESULT([no, error linking test module])
 431 else
 432   cat > conftest.c <<EOF
 433 #include <gmodule.h>
 434 main() {
 435 GModule *m; int (*modfunc)(void);
 436 m = g_module_open(".libs/$libfile", 0);
 437 if (!m) g_print("error loading: %s", g_module_error());
 438 else if (!g_module_symbol(m, "modfunc", (gpointer *) &modfunc))
 439   g_print("modfunc() symbol not found from module");
 440 else if (modfunc() == 1) g_print("ok"); else g_print("wrong result?! 1 vs %d", modfunc());
 441 return 0; }
 442 EOF
 443   $CC $CFLAGS $LDFLAGS conftest.c -o conftest $GLIB_CFLAGS $GLIB_LIBS 2> /dev/null > /dev/null
 444   if test ! -s conftest; then
 445     AC_MSG_RESULT([no, error compiling test program])
 446   else
 447     status="`./conftest`"
 448     if test "x$status" = "xok"; then
 449       DYNLIB_MODULES=yes
 450       AC_MSG_RESULT([yes])
 451     else
 452       AC_MSG_RESULT([no, error running: $status])
 453     fi
 454   fi
 455 fi
 456 rm -rf conftest conftest.* libconftest.* .libs
 457
 458 dnl **
 459 dnl ** curses checks
 460 dnl **
 461
 462 if test "x$want_textui" = "xyes"; then
 463         AC_CHECK_CURSES
 464
 465         LIBS="$LIBS $CURSES_LIBS"
 466         if test "x$has_curses" = "xtrue"; then
 467                 AC_CHECK_FUNC(use_default_colors, AC_DEFINE(HAVE_NCURSES_USE_DEFAULT_COLORS))
 468                 AC_CHECK_FUNC(idcok, AC_DEFINE(HAVE_CURSES_IDCOK))
 469                 AC_CHECK_FUNC(resizeterm, AC_DEFINE(HAVE_CURSES_RESIZETERM))
 470                 AC_CHECK_FUNC(wresize, AC_DEFINE(HAVE_CURSES_WRESIZE))
 471                 AC_CHECK_FUNC(setupterm,, [
 472                         want_termcap=yes
 473                 ])
 474         else
 475                 AC_CHECK_LIB(tinfo, setupterm, [
 476                   LIBS="$LIBS -ltinfo"
 477                   want_terminfo=yes
 478                 ], AC_CHECK_LIB(termlib, tgetent, [
 479                   LIBS="$LIBS -ltermlib"
 480                   want_termcap=yes
 481                 ], AC_CHECK_LIB(termcap, tgetent, [
 482                   LIBS="$LIBS -ltermcap"
 483                   want_termcap=yes
 484                 ], [
 485                   AC_ERROR(Terminfo/termcap not found - install ncurses-devel package)
 486                   want_textui=no
 487                 ])))
 488         fi
 489         if test "x$want_termcap" = "xyes"; then
 490                 AC_CHECK_FUNC(tparm,, need_tparm=yes)
 491         else
 492                 AC_DEFINE(HAVE_TERMINFO)
 493         fi
 494 fi
 495
 496 dnl **
 497 dnl ** perl checks
 498 dnl **
 499
 500 if test "$want_perl" != "no"; then
 501         AC_MSG_CHECKING(for working Perl support)
 502
 503         if test -z "$perlpath"; then
 504                 perl_check_error="perl binary not found"
 505         else
 506                 PERL_CFLAGS=`$perlpath -MExtUtils::Embed -e ccopts 2>/dev/null`
 507         fi
 508
 509         if test -z "$PERL_CFLAGS"; then
 510                 if test -n "$perl_check_error"; then
 511                         perl_check_error="Error getting perl CFLAGS"
 512                 fi
 513                 AC_MSG_RESULT([not found, building without Perl])
 514                 want_perl=no
 515         else
 516                 PERL_LDFLAGS=`$perlpath -MExtUtils::Embed -e ldopts 2>/dev/null`
 517
 518                 dnl * Perl 5.004 and older use perl_xxx variables while
 519                 dnl * later use PL_perl_xxx variables ..
 520                 have_pl_perl=`$perlpath -e 'print $] < 5.005 ? "no" : "yes";'`
 521                 if test "x$have_pl_perl" = "xyes"; then
 522                         AC_DEFINE(HAVE_PL_PERL)
 523                 fi
 524
 525                 if test "x$DYNLIB_MODULES" = "xno" -a "$want_perl" != "static"; then
 526                         dnl * wanted perl as module, won't get it.
 527                         want_perl=static
 528                         perl_mod_error="Dynamic library dependencies don't work with modules"
 529                 fi
 530
 531                 if test "$want_perl" != "static"; then
 532                         dnl * dynaloader.a -> libperl_dynaloader.la
 533                         DYNALOADER_A=`echo $PERL_LDFLAGS | $perlpath -pe 's/^(.* )*([[^ ]]*DynaLoader\.a).*/\2/'`
 534                 fi
 535
 536                 dnl * don't check libperl.a if dynaloader.a wasn't found..
 537                 if test -n "$DYNALOADER_A"; then
 538                         dnl * find either libperl.a or libperl.so
 539                         LIBPERL_A=`echo "$PERL_LDFLAGS -L/usr/lib"|$perlpath -e 'foreach (split(/ /, <STDIN>)) { if (/^-L(.*)/) { my $dir=$1; if (\`ls $dir/libperl.so* 2>/dev/null\`) { print "-lperl"; last; }; if (-e "$dir/libperl.a") { print "$dir/libperl.a"; last } } };'`
 540                         if test -z "$LIBPERL_A"; then
 541                                 perl_mod_error="Didn't find location of -lperl"
 542                                 DYNALOADER_A=
 543                         elif test "$LIBPERL_A" = "-lperl"; then
 544                                 LIBPERL_A=
 545                         fi
 546                 fi
 547
 548                 dnl * remove all database stuffs
 549                 dnl * nsl is already in ldflags
 550                 dnl * libc is of course linked without needing -lc
 551                 dnl * -rdynamic must not be in LIBADD line
 552                 for word in -ldb -ldbm -lndbm -lgdbm -lc -rdynamic; do
 553                   PERL_LDFLAGS=`echo $PERL_LDFLAGS | $sedpath -e "s/$word //" -e "s/$word$//"`
 554                 done
 555
 556                 case "$host_os" in
 557                   linux*)
 558                     PERL_LDFLAGS=`echo $PERL_LDFLAGS | $sedpath -e 's/-lposix //' -e 's/-lposix$//'`
 559                     ;;
 560                   hpux*)
 561                     if test "x$ac_cv_prog_gcc" = "xyes"; then
 562                       PERL_CFLAGS=`echo $PERL_CFLAGS | $sedpath -e 's/-Ae //' -e 's/-Ae$//'`
 563                       PERL_LDFLAGS=`echo $PERL_LDFLAGS | $sedpath -e 's/-Ae //' -e 's/-Ae$//'`
 564                     fi
 565                     ;;
 566                   *)
 567                     ;;
 568                 esac
 569
 570                 dnl * check that perl's ldflags actually work
 571                 echo "main(){perl_alloc(); return 0;}" > conftest.c
 572                 $CC $CFLAGS conftest.c -o conftest $LDFLAGS $PERL_LDFLAGS 2> perl.error.tmp > /dev/null
 573                 if test ! -s conftest; then
 574                         perl_check_error="Error linking with perl libraries: $PERL_LDFLAGS: `cat perl.error.tmp`"
 575                         AC_MSG_RESULT([error linking with perl libraries, building without Perl])
 576                         want_perl=no
 577                 fi
 578
 579                 rm -f perl.error.tmp
 580         fi
 581
 582         if test "x$want_perl" != "xno"; then
 583                 if test "x$want_perl" = "xstatic"; then
 584                         AC_MSG_RESULT(ok)
 585                 elif test -z "$DYNALOADER_A"; then
 586                         AC_MSG_RESULT([error parsing ldopts, building Perl into irssi binary instead of as module])
 587                         want_perl=static
 588                 else
 589                         AC_MSG_RESULT(ok)
 590                         PERL_LDFLAGS=`echo $PERL_LDFLAGS | $perlpath -pe 's/^(.* )*[[^ ]]*DynaLoader\.a/\1libperl_dynaloader.la/'`
 591                         if test -n "$LIBPERL_A"; then
 592                                 PERL_LDFLAGS=`echo $PERL_LDFLAGS | $sedpath -e 's/-lperl /libperl_orig.la /' -e 's/-lperl$/libperl_orig.la$/'`
 593                         fi
 594                         AC_SUBST(LIBPERL_A)
 595                         AC_SUBST(DYNALOADER_A)
 596                 fi
 597
 598                 if test "x$want_perl" = "xstatic"; then
 599                         dnl * building with static perl support
 600                         dnl * all PERL_LDFLAGS linking is done in fe-text
 601                         PERL_LINK_FLAGS="$PERL_LDFLAGS"
 602                         PERL_LINK_LIBS="../perl/libperl_core_static.la"
 603                         PERL_FE_LINK_LIBS="../perl/libfe_perl_static.la"
 604                         PERL_LDFLAGS=
 605                         AC_DEFINE(HAVE_STATIC_PERL)
 606
 607                         dnl * build only static library of perl module
 608                         perl_module_lib=
 609                         perl_module_fe_lib=
 610                         perl_static_lib=libperl_core_static.la
 611                         perl_static_fe_lib=libfe_perl_static.la
 612                         PERL_LIBTOOL='$(SHELL) $(top_builddir)/libtool'
 613                 else
 614                         dnl * build dynamic library of perl module
 615                         perl_module_lib=libperl_core.la
 616                         perl_module_fe_lib=libfe_perl.la
 617                         perl_static_lib=
 618                         perl_static_fe_lib=
 619                         PERL_LIBTOOL='$(SHELL) $(top_builddir)/libtool'
 620                 fi
 621
 622                 if test "x$want_staticperllib" = "xyes"; then
 623                         PERL_MM_PARAMS="$PERL_MM_PARAMS LINKTYPE=static"
 624                         PERL_LINK_LIBS="$PERL_LINK_LIBS ../perl/common/blib/arch/auto/Irssi/Irssi.a ../perl/irc/blib/arch/auto/Irssi/Irc/Irc.a ../perl/ui/blib/arch/auto/Irssi/UI/UI.a ../perl/textui/blib/arch/auto/Irssi/TextUI/TextUI.a"
 625                         PERL_STATIC_LIBS=1
 626                 else
 627                         PERL_STATIC_LIBS=0
 628                 fi
 629
 630                 # figure out the correct @INC path - we'll need to do this
 631                 # through MakeMaker since it's difficult to get it right
 632                 # otherwise.
 633                 if test "x$perl_set_use_lib" = "xyes"; then
 634                         perl -e 'use ExtUtils::MakeMaker; WriteMakefile("NAME" => "test", "MAKEFILE" => "Makefile.test");' $PERL_MM_PARAMS >/dev/null
 635                         PERL_USE_LIB=`perl -e 'open(F, "Makefile.test"); while (<F>) { chomp; if (/^(\w+) = (.*$)/) { $keys{$1} = $2; } }; $key = $keys{INSTALLARCHLIB}; while ($key =~ /\\$\((\w+)\)/) { $value = $keys{$1}; $key =~ s/\\$\($1\)/$value/; }; print $key;'`
 636                         rm -f Makefile.test
 637                 fi
 638
 639                 AC_SUBST(perl_module_lib)
 640                 AC_SUBST(perl_static_lib)
 641                 AC_SUBST(perl_module_fe_lib)
 642                 AC_SUBST(perl_static_fe_lib)
 643                 AC_SUBST(PERL_LIBTOOL)
 644
 645                 AC_SUBST(PERL_LINK_FLAGS)
 646                 AC_SUBST(PERL_LINK_LIBS)
 647                 AC_SUBST(PERL_FE_LINK_LIBS)
 648
 649                 AC_SUBST(PERL_LDFLAGS)
 650                 AC_SUBST(PERL_CFLAGS)
 651
 652                 AC_SUBST(PERL_USE_LIB)
 653                 AC_SUBST(PERL_MM_PARAMS)
 654                 AC_SUBST(PERL_STATIC_LIBS)
 655         fi
 656 fi
 657
 658 dnl ** check what we want to build
 659 AM_CONDITIONAL(BUILD_TEXTUI, test "$want_textui" = "yes")
 660 AM_CONDITIONAL(BUILD_IRSSIBOT, test "$want_irssibot" = "yes")
 661 AM_CONDITIONAL(BUILD_IRSSIPROXY, test "$want_irssiproxy" = "yes")
 662 AM_CONDITIONAL(BUILD_PLUGINS, test "$want_plugins" = "yes")
 663 AM_CONDITIONAL(BUILD_SERVERTEST, test -n "$TEST_DIR")
 664 AM_CONDITIONAL(HAVE_PERL, test "$want_perl" != "no")
 665 AM_CONDITIONAL(HAVE_STATIC_PERL, test "$want_perl" = "static")
 666 AM_CONDITIONAL(NEED_TPARM, test "$need_tparm" = "yes")
 667 AM_CONDITIONAL(USE_CURSES, test "$want_terminfo" != "yes" -a "$want_termcap" != "yes")
 668
 669 # move LIBS to PROG_LIBS so they're not tried to be used when linking eg. perl libraries
 670 PROG_LIBS=$LIBS
 671 LIBS=
 672 AC_SUBST(PROG_LIBS)
 673
 674 dnl **
 675 dnl ** Keep all the libraries here so each frontend doesn't need to
 676 dnl ** keep track of them all
 677 dnl **
 678 dnl ** (these could be made configurable)
 679
 680 CHAT_MODULES="silc"
 681 silc_MODULES=""
 682 if test -n "$build_modules"; then
 683         silc_MODULES="$silc_MODULES $build_modules"
 684 fi
 685
 686 dnl ****************************************
 687
 688 AC_SUBST(CHAT_MODULES)
 689 AC_SUBST(silc_MODULES)
 690
 691 CORE_LIBS="../core/libcore.a ../lib-config/libirssi_config.a ../lib-popt/libpopt.a"
 692 FE_COMMON_LIBS=""
 693
 694 CHAT_LIBS=""
 695 for c in $CHAT_MODULES; do
 696         module_inits=""
 697         module_deinits=""
 698         fe_module_inits=""
 699         fe_module_deinits=""
 700         CHAT_LIBS="$CHAT_LIBS ../$c/lib$c.a ../$c/core/lib${c}_core.a"
 701         if test -f $srcdir/src/fe-common/$c/module.h; then
 702                 FE_COMMON_LIBS="$FE_COMMON_LIBS../fe-common/$c/libfe_common_$c.a "
 703         fi
 704         for s in `eval echo \\$${c}_MODULES`; do
 705                 CHAT_LIBS="$CHAT_LIBS ../$c/$s/lib${c}_$s.a"
 706                 module_inits="$module_inits ${c}_${s}_init();"
 707                 module_deinits="${c}_${s}_deinit(); $module_deinits"
 708                 if test -f $srcdir/src/fe-common/$c/$s/module.h; then
 709                         FE_COMMON_LIBS="$FE_COMMON_LIBS../fe-common/$c/$s/libfe_${c}_$s.a "
 710                         fe_module_inits="$fe_module_inits fe_${c}_${s}_init();"
 711                         fe_module_deinits="fe_${c}_${s}_deinit(); $fe_module_deinits"
 712                 fi
 713         done
 714
 715         file="$srcdir/src/$c/$c.c"
 716         echo "/* this file is automatically generated by configure - don't change */" > $file
 717         echo "void ${c}_core_init(void); void ${c}_core_deinit(void);" >> $file
 718         if test -n "$module_inits"; then
 719                 echo "$module_inits" | $sedpath -e 's/()/(void)/g' -e 's/ /void /g' >> $file
 720                 echo "$module_deinits" | $sedpath -e 's/ *$//' -e 's/()/(void)/g' -e 's/ /void /g' -e 's/^/void /' >> $file
 721         fi
 722         echo "void ${c}_init(void) { ${c}_core_init(); $module_inits }" >> $file
 723         echo "void ${c}_deinit(void) { $module_deinits ${c}_core_deinit(); }" >> $file
 724
 725         if test -f $srcdir/src/fe-common/$c/module.h; then
 726                 file="$srcdir/src/fe-common/$c/${c}-modules.c"
 727                 echo "/* this file is automatically generated by configure - don't change */" > $file
 728                 if test -n "$fe_module_inits"; then
 729                         echo "$fe_module_inits" | $sedpath -e 's/()/(void)/g' -e 's/ /void /g' >> $file
 730                         echo "$fe_module_deinits" | $sedpath -e 's/ *$//' -e 's/()/(void)/g' -e 's/ /void /g' -e 's/^/void /' >> $file
 731                 fi
 732                 echo "void fe_${c}_modules_init(void) { $fe_module_inits }" >> $file
 733                 echo "void fe_${c}_modules_deinit(void) { $fe_module_deinits }" >> $file
 734         fi
 735 done
 736
 737 FE_COMMON_LIBS="$FE_COMMON_LIBS../fe-common/core/libfe_common_core.a"
 738
 739 dnl ** common libraries needed by frontends
 740 COMMON_NOUI_LIBS="$CHAT_LIBS $CORE_LIBS $INTLLIBS"
 741 COMMON_LIBS="$FE_COMMON_LIBS $COMMON_NOUI_LIBS"
 742 AC_SUBST(COMMON_NOUI_LIBS)
 743 AC_SUBST(COMMON_LIBS)
 744
 745 dnl **
 746 dnl ** IPv6 support
 747 dnl **
 748
 749 if test "x$want_ipv6" = "xyes"; then
 750         AC_MSG_CHECKING([for IPv6])
 751         AC_CACHE_VAL(irssi_cv_type_in6_addr,
 752         [AC_TRY_COMPILE([
 753         #include <sys/types.h>
 754         #include <sys/socket.h>
 755         #include <netinet/in.h>
 756         #include <netdb.h>
 757         #include <arpa/inet.h>],
 758         [struct in6_addr i;],
 759         irssi_cv_type_in6_addr=yes,
 760         irssi_cv_type_in6_addr=no,
 761         )])
 762         if test $irssi_cv_type_in6_addr = yes; then
 763                 AC_DEFINE(HAVE_IPV6)
 764         fi
 765         AC_MSG_RESULT($irssi_cv_type_in6_addr)
 766 fi
 767
 768 dnl **
 769 dnl ** IRSSI_VERSION_DATE and IRSSI_VERSION_TIME
 770 dnl **
 771 #VERSION_DATE=`head -1 $srcdir/ChangeLog|sed 's/^\(....\)-\(..\)-\(..\).*/\1\2\3/'`
 772 #VERSION_TIME=`head -1 $srcdir/ChangeLog|sed -e 's/^[[^ ]]* \(..\):\(..\).*/\1\2/' -e 's/^0*//'`
 773 #AC_SUBST(VERSION_DATE)
 774 #AC_SUBST(VERSION_TIME)
 775
 776 #
 777 # Glue into SILC build system
 778 #
 779 INCLUDE_DEFINES_INT="include \$(top_srcdir)/Makefile.defines_int"
 780 AC_SUBST(INCLUDE_DEFINES_INT)
 781
 782 AC_OUTPUT(
 783 Makefile
 784 src/Makefile
 785 src/core/Makefile
 786 src/fe-common/Makefile
 787 src/fe-common/core/Makefile
 788 src/fe-common/silc/Makefile
 789 src/fe-text/Makefile
 790 src/lib-config/Makefile
 791 src/lib-popt/Makefile
 792 src/silc/Makefile
 793 src/silc/core/Makefile
 794 src/perl/Makefile
 795 src/perl/common/Makefile.PL
 796 src/perl/ui/Makefile.PL
 797 src/perl/textui/Makefile.PL
 798 scripts/Makefile
 799 docs/Makefile
 800 docs/help/Makefile
 801 docs/help/in/Makefile
 802 irssi-version.h
 803 stamp.h
 804 irssi.spec
 805 irssi-config)
 806
 807 dnl ** for building from objdir
 808 old_dir=`pwd` && cd $srcdir && whole_dir=`pwd` && cd $old_dir
 809 if test "x$old_dir" != "x$whole_dir"; then
 810         $LN_S $srcdir/irssi-version.h irssi-version.h
 811
 812         if test "x$want_perl" != "xno"; then
 813                 subdirfiles=""
 814                 for i in $whole_dir/src/perl/common $whole_dir/src/perl/irc $whole_dir/src/perl/ui $whole_dir/src/perl/textui; do
 815                         subdirfiles=`echo $subdirfiles $i/typemap $i/module.h $i/*.pm $i/*.xs`
 816                 done
 817                 for file in $whole_dir/src/perl/*.[[ch]] $whole_dir/src/perl/libperl_orig.la $whole_dir/src/perl/libperl_dynaloader.la $subdirfiles; do
 818                         link=`echo $file|$sedpath "s?$whole_dir/??"`
 819                         rm -f $link
 820                         $LN_S $file $link
 821                 done
 822         fi
 823 fi
 824
 825 echo
 826
 827 if test "x$want_textui" = "xno"; then
 828         text=no
 829 elif test "x$want_termcap" = "xyes"; then
 830         text="yes, using termcap"
 831 elif test "x$want_terminfo" = "xyes"; then
 832         text="yes, using terminfo"
 833 else
 834         text="yes, using curses"
 835 fi
 836 echo "Building text frontend ..... : $text"
 837 echo "Building irssi bot ......... : $want_irssibot"
 838 echo "Building irssi proxy ....... : $want_irssiproxy"
 839 echo "Building with IPv6 support . : $want_ipv6"
 840 if test "x$have_gmodule" = "xyes"; then
 841         echo "Building with module support : yes"
 842 else
 843         echo "Building with module support : NO!! /LOAD will not work!"
 844         echo " - You're missing gmodule (comes with glib) for some reason,"
 845         echo "   or it doesn't work in your system."
 846 fi
 847
 848 if test "x$want_perl" = "xstatic"; then
 849         echo "Building with Perl support . : static (in irssi binary)"
 850 elif test "x$want_perl" = "xmodule"; then
 851         echo "Building with Perl support . : module"
 852 else
 853         if test -z "$perl_check_error"; then
 854                 echo "Building with Perl support . : no"
 855         else
 856                 echo "Building with Perl support . : NO!"
 857                 echo " - $perl_check_error"
 858         fi
 859 fi
 860
 861 if test "x$want_perl" != "xno" -a "x$perl_mod_error" != "x"; then
 862         echo " - NOTE: Perl support will be compiled statically to irssi, not as"
 863         echo "   a module as requested. Reason:"
 864         echo "   $perl_mod_error"
 865
 866         if test -f /etc/debian_version; then
 867                 echo " - Try: apt-get install libperl-dev"
 868         fi
 869 fi
 870
 871 if test "x$want_perl" != "xno"; then
 872         if test "$perl_library_dir" = "PERL_USE_LIB"; then
 873                 perl_library_dir=$PERL_USE_LIB
 874         fi
 875         if test -z "$perl_library_dir"; then
 876                 perl_library_dir="(site default - `$perlpath -e 'use Config; print $Config{sitearch}'`)"
 877         fi
 878         echo "Perl library directory ..... : $perl_library_dir"
 879         if test "x$perl_prefix_note" = "xyes"; then
 880                 echo "  - NOTE: This was automatically set to the same directory you gave with"
 881                 echo "  --prefix. If you want the perl libraries to install to their 'correct'"
 882                 echo "  path, you'll need to give --with-perl-lib=site option to configure."
 883                 echo "  Anyway, installing perl to this directory should work just as well."
 884         fi
 885 fi
 886
 887 echo "Install prefix ............. : $prefix"
 888
 889 echo
 890 echo "If there was any problems, read the INSTALL file."