configure.ad

   1 #
   2 #  configure.ad
   3 #
   4 #  Author: Pekka Riikonen <priikone@silcnet.org>
   5 #
   6 #  Copyright (C) 2000 - 2008 Pekka Riikonen
   7 #
   8 #  This program is free software; you can redistribute it and/or modify
   9 #  it under the terms of the GNU General Public License as published by
  10 #  the Free Software Foundation; version 2 of the License.
  11 #
  12 #  This program is distributed in the hope that it will be useful,
  13 #  but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #  GNU General Public License for more details.
  16 #
  17
  18 AD_INIT
  19 AC_CANONICAL_SYSTEM
  20 AM_INIT_AUTOMAKE
  21 AC_PREREQ(2.52)
  22 AC_CONFIG_HEADERS(runtimedefs.h)
  23
  24 AC_PROG_INSTALL
  25 AC_PROG_MAKE_SET
  26
  27 AC_PROG_LN_S
  28 AC_PROG_EGREP
  29 AC_SUBST(LN_S)
  30 AC_PATH_PROG(sedpath, sed)
  31
  32 AC_PROG_CC
  33 AM_PROG_AS
  34 AC_C_INLINE
  35 AC_C_CONST
  36
  37 AC_PROG_RANLIB
  38 #ifdef SILC_DIST_INPLACE
  39 AC_DISABLE_SHARED
  40 #endif SILC_DIST_INPLACE
  41 AC_PROG_LIBTOOL
  42
  43 SILC_TOP_SRCDIR=`pwd`
  44
  45 ##
  46 ## Library versioning.
  47 ##
  48
  49 # Do the releases and library versioning according to following rules:
  50 #
  51 #  - If any code has changed in library, increment RUNTIME_REVISION
  52 #  - If API were added, removed or changed, set RUNTIME_REVISION to 0
  53 #  - If API were added, removed or changed, increment RUNTIME_CURRENT
  54 #  - If APi were added, increment RUNTIME_AGE
  55 #  - If API were removed, set RUNTIME_AGE to 0
  56 #
  57
  58 # Base version for library.
  59 RUNTIME_BASE_VERSION=1.2
  60
  61 # libsilc versions
  62 RUNTIME_CURRENT=1               # prev = 0
  63 RUNTIME_REVISION=0              # prev = 0
  64 RUNTIME_AGE=0                   # prev = 0
  65
  66 # Substitute the version numbers
  67 AC_SUBST(RUNTIME_BASE_VERSION)
  68 AC_SUBST(RUNTIME_CURRENT)
  69 AC_SUBST(RUNTIME_REVISION)
  70 AC_SUBST(RUNTIME_AGE)
  71
  72
  73 ##
  74 ##  Installation
  75 ##
  76
  77 # Default installation destination
  78 AC_PREFIX_DEFAULT(/usr/local)
  79 if test "x$prefix" != xNONE; then
  80   silc_prefix="$prefix"
  81 else
  82   silc_prefix="$ac_default_prefix"
  83   prefix="$silc_prefix"
  84 fi
  85
  86
  87 ##
  88 ## Detect CPU
  89 ##
  90
  91 # Disable all CPU feature optimizations
  92 AC_MSG_CHECKING(whether to enable CPU feature optimizations)
  93 AC_ARG_ENABLE(cpu-optimizations,
  94   [  --disable-cpu-optimizations  do not use any CPU feature optimizations],
  95   [
  96     AC_MSG_RESULT(no)
  97     AC_DEFINE([SILC_NO_CPU_OPTIMIZATIONS], [], [SILC_NO_CPU_OPTIMIZATIONS])
  98     want_cpu_optimizations=false
  99   ],
 100   [
 101     AC_MSG_RESULT(yes)
 102     want_cpu_optimizations=true
 103   ])
 104 AM_CONDITIONAL(SILC_NO_CPU_OPTIMIZATIONS,
 105                test x$want_cpu_optimizations = xfalse)
 106
 107 SILC_SYSTEM_IS_SMP(AC_DEFINE([SILC_SMP], [], [SILC_SMP]), [],
 108                    AC_DEFINE([SILC_SMP], [], [SILC_SMP]))
 109 cpu_i386=false
 110 cpu_i486=false
 111 cpu_i586=false
 112 cpu_i686=false
 113 cpu_i786=false
 114 cpu_x86_64=false
 115 cpu_ppc=false
 116 cpu_ia64=false
 117 case "$host_cpu" in
 118   # All following Intels are considered 32-bit CPUs.
 119   i?86)
 120     # All CPUs of today are considered i386 and i486 compatible */
 121     AC_DEFINE([SILC_I386], [], [SILC_I386])
 122     AC_DEFINE([SILC_I486], [], [SILC_I486])
 123     cpu_i386=true
 124     cpu_i486=true
 125
 126     if test "x$host_cpu" = "xi586"; then
 127       AC_DEFINE([SILC_I586], [], [SILC_I586])
 128       cpu_i586=true
 129     fi
 130
 131     if test "x$host_cpu" = "xi686"; then
 132       AC_DEFINE([SILC_I586], [], [SILC_I586])
 133       AC_DEFINE([SILC_I686], [], [SILC_I686])
 134       cpu_i586=true
 135       cpu_i686=true
 136     fi
 137
 138     if test "x$host_cpu" = "xi786"; then
 139       AC_DEFINE([SILC_I586], [], [SILC_I586])
 140       AC_DEFINE([SILC_I686], [], [SILC_I686])
 141       AC_DEFINE([SILC_I786], [], [SILC_I786])
 142       cpu_i586=true
 143       cpu_i686=true
 144       cpu_i786=true
 145     fi
 146
 147     # Check for specific CPU features
 148     SILC_CPU_FLAG(mmx, true, AC_DEFINE([SILC_CPU_MMX], [], [SILC_CPU_MMX]), [])
 149     SILC_CPU_FLAG(sse2, true, AC_DEFINE([SILC_CPU_SSE2], [], [SILC_CPU_SSE2]), [])
 150     SILC_CPU_FLAG(pni, true, AC_DEFINE([SILC_CPU_SSE3], [], [SILC_CPU_SSE3]), [])
 151     SILC_CPU_FLAG(ssse3, true, AC_DEFINE([SILC_CPU_SSSE3], [], [SILC_CPU_SSSE3]), [])
 152     SILC_CPU_FLAG(sse4, true, AC_DEFINE([SILC_CPU_SSE4], [], [SILC_CPU_SSE4]), [])
 153     ;;
 154
 155   # Intel IA-64, 64-bit CPU (not x86_64 compatible)
 156   ia64)
 157     AC_DEFINE([SILC_IA64], [], [SILC_IA64])
 158     cpu_ia64=true
 159
 160     # Check for specific CPU features
 161     SILC_CPU_FLAG(mmx, true, AC_DEFINE([SILC_CPU_MMX], [], [SILC_CPU_MMX]), [])
 162     SILC_CPU_FLAG(sse2, true, AC_DEFINE([SILC_CPU_SSE2], [], [SILC_CPU_SSE2]), [])
 163     SILC_CPU_FLAG(pni, true, AC_DEFINE([SILC_CPU_SSE3], [], [SILC_CPU_SSE3]), [])
 164     SILC_CPU_FLAG(ssse3, true, AC_DEFINE([SILC_CPU_SSSE3], [], [SILC_CPU_SSSE3]), [])
 165     SILC_CPU_FLAG(sse4, true, AC_DEFINE([SILC_CPU_SSE4], [], [SILC_CPU_SSE4]), [])
 166     ;;
 167
 168   # AMD/Intel x86_64, 64-bit CPU
 169   x86_64)
 170     AC_DEFINE([SILC_X86_64], [], [SILC_X86_64])
 171     cpu_x86_64=true
 172
 173     # Check for specific CPU features
 174     SILC_CPU_FLAG(mmx, true, AC_DEFINE([SILC_CPU_MMX], [], [SILC_CPU_MMX]), [])
 175     SILC_CPU_FLAG(sse2, true, AC_DEFINE([SILC_CPU_SSE2], [], [SILC_CPU_SSE2]), [])
 176     SILC_CPU_FLAG(pni, true, AC_DEFINE([SILC_CPU_SSE3], [], [SILC_CPU_SSE3]), [])
 177     SILC_CPU_FLAG(ssse3, true, AC_DEFINE([SILC_CPU_SSSE3], [], [SILC_CPU_SSSE3]), [])
 178     SILC_CPU_FLAG(sse4, true, AC_DEFINE([SILC_CPU_SSE4], [], [SILC_CPU_SSE4]), [])
 179     ;;
 180
 181   # PowerPC, 32-bit and 64-bit CPUs
 182   powerpc*)
 183     AC_DEFINE([SILC_POWERPC], [], [SILC_POWERPC])
 184     cpu_ppc=true
 185     ;;
 186 esac
 187 AM_CONDITIONAL(SILC_I386, test x$cpu_i386 = xtrue)
 188 AM_CONDITIONAL(SILC_I486, test x$cpu_i486 = xtrue)
 189 AM_CONDITIONAL(SILC_I586, test x$cpu_i586 = xtrue)
 190 AM_CONDITIONAL(SILC_I686, test x$cpu_i686 = xtrue)
 191 AM_CONDITIONAL(SILC_7686, test x$cpu_i786 = xtrue)
 192 AM_CONDITIONAL(SILC_X86_64, test x$cpu_x86_64 = xtrue)
 193 AM_CONDITIONAL(SILC_POWERPC, test x$cpu_ppc = xtrue)
 194 AM_CONDITIONAL(SILC_IA64, test x$cpu_ia64 = xtrue)
 195
 196 if test x$want_cpu_optimizations = xtrue; then
 197   # Set some compiler options based on CPU
 198   if test "x$CC" = "xicc"; then
 199     # ICC flags
 200     if test x$x_have_cpu_sse4 = xtrue; then
 201       SILC_ADD_CFLAGS(-axS)
 202     fi
 203     if test x$x_have_cpu_ssse3 = xtrue; then
 204       SILC_ADD_CFLAGS(-axT)
 205     elif test x$x_have_cpu_pni = xtrue; then
 206       SILC_ADD_CFLAGS(-axP)
 207     elif test x$x_have_cpu_sse2 = xtrue; then
 208       SILC_ADD_CFLAGS(-axW)
 209     fi
 210   else
 211     # Other compilers
 212     if test x$x_have_cpu_sse2 = xtrue; then
 213       SILC_ADD_CFLAGS(-msse2)
 214     fi
 215     if test x$x_have_cpu_pni = xtrue; then
 216       SILC_ADD_CFLAGS(-msse3)
 217     fi
 218     if test x$x_have_cpu_ssse3 = xtrue; then
 219       SILC_ADD_CFLAGS(-mssse3)
 220     fi
 221     if test x$x_have_cpu_sse4 = xtrue; then
 222       SILC_ADD_CFLAGS(-msse4)
 223     fi
 224   fi
 225 fi
 226
 227
 228 ##
 229 ## Put here any platform specific stuff
 230 ##
 231
 232 case "$target" in
 233   *-*-linux*)
 234     check_threads=true
 235     CFLAGS=`echo $CFLAGS -D_GNU_SOURCE`
 236     ;;
 237   *-*-freebsd*)
 238     check_threads=true
 239     ;;
 240   *-*-netbsd*)
 241     check_threads=true
 242     ;;
 243   *-*-*bsd*)
 244     check_threads=false
 245     ;;
 246   *)
 247     check_threads=true
 248     ;;
 249 esac
 250
 251
 252 ##
 253 ## Header checking
 254 ##
 255 AC_HEADER_STDC
 256 AC_HEADER_TIME
 257 AC_HEADER_STAT
 258
 259 # More header checking
 260 #
 261 AC_CHECK_HEADERS(unistd.h string.h errno.h fcntl.h assert.h execinfo.h)
 262 AC_CHECK_HEADERS(sys/types.h sys/stat.h sys/time.h stddef.h)
 263 AC_CHECK_HEADERS(netinet/in.h netinet/tcp.h xti.h netdb.h sys/resource.h)
 264 AC_CHECK_HEADERS(pwd.h grp.h termcap.h paths.h)
 265 AC_CHECK_HEADERS(ncurses.h signal.h ctype.h utime.h dirent.h)
 266 AC_CHECK_HEADERS(arpa/inet.h sys/mman.h limits.h termios.h locale.h langinfo.h)
 267
 268
 269 ##
 270 ## Data type checking
 271 ##
 272 AC_TYPE_SIGNAL
 273 AC_TYPE_SIZE_T
 274 AC_TYPE_MODE_T
 275 AC_TYPE_UID_T
 276 AC_TYPE_PID_T
 277 AC_CHECK_SIZEOF(long long, 0)
 278 AC_SUBST(SILC_SIZEOF_LONG_LONG, $ac_cv_sizeof_long_long)
 279 AC_CHECK_SIZEOF(long, 0)
 280 AC_SUBST(SILC_SIZEOF_LONG, $ac_cv_sizeof_long)
 281 AC_CHECK_SIZEOF(int, 0)
 282 AC_SUBST(SILC_SIZEOF_INT, $ac_cv_sizeof_int)
 283 AC_CHECK_SIZEOF(short, 0)
 284 AC_SUBST(SILC_SIZEOF_SHORT, $ac_cv_sizeof_short)
 285 AC_CHECK_SIZEOF(char, 0)
 286 AC_SUBST(SILC_SIZEOF_CHAR, $ac_cv_sizeof_char)
 287 AC_CHECK_SIZEOF(void *, 0)
 288 AC_SUBST(SILC_SIZEOF_VOID_P, $ac_cv_sizeof_void_p)
 289 AC_CHECK_TYPES(long long)
 290 AC_CHECK_TYPES(long double)
 291
 292 # Check for big-endian machines
 293 AC_C_BIGENDIAN
 294
 295
 296 ##
 297 ## Compiler and compiler flag checks
 298 ##
 299
 300 # Disable all compiler optimizations
 301 AC_MSG_CHECKING(whether to enable compiler optimizations)
 302 AC_ARG_ENABLE(optimizations,
 303   [  --disable-optimizations do not use any compiler optimizations],
 304   [
 305     AC_MSG_RESULT(no)
 306     AC_DEFINE([SILC_NO_CC_OPTIMIZATIONS], [], [SILC_NO_CC_OPTIMIZATIONS])
 307     want_cc_optimizations=false
 308   ],
 309   [
 310     AC_MSG_RESULT(yes)
 311     want_cc_optimizations=true
 312   ])
 313 AM_CONDITIONAL(SILC_NO_CC_OPTIMIZATIONS, test x$want_cc_optimizations = xfalse)
 314
 315 if test "$GCC"; then
 316   # GCC specific options
 317   if test "x$summary_debug" = "xyes"; then
 318     SILC_ADD_CFLAGS(-g)
 319   else
 320     SILC_ADD_CFLAGS(-g)
 321   fi
 322   SILC_ADD_CFLAGS(-Wall -finline-functions)
 323   SILC_ADD_CFLAGS(-Wno-pointer-sign)
 324 else
 325   # Other compilers
 326   case "$target" in
 327     alpha*-dec-osf*)
 328       SILC_ADD_CFLAGS(-g3)
 329       ;;
 330     mips*-sgi-irix*)
 331       SILC_ADD_CFLAGS(-g3)
 332       ;;
 333     *)
 334       SILC_ADD_CFLAGS(-g)
 335       ;;
 336   esac
 337
 338   # Intel C++ Compiler flags
 339   if test "x$CC" = "xicc"; then
 340     SILC_ADD_CFLAGS(-restrict)
 341     SILC_ADD_CFLAGS(-finline-functions)
 342
 343     # Don't define __GNUC__ except for system includes
 344     SILC_ADD_CFLAGS(-gcc-sys)
 345   fi
 346 fi
 347
 348 if test x$want_cc_optimizations = xtrue; then
 349   if test "$GCC"; then
 350     # GCC specific options
 351     if test "x$summary_debug" = "xyes"; then
 352       SILC_ADD_CFLAGS(-O)
 353     else
 354       SILC_ADD_CFLAGS(-O2)
 355     fi
 356   else
 357     # Other compilers
 358     case "$target" in
 359       alpha*-dec-osf*)
 360         SILC_ADD_CFLAGS(-O2, SILC_ADD_CFLAGS(-O))
 361         ;;
 362       mips*-sgi-irix*)
 363         SILC_ADD_CFLAGS(-O2, SILC_ADD_CFLAGS(-O))
 364         ;;
 365       *)
 366         SILC_ADD_CFLAGS(-O2, SILC_ADD_CFLAGS(-O))
 367         ;;
 368     esac
 369   fi
 370 fi
 371
 372
 373 ##
 374 ## Function and libary checking
 375 ##
 376 AC_CHECK_FUNCS(gethostname gethostbyaddr getservbyname getservbyport)
 377 AC_CHECK_FUNCS(poll select listen bind shutdown close connect setsockopt)
 378 AC_CHECK_FUNCS(setrlimit time ctime utime gettimeofday getrusage)
 379 AC_CHECK_FUNCS(chmod fcntl stat fstat getenv putenv strerror)
 380 AC_CHECK_FUNCS(getpid getgid getsid getpgid getpgrp getuid sched_yield)
 381 AC_CHECK_FUNCS(setgroups initgroups nl_langinfo nanosleep)
 382 AC_CHECK_FUNCS(strchr snprintf strstr strcpy strncpy memcpy memset memmove)
 383 AC_CHECK_FUNCS(setenv getenv putenv unsetenv clearenv backtrace)
 384
 385 # Check getopt_long
 386 AC_CHECK_FUNC(getopt_long,
 387   [
 388     AC_DEFINE([HAVE_GETOPT_LONG], [], [HAVE_GETOPT_LONG])
 389     have_getopt_long=1
 390   ], have_getopt_long=0
 391 )
 392
 393 # Check gethostbyname
 394 AC_CHECK_FUNC(gethostbyname, [],
 395   [
 396     AC_CHECK_LIB(nsl, gethostbyname, LIBS="$LIBS -lnsl")
 397     AC_CHECK_FUNC(res_gethostbyname, [],
 398        AC_CHECK_LIB(resolv, res_gethostbyname, LIBS="$LIBS -lresolv")
 399     )
 400   ])
 401
 402 # Check socket
 403 AC_CHECK_FUNC(socket, [],
 404   AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
 405 )
 406
 407 # Check clock_gettime
 408 AC_CHECK_FUNC(clock_gettime, [],
 409   [
 410     AC_CHECK_LIB(rt, clock_gettime,
 411                  [ LIBS="$LIBS -lrt"
 412                    AC_DEFINE([HAVE_CLOCK_GETTIME], [], [HAVE_CLOCK_GETTIME])])
 413   ])
 414
 415 # Check for epoll_wait and verify that epoll_create works
 416 AC_CHECK_FUNC(epoll_wait,
 417   [
 418     AC_RUN_IFELSE(
 419       [
 420         #include <sys/epoll.h>
 421         int main()
 422         {
 423           int ret = epoll_create(5);
 424           if (ret < 0)
 425             return 1;
 426           close(ret);
 427           return 0;
 428         }
 429       ],
 430       [
 431         AC_DEFINE([HAVE_EPOLL_WAIT], [1], [HAVE_EPOLL_WAIT])
 432       ],
 433     )
 434   ])
 435
 436 # Check for va_copy
 437 va_copy=false
 438 AC_MSG_CHECKING(for va_copy)
 439 AC_TRY_COMPILE(
 440   [
 441     #include <stdarg.h>
 442     #include <stdlib.h>
 443   ],
 444   [
 445     int t(int x, ...)
 446     {
 447       va_list va, cp;
 448       va_start(va, x);
 449       va_copy(cp, va);
 450       if (va_arg(cp, int) != 0xff11)
 451         return 1;
 452       va_end(va);
 453       va_end(cp);
 454       return 0;
 455     }
 456     int main()
 457     {
 458       return t(0, 0xff11);
 459     }
 460   ],
 461   [
 462     AC_DEFINE([HAVE_VA_COPY], [], [HAVE_VA_COPY])
 463     AC_MSG_RESULT(yes)
 464     va_copy=true
 465   ],
 466   [
 467     AC_MSG_RESULT(no)
 468     va_copy=false
 469   ]
 470 )
 471
 472 if test x$va_copy = xfalse; then
 473   AC_MSG_CHECKING(for __va_copy)
 474   AC_TRY_COMPILE(
 475   [
 476     #include <stdarg.h>
 477     #include <stdlib.h>
 478   ],
 479   [
 480     int t(int x, ...)
 481     {
 482       va_list va, cp;
 483       va_start(va, x);
 484       __va_copy(cp, va);
 485       if (va_arg(cp, int) != 0xff11)
 486         return 1;
 487       va_end(va);
 488       va_end(cp);
 489       return 0;
 490     }
 491     int main()
 492     {
 493       return t(0, 0xff11);
 494     }
 495   ],
 496   [
 497     AC_DEFINE([HAVE___VA_COPY], [], [HAVE___VA_COPY])
 498     AC_MSG_RESULT(yes)
 499     va_copy=true
 500   ],
 501   [
 502     AC_MSG_RESULT(no)
 503     va_copy=false
 504   ]
 505   )
 506 fi
 507
 508 if test x$va_copy = xfalse; then
 509   AC_RUN_IFELSE(
 510     [
 511       #include <stdarg.h>
 512       #include <stdlib.h>
 513       int t(int x, ...)
 514       {
 515         va_list va, cp;
 516         va_start(va, x);
 517         cp = va;
 518         if (va_arg(cp, int) != 0xff11)
 519           return 1;
 520         va_end(va);
 521         va_end(cp);
 522         return 0;
 523       }
 524       int main()
 525       {
 526         return t(0, 0xff11);
 527       }
 528     ],
 529     [va_copy=false],
 530     [
 531       AC_DEFINE([SILC_VA_COPY_ARRAY], [], [SILC_VA_COPY_ARRAY])
 532     ],
 533     [va=copy=false]
 534   )
 535 fi
 536
 537 # Check for timezone and tm_gmtoff for timezone information
 538 AC_MSG_CHECKING(whether system has timezone)
 539 AC_RUN_IFELSE(
 540   [
 541     #include <stdio.h>
 542     #include <time.h>
 543     int main()
 544     {
 545       timezone = 0;
 546       return 0;
 547     }
 548   ],
 549   [ AC_MSG_RESULT(yes)
 550     AC_DEFINE([HAVE_TIMEZONE], [], [HAVE_TIMEZONE]) ],
 551   [ AC_MSG_RESULT(no) ],
 552   [ AC_MSG_RESULT(no) ]
 553 )
 554 AC_MSG_CHECKING(whether system has tm_gmtoff)
 555 AC_RUN_IFELSE(
 556   [
 557     #include <stdio.h>
 558     #include <time.h>
 559     int main()
 560     {
 561       struct tm tm;
 562       tm.tm_gmtoff = 0;
 563       return 0;
 564     }
 565   ],
 566   [ AC_MSG_RESULT(yes)
 567     AC_DEFINE([HAVE_TM_GMTOFF], [], [HAVE_TM_GMTOFF]) ],
 568   [ AC_MSG_RESULT(no) ],
 569   [ AC_MSG_RESULT(no) ]
 570 )
 571 AC_MSG_CHECKING(whether system has __tm_gmtoff)
 572 AC_RUN_IFELSE(
 573   [
 574     #include <stdio.h>
 575     #include <time.h>
 576     int main()
 577     {
 578       struct tm tm;
 579       tm.__tm_gmtoff = 0;
 580       return 0;
 581     }
 582   ],
 583   [ AC_MSG_RESULT(yes)
 584     AC_DEFINE([HAVE___TM_GMTOFF], [], [HAVE___TM_GMTOFF]) ],
 585   [ AC_MSG_RESULT(no) ],
 586   [ AC_MSG_RESULT(no) ]
 587 )
 588 AC_MSG_CHECKING(whether system has __tm_gmtoff__)
 589 AC_RUN_IFELSE(
 590   [
 591     #include <stdio.h>
 592     #include <time.h>
 593     int main()
 594     {
 595       struct tm tm;
 596       tm.__tm_gmtoff__ = 0;
 597       return 0;
 598     }
 599   ],
 600   [ AC_MSG_RESULT(yes)
 601     AC_DEFINE([HAVE___TM_GMTOFF__], [], [HAVE___TM_GMTOFF__]) ],
 602   [ AC_MSG_RESULT(no) ],
 603   [ AC_MSG_RESULT(no) ]
 604 )
 605
 606 # Check for dlopen() and friends
 607 AC_CHECK_HEADERS(dlfcn.h,
 608   [
 609     AC_CHECK_LIB(dl, dlopen,
 610       [
 611         AC_DEFINE([HAVE_DLOPEN], [], [HAVE_DLOPEN])
 612         LIBS="$LIBS -ldl"
 613       ],
 614       [
 615         AC_CHECK_LIB(c, dlopen,
 616           [
 617             AC_DEFINE([HAVE_DLOPEN], [], [HAVE_DLOPEN])
 618           ])
 619       ])
 620   ])
 621
 622 __SILC_ENABLE_DEBUG=""
 623
 624 runtimever=`echo $VERSION | sed 's/\./ /g'`
 625 maj=0
 626 min=0
 627 bld=0
 628 for v in $runtimever
 629 do
 630   if test $maj -eq 0; then
 631     maj=$v
 632     continue
 633   fi
 634   if test $min -eq 0; then
 635     min=$v
 636     continue
 637   fi
 638   if test $bld -eq 0; then
 639     bld=$v
 640     continue
 641   fi
 642 done
 643 __RUNTIME_PACKAGE_VERSION="#define __SILC_RUNTIME_VERSION SILC_VERSION($maj,$min,$bld)"
 644
 645
 646 ##
 647 ##  Enable/disable checking
 648 ##
 649
 650 # IPv6 support
 651 AC_MSG_CHECKING(whether to enable IPv6 support)
 652 AC_ARG_ENABLE(ipv6,
 653   [  --enable-ipv6           enable IPv6 support],
 654   [
 655     case "${enableval}" in
 656       yes)
 657         want_ipv6=true
 658         check_ipv6=false
 659         summary_ipv6="yes"
 660         AC_DEFINE([HAVE_IPV6], [], [HAVE_IPV6])
 661         AC_MSG_RESULT(yes)
 662         ;;
 663       *)
 664         want_ipv6=false
 665         check_ipv6=false
 666         summary_ipv6="no"
 667         AC_MSG_RESULT(no)
 668         ;;
 669     esac
 670   ],
 671     check_ipv6=true
 672   )
 673
 674 if test x$check_ipv6 = xtrue; then
 675   summary_ipv6="no"
 676   AC_TRY_COMPILE(
 677     [
 678       #ifdef HAVE_SYS_TYPES_H
 679       #include <sys/types.h>
 680       #endif
 681       #ifdef HAVE_NETINET_TCP_H
 682       #include <netinet/tcp.h>
 683       #endif
 684       #ifdef HAVE_NETDB_H
 685       #include <netdb.h>
 686       #endif
 687       #include <sys/socket.h>
 688       #ifdef HAVE_NETINET_IN_H
 689       #include <netinet/in.h>
 690       #endif
 691     ],
 692     [
 693       struct sockaddr_in6 sin6;
 694       int family = AF_INET6;
 695     ],
 696     [
 697       AC_DEFINE([HAVE_IPV6], [], [HAVE_IPV6])
 698       AC_MSG_RESULT(yes)
 699       summary_ipv6="yes"
 700     ],
 701       AC_MSG_RESULT(no)
 702     )
 703 fi
 704
 705 # Memory alignment.  User can specify what alignment memory allocation and
 706 # SilcStack allocation use.  Default is system default alignemnt.
 707 AC_ARG_WITH(alignment,
 708   [  --with-alignment=NUMBER Memory alignment in bytes],
 709   [
 710     AC_DEFINE_UNQUOTED([SILC_ALIGNMENT], [$withval], [SILC_ALIGNMENT])
 711     AC_MSG_RESULT(Memory allocation alignment is $withval bytes)
 712   ],
 713   [
 714     AC_DEFINE([SILC_ALIGNMENT], SILC_SIZEOF_VOID_P, [SILC_ALIGNMENT])
 715   ])
 716
 717 # Stack trace checking
 718 AC_MSG_CHECKING(whether to enable stack tracing)
 719 AC_ARG_ENABLE(stack-trace,
 720   [  --enable-stack-trace    enable memory stack trace],
 721   [
 722     case "${enableval}" in
 723     yes)
 724       AC_MSG_RESULT(yes)
 725       AC_DEFINE([SILC_STACKTRACE], [], [SILC_STACKTRACE])
 726       CFLAGS="$CFLAGS -rdynamic"
 727       ;;
 728     *)
 729       AC_MSG_RESULT(no)
 730       ;;
 731     esac
 732   ],
 733     AC_MSG_RESULT(no)
 734   )
 735
 736 #ifdef SILC_DIST_INPLACE
 737 #
 738 # Profiling options (never delivered to distributions)
 739 #
 740 AC_MSG_CHECKING(whether to enable gprof)
 741 AC_ARG_ENABLE(gprof,
 742   [  --enable-gprof          enable gprof profiling],
 743   [
 744     case "${enableval}" in
 745       yes)
 746         AC_MSG_RESULT(yes)
 747         SILC_ADD_CFLAGS(-pg)
 748         LIBS="$LIBS -pg"
 749         ;;
 750       *)
 751         AC_MSG_RESULT(no)
 752         ;;
 753     esac
 754   ],
 755   [
 756     AC_MSG_RESULT(no)
 757   ])
 758
 759 AC_MSG_CHECKING(whether to enable gcov)
 760 AC_ARG_ENABLE(gcov,
 761   [  --enable-gcov           enable gcov],
 762   [
 763     case "${enableval}" in
 764       yes)
 765         AC_MSG_RESULT(yes)
 766         SILC_ADD_CFLAGS(-fprofile-arcs)
 767         LIBS="$LIBS -lgcov"
 768         ;;
 769       *)
 770         AC_MSG_RESULT(no)
 771         ;;
 772     esac
 773   ],
 774   [
 775     AC_MSG_RESULT(no)
 776   ])
 777 #endif SILC_DIST_INPLACE
 778
 779 # Debug checking
 780 AC_MSG_CHECKING(whether to enable debugging)
 781 summary_debug="no"
 782 __SILC_ENABLE_DEBUG=""
 783 AC_ARG_ENABLE(debug,
 784   [  --enable-debug          enable debugging],
 785   [
 786     case "${enableval}" in
 787       yes)
 788         AC_MSG_RESULT(yes)
 789         AC_DEFINE([SILC_DEBUG], [], [enable-debug])
 790         summary_debug="yes"
 791         __SILC_ENABLE_DEBUG="#define __SILC_ENABLE_DEBUG 1"
 792         ;;
 793       *)
 794         AC_MSG_RESULT(no)
 795         ;;
 796     esac
 797   ],
 798   [
 799     AC_MSG_RESULT(no)
 800   ])
 801
 802 # Disable all assembler optimizations
 803 AC_MSG_CHECKING(whether to enable assembler optimizations)
 804 AC_ARG_ENABLE(asm,
 805   [  --disable-asm           do not use assembler optimizations],
 806   [
 807     AC_MSG_RESULT(no)
 808     AC_DEFINE([SILC_NO_ASM], [], [SILC_NO_ASM])
 809     want_asm=false
 810   ],
 811   [
 812     AC_MSG_RESULT(yes)
 813     want_asm=true
 814   ])
 815 AM_CONDITIONAL(SILC_NO_ASM, test x$want_asm = xfalse)
 816
 817 # Check for assembler
 818 SILC_ASSEMBLER=""
 819 have_assembler=false
 820 if test x$want_asm = xtrue; then
 821   AC_PATH_PROG([NASM], [nasm], [no])
 822   if test "x$NASM" != "xno"; then
 823     if test x$cpu_x86_64 = xtrue; then
 824       SILC_ASSEMBLER="$NASM -O2 -felf64"
 825     else
 826       SILC_ASSEMBLER="$NASM -O2 -felf"
 827     fi
 828     have_assembler=true
 829   fi
 830
 831   AC_PATH_PROG([YASM], [yasm], [no])
 832   if test "x$YASM" != "xno"; then
 833     if test x$cpu_x86_64 = xtrue; then
 834       SILC_ASSEMBLER="$YASM -Xgnu -felf64"
 835     else
 836       SILC_ASSEMBLER="$YASM -Xgnu -felf"
 837     fi
 838     have_assembler=true
 839   fi
 840 fi
 841 AC_SUBST(SILC_ASSEMBLER)
 842
 843
 844 ##
 845 ##  With/without checkings
 846 ##
 847
 848 LIBSUBDIR=lib
 849 LDFLAGS="-L\$(silc_top_srcdir)/lib $LDFLAGS"
 850
 851 SILC_LIB_INCLUDES="$SILC_LIB_INCLUDES -I$SILC_TOP_SRCDIR/lib/contrib"
 852 SILC_LIB_INCLUDES="$SILC_LIB_INCLUDES -I$SILC_TOP_SRCDIR/lib/silcutil"
 853
 854
 855 # Check for iconv support
 856 check_iconv=true
 857 has_iconv=false
 858 SAVE_LIBS="$LIBS"
 859 SAVE_CFLAGS="$CFLAGS"
 860 SAVE_LDFLAGS="$LDFLAGS"
 861 SAVE_CPPFLAGS="$CPPFLAGS"
 862 AC_MSG_CHECKING(whether to implicit search for libiconv)
 863 AC_ARG_WITH(iconv,
 864   [[  --with-iconv[=DIR]      use libiconv [search in DIR/include and DIR/lib]]],
 865   [
 866     case "${withval}" in
 867       no)
 868         AC_MSG_RESULT(no)
 869         AC_CHECK_HEADERS(iconv.h,
 870           [
 871             AC_CHECK_FUNC(iconv, has_iconv=true)
 872           ])
 873         check_iconv=false
 874         ;;
 875       *)
 876         AC_MSG_RESULT(yes)
 877         if test -d $withval/include; then
 878           CPPFLAGS="$CPPFLAGS -I$withval/include"
 879           CFLAGS="$CFLAGS -I$withval/include"
 880         fi
 881         if test -d $withval/lib; then
 882           LDFLAGS="$LDFLAGS -L$withval/lib"
 883         fi
 884         ;;
 885     esac
 886   ],
 887   [
 888     AC_MSG_RESULT(no)
 889     AC_CHECK_HEADERS(iconv.h,
 890       [
 891         AC_CHECK_FUNCS(iconv,
 892           [
 893             has_iconv=true
 894             check_iconv=false
 895           ])
 896       ])
 897   ])
 898
 899 if test x$check_iconv = xtrue; then
 900   AC_MSG_RESULT(Searching for iconv...)
 901
 902   # XXX
 903   unset ac_cv_header__iconv_h_ ac_cv_header_iconv_h || true
 904
 905   AC_CHECK_HEADERS(iconv.h,
 906     [
 907       LIBS="$LIBS -liconv"
 908       AC_MSG_CHECKING(for iconv in -liconv)
 909       AC_TRY_LINK(
 910         [
 911           #include <stdlib.h>
 912           #include <iconv.h>
 913         ],
 914         [
 915           iconv_t cd = iconv_open("", "");
 916           iconv(cd, NULL, NULL, NULL, NULL);
 917           iconv_close(cd);
 918         ],
 919         [
 920           echo "yes"
 921           AC_DEFINE([HAVE_ICONV], [], [Define if you have the iconv() function.])
 922           has_iconv=true
 923           check_iconv=false
 924         ],
 925         [
 926           echo "no"
 927           LIBS="$SAVE_LIBS"
 928           CFLAGS="$SAVE_CFLAGS"
 929           LDFLAGS="$SAVE_LDFLAGS"
 930           CPPFLAGS="$SAVE_CPPFLAGS"
 931         ])
 932      ])
 933 fi
 934
 935 if test x$check_iconv = xtrue; then
 936   # search for iconv library..
 937   SAVE_LIBS="$LIBS"
 938   SAVE_CFLAGS="$CFLAGS"
 939   SAVE_LDFLAGS="$LDFLAGS"
 940   SAVE_CPPFLAGS="$CPPFLAGS"
 941
 942   for dir in `echo "/usr/local /usr/pkg /usr/contrib"`; do
 943     if test x$has_iconv = xfalse; then
 944       AC_MSG_RESULT(searching in $dir...)
 945
 946       if test -d $dir/include; then
 947         CPPFLAGS="$CPPFLAGS -I$dir/include"
 948         CFLAGS="$CFLAGS -I$dir/include"
 949       fi
 950       if test -d $dir/lib; then
 951         LDFLAGS="$LDFLAGS -L$dir/lib"
 952       fi
 953
 954       # XXX
 955       unset ac_cv_header__iconv_h_ ac_cv_header_iconv_h || true
 956
 957       AC_CHECK_HEADERS(iconv.h,
 958         [
 959           LIBS="$LIBS -liconv"
 960           AC_MSG_CHECKING(for iconv in -liconv)
 961           AC_TRY_LINK(
 962             [
 963               #include <stdlib.h>
 964               #include <iconv.h>
 965             ],
 966             [
 967               iconv_t cd = iconv_open("", "");
 968               iconv(cd, NULL, NULL, NULL, NULL);
 969               iconv_close(cd);
 970             ],
 971             [
 972               echo "yes"
 973               has_iconv=true
 974               AC_DEFINE([HAVE_ICONV], [], [Define if you have the iconv() function.])
 975             ],
 976             [
 977               echo "no"
 978               has_iconv=false
 979
 980               LIBS="$SAVE_LIBS"
 981               CFLAGS="$SAVE_CFLAGS"
 982               LDFLAGS="$SAVE_LDFLAGS"
 983               CPPFLAGS="$SAVE_CPPFLAGS"
 984             ])
 985          ],
 986          [
 987            CFLAGS="$SAVE_CFLAGS"
 988            LDFLAGS="$SAVE_LDFLAGS"
 989            CPPFLAGS="$SAVE_CPPFLAGS"
 990          ])
 991       fi
 992     done
 993 fi
 994
 995 if test x$has_iconv = xtrue; then
 996   # (1) Some implementations of iconv won't convert from UTF-8 to UTF-8.
 997   # (2) In glibc-2.1.2 and earlier there is a bug that messes up ob and
 998   #     obl when args 2 and 3 are 0 (fixed in glibc-2.1.3).
 999   #
