#
#  lib/configure.ad
#
#  Author: Pekka Riikonen <priikone@silcnet.org>
#
#  Copyright (C) 2005 Pekka Riikonen
#
#  This program is free software; you can redistribute it and/or modify
#  it under the terms of the GNU General Public License as published by
#  the Free Software Foundation; version 2 of the License.
#
#  This program is distributed in the hope that it will be useful,
#  but WITHOUT ANY WARRANTY; without even the implied warranty of
#  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
#  GNU General Public License for more details.
#

if test x$compile_libs = xfalse; then

##
## Not compiling included libs.
##

# Remove lib subdir from SUBDIRS
SILC_DIST_SUBDIRS=`echo $SILC_DIST_SUBDIRS | $sedpath -e 's/lib//'`

else	# compile_libs = true

##
## Will compile included libs
##
AC_MSG_NOTICE([Configuring SILC libraries])

# SILC Library directories
SILC_LIB_INCLUDES="$SILC_LIB_INCLUDES -I$SILC_TOP_SRCDIR/lib/silccore"
SILC_LIB_INCLUDES="$SILC_LIB_INCLUDES -I$SILC_TOP_SRCDIR/lib/silccrypt"
SILC_LIB_INCLUDES="$SILC_LIB_INCLUDES -I$SILC_TOP_SRCDIR/lib/silcmath"
SILC_LIB_INCLUDES="$SILC_LIB_INCLUDES -I$SILC_TOP_SRCDIR/lib/silcmath/mpi"
SILC_LIB_INCLUDES="$SILC_LIB_INCLUDES -I$SILC_TOP_SRCDIR/lib/silcske"
SILC_LIB_INCLUDES="$SILC_LIB_INCLUDES -I$SILC_TOP_SRCDIR/lib/silcsim"
SILC_LIB_INCLUDES="$SILC_LIB_INCLUDES -I$SILC_TOP_SRCDIR/lib/silcutil"
SILC_LIB_INCLUDES="$SILC_LIB_INCLUDES -I$SILC_TOP_SRCDIR/lib/silcsftp"
SILC_LIB_INCLUDES="$SILC_LIB_INCLUDES -I$SILC_TOP_SRCDIR/lib/silcclient"
SILC_LIB_INCLUDES="$SILC_LIB_INCLUDES -I$SILC_TOP_SRCDIR/lib/contrib"

##
## Library versioning.
##
# Do the releases and library versioning according to following rules:
#
#  - If any code has changed in library, increment [LIB]_REVISION
#  - If functions were added, set [LIB]_REVISION to 0
#  - If functions were added, removed or changed, increment [LIB]_CURRENT
#  - If functions were added, increment [LIB]_AGE
#  - If functions were removed, set [LIB]_AGE to 0
#
# where [LIB] is LIBSILC and LIBSILCCLIENT, and where "functions" means
# functions public interfaces.
#
# The LIB_BASE_VERSION defines the SILC software major.minor version and
# it is increment only when these version numbers actually change.
#

# Base version for libraries.  Do not change this unless SILC version
# changes too.
LIB_BASE_VERSION=1.0

# libsilc versions
LIBSILC_CURRENT=3
LIBSILC_REVISION=0
LIBSILC_AGE=2

# libsilcclient versions
LIBSILCCLIENT_CURRENT=3
LIBSILCCLIENT_REVISION=0
LIBSILCCLIENT_AGE=2

# Substitute the version numbers
AC_SUBST(LIB_BASE_VERSION)
AC_SUBST(LIBSILC_CURRENT)
AC_SUBST(LIBSILC_REVISION)
AC_SUBST(LIBSILC_AGE)
AC_SUBST(LIBSILCCLIENT_CURRENT)
AC_SUBST(LIBSILCCLIENT_REVISION)
AC_SUBST(LIBSILCCLIENT_AGE)

# Stack trace checking
#
AC_MSG_CHECKING(whether to enable stack tracing)
AC_ARG_ENABLE(stack-trace,
  [  --enable-stack-trace    enable memory stack trace],
  [
    case "${enableval}" in
    yes)
      AC_MSG_RESULT(yes)
      AC_DEFINE(SILC_STACKTRACE)
      ;;
    *)
      AC_MSG_RESULT(no)
      ;;
    esac
  ],
    AC_MSG_RESULT(no)
  )

#
# Makefile outputs
#
AC_CONFIG_FILES(
lib/Makefile
lib/contrib/Makefile
lib/silccore/Makefile
lib/silccore/tests/Makefile
lib/silccrypt/Makefile
lib/silccrypt/tests/Makefile
lib/silcsim/Makefile
lib/silcske/Makefile
lib/silcutil/Makefile
lib/silcutil/unix/Makefile
lib/silcutil/win32/Makefile
lib/silcutil/beos/Makefile
lib/silcutil/os2/Makefile
lib/silcutil/epoc/Makefile
lib/silcutil/tests/Makefile
lib/silcmath/Makefile
lib/silcsftp/Makefile
lib/silcsftp/tests/Makefile
)

if test "x$silc_dist" = "xsilc-client" ||
   test "x$silc_dist" = "xsilc-toolkit"; then
  AC_CONFIG_FILES(lib/silcclient/Makefile)
fi

fi	# compile_libs