configure.ad

   1 #
   2 #  configure.ad
   3 #
   4 #  Author: Pekka Riikonen <priikone@silcnet.org>
   5 #
   6 #  Copyright (C) 2000 - 2008 Pekka Riikonen
   7 #
   8 #  This program is free software; you can redistribute it and/or modify
   9 #  it under the terms of the GNU General Public License as published by
  10 #  the Free Software Foundation; version 2 of the License.
  11 #
  12 #  This program is distributed in the hope that it will be useful,
  13 #  but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #  GNU General Public License for more details.
  16 #
  17
  18 AD_INIT
  19 AC_CANONICAL_SYSTEM
  20 AM_INIT_AUTOMAKE
  21 AC_PREREQ(2.52)
  22 AC_CONFIG_HEADERS(silcdefs.h)
  23
  24 AC_PROG_INSTALL
  25 AC_PROG_MAKE_SET
  26
  27 AC_PROG_LN_S
  28 AC_PROG_EGREP
  29 AC_SUBST(LN_S)
  30 AC_PATH_PROG(sedpath, sed)
  31
  32 AC_PROG_CC
  33 AM_PROG_AS
  34 AC_C_INLINE
  35 AC_C_CONST
  36
  37 AC_PROG_RANLIB
  38 #ifdef SILC_DIST_INPLACE
  39 AC_DISABLE_SHARED
  40 #endif SILC_DIST_INPLACE
  41 AC_PROG_LIBTOOL
  42
  43 SILC_TOP_SRCDIR=`pwd`
  44
  45 ##
  46 ## Library versioning.
  47 ##
  48
  49 # Do the releases and library versioning according to following rules:
  50 #
  51 #  - If any code has changed in library, increment RUNTIME_REVISION
  52 #  - If API were added, removed or changed, set RUNTIME_REVISION to 0
  53 #  - If API were added, removed or changed, increment RUNTIME_CURRENT
  54 #  - If APi were added, increment RUNTIME_AGE
  55 #  - If API were removed, set RUNTIME_AGE to 0
  56 #
  57
  58 # Base version for library.
  59 RUNTIME_BASE_VERSION=1.2
  60
  61 # libsilc versions
  62 RUNTIME_CURRENT=1               # prev = 0
  63 RUNTIME_REVISION=0              # prev = 0
  64 RUNTIME_AGE=0                   # prev = 0
  65
  66 # Substitute the version numbers
  67 AC_SUBST(RUNTIME_BASE_VERSION)
  68 AC_SUBST(RUNTIME_CURRENT)
  69 AC_SUBST(RUNTIME_REVISION)
  70 AC_SUBST(RUNTIME_AGE)
  71
  72
  73 ##
  74 ##  Installation
  75 ##
  76
  77 # Default installation destination
  78 AC_PREFIX_DEFAULT(/usr/local)
  79 if test "x$prefix" != xNONE; then
  80   silc_prefix="$prefix"
  81 else
  82   silc_prefix="$ac_default_prefix"
  83   prefix="$silc_prefix"
  84 fi
  85
  86
  87 ##
  88 ## Detect CPU
  89 ##
  90
  91 # Disable all CPU feature optimizations
  92 AC_MSG_CHECKING(whether to enable CPU feature optimizations)
  93 AC_ARG_ENABLE(cpu-optimizations,
  94   [  --disable-cpu-optimizations  do not use any CPU feature optimizations],
  95   [
  96     AC_MSG_RESULT(no)
  97     AC_DEFINE([SILC_NO_CPU_OPTIMIZATIONS], [], [SILC_NO_CPU_OPTIMIZATIONS])
  98     want_cpu_optimizations=false
  99   ],
 100   [
 101     AC_MSG_RESULT(yes)
 102     want_cpu_optimizations=true
 103   ])
 104 AM_CONDITIONAL(SILC_NO_CPU_OPTIMIZATIONS,
 105                test x$want_cpu_optimizations = xfalse)
 106
 107 SILC_SYSTEM_IS_SMP(AC_DEFINE([SILC_SMP], [], [SILC_SMP]), [],
 108                    AC_DEFINE([SILC_SMP], [], [SILC_SMP]))
 109 cpu_i386=false
 110 cpu_i486=false
 111 cpu_i586=false
 112 cpu_i686=false
 113 cpu_i786=false
 114 cpu_x86_64=false
 115 cpu_ppc=false
 116 cpu_ia64=false
 117 case "$host_cpu" in
 118   # All following Intels are considered 32-bit CPUs.
 119   i?86)
 120     # All CPUs of today are considered i386 and i486 compatible */
 121     AC_DEFINE([SILC_I386], [], [SILC_I386])
 122     AC_DEFINE([SILC_I486], [], [SILC_I486])
 123     cpu_i386=true
 124     cpu_i486=true
 125
 126     if test "x$host_cpu" = "xi586"; then
 127       AC_DEFINE([SILC_I586], [], [SILC_I586])
 128       cpu_i586=true
 129     fi
 130
 131     if test "x$host_cpu" = "xi686"; then
 132       AC_DEFINE([SILC_I586], [], [SILC_I586])
 133       AC_DEFINE([SILC_I686], [], [SILC_I686])
 134       cpu_i586=true
 135       cpu_i686=true
 136     fi
 137
 138     if test "x$host_cpu" = "xi786"; then
 139       AC_DEFINE([SILC_I586], [], [SILC_I586])
 140       AC_DEFINE([SILC_I686], [], [SILC_I686])
 141       AC_DEFINE([SILC_I786], [], [SILC_I786])
 142       cpu_i586=true
 143       cpu_i686=true
 144       cpu_i786=true
 145     fi
 146
 147     # Check for specific CPU features
 148     SILC_CPU_FLAG(mmx, true, AC_DEFINE([SILC_CPU_MMX], [], [SILC_CPU_MMX]), [])
 149     SILC_CPU_FLAG(sse2, true, AC_DEFINE([SILC_CPU_SSE2], [], [SILC_CPU_SSE2]), [])
 150     SILC_CPU_FLAG(pni, true, AC_DEFINE([SILC_CPU_SSE3], [], [SILC_CPU_SSE3]), [])
 151     SILC_CPU_FLAG(ssse3, true, AC_DEFINE([SILC_CPU_SSSE3], [], [SILC_CPU_SSSE3]), [])
 152     SILC_CPU_FLAG(sse4, true, AC_DEFINE([SILC_CPU_SSE4], [], [SILC_CPU_SSE4]), [])
 153     ;;
 154
 155   # Intel IA-64, 64-bit CPU (not x86_64 compatible)
 156   ia64)
 157     AC_DEFINE([SILC_IA64], [], [SILC_IA64])
 158     cpu_ia64=true
 159
 160     # Check for specific CPU features
 161     SILC_CPU_FLAG(mmx, true, AC_DEFINE([SILC_CPU_MMX], [], [SILC_CPU_MMX]), [])
 162     SILC_CPU_FLAG(sse2, true, AC_DEFINE([SILC_CPU_SSE2], [], [SILC_CPU_SSE2]), [])
 163     SILC_CPU_FLAG(pni, true, AC_DEFINE([SILC_CPU_SSE3], [], [SILC_CPU_SSE3]), [])
 164     SILC_CPU_FLAG(ssse3, true, AC_DEFINE([SILC_CPU_SSSE3], [], [SILC_CPU_SSSE3]), [])
 165     SILC_CPU_FLAG(sse4, true, AC_DEFINE([SILC_CPU_SSE4], [], [SILC_CPU_SSE4]), [])
 166     ;;
 167
 168   # AMD/Intel x86_64, 64-bit CPU
 169   x86_64)
 170     AC_DEFINE([SILC_X86_64], [], [SILC_X86_64])
 171     cpu_x86_64=true
 172
 173     # Check for specific CPU features
 174     SILC_CPU_FLAG(mmx, true, AC_DEFINE([SILC_CPU_MMX], [], [SILC_CPU_MMX]), [])
 175     SILC_CPU_FLAG(sse2, true, AC_DEFINE([SILC_CPU_SSE2], [], [SILC_CPU_SSE2]), [])
 176     SILC_CPU_FLAG(pni, true, AC_DEFINE([SILC_CPU_SSE3], [], [SILC_CPU_SSE3]), [])
 177     SILC_CPU_FLAG(ssse3, true, AC_DEFINE([SILC_CPU_SSSE3], [], [SILC_CPU_SSSE3]), [])
 178     SILC_CPU_FLAG(sse4, true, AC_DEFINE([SILC_CPU_SSE4], [], [SILC_CPU_SSE4]), [])
 179     ;;
 180
 181   # PowerPC, 32-bit and 64-bit CPUs
 182   powerpc*)
 183     AC_DEFINE([SILC_POWERPC], [], [SILC_POWERPC])
 184     cpu_ppc=true
 185     ;;
 186 esac
 187 AM_CONDITIONAL(SILC_I386, test x$cpu_i386 = xtrue)
 188 AM_CONDITIONAL(SILC_I486, test x$cpu_i486 = xtrue)
 189 AM_CONDITIONAL(SILC_I586, test x$cpu_i586 = xtrue)
 190 AM_CONDITIONAL(SILC_I686, test x$cpu_i686 = xtrue)
 191 AM_CONDITIONAL(SILC_7686, test x$cpu_i786 = xtrue)
 192 AM_CONDITIONAL(SILC_X86_64, test x$cpu_x86_64 = xtrue)
 193 AM_CONDITIONAL(SILC_POWERPC, test x$cpu_ppc = xtrue)
 194 AM_CONDITIONAL(SILC_IA64, test x$cpu_ia64 = xtrue)
 195
 196 if test x$want_cpu_optimizations = xtrue; then
 197   # Set some compiler options based on CPU
 198   if test "x$CC" = "xicc"; then
 199     # ICC flags
 200     if test x$x_have_cpu_sse2 = xtrue; then
 201       SILC_ADD_CFLAGS(-axW)
 202     fi
 203     if test x$x_have_cpu_sse3 = xtrue; then
 204       SILC_ADD_CFLAGS(-axP)
 205     fi
 206     if test x$x_have_cpu_ssse3 = xtrue; then
 207       SILC_ADD_CFLAGS(-axT)
 208     fi
 209     if test x$x_have_cpu_sse4 = xtrue; then
 210       SILC_ADD_CFLAGS(-axS)
 211     fi
 212   else
 213     # Other compilers
 214     if test x$x_have_cpu_sse2 = xtrue; then
 215       SILC_ADD_CFLAGS(-msse2)
 216     fi
 217     if test x$x_have_cpu_pni = xtrue; then
 218       SILC_ADD_CFLAGS(-msse3)
 219     fi
 220     if test x$x_have_cpu_ssse3 = xtrue; then
 221       SILC_ADD_CFLAGS(-mssse3)
 222     fi
 223     if test x$x_have_cpu_sse4 = xtrue; then
 224       SILC_ADD_CFLAGS(-msse4)
 225     fi
 226   fi
 227 fi
 228
 229
 230 ##
 231 ## Put here any platform specific stuff
 232 ##
 233
 234 case "$target" in
 235   *-*-linux*)
 236     check_threads=true
 237     CFLAGS=`echo $CFLAGS -D_GNU_SOURCE`
 238     ;;
 239   *-*-freebsd*)
 240     check_threads=true
 241     ;;
 242   *-*-netbsd*)
 243     check_threads=true
 244     ;;
 245   *-*-*bsd*)
 246     check_threads=false
 247     ;;
 248   *)
 249     check_threads=true
 250     ;;
 251 esac
 252
 253
 254 ##
 255 ## Header checking
 256 ##
 257 AC_HEADER_STDC
 258 AC_HEADER_TIME
 259 AC_HEADER_STAT
 260
 261 # More header checking
 262 #
 263 AC_CHECK_HEADERS(unistd.h string.h errno.h fcntl.h assert.h)
 264 AC_CHECK_HEADERS(sys/types.h sys/stat.h sys/time.h stddef.h)
 265 AC_CHECK_HEADERS(netinet/in.h netinet/tcp.h xti.h netdb.h sys/resource.h)
 266 AC_CHECK_HEADERS(pwd.h grp.h termcap.h paths.h)
 267 AC_CHECK_HEADERS(ncurses.h signal.h ctype.h utime.h dirent.h)
 268 AC_CHECK_HEADERS(arpa/inet.h sys/mman.h limits.h termios.h locale.h langinfo.h)
 269
 270
 271 ##
 272 ## Data type checking
 273 ##
 274 AC_TYPE_SIGNAL
 275 AC_TYPE_SIZE_T
 276 AC_TYPE_MODE_T
 277 AC_TYPE_UID_T
 278 AC_TYPE_PID_T
 279 AC_CHECK_SIZEOF(long long, 0)
 280 AC_SUBST(SILC_SIZEOF_LONG_LONG, $ac_cv_sizeof_long_long)
 281 AC_CHECK_SIZEOF(long, 0)
 282 AC_SUBST(SILC_SIZEOF_LONG, $ac_cv_sizeof_long)
 283 AC_CHECK_SIZEOF(int, 0)
 284 AC_SUBST(SILC_SIZEOF_INT, $ac_cv_sizeof_int)
 285 AC_CHECK_SIZEOF(short, 0)
 286 AC_SUBST(SILC_SIZEOF_SHORT, $ac_cv_sizeof_short)
 287 AC_CHECK_SIZEOF(char, 0)
 288 AC_SUBST(SILC_SIZEOF_CHAR, $ac_cv_sizeof_char)
 289 AC_CHECK_SIZEOF(void *, 0)
 290 AC_SUBST(SILC_SIZEOF_VOID_P, $ac_cv_sizeof_void_p)
 291 AC_CHECK_TYPES(long long)
 292 AC_CHECK_TYPES(long double)
 293
 294 # Check for big-endian machines
 295 AC_C_BIGENDIAN
 296
 297
 298 ##
 299 ## Compiler and compiler flag checks
 300 ##
 301
 302 # Disable all compiler optimizations
 303 AC_MSG_CHECKING(whether to enable compiler optimizations)
 304 AC_ARG_ENABLE(optimizations,
 305   [  --disable-optimizations do not use any compiler optimizations],
 306   [
 307     AC_MSG_RESULT(no)
 308     AC_DEFINE([SILC_NO_CC_OPTIMIZATIONS], [], [SILC_NO_CC_OPTIMIZATIONS])
 309     want_cc_optimizations=false
 310   ],
 311   [
 312     AC_MSG_RESULT(yes)
 313     want_cc_optimizations=true
 314   ])
 315 AM_CONDITIONAL(SILC_NO_CC_OPTIMIZATIONS, test x$want_cc_optimizations = xfalse)
 316
 317 if test "$GCC"; then
 318   # GCC specific options
 319   if test "x$summary_debug" = "xyes"; then
 320     SILC_ADD_CFLAGS(-g)
 321   else
 322     SILC_ADD_CFLAGS(-g)
 323   fi
 324   SILC_ADD_CFLAGS(-Wall -finline-functions)
 325   SILC_ADD_CFLAGS(-Wno-pointer-sign)
 326 else
 327   # Other compilers
 328   case "$target" in
 329     alpha*-dec-osf*)
 330       SILC_ADD_CFLAGS(-g3)
 331       ;;
 332     mips*-sgi-irix*)
 333       SILC_ADD_CFLAGS(-g3)
 334       ;;
 335     *)
 336       SILC_ADD_CFLAGS(-g)
 337       ;;
 338   esac
 339
 340   # Intel C++ Compiler flags
 341   if test "x$CC" = "xicc"; then
 342     SILC_ADD_CFLAGS(-restrict)
 343     SILC_ADD_CFLAGS(-finline-functions)
 344
 345     # Don't define __GNUC__ except for system includes
 346     SILC_ADD_CFLAGS(-gcc-sys)
 347   fi
 348 fi
 349
 350 if test x$want_cc_optimizations = xtrue; then
 351   if test "$GCC"; then
 352     # GCC specific options
 353     if test "x$summary_debug" = "xyes"; then
 354       SILC_ADD_CFLAGS(-O)
 355     else
 356       SILC_ADD_CFLAGS(-O2)
 357     fi
 358   else
 359     # Other compilers
 360     case "$target" in
 361       alpha*-dec-osf*)
 362         SILC_ADD_CFLAGS(-O2, SILC_ADD_CFLAGS(-O))
 363         ;;
 364       mips*-sgi-irix*)
 365         SILC_ADD_CFLAGS(-O2, SILC_ADD_CFLAGS(-O))
 366         ;;
 367       *)
 368         SILC_ADD_CFLAGS(-O2, SILC_ADD_CFLAGS(-O))
 369         ;;
 370     esac
 371   fi
 372 fi
 373
 374
 375 ##
 376 ## Function and libary checking
 377 ##
 378 AC_CHECK_FUNCS(gethostname gethostbyaddr getservbyname getservbyport)
 379 AC_CHECK_FUNCS(poll select listen bind shutdown close connect setsockopt)
 380 AC_CHECK_FUNCS(setrlimit time ctime utime gettimeofday getrusage)
 381 AC_CHECK_FUNCS(chmod fcntl stat fstat getenv putenv strerror)
 382 AC_CHECK_FUNCS(getpid getgid getsid getpgid getpgrp getuid sched_yield)
 383 AC_CHECK_FUNCS(setgroups initgroups nl_langinfo nanosleep)
 384 AC_CHECK_FUNCS(strchr snprintf strstr strcpy strncpy memcpy memset memmove)
 385 AC_CHECK_FUNCS(setenv getenv putenv unsetenv clearenv)
 386
 387 # Check getopt_long
 388 AC_CHECK_FUNC(getopt_long,
 389   [
 390     AC_DEFINE([HAVE_GETOPT_LONG], [], [HAVE_GETOPT_LONG])
 391     have_getopt_long=1
 392   ], have_getopt_long=0
 393 )
 394
 395 # Check gethostbyname
 396 AC_CHECK_FUNC(gethostbyname, [],
 397   [
 398     AC_CHECK_LIB(nsl, gethostbyname, LIBS="$LIBS -lnsl")
 399     AC_CHECK_FUNC(res_gethostbyname, [],
 400        AC_CHECK_LIB(resolv, res_gethostbyname, LIBS="$LIBS -lresolv")
 401     )
 402   ])
 403
 404 # Check socket
 405 AC_CHECK_FUNC(socket, [],
 406   AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
 407 )
 408
 409 # Check clock_gettime
 410 AC_CHECK_FUNC(clock_gettime, [],
 411   [
 412     AC_CHECK_LIB(rt, clock_gettime,
 413                  [ LIBS="$LIBS -lrt"
 414                    AC_DEFINE([HAVE_CLOCK_GETTIME], [], [HAVE_CLOCK_GETTIME])])
 415   ])
 416
 417 # Check for epoll_wait and verify that epoll_create works
 418 AC_CHECK_FUNC(epoll_wait,
 419   [
 420     AC_RUN_IFELSE(
 421       [
 422         #include <sys/epoll.h>
 423         int main()
 424         {
 425           int ret = epoll_create(5);
 426           if (ret < 0)
 427             return 1;
 428           close(ret);
 429           return 0;
 430         }
 431       ],
 432       [
 433         AC_DEFINE([HAVE_EPOLL_WAIT], [1], [HAVE_EPOLL_WAIT])
 434       ],
 435     )
 436   ])
 437
 438 # Check for va_copy
 439 va_copy=false
 440 AC_MSG_CHECKING(for va_copy)
 441 AC_TRY_COMPILE(
 442   [
 443     #include <stdarg.h>
 444     #include <stdlib.h>
 445   ],
 446   [
 447     int t(int x, ...)
 448     {
 449       va_list va, cp;
 450       va_start(va, x);
 451       va_copy(cp, va);
 452       if (va_arg(cp, int) != 0xff11)
 453         return 1;
 454       va_end(va);
 455       va_end(cp);
 456       return 0;
 457     }
 458     int main()
 459     {
 460       return t(0, 0xff11);
 461     }
 462   ],
 463   [
 464     AC_DEFINE([HAVE_VA_COPY], [], [HAVE_VA_COPY])
 465     AC_MSG_RESULT(yes)
 466     va_copy=true
 467   ],
 468   [
 469     AC_MSG_RESULT(no)
 470     va_copy=false
 471   ]
 472 )
 473
 474 if test x$va_copy = xfalse; then
 475   AC_MSG_CHECKING(for __va_copy)
 476   AC_TRY_COMPILE(
 477   [
 478     #include <stdarg.h>
 479     #include <stdlib.h>
 480   ],
 481   [
 482     int t(int x, ...)
 483     {
 484       va_list va, cp;
 485       va_start(va, x);
 486       __va_copy(cp, va);
 487       if (va_arg(cp, int) != 0xff11)
 488         return 1;
 489       va_end(va);
 490       va_end(cp);
 491       return 0;
 492     }
 493     int main()
 494     {
 495       return t(0, 0xff11);
 496     }
 497   ],
 498   [
 499     AC_DEFINE([HAVE___VA_COPY], [], [HAVE___VA_COPY])
 500     AC_MSG_RESULT(yes)
 501     va_copy=true
 502   ],
 503   [
 504     AC_MSG_RESULT(no)
 505     va_copy=false
 506   ]
 507   )
 508 fi
 509
 510 if test x$va_copy = xfalse; then
 511   AC_RUN_IFELSE(
 512     [
 513       #include <stdarg.h>
 514       #include <stdlib.h>
 515       int t(int x, ...)
 516       {
 517         va_list va, cp;
 518         va_start(va, x);
 519         cp = va;
 520         if (va_arg(cp, int) != 0xff11)
 521           return 1;
 522         va_end(va);
 523         va_end(cp);
 524         return 0;
 525       }
 526       int main()
 527       {
 528         return t(0, 0xff11);
 529       }
 530     ],
 531     [va_copy=false],
 532     [
 533       AC_DEFINE([SILC_VA_COPY_ARRAY], [], [SILC_VA_COPY_ARRAY])
 534     ],
 535     [va=copy=false]
 536   )
 537 fi
 538
 539 # Check for timezone and tm_gmtoff for timezone information
 540 AC_MSG_CHECKING(whether system has timezone)
 541 AC_RUN_IFELSE(
 542   [
 543     #include <stdio.h>
 544     #include <time.h>
 545     int main()
 546     {
 547       timezone = 0;
 548       return 0;
 549     }
 550   ],
 551   [ AC_MSG_RESULT(yes)
 552     AC_DEFINE([HAVE_TIMEZONE], [], [HAVE_TIMEZONE]) ],
 553   [ AC_MSG_RESULT(no) ],
 554   [ AC_MSG_RESULT(no) ]
 555 )
 556 AC_MSG_CHECKING(whether system has tm_gmtoff)
 557 AC_RUN_IFELSE(
 558   [
 559     #include <stdio.h>
 560     #include <time.h>
 561     int main()
 562     {
 563       struct tm tm;
 564       tm.tm_gmtoff = 0;
 565       return 0;
 566     }
 567   ],
 568   [ AC_MSG_RESULT(yes)
 569     AC_DEFINE([HAVE_TM_GMTOFF], [], [HAVE_TM_GMTOFF]) ],
 570   [ AC_MSG_RESULT(no) ],
 571   [ AC_MSG_RESULT(no) ]
 572 )
 573 AC_MSG_CHECKING(whether system has __tm_gmtoff)
 574 AC_RUN_IFELSE(
 575   [
 576     #include <stdio.h>
 577     #include <time.h>
 578     int main()
 579     {
 580       struct tm tm;
 581       tm.__tm_gmtoff = 0;
 582       return 0;
 583     }
 584   ],
 585   [ AC_MSG_RESULT(yes)
 586     AC_DEFINE([HAVE___TM_GMTOFF], [], [HAVE___TM_GMTOFF]) ],
 587   [ AC_MSG_RESULT(no) ],
 588   [ AC_MSG_RESULT(no) ]
 589 )
 590 AC_MSG_CHECKING(whether system has __tm_gmtoff__)
 591 AC_RUN_IFELSE(
 592   [
 593     #include <stdio.h>
 594     #include <time.h>
 595     int main()
 596     {
 597       struct tm tm;
 598       tm.__tm_gmtoff__ = 0;
 599       return 0;
 600     }
 601   ],
 602   [ AC_MSG_RESULT(yes)
 603     AC_DEFINE([HAVE___TM_GMTOFF__], [], [HAVE___TM_GMTOFF__]) ],
 604   [ AC_MSG_RESULT(no) ],
 605   [ AC_MSG_RESULT(no) ]
 606 )
 607
 608 # Check for dlopen() and friends
 609 AC_CHECK_HEADERS(dlfcn.h,
 610   [
 611     AC_CHECK_LIB(dl, dlopen,
 612       [
 613         AC_DEFINE([HAVE_DLOPEN], [], [HAVE_DLOPEN])
 614         LIBS="$LIBS -ldl"
 615       ],
 616       [
 617         AC_CHECK_LIB(c, dlopen,
 618           [
 619             AC_DEFINE([HAVE_DLOPEN], [], [HAVE_DLOPEN])
 620           ])
 621       ])
 622   ])
 623
 624 __SILC_ENABLE_DEBUG=""
 625
 626 runtimever=`echo $VERSION | sed 's/\./ /g'`
 627 maj=0
 628 min=0
 629 bld=0
 630 for v in $runtimever
 631 do
 632   if test $maj -eq 0; then
 633     maj=$v
 634     continue
 635   fi
 636   if test $min -eq 0; then
 637     min=$v
 638     continue
 639   fi
 640   if test $bld -eq 0; then
 641     bld=$v
 642     continue
 643   fi
 644 done
 645 __RUNTIME_PACKAGE_VERSION="#define __SILC_RUNTIME_VERSION SILC_VERSION($maj,$min,$bld)"
 646
 647
 648 ##
 649 ##  Enable/disable checking
 650 ##
 651
 652 # IPv6 support
 653 AC_MSG_CHECKING(whether to enable IPv6 support)
 654 AC_ARG_ENABLE(ipv6,
 655   [  --enable-ipv6           enable IPv6 support],
 656   [
 657     case "${enableval}" in
 658       yes)
 659         want_ipv6=true
 660         check_ipv6=false
 661         summary_ipv6="yes"
 662         AC_DEFINE([HAVE_IPV6], [], [HAVE_IPV6])
 663         AC_MSG_RESULT(yes)
 664         ;;
 665       *)
 666         want_ipv6=false
 667         check_ipv6=false
 668         summary_ipv6="no"
 669         AC_MSG_RESULT(no)
 670         ;;
 671     esac
 672   ],
 673     check_ipv6=true
 674   )
 675
 676 if test x$check_ipv6 = xtrue; then
 677   summary_ipv6="no"
 678   AC_TRY_COMPILE(
 679     [
 680       #ifdef HAVE_SYS_TYPES_H
 681       #include <sys/types.h>
 682       #endif
 683       #ifdef HAVE_NETINET_TCP_H
 684       #include <netinet/tcp.h>
 685       #endif
 686       #ifdef HAVE_NETDB_H
 687       #include <netdb.h>
 688       #endif
 689       #include <sys/socket.h>
 690       #ifdef HAVE_NETINET_IN_H
 691       #include <netinet/in.h>
 692       #endif
 693     ],
 694     [
 695       struct sockaddr_in6 sin6;
 696       int family = AF_INET6;
 697     ],
 698     [
 699       AC_DEFINE([HAVE_IPV6], [], [HAVE_IPV6])
 700       AC_MSG_RESULT(yes)
 701       summary_ipv6="yes"
 702     ],
 703       AC_MSG_RESULT(no)
 704     )
 705 fi
 706
 707 # Memory alignment.  User can specify what alignment memory allocation and
 708 # SilcStack allocation use.  Default is system default alignemnt.
 709 AC_ARG_WITH(alignment,
 710   [  --with-alignment=NUMBER Memory alignment in bytes],
 711   [
 712     AC_DEFINE_UNQUOTED([SILC_ALIGNMENT], [$withval], [SILC_ALIGNMENT])
 713     AC_MSG_RESULT(Memory allocation alignment is $withval bytes)
 714   ],
 715   [
 716     AC_DEFINE([SILC_ALIGNMENT], SILC_SIZEOF_VOID_P, [SILC_ALIGNMENT])
 717   ])
 718
 719 # Stack trace checking
 720 AC_MSG_CHECKING(whether to enable stack tracing)
 721 AC_ARG_ENABLE(stack-trace,
 722   [  --enable-stack-trace    enable memory stack trace],
 723   [
 724     case "${enableval}" in
 725     yes)
 726       AC_MSG_RESULT(yes)
 727       AC_DEFINE([SILC_STACKTRACE], [], [SILC_STACKTRACE])
 728       ;;
 729     *)
 730       AC_MSG_RESULT(no)
 731       ;;
 732     esac
 733   ],
 734     AC_MSG_RESULT(no)
 735   )
 736
 737 #ifdef SILC_DIST_INPLACE
 738 #
 739 # Profiling options (never delivered to distributions)
 740 #
 741 AC_MSG_CHECKING(whether to enable gprof)
 742 AC_ARG_ENABLE(gprof,
 743   [  --enable-gprof          enable gprof profiling],
 744   [
 745     case "${enableval}" in
 746       yes)
 747         AC_MSG_RESULT(yes)
 748         SILC_ADD_CFLAGS(-pg)
 749         LIBS="$LIBS -pg"
 750         ;;
 751       *)
 752         AC_MSG_RESULT(no)
 753         ;;
 754     esac
 755   ],
 756   [
 757     AC_MSG_RESULT(no)
 758   ])
 759
 760 AC_MSG_CHECKING(whether to enable gcov)
 761 AC_ARG_ENABLE(gcov,
 762   [  --enable-gcov           enable gcov],
 763   [
 764     case "${enableval}" in
 765       yes)
 766         AC_MSG_RESULT(yes)
 767         SILC_ADD_CFLAGS(-fprofile-arcs)
 768         LIBS="$LIBS -lgcov"
 769         ;;
 770       *)
 771         AC_MSG_RESULT(no)
 772         ;;
 773     esac
 774   ],
 775   [
 776     AC_MSG_RESULT(no)
 777   ])
 778 #endif SILC_DIST_INPLACE
 779
 780 # Debug checking
 781 AC_MSG_CHECKING(whether to enable debugging)
 782 summary_debug="no"
 783 __SILC_ENABLE_DEBUG=""
 784 AC_ARG_ENABLE(debug,
 785   [  --enable-debug          enable debugging],
 786   [
 787     case "${enableval}" in
 788       yes)
 789         AC_MSG_RESULT(yes)
 790         AC_DEFINE([SILC_DEBUG], [], [enable-debug])
 791         summary_debug="yes"
 792         __SILC_ENABLE_DEBUG="#define __SILC_ENABLE_DEBUG 1"
 793         ;;
 794       *)
 795         AC_MSG_RESULT(no)
 796         ;;
 797     esac
 798   ],
 799   [
 800     AC_MSG_RESULT(no)
 801   ])
 802
 803 # Disable all assembler optimizations
 804 AC_MSG_CHECKING(whether to enable assembler optimizations)
 805 AC_ARG_ENABLE(asm,
 806   [  --disable-asm           do not use assembler optimizations],
 807   [
 808     AC_MSG_RESULT(no)
 809     AC_DEFINE([SILC_NO_ASM], [], [SILC_NO_ASM])
 810     want_asm=false
 811   ],
 812   [
 813     AC_MSG_RESULT(yes)
 814     want_asm=true
 815   ])
 816 AM_CONDITIONAL(SILC_NO_ASM, test x$want_asm = xfalse)
 817
 818 # Check for assembler
 819 SILC_ASSEMBLER=""
 820 have_assembler=false
 821 if test x$want_asm = xtrue; then
 822   AC_PATH_PROG([NASM], [nasm], [no])
 823   if test "x$NASM" != "xno"; then
 824     if test x$cpu_x86_64 = xtrue; then
 825       SILC_ASSEMBLER="$NASM -O2 -felf64"
 826     else
 827       SILC_ASSEMBLER="$NASM -O2 -felf"
 828     fi
 829     have_assembler=true
 830   fi
 831
 832   AC_PATH_PROG([YASM], [yasm], [no])
 833   if test "x$YASM" != "xno"; then
 834     if test x$cpu_x86_64 = xtrue; then
 835       SILC_ASSEMBLER="$YASM -Xgnu -felf64"
 836     else
 837       SILC_ASSEMBLER="$YASM -Xgnu -felf"
 838     fi
 839     have_assembler=true
 840   fi
 841 fi
 842 AC_SUBST(SILC_ASSEMBLER)
 843
 844
 845 ##
 846 ##  With/without checkings
 847 ##
 848
 849 LIBSUBDIR=lib
 850 LDFLAGS="-L\$(silc_top_srcdir)/lib $LDFLAGS"
 851
 852 SILC_LIB_INCLUDES="$SILC_LIB_INCLUDES -I$SILC_TOP_SRCDIR/lib/contrib"
 853 SILC_LIB_INCLUDES="$SILC_LIB_INCLUDES -I$SILC_TOP_SRCDIR/lib/silcutil"
 854
 855
 856 # Check for iconv support
 857 check_iconv=true
 858 has_iconv=false
 859 SAVE_LIBS="$LIBS"
 860 SAVE_CFLAGS="$CFLAGS"
 861 SAVE_LDFLAGS="$LDFLAGS"
 862 SAVE_CPPFLAGS="$CPPFLAGS"
 863 AC_MSG_CHECKING(whether to implicit search for libiconv)
 864 AC_ARG_WITH(iconv,
 865   [[  --with-iconv[=DIR]      use libiconv [search in DIR/include and DIR/lib]]],
 866   [
 867     case "${withval}" in
 868       no)
 869         AC_MSG_RESULT(no)
 870         AC_CHECK_HEADERS(iconv.h,
 871           [
 872             AC_CHECK_FUNC(iconv, has_iconv=true)
 873           ])
 874         check_iconv=false
 875         ;;
 876       *)
 877         AC_MSG_RESULT(yes)
 878         if test -d $withval/include; then
 879           CPPFLAGS="$CPPFLAGS -I$withval/include"
 880           CFLAGS="$CFLAGS -I$withval/include"
 881         fi
 882         if test -d $withval/lib; then
 883           LDFLAGS="$LDFLAGS -L$withval/lib"
 884         fi
 885         ;;
 886     esac
 887   ],
 888   [
 889     AC_MSG_RESULT(no)
 890     AC_CHECK_HEADERS(iconv.h,
 891       [
 892         AC_CHECK_FUNCS(iconv,
 893           [
 894             has_iconv=true
 895             check_iconv=false
 896           ])
 897       ])
 898   ])
 899
 900 if test x$check_iconv = xtrue; then
 901   AC_MSG_RESULT(Searching for iconv...)
 902
 903   # XXX
 904   unset ac_cv_header__iconv_h_ ac_cv_header_iconv_h || true
 905
 906   AC_CHECK_HEADERS(iconv.h,
 907     [
 908       LIBS="$LIBS -liconv"
 909       AC_MSG_CHECKING(for iconv in -liconv)
 910       AC_TRY_LINK(
 911         [
 912           #include <stdlib.h>
 913           #include <iconv.h>
 914         ],
 915         [
 916           iconv_t cd = iconv_open("", "");
 917           iconv(cd, NULL, NULL, NULL, NULL);
 918           iconv_close(cd);
 919         ],
 920         [
 921           echo "yes"
 922           AC_DEFINE([HAVE_ICONV], [], [Define if you have the iconv() function.])
 923           has_iconv=true
 924           check_iconv=false
 925         ],
 926         [
 927           echo "no"
 928           LIBS="$SAVE_LIBS"
 929           CFLAGS="$SAVE_CFLAGS"
 930           LDFLAGS="$SAVE_LDFLAGS"
 931           CPPFLAGS="$SAVE_CPPFLAGS"
 932         ])
 933      ])
 934 fi
 935
 936 if test x$check_iconv = xtrue; then
 937   # search for iconv library..
 938   SAVE_LIBS="$LIBS"
 939   SAVE_CFLAGS="$CFLAGS"
 940   SAVE_LDFLAGS="$LDFLAGS"
 941   SAVE_CPPFLAGS="$CPPFLAGS"
 942
 943   for dir in `echo "/usr/local /usr/pkg /usr/contrib"`; do
 944     if test x$has_iconv = xfalse; then
 945       AC_MSG_RESULT(searching in $dir...)
 946
 947       if test -d $dir/include; then
 948         CPPFLAGS="$CPPFLAGS -I$dir/include"
 949         CFLAGS="$CFLAGS -I$dir/include"
 950       fi
 951       if test -d $dir/lib; then
 952         LDFLAGS="$LDFLAGS -L$dir/lib"
 953       fi
 954
 955       # XXX
 956       unset ac_cv_header__iconv_h_ ac_cv_header_iconv_h || true
 957
 958       AC_CHECK_HEADERS(iconv.h,
 959         [
 960           LIBS="$LIBS -liconv"
 961           AC_MSG_CHECKING(for iconv in -liconv)
 962           AC_TRY_LINK(
 963             [
 964               #include <stdlib.h>
 965               #include <iconv.h>
 966             ],
 967             [
 968               iconv_t cd = iconv_open("", "");
 969               iconv(cd, NULL, NULL, NULL, NULL);
 970               iconv_close(cd);
 971             ],
 972             [
 973               echo "yes"
 974               has_iconv=true
 975               AC_DEFINE([HAVE_ICONV], [], [Define if you have the iconv() function.])
 976             ],
 977             [
 978               echo "no"
 979               has_iconv=false
 980
 981               LIBS="$SAVE_LIBS"
 982               CFLAGS="$SAVE_CFLAGS"
 983               LDFLAGS="$SAVE_LDFLAGS"
 984               CPPFLAGS="$SAVE_CPPFLAGS"
 985             ])
 986          ],
 987          [
 988            CFLAGS="$SAVE_CFLAGS"
 989            LDFLAGS="$SAVE_LDFLAGS"
 990            CPPFLAGS="$SAVE_CPPFLAGS"
 991          ])
 992       fi
 993     done
 994 fi
 995
 996 if test x$has_iconv = xtrue; then
 997   # (1) Some implementations of iconv won't convert from UTF-8 to UTF-8.
 998   # (2) In glibc-2.1.2 and earlier there is a bug that messes up ob and
 999   #     obl when args 2 and 3 are 0 (fixed in glibc-2.1.3).