1000   AC_CACHE_CHECK([whether this iconv is good enough], ac_iconv_good,
1001     AC_TRY_RUN(
1002       [
1003         #include <iconv.h>
1004         int main() {
1005           iconv_t cd;
1006         changequote(, )dnl
1007           char buf[4];
1008         changequote([, ])dnl
1009           char *ob;
1010           size_t obl;
1011           ob = buf, obl = sizeof(buf);
1012           return ((cd = iconv_open("UTF-8", "UTF-8")) != (iconv_t)(-1) &&
1013                  (iconv(cd, 0, 0, &ob, &obl) ||
1014                  !(ob == buf && obl == sizeof(buf)) ||
1015                  iconv_close(cd)));
1016         }
1017       ],
1018       [
1019         ac_iconv_good=yes
1020       ],
1021       [
1022         ac_iconv_good=no
1023       ],
1024       [
1025         ac_iconv_good=yes
1026       ])
1027     )
1028
1029   if test x$ac_iconv_good = xno; then
1030     AC_MSG_RESULT(Try using libiconv instead.)
1031   fi
1032 fi
1033
1034 # Check for POSIX threads support
1035 AC_MSG_CHECKING(whether to search for POSIX threads)
1036 AC_ARG_WITH(pthreads,
1037   [[  --with-pthreads[=DIR]   use POSIX threads [search in DIR/include and DIR/lib]]],
1038   [
1039     case "${withval}" in
1040       no)
1041         check_threads=false
1042         ;;
1043       *)
1044         if test -d $withval/include; then
1045           CPPFLAGS="$CPPFLAGS -I$withval/include"
1046           CFLAGS="$CFLAGS -I$withval/include"
1047         fi
1048         if test -d $withval/lib; then
1049           LDFLAGS="$LDFLAGS -L$withval/lib"
1050         fi
1051
1052         check_threads=true
1053         ;;
1054     esac
1055   ])
1056
1057 if test x$check_threads = xtrue; then
1058   has_threads=false
1059   SAVE_LIBS="$LIBS"
1060   SAVE_CFLAGS="$CFLAGS"
1061   SAVE_LDFLAGS="$LDFLAGS"
1062   SAVE_CPPFLAGS="$CPPFLAGS"
1063
1064   AC_MSG_RESULT(yes)
1065   AC_CHECK_HEADERS(pthread.h,
1066     [
1067       LIBS="$LIBS -lpthread"
1068       AC_CHECK_LIB(pthread, pthread_attr_init, has_threads=true,
1069         [
1070           # FreeBSD
1071           case "${target}" in
1072             *-*-freebsd*)
1073               LIBS="$SAVE_LIBS -pthread"
1074               AC_CHECK_LIB(c_r, pthread_attr_init, has_threads=true, LIBS="$SAVE_LIBS")
1075               ;;
1076             *)
1077               LIBS="$SAVE_LIBS"
1078               ;;
1079           esac
1080         ])
1081     ],
1082     [
1083       # search for pthread library..
1084       for dir in `echo "/usr/local /usr/pkg /usr/contrib /usr/pkg/pthreads /usr/local/pthreads"`; do
1085         if test x$has_threads = xfalse; then
1086           AC_MSG_RESULT(searching in $dir...)
1087
1088           if test -d $dir/include; then
1089             CPPFLAGS="$CPPFLAGS -I$dir/include"
1090             CFLAGS="$CFLAGS -I$dir/include"
1091           fi
1092           if test -d $dir/lib; then
1093             LDFLAGS="$LDFLAGS -L$dir/lib"
1094           fi
1095
1096           # XXX
1097           unset ac_cv_header__pthread_h_ ac_cv_header_pthread_h || true
1098
1099           AC_CHECK_HEADERS(pthread.h,
1100             [
1101               LIBS="$LIBS -lpthread"
1102               AC_CHECK_LIB(pthread, pthread_attr_init, has_threads=true,
1103                 [
1104                   has_threads=false
1105
1106                   LIBS="$SAVE_LIBS"
1107                   CFLAGS="$SAVE_CFLAGS"
1108                   LDFLAGS="$SAVE_LDFLAGS"
1109                   CPPFLAGS="$SAVE_CPPFLAGS"
1110                 ])
1111             ],
1112             [
1113               CFLAGS="$SAVE_CFLAGS"
1114               LDFLAGS="$SAVE_LDFLAGS"
1115               CPPFLAGS="$SAVE_CPPFLAGS"
1116             ])
1117         fi
1118       done
1119     ])
1120 else
1121   AC_MSG_RESULT(no)
1122   has_threads=false
1123 fi
1124
1125 __SILC_HAVE_PTHREAD=""
1126 AM_CONDITIONAL(SILC_THREADS, test x$has_threads = xtrue)
1127 if test x$has_threads = xtrue; then
1128   CFLAGS="$CFLAGS -D_REENTRANT"
1129
1130   # XXX possibly incomplete
1131   case "${target}" in
1132     *-*-aix*)
1133       CFLAGS="$CFLAGS -D_THREAD_SAFE"
1134       if test x"$GCC" = xyes; then
1135         CFLAGS="$CFLAGS -mthreads"
1136       fi
1137       ;;
1138     *-*-freebsd*)
1139       CFLAGS="$CFLAGS -D_THREAD_SAFE"
1140       ;;
1141     *-*-sysv5uw7*)  # UnixWare 7
1142       if test "$GCC" != "yes"; then
1143         CFLAGS="$CFLAGS -Kthread"
1144       else
1145         CFLAGS="$CFLAGS -pthread"
1146       fi
1147       ;;
1148     *-dg-dgux*)  # DG/UX
1149       CFLAGS="$CFLAGS -D_POSIX4A_DRAFT10_SOURCE"
1150       ;;
1151    esac
1152
1153   # Check for threads
1154   AC_CHECK_FUNCS(pthread_create pthread_key_create pthread_once)
1155
1156   # Check for read/write locks
1157   AC_CHECK_FUNC(pthread_rwlock_init,
1158   [
1159     AC_RUN_IFELSE(
1160       [
1161         #include <pthread.h>
1162         int main()
1163         {
1164           pthread_rwlock_t rwlock;
1165           pthread_rwlock_init(&rwlock, NULL);
1166           pthread_rwlock_destroy(&rwlock);
1167           return 0;
1168         }
1169       ],
1170       [],
1171       [
1172         # Rwlock not defined
1173         CFLAGS="$CFLAGS -D_XOPEN_SOURCE=600"
1174       ]
1175     )
1176   ],
1177   [
1178     # Rwlock not defined
1179     CFLAGS="$CFLAGS -D_XOPEN_SOURCE=600"
1180   ])
1181
1182   AC_DEFINE([SILC_HAVE_PTHREAD], [], [HAVE_PTHREAD])
1183   AC_DEFINE([SILC_THREADS], [], [HAVE_THREAD])
1184   __SILC_HAVE_PTHREAD="#define __SILC_HAVE_PTHREAD 1"
1185 fi
1186
1187
1188 ##
1189 ## Native WIN32 compilation under cygwin
1190 ##
1191 AC_MSG_CHECKING(whether to compile native WIN32 code)
1192 AC_ARG_WITH(win32,
1193   [  --with-win32            compile native WIN32 (MinGW) code (-mno-cygwin)],
1194   [
1195     AC_MSG_RESULT(yes)
1196     AC_DEFINE([SILC_WIN32], [], [SILC_WIN32])
1197     win32_support=true
1198     CFLAGS="-mno-cygwin $CFLAGS"
1199     LIBS="$LIBS -lwsock32"
1200   ],
1201   [
1202     AC_MSG_RESULT(no)
1203     win32_support=false
1204   ])
1205 AM_CONDITIONAL(SILC_WIN32, test x$win32_support = xtrue)
1206
1207
1208 ##
1209 ## Outputs and substitutions
1210 ##
1211
1212 AC_SUBST(LIBSUBDIR)
1213 AC_SUBST(SILC_TOP_SRCDIR)
1214 AC_SUBST(LDFLAGS)
1215 AC_SUBST(LIBS)
1216 AC_SUBST(SILC_LIB_INCLUDES)
1217 AC_SUBST(__SILC_ENABLE_DEBUG)
1218 AC_SUBST(__SILC_HAVE_PTHREAD)
1219 AC_SUBST(__RUNTIME_PACKAGE_VERSION)
1220
1221 # Native Symbian OS support (disabled by default)
1222 AM_CONDITIONAL(SILC_SYMBIAN, test xfalse = xtrue)
1223
1224 # Make enable-shared aware
1225 AM_CONDITIONAL(SILC_ENABLE_SHARED, test "$enable_shared" = yes)
1226
1227 ETCDIR=`eval echo $sysconfdir`;ETCDIR=`eval echo $ETCDIR`
1228 AC_SUBST(ETCDIR)
1229 AC_DEFINE_UNQUOTED([SILC_ETCDIR], "$ETCDIR", [SILC_ETCDIR])
1230
1231 DOCDIR=`eval echo $docdir`;DOCDIR=`eval echo $DOCDIR`
1232 AC_SUBST(DOCDIR)
1233 AC_DEFINE_UNQUOTED([SILC_DOCDIR], "$DOCDIR", [SILC_DOCDIR])
1234
1235 INCLUDE_DEFINES_INT="include \$(top_srcdir)/Makefile.defines_int"
1236 AC_SUBST(INCLUDE_DEFINES_INT)
1237
1238 DATE=`date`
1239 AC_SUBST(DATE)
1240
1241
1242 #
1243 # Makefile outputs
1244 #
1245 AC_CONFIG_FILES(
1246 Makefile
1247 doc/Makefile
1248 doc/runtime.in/index.html
1249 Makefile.defines
1250 Makefile.defines_int
1251 includes/Makefile
1252 apps/Makefile
1253 win32/Makefile
1254 )
1255
1256 AC_CONFIG_FILES(
1257 lib/Makefile
1258 lib/contrib/Makefile
1259 lib/silcutil/silcruntime.h
1260 lib/silcutil/Makefile
1261 lib/silcutil/tests/Makefile
1262 lib/silcutil/unix/Makefile
1263 lib/silcutil/win32/Makefile
1264 lib/silcutil/symbian/Makefile
1265 lib/srt.pc
1266 )
1267
1268 AC_OUTPUT
1269
1270
1271 ##
1272 ## Summary output
1273 ##
1274
1275 s_bindir=`eval echo $bindir`;s_bindir=`eval echo $s_bindir`
1276 s_sbindir=`eval echo $sbindir`;s_sbindir=`eval echo $s_sbindir`
1277 s_mandir=`eval echo $mandir`;s_mandir=`eval echo $s_mandir`
1278 s_includedir=`eval echo $includedir`;s_includedir=`eval echo $s_includedir`
1279
1280 echo ""
1281 echo "SILC Runtime Toolkit configuration summary:"
1282 echo "------------------------------------------"
1283 echo " Target host ...................: $target"
1284 echo " Compiler ......................: $CC"
1285 echo " CFLAGS ........................: $CFLAGS"
1286 echo " LDFLAGS .......................: $LDFLAGS"
1287 echo " LIBS ..........................: $LIBS"
1288 echo ""
1289 echo " Installation prefix ...........: $prefix"
1290 echo " bin directory .................: $s_bindir"
1291 echo " sbin directory ................: $s_sbindir"
1292 echo " etc directory .................: $ETCDIR"
1293 echo " man directory .................: $s_mandir"
1294 echo " doc directory .................: $DOCDIR"
1295 echo " include directory .............: $s_includedir"
1296 echo ""
1297 echo " IPv6 support ..................: $summary_ipv6"
1298
1299 if test x$has_iconv = xfalse; then
1300   iconv_support="no"
1301 else
1302   iconv_support="yes"
1303 fi
1304 echo " Iconv support .................: $iconv_support"
1305
1306 if test x$want_asm = xfalse; then
1307   summary_asm="no"
1308 else
1309   summary_asm="yes"
1310 fi
1311 echo " Assembler optimizations .......: $summary_asm"
1312
1313 if test x$want_cc_optimizations = xfalse; then
1314   summary_cc_opt="no"
1315 else
1316   summary_cc_opt="yes"
1317 fi
1318 echo " Compiler optimizations ........: $summary_cc_opt"
1319
1320 if test x$want_cpu_optimizations = xfalse; then
1321   summary_cpu_opt="no"
1322 else
1323   summary_cpu_opt="yes"
1324 fi
1325 echo " CPU feature optimizations .....: $summary_cpu_opt"
1326
1327 threads="no"
1328 if test x$has_threads = xtrue; then
1329   threads="yes"
1330 fi
1331 echo " Multi-threads support .........: $threads"
1332 echo " Debugging enabled .............: $summary_debug"
1333 echo ""
1334 echo "Compile the sources with 'make' or 'gmake' command."