1000   #
1001   AC_CACHE_CHECK([whether this iconv is good enough], ac_iconv_good,
1002     AC_TRY_RUN(
1003       [
1004         #include <iconv.h>
1005         int main() {
1006           iconv_t cd;
1007         changequote(, )dnl
1008           char buf[4];
1009         changequote([, ])dnl
1010           char *ob;
1011           size_t obl;
1012           ob = buf, obl = sizeof(buf);
1013           return ((cd = iconv_open("UTF-8", "UTF-8")) != (iconv_t)(-1) &&
1014                  (iconv(cd, 0, 0, &ob, &obl) ||
1015                  !(ob == buf && obl == sizeof(buf)) ||
1016                  iconv_close(cd)));
1017         }
1018       ],
1019       [
1020         ac_iconv_good=yes
1021       ],
1022       [
1023         ac_iconv_good=no
1024       ],
1025       [
1026         ac_iconv_good=yes
1027       ])
1028     )
1029
1030   if test x$ac_iconv_good = xno; then
1031     AC_MSG_RESULT(Try using libiconv instead.)
1032   fi
1033 fi
1034
1035 # Check for POSIX threads support
1036 AC_MSG_CHECKING(whether to search for POSIX threads)
1037 AC_ARG_WITH(pthreads,
1038   [[  --with-pthreads[=DIR]   use POSIX threads [search in DIR/include and DIR/lib]]],
1039   [
1040     case "${withval}" in
1041       no)
1042         check_threads=false
1043         ;;
1044       *)
1045         if test -d $withval/include; then
1046           CPPFLAGS="$CPPFLAGS -I$withval/include"
1047           CFLAGS="$CFLAGS -I$withval/include"
1048         fi
1049         if test -d $withval/lib; then
1050           LDFLAGS="$LDFLAGS -L$withval/lib"
1051         fi
1052
1053         check_threads=true
1054         ;;
1055     esac
1056   ])
1057
1058 if test x$check_threads = xtrue; then
1059   has_threads=false
1060   SAVE_LIBS="$LIBS"
1061   SAVE_CFLAGS="$CFLAGS"
1062   SAVE_LDFLAGS="$LDFLAGS"
1063   SAVE_CPPFLAGS="$CPPFLAGS"
1064
1065   AC_MSG_RESULT(yes)
1066   AC_CHECK_HEADERS(pthread.h,
1067     [
1068       LIBS="$LIBS -lpthread"
1069       AC_CHECK_LIB(pthread, pthread_attr_init, has_threads=true,
1070         [
1071           # FreeBSD
1072           case "${target}" in
1073             *-*-freebsd*)
1074               LIBS="$SAVE_LIBS -pthread"
1075               AC_CHECK_LIB(c_r, pthread_attr_init, has_threads=true, LIBS="$SAVE_LIBS")
1076               ;;
1077             *)
1078               LIBS="$SAVE_LIBS"
1079               ;;
1080           esac
1081         ])
1082     ],
1083     [
1084       # search for pthread library..
1085       for dir in `echo "/usr/local /usr/pkg /usr/contrib /usr/pkg/pthreads /usr/local/pthreads"`; do
1086         if test x$has_threads = xfalse; then
1087           AC_MSG_RESULT(searching in $dir...)
1088
1089           if test -d $dir/include; then
1090             CPPFLAGS="$CPPFLAGS -I$dir/include"
1091             CFLAGS="$CFLAGS -I$dir/include"
1092           fi
1093           if test -d $dir/lib; then
1094             LDFLAGS="$LDFLAGS -L$dir/lib"
1095           fi
1096
1097           # XXX
1098           unset ac_cv_header__pthread_h_ ac_cv_header_pthread_h || true
1099
1100           AC_CHECK_HEADERS(pthread.h,
1101             [
1102               LIBS="$LIBS -lpthread"
1103               AC_CHECK_LIB(pthread, pthread_attr_init, has_threads=true,
1104                 [
1105                   has_threads=false
1106
1107                   LIBS="$SAVE_LIBS"
1108                   CFLAGS="$SAVE_CFLAGS"
1109                   LDFLAGS="$SAVE_LDFLAGS"
1110                   CPPFLAGS="$SAVE_CPPFLAGS"
1111                 ])
1112             ],
1113             [
1114               CFLAGS="$SAVE_CFLAGS"
1115               LDFLAGS="$SAVE_LDFLAGS"
1116               CPPFLAGS="$SAVE_CPPFLAGS"
1117             ])
1118         fi
1119       done
1120     ])
1121 else
1122   AC_MSG_RESULT(no)
1123   has_threads=false
1124 fi
1125
1126 __SILC_HAVE_PTHREAD=""
1127 AM_CONDITIONAL(SILC_THREADS, test x$has_threads = xtrue)
1128 if test x$has_threads = xtrue; then
1129   CFLAGS="$CFLAGS -D_REENTRANT"
1130
1131   # XXX possibly incomplete
1132   case "${target}" in
1133     *-*-aix*)
1134       CFLAGS="$CFLAGS -D_THREAD_SAFE"
1135       if test x"$GCC" = xyes; then
1136         CFLAGS="$CFLAGS -mthreads"
1137       fi
1138       ;;
1139     *-*-freebsd*)
1140       CFLAGS="$CFLAGS -D_THREAD_SAFE"
1141       ;;
1142     *-*-sysv5uw7*)  # UnixWare 7
1143       if test "$GCC" != "yes"; then
1144         CFLAGS="$CFLAGS -Kthread"
1145       else
1146         CFLAGS="$CFLAGS -pthread"
1147       fi
1148       ;;
1149     *-dg-dgux*)  # DG/UX
1150       CFLAGS="$CFLAGS -D_POSIX4A_DRAFT10_SOURCE"
1151       ;;
1152    esac
1153
1154   # Check for threads
1155   AC_CHECK_FUNCS(pthread_create pthread_key_create pthread_once)
1156
1157   # Check for read/write locks
1158   AC_CHECK_FUNC(pthread_rwlock_init,
1159   [
1160     AC_RUN_IFELSE(
1161       [
1162         #include <pthread.h>
1163         int main()
1164         {
1165           pthread_rwlock_t rwlock;
1166           pthread_rwlock_init(&rwlock, NULL);
1167           pthread_rwlock_destroy(&rwlock);
1168           return 0;
1169         }
1170       ],
1171       [],
1172       [
1173         # Rwlock not defined
1174         CFLAGS="$CFLAGS -D_XOPEN_SOURCE=600"
1175       ]
1176     )
1177   ],
1178   [
1179     # Rwlock not defined
1180     CFLAGS="$CFLAGS -D_XOPEN_SOURCE=600"
1181   ])
1182
1183   AC_DEFINE([SILC_HAVE_PTHREAD], [], [HAVE_PTHREAD])
1184   AC_DEFINE([SILC_THREADS], [], [HAVE_THREAD])
1185   __SILC_HAVE_PTHREAD="#define __SILC_HAVE_PTHREAD 1"
1186 fi
1187
1188
1189 ##
1190 ## Outputs and substitutions
1191 ##
1192
1193 AC_SUBST(LIBSUBDIR)
1194 AC_SUBST(SILC_TOP_SRCDIR)
1195 AC_SUBST(LDFLAGS)
1196 AC_SUBST(LIBS)
1197 AC_SUBST(SILC_LIB_INCLUDES)
1198 AC_SUBST(__SILC_ENABLE_DEBUG)
1199 AC_SUBST(__SILC_HAVE_PTHREAD)
1200 AC_SUBST(__RUNTIME_PACKAGE_VERSION)
1201
1202 # Native Windows support (disabled by default)
1203 AM_CONDITIONAL(SILC_WIN32, test xfalse = xtrue)
1204
1205 # Native Symbian OS support (disabled by default)
1206 AM_CONDITIONAL(SILC_SYMBIAN, test xfalse = xtrue)
1207
1208 # Make enable-shared aware
1209 AM_CONDITIONAL(SILC_ENABLE_SHARED, test "$enable_shared" = yes)
1210
1211 ETCDIR=`eval echo $sysconfdir`;ETCDIR=`eval echo $ETCDIR`
1212 AC_SUBST(ETCDIR)
1213 AC_DEFINE_UNQUOTED([SILC_ETCDIR], "$ETCDIR", [SILC_ETCDIR])
1214
1215 DOCDIR=`eval echo $docdir`;DOCDIR=`eval echo $DOCDIR`
1216 AC_SUBST(DOCDIR)
1217 AC_DEFINE_UNQUOTED([SILC_DOCDIR], "$DOCDIR", [SILC_DOCDIR])
1218
1219 INCLUDE_DEFINES_INT="include \$(top_srcdir)/Makefile.defines_int"
1220 AC_SUBST(INCLUDE_DEFINES_INT)
1221
1222
1223 #
1224 # Makefile outputs
1225 #
1226 AC_CONFIG_FILES(
1227 Makefile
1228 doc/Makefile
1229 Makefile.defines
1230 Makefile.defines_int
1231 includes/Makefile
1232 includes/silcversion.h
1233 includes/silc.h
1234 apps/Makefile
1235 win32/Makefile
1236 )
1237
1238 AC_CONFIG_FILES(
1239 lib/Makefile
1240 lib/contrib/Makefile
1241 lib/silcutil/silcruntime.h
1242 lib/silcutil/Makefile
1243 lib/silcutil/tests/Makefile
1244 lib/silcutil/unix/Makefile
1245 lib/silcutil/win32/Makefile
1246 lib/silcutil/symbian/Makefile
1247 lib/srt.pc
1248 )
1249
1250 AC_OUTPUT
1251
1252
1253 ##
1254 ## Summary output
1255 ##
1256
1257 s_bindir=`eval echo $bindir`;s_bindir=`eval echo $s_bindir`
1258 s_sbindir=`eval echo $sbindir`;s_sbindir=`eval echo $s_sbindir`
1259 s_mandir=`eval echo $mandir`;s_mandir=`eval echo $s_mandir`
1260 s_includedir=`eval echo $includedir`;s_includedir=`eval echo $s_includedir`
1261
1262 echo ""
1263 echo "SILC Runtime Toolkit configuration summary:"
1264 echo "------------------------------------------"
1265 echo " Target host ...................: $target"
1266 echo " Compiler ......................: $CC"
1267 echo " CFLAGS ........................: $CFLAGS"
1268 echo " LDFLAGS .......................: $LDFLAGS"
1269 echo " LIBS ..........................: $LIBS"
1270 echo ""
1271 echo " Installation prefix ...........: $prefix"
1272 echo " bin directory .................: $s_bindir"
1273 echo " sbin directory ................: $s_sbindir"
1274 echo " etc directory .................: $ETCDIR"
1275 echo " man directory .................: $s_mandir"
1276 echo " doc directory .................: $DOCDIR"
1277 echo " include directory .............: $s_includedir"
1278 echo ""
1279 echo " IPv6 support ..................: $summary_ipv6"
1280
1281 if test x$has_iconv = xfalse; then
1282   iconv_support="no"
1283 else
1284   iconv_support="yes"
1285 fi
1286 echo " Iconv support .................: $iconv_support"
1287
1288 if test x$want_asm = xfalse; then
1289   summary_asm="no"
1290 else
1291   summary_asm="yes"
1292 fi
1293 echo " Assembler optimizations .......: $summary_asm"
1294
1295 if test x$want_cc_optimizations = xfalse; then
1296   summary_cc_opt="no"
1297 else
1298   summary_cc_opt="yes"
1299 fi
1300 echo " Compiler optimizations ........: $summary_cc_opt"
1301
1302 if test x$want_cpu_optimizations = xfalse; then
1303   summary_cpu_opt="no"
1304 else
1305   summary_cpu_opt="yes"
1306 fi
1307 echo " CPU feature optimizations .....: $summary_cpu_opt"
1308
1309 threads="no"
1310 if test x$has_threads = xtrue; then
1311   threads="yes"
1312 fi
1313 echo " Multi-threads support .........: $threads"
1314 echo " Debugging enabled .............: $summary_debug"
1315 echo ""
1316 echo "Compile the sources with 'make' or 'gmake' command